1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
2 # License: GPLv2 or later <https://www.gnu.org/licenses/gpl-2.0.txt>
4 # Used to read files from a git repository without excessive forking.
5 # Used in our web interfaces as well as our -nntpd server.
6 # This is based on code in Git.pm which is GPLv2+, but modified to avoid
7 # dependence on environment variables for compatibility with mod_perl.
8 # There are also API changes to simplify our usage and data set.
9 package PublicInbox::Git;
12 use parent qw(Exporter);
14 use IO::Handle; # ->autoflush
16 use File::Glob qw(bsd_glob GLOB_NOSORT);
17 use Time::HiRes qw(stat);
18 use PublicInbox::Spawn qw(popen_rd);
19 use PublicInbox::Tmpfile;
21 our @EXPORT_OK = qw(git_unquote git_quote);
22 our $PIPE_BUFSIZ = 65536; # Linux default
25 use constant MAX_INFLIGHT =>
26 (($^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF()) * 3)
28 65; # SHA-256 hex size + "\n" in preparation for git using non-SHA1
41 my %ESC_GIT = map { $GIT_ESC{$_} => $_ } keys %GIT_ESC;
44 # unquote pathnames used by git, see quote.c::unquote_c_style.c in git.git
46 return $_[0] unless ($_[0] =~ /\A"(.*)"\z/);
48 $_[0] =~ s/\\([\\"abfnrtv])/$GIT_ESC{$1}/g;
49 $_[0] =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
54 if ($_[0] =~ s/([\\"\a\b\f\n\r\t\013]|[^[:print:]])/
55 '\\'.($ESC_GIT{$1}||sprintf("%0o",ord($1)))/egs) {
62 my ($class, $git_dir) = @_;
63 # may contain {-tmp} field for File::Temp::Dir
64 bless { git_dir => $git_dir, alt_st => '', -git_path => {} }, $class
68 my ($self, $path) = @_;
69 $self->{-git_path}->{$path} ||= do {
71 chomp(my $str = $self->qx(qw(rev-parse --git-path), $path));
73 # git prior to 2.5.0 did not understand --git-path
74 if ($str eq "--git-path\n$path") {
75 $str = "$self->{git_dir}/$path";
81 sub alternates_changed {
83 my $alt = git_path($self, 'objects/info/alternates');
84 my @st = stat($alt) or return 0;
86 # can't rely on 'q' on some 32-bit builds, but `d' works
87 my $st = pack('dd', $st[10], $st[7]); # 10: ctime, 7: size
88 return 0 if $self->{alt_st} eq $st;
89 $self->{alt_st} = $st; # always a true value
94 my $fh = $self->{err_c} or return;
95 sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
96 defined(sysread($fh, my $buf, -s $fh)) or
97 fail($self, "sysread failed: $!");
102 my ($self, $batch, $in, $out, $pid, $err) = @_;
104 if (defined $err) { # "err_c"
105 my $fh = $self->{$err};
106 sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
107 truncate($fh, 0) or fail($self, "truncate failed: $!");
112 pipe($out_r, $out_w) or fail($self, "pipe failed: $!");
113 my @cmd = (qw(git), "--git-dir=$self->{git_dir}",
114 qw(-c core.abbrev=40 cat-file), $batch);
115 my $redir = { 0 => $out_r };
117 my $id = "git.$self->{git_dir}$batch.err";
118 my $fh = tmpfile($id) or fail($self, "tmpfile($id): $!");
122 my ($in_r, $p) = popen_rd(\@cmd, undef, $redir);
124 $out_w->autoflush(1);
125 if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ
126 fcntl($out_w, 1031, 4096);
127 fcntl($in_r, 1031, 4096) if $batch eq '--batch-check';
129 $self->{$out} = $out_w;
130 $self->{$in} = $in_r;
134 my ($fh, $rbuf, $len) = @_;
135 my $left = $len - length($$rbuf);
138 $r = sysread($fh, $$rbuf, $PIPE_BUFSIZ, length($$rbuf));
142 next if (!defined($r) && $! == EINTR);
146 \substr($$rbuf, 0, $len, '');
149 sub my_readline ($$) {
150 my ($fh, $rbuf) = @_;
152 if ((my $n = index($$rbuf, "\n")) >= 0) {
153 return substr($$rbuf, 0, $n + 1, '');
155 my $r = sysread($fh, $$rbuf, $PIPE_BUFSIZ, length($$rbuf));
156 next if $r || (!defined($r) && $! == EINTR);
157 return defined($r) ? '' : undef; # EOF or error
161 sub cat_async_retry ($$$$$) {
162 my ($self, $inflight, $req, $cb, $arg) = @_;
164 # {inflight} may be non-existent, but if it isn't we delete it
165 # here to prevent cleanup() from waiting:
166 delete $self->{inflight};
169 $self->{inflight} = $inflight;
170 batch_prepare($self);
172 for (my $i = 0; $i < @$inflight; $i += 3) {
173 $buf .= "$inflight->[$i]\n";
175 print { $self->{out} } $buf or fail($self, "write error: $!");
176 unshift(@$inflight, \$req, $cb, $arg); # \$ref to indicate retried
178 cat_async_step($self, $inflight); # take one step
181 sub cat_async_step ($$) {
182 my ($self, $inflight) = @_;
183 die 'BUG: inflight empty or odd' if scalar(@$inflight) < 3;
184 my ($req, $cb, $arg) = splice(@$inflight, 0, 3);
185 my $rbuf = delete($self->{cat_rbuf}) // \(my $new = '');
186 my ($bref, $oid, $type, $size);
187 my $head = my_readline($self->{in}, $rbuf);
188 # ->fail may be called via Gcf2Client.pm
189 if ($head =~ /^([0-9a-f]{40,}) (\S+) ([0-9]+)$/) {
190 ($oid, $type, $size) = ($1, $2, $3 + 0);
191 $bref = my_read($self->{in}, $rbuf, $size + 1) or
192 $self->fail(defined($bref) ? 'read EOF' : "read: $!");
193 chop($$bref) eq "\n" or $self->fail('LF missing after blob');
194 } elsif ($head =~ s/ missing\n//s) {
196 # ref($req) indicates it's already been retried
197 # -gcf2 retries internally, so it never hits this path:
198 if (!ref($req) && !$in_cleanup && $self->alternates_changed) {
199 return cat_async_retry($self, $inflight,
203 $oid = ref($req) ? $$req : $req if $oid eq '';
205 $self->fail("Unexpected result from async git cat-file: $head");
207 $self->{cat_rbuf} = $rbuf if $$rbuf ne '';
208 eval { $cb->($bref, $oid, $type, $size, $arg) };
209 warn "E: $oid: $@\n" if $@;
212 sub cat_async_wait ($) {
214 my $inflight = $self->{inflight} or return;
215 while (scalar(@$inflight)) {
216 cat_async_step($self, $inflight);
220 sub batch_prepare ($) {
221 _bidi_pipe($_[0], qw(--batch in out pid));
225 my ($bref, undef, undef, $size, $result) = @_;
226 @$result = ($bref, $size);
230 my ($self, $oid, $sizeref) = @_;
232 cat_async($self, $oid, \&_cat_file_cb, $result);
233 cat_async_wait($self);
234 $$sizeref = $result->[1] if $sizeref;
238 sub check_async_step ($$) {
239 my ($self, $inflight_c) = @_;
240 die 'BUG: inflight empty or odd' if scalar(@$inflight_c) < 3;
241 my ($req, $cb, $arg) = splice(@$inflight_c, 0, 3);
242 my $rbuf = delete($self->{chk_rbuf}) // \(my $new = '');
243 chomp(my $line = my_readline($self->{in_c}, $rbuf));
244 my ($hex, $type, $size) = split(/ /, $line);
246 # Future versions of git.git may have type=ambiguous, but for now,
247 # we must handle 'dangling' below (and maybe some other oddball
249 # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
250 if ($hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop') {
251 my $ret = my_read($self->{in_c}, $rbuf, $type + 1);
252 fail($self, defined($ret) ? 'read EOF' : "read: $!") if !$ret;
254 $self->{chk_rbuf} = $rbuf if $$rbuf ne '';
255 eval { $cb->($hex, $type, $size, $arg, $self) };
256 warn "E: check($req) $@\n" if $@;
259 sub check_async_wait ($) {
261 my $inflight_c = $self->{inflight_c} or return;
262 while (scalar(@$inflight_c)) {
263 check_async_step($self, $inflight_c);
267 sub check_async_begin ($) {
269 cleanup($self) if alternates_changed($self);
270 _bidi_pipe($self, qw(--batch-check in_c out_c pid_c err_c));
271 die 'BUG: already in async check' if $self->{inflight_c};
272 $self->{inflight_c} = [];
275 sub check_async ($$$$) {
276 my ($self, $oid, $cb, $arg) = @_;
277 my $inflight_c = $self->{inflight_c} // check_async_begin($self);
278 while (scalar(@$inflight_c) >= MAX_INFLIGHT) {
279 check_async_step($self, $inflight_c);
281 print { $self->{out_c} } $oid, "\n" or fail($self, "write error: $!");
282 push(@$inflight_c, $oid, $cb, $arg);
285 sub _check_cb { # check_async callback
286 my ($hex, $type, $size, $result) = @_;
287 @$result = ($hex, $type, $size);
291 my ($self, $oid) = @_;
293 check_async($self, $oid, \&_check_cb, $result);
294 check_async_wait($self);
295 my ($hex, $type, $size) = @$result;
297 # Future versions of git.git may show 'ambiguous', but for now,
298 # we must handle 'dangling' below (and maybe some other oddball
300 # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
301 return if $type eq 'missing' || $type eq 'ambiguous';
302 return if $hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop';
303 ($hex, $type, $size);
307 my ($self, $rbuf, $in, $out, $pid, $err) = @_;
308 delete @$self{($rbuf, $in, $out)};
309 delete $self->{$err} if $err; # `err_c'
311 # GitAsyncCat::event_step may delete {pid}
312 my $p = delete $self->{$pid} or return;
314 # PublicInbox::DS may not be loaded
315 eval { PublicInbox::DS::dwaitpid($p, undef, undef) };
316 waitpid($p, 0) if $@; # wait synchronously if not in event loop
319 sub cat_async_abort ($) {
321 if (my $inflight = $self->{inflight}) {
323 my ($req, $cb, $arg) = splice(@$inflight, 0, 3);
324 $req =~ s/ .*//; # drop git_dir for Gcf2Client
325 eval { $cb->(undef, $req, undef, undef, $arg) };
326 warn "E: $req: $@ (in abort)\n" if $@;
328 delete $self->{cat_rbuf};
329 delete $self->{inflight};
335 my ($self, $msg) = @_;
336 cat_async_abort($self);
337 croak(ref($self) . ' ' . ($self->{git_dir} // '') . ": $msg");
341 my ($self, @cmd) = @_;
342 @cmd = ('git', "--git-dir=$self->{git_dir}", @cmd);
347 my ($self, @cmd) = @_;
348 my $fh = $self->popen(@cmd);
350 return <$fh> if wantarray;
355 # check_async and cat_async may trigger the other, so ensure they're
356 # both completely done by using this:
357 sub async_wait_all ($) {
359 while (scalar(@{$self->{inflight_c} // []}) ||
360 scalar(@{$self->{inflight} // []})) {
361 $self->check_async_wait;
362 $self->cat_async_wait;
366 # returns true if there are pending "git cat-file" processes
369 local $in_cleanup = 1;
370 delete $self->{async_cat};
371 async_wait_all($self);
372 delete $self->{inflight};
373 delete $self->{inflight_c};
374 _destroy($self, qw(cat_rbuf in out pid));
375 _destroy($self, qw(chk_rbuf in_c out_c pid_c err_c));
376 !!($self->{pid} || $self->{pid_c});
380 # assuming a well-maintained repo, this should be a somewhat
381 # accurate estimation of its size
382 # TODO: show this in the WWW UI as a hint to potential cloners
386 my $pack_dir = git_path($self, 'objects/pack');
387 foreach my $p (bsd_glob("$pack_dir/*.pack", GLOB_NOSORT)) {
393 sub DESTROY { cleanup(@_) }
398 # don't show full FS path, basename should be OK:
399 if ($self->{git_dir} =~ m!/([^/]+)(?:/\.git)?\z!) {
400 $ret = "/path/to/$1";
402 wantarray ? ($ret) : $ret;
405 sub host_prefix_url ($$) {
406 my ($env, $url) = @_;
407 return $url if index($url, '//') >= 0;
408 my $scheme = $env->{'psgi.url_scheme'};
409 my $host_port = $env->{HTTP_HOST} //
410 "$env->{SERVER_NAME}:$env->{SERVER_PORT}";
411 "$scheme://$host_port". ($env->{SCRIPT_NAME} || '/') . $url;
415 my ($self, $env) = @_;
416 if (my $urls = $self->{cgit_url}) {
417 return map { host_prefix_url($env, $_) } @$urls;
422 sub cat_async_begin {
424 cleanup($self) if $self->alternates_changed;
425 $self->batch_prepare;
426 die 'BUG: already in async' if $self->{inflight};
427 $self->{inflight} = [];
430 sub cat_async ($$$;$) {
431 my ($self, $oid, $cb, $arg) = @_;
432 my $inflight = $self->{inflight} // cat_async_begin($self);
433 while (scalar(@$inflight) >= MAX_INFLIGHT) {
434 cat_async_step($self, $inflight);
436 print { $self->{out} } $oid, "\n" or fail($self, "write error: $!");
437 push(@$inflight, $oid, $cb, $arg);
441 my ($self, $oid, $cb, $arg) = @_;
442 if (my $inflight = $self->{inflight}) {
443 # we could use MAX_INFLIGHT here w/o the halving,
444 # but lets not allow one client to monopolize a git process
445 if (scalar(@$inflight) < int(MAX_INFLIGHT/2)) {
446 print { $self->{out} } $oid, "\n" or
447 fail($self, "write error: $!");
448 return push(@$inflight, $oid, $cb, $arg);
454 sub extract_cmt_time {
455 my ($bref, undef, undef, undef, $modified) = @_;
457 if ($$bref =~ /^committer .*?> ([0-9]+) [\+\-]?[0-9]+/sm) {
458 my $cmt_time = $1 + 0;
459 $$modified = $cmt_time if $cmt_time > $$modified;
463 # returns the modified time of a git repo, same as the "modified" field
464 # of a grokmirror manifest
468 my $fh = popen($self, qw(rev-parse --branches));
470 while (my $oid = <$fh>) {
472 cat_async($self, $oid, \&extract_cmt_time, \$modified);
474 cat_async_wait($self);
484 PublicInbox::Git - git wrapper
492 use PublicInbox::Git;
493 chomp(my $git_dir = `git rev-parse --git-dir`);
494 $git_dir or die "GIT_DIR= must be specified\n";
495 my $git = PublicInbox::Git->new($git_dir);
499 Unstable API outside of the L</new> method.
500 It requires L<git(1)> to be installed.
508 my $git = PublicInbox::Git->new($git_dir);
510 Initialize a new PublicInbox::Git object for use with L<PublicInbox::Import>
511 This is the only public API method we support. Everything else
512 in this module is subject to change.
516 L<Git>, L<PublicInbox::Import>
520 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
522 The mail archives are hosted at L<https://public-inbox.org/meta/>
526 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
528 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>