+ push @{$limiter->{run_queue}}, [ $self, $start_cb ];
+ }
+}
+
+# Similar to `backtick` or "qx" ("perldoc -f qx"), it calls $qx_cb with
+# the stdout of the given command when done; but respects the given limiter
+# $env is the PSGI env. As with ``/qx; only use this when output is small
+# and safe to slurp.
+sub psgi_qx {
+ my ($self, $env, $limiter, $qx_cb) = @_;
+ my $scalar = '';
+ open(my $qx, '+>', \$scalar) or die; # PerlIO::scalar
+ my $end = sub {
+ my $err = $_[0]; # $!
+ log_err($env, "psgi_qx: $err") if defined($err);
+ finish($self, $env, sub { $qx_cb->(\$scalar) });
+ $qx = undef;
+ };
+ my $rpipe; # comes from popen_rd
+ my $async = $env->{'pi-httpd.async'};
+ my $cb = sub {
+ my ($r, $buf);
+reread:
+ $r = sysread($rpipe, $buf, 65536);
+ if ($async) {
+ $async->async_pass($env->{'psgix.io'}, $qx, \$buf);
+ } elsif (defined $r) {
+ $r ? $qx->write($buf) : $end->();
+ } else {
+ return if $! == EAGAIN; # try again when notified
+ goto reread if $! == EINTR;
+ $end->($!);
+ }
+ };
+ $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
+ $self->start($limiter, sub { # start_cb, may run later, much later...
+ ($rpipe) = @_; # popen_rd result
+ if ($async) {
+ # PublicInbox::HTTPD::Async->new($rpipe, $cb, $end)
+ $async = $async->($rpipe, $cb, $end);
+ # $cb will call ->async_pass or ->close
+ } else { # generic PSGI
+ $cb->() while $qx;
+ }
+ });
+}
+
+# create a filter for "push"-based streaming PSGI writes used by HTTPD::Async
+sub filter_fh ($$) {
+ my ($fh, $filter) = @_;
+ Plack::Util::inline_object(
+ close => sub {
+ $fh->write($filter->(undef));
+ $fh->close;
+ },
+ write => sub {
+ $fh->write($filter->($_[0]));
+ });
+}
+
+# Used for streaming the stdout of one process as a PSGI response.
+#
+# $env is the PSGI env.
+# optional keys in $env:
+# $env->{'qspawn.wcb'} - the write callback from the PSGI server
+# optional, use this if you've already
+# captured it elsewhere. If not given,
+# psgi_return will return an anonymous
+# sub for the PSGI server to call
+#
+# $env->{'qspawn.filter'} - filter callback, receives a string as input,
+# undef on EOF
+#
+# $limiter - the Limiter object to use (uses the def_limiter if not given)
+#
+# $parse_hdr - Initial read function; often for parsing CGI header output.
+# It will be given the return value of sysread from the pipe
+# and a string ref of the current buffer. Returns an arrayref
+# for PSGI responses. 2-element arrays in PSGI mean the
+# body will be streamed, later, via writes (push-based) to
+# psgix.io. 3-element arrays means the body is available
+# immediately (or streamed via ->getline (pull-based)).
+sub psgi_return {
+ my ($self, $env, $limiter, $parse_hdr) = @_;
+ my ($fh, $rpipe);
+ my $end = sub {
+ my $err = $_[0]; # $!
+ log_err($env, "psgi_return: $err") if defined($err);
+ finish($self, $env);
+ $fh->close if $fh; # async-only
+ };
+
+ my $buf = '';
+ my $rd_hdr = sub {
+ # typically used for reading CGI headers
+ # we must loop until EAGAIN for EPOLLET in HTTPD/Async.pm
+ # We also need to check EINTR for generic PSGI servers.
+ my $ret;
+ my $total_rd = 0;
+ do {
+ my $r = sysread($rpipe, $buf, 4096, length($buf));
+ if (defined($r)) {
+ $total_rd += $r;
+ $ret = $parse_hdr->($r ? $total_rd : 0, \$buf);
+ } else {
+ # caller should notify us when it's ready:
+ return if $! == EAGAIN;
+ next if $! == EINTR; # immediate retry
+ log_err($env, "error reading header: $!");
+ $ret = [ 500, [], [ "Internal error\n" ] ];
+ }
+ } until (defined $ret);
+ $ret;
+ };
+
+ my $wcb = delete $env->{'qspawn.wcb'}; # or PSGI server supplies it
+ my $async = $env->{'pi-httpd.async'};
+
+ my $cb = sub {
+ my $r = $rd_hdr->() or return;
+ $rd_hdr = undef; # done reading headers
+ my $filter = delete $env->{'qspawn.filter'};
+ if (scalar(@$r) == 3) { # error
+ if ($async) {
+ $async->close; # calls rpipe->close and $end
+ } else {
+ $rpipe->close;
+ $end->();
+ }
+ $wcb->($r);
+ } elsif ($async) {
+ # done reading headers, handoff to read body
+ $fh = $wcb->($r); # scalar @$r == 2
+ $fh = filter_fh($fh, $filter) if $filter;
+ $async->async_pass($env->{'psgix.io'}, $fh, \$buf);
+ } else { # for synchronous PSGI servers
+ require PublicInbox::GetlineBody;
+ $r->[2] = PublicInbox::GetlineBody->new($rpipe, $end,
+ $buf, $filter);
+ $wcb->($r);
+ }
+
+ # Workaround a leak under Perl 5.16.3 when combined with
+ # Plack::Middleware::Deflater:
+ $wcb = undef;
+ };
+ $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
+ my $start_cb = sub { # may run later, much later...
+ ($rpipe) = @_;
+ if ($async) {
+ # PublicInbox::HTTPD::Async->new($rpipe, $cb, $end)
+ $async = $async->($rpipe, $cb, $end);
+ # $cb will call ->async_pass or ->close
+ } else { # generic PSGI
+ $cb->() while $rd_hdr;
+ }
+ };
+
+ # the caller already captured the PSGI write callback from
+ # the PSGI server, so we can call ->start, here:
+ return $self->start($limiter, $start_cb) if $wcb;
+
+ # the caller will return this sub to the PSGI server, so
+ # it can set the response callback (that is, for PublicInbox::HTTP,
+ # the chunked_wcb or identity_wcb callback), but other HTTP servers
+ # are supported:
+ sub {
+ ($wcb) = @_;
+ $self->start($limiter, $start_cb);
+ };
+}
+
+package PublicInbox::Qspawn::Limiter;
+use strict;
+use warnings;
+
+sub new {
+ my ($class, $max) = @_;
+ bless {
+ # 32 is same as the git-daemon connection limit
+ max => $max || 32,
+ running => 0,
+ run_queue => [],
+ # RLIMIT_CPU => undef,
+ # RLIMIT_DATA => undef,
+ # RLIMIT_CORE => undef,
+ }, $class;
+}
+
+sub setup_rlimit {
+ my ($self, $name, $config) = @_;
+ foreach my $rlim (PublicInbox::Spawn::RLIMITS()) {
+ my $k = lc($rlim);
+ $k =~ tr/_//d;
+ $k = "publicinboxlimiter.$name.$k";
+ defined(my $v = $config->{$k}) or next;
+ my @rlimit = split(/\s*,\s*/, $v);
+ if (scalar(@rlimit) == 1) {
+ push @rlimit, $rlimit[0];
+ } elsif (scalar(@rlimit) != 2) {
+ warn "could not parse $k: $v\n";
+ }
+ eval { require BSD::Resource };
+ if ($@) {
+ warn "BSD::Resource missing for $rlim";
+ next;
+ }
+ foreach my $i (0..$#rlimit) {
+ next if $rlimit[$i] ne 'INFINITY';
+ $rlimit[$i] = BSD::Resource::RLIM_INFINITY();
+ }
+ $self->{$rlim} = \@rlimit;