lib/PublicInbox/LeiOverview.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # per-mitem/smsg iterators for search results
   5 # "ovv" => "Overview viewer"
   6 package PublicInbox::LeiOverview;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use POSIX qw(strftime);
  11 use Fcntl qw(F_GETFL O_APPEND);
  12 use File::Spec;
  13 use File::Temp ();
  14 use PublicInbox::MID qw($MID_EXTRACT);
  15 use PublicInbox::Address qw(pairs);
  16 use PublicInbox::Config;
  17 use PublicInbox::Search qw(get_pct);
  18 use PublicInbox::LeiDedupe;
  19 use PublicInbox::LeiToMail;
  20
  21 # cf. https://en.wikipedia.org/wiki/JSON_streaming
  22 my $JSONL = 'ldjson|ndjson|jsonl'; # 3 names for the same thing
  23
  24 sub _iso8601 ($) { strftime('%Y-%m-%dT%H:%M:%SZ', gmtime($_[0])) }
  25
  26 # we open this in the parent process before ->wq_do handoff
  27 sub ovv_out_lk_init ($) {
  28         my ($self) = @_;
  29         $self->{tmp_lk_id} = "$self.$$";
  30         my $tmp = File::Temp->new("lei-ovv.dst.$$.lock-XXXXXX",
  31                                         TMPDIR => 1, UNLINK => 0);
  32         $self->{lock_path} = $tmp->filename;
  33 }
  34
  35 sub ovv_out_lk_cancel ($) {
  36         my ($self) = @_;
  37         ($self->{tmp_lk_id}//'') eq "$self.$$" and
  38                 unlink(delete($self->{lock_path}));
  39 }
  40
  41 sub new {
  42         my ($class, $lei) = @_;
  43         my $opt = $lei->{opt};
  44         my $dst = $opt->{output} // '-';
  45         $dst = '/dev/stdout' if $dst eq '-';
  46
  47         my $fmt = $opt->{'format'};
  48         $fmt = lc($fmt) if defined $fmt;
  49         if ($dst =~ s/\A([a-z0-9]+)://is) { # e.g. Maildir:/home/user/Mail/
  50                 my $ofmt = lc $1;
  51                 $fmt //= $ofmt;
  52                 return $lei->fail(<<"") if $fmt ne $ofmt;
  53 --format=$fmt and --output=$ofmt conflict
  54
  55         }
  56         $fmt //= 'json' if $dst eq '/dev/stdout';
  57         $fmt //= 'maildir';
  58
  59         if (index($dst, '://') < 0) { # not a URL, so assume path
  60                  $dst = File::Spec->canonpath($dst);
  61         } # else URL
  62
  63         my $self = bless { fmt => $fmt, dst => $dst }, $class;
  64         $lei->{ovv} = $self;
  65         my $json;
  66         if ($fmt =~ /\A($JSONL|(?:concat)?json)\z/) {
  67                 $json = $self->{json} = ref(PublicInbox::Config->json);
  68         }
  69         my ($isatty, $seekable);
  70         if ($dst eq '/dev/stdout') {
  71                 $isatty = -t $lei->{1};
  72                 $lei->start_pager if $isatty;
  73                 $opt->{pretty} //= $isatty;
  74                 if (!$isatty && -f _) {
  75                         my $fl = fcntl($lei->{1}, F_GETFL, 0) //
  76                                 return $lei->fail("fcntl(stdout): $!");
  77                         ovv_out_lk_init($self) unless ($fl & O_APPEND);
  78                 } else {
  79                         ovv_out_lk_init($self);
  80                 }
  81         }
  82         if (!$json) {
  83                 # default to the cheapest sort since MUA usually resorts
  84                 $lei->{opt}->{'sort'} //= 'docid' if $dst ne '/dev/stdout';
  85                 $lei->{l2m} = PublicInbox::LeiToMail->new($lei);
  86         }
  87         $lei->{dedupe} //= PublicInbox::LeiDedupe->new($lei);
  88         $self;
  89 }
  90
  91 # called once by parent
  92 sub ovv_begin {
  93         my ($self, $lei) = @_;
  94         if ($self->{fmt} eq 'json') {
  95                 print { $lei->{1} } '[';
  96         } # TODO HTML/Atom/...
  97 }
  98
  99 # called once by parent (via PublicInbox::EOFpipe)
 100 sub ovv_end {
 101         my ($self, $lei) = @_;
 102         my $out = $lei->{1} or return;
 103         if ($self->{fmt} eq 'json') {
 104                 # JSON doesn't allow trailing commas, and preventing
 105                 # trailing commas is a PITA when parallelizing outputs
 106                 print $out "null]\n";
 107         } elsif ($self->{fmt} eq 'concatjson') {
 108                 print $out "\n";
 109         }
 110 }
 111
 112 sub ovv_atfork_child {
 113         my ($self) = @_;
 114         # reopen dedupe here
 115 }
 116
 117 # prepares an smsg for JSON
 118 sub _unbless_smsg {
 119         my ($smsg, $mitem) = @_;
 120
 121         delete @$smsg{qw(lines bytes num tid)};
 122         $smsg->{rt} = _iso8601(delete $smsg->{ts}); # JMAP receivedAt
 123         $smsg->{dt} = _iso8601(delete $smsg->{ds}); # JMAP UTCDate
 124         $smsg->{relevance} = get_pct($mitem) if $mitem;
 125
 126         if (my $r = delete $smsg->{references}) {
 127                 $smsg->{refs} = [
 128                                 map { "<$_>" } ($r =~ m/$MID_EXTRACT/go) ];
 129         }
 130         if (my $m = delete($smsg->{mid})) {
 131                 $smsg->{'m'} = "<$m>";
 132         }
 133         for my $f (qw(from to cc)) {
 134                 my $v = delete $smsg->{$f} or next;
 135                 $smsg->{substr($f, 0, 1)} = pairs($v);
 136         }
 137         $smsg->{'s'} = delete $smsg->{subject};
 138         # can we be bothered to parse From/To/Cc into arrays?
 139         scalar { %$smsg }; # unbless
 140 }
 141
 142 sub ovv_atexit_child {
 143         my ($self, $lei) = @_;
 144         if (my $l2m = delete $lei->{l2m}) {
 145                 # gracefully stop lei2mail processes after all
 146                 # ->write_mail work is complete
 147                 delete $l2m->{-wq_s1};
 148                 if (my $rd = delete $l2m->{each_smsg_done}) {
 149                         read($rd, my $buf, 1); # wait for EOF
 150                 }
 151         }
 152         # order matters, git->{-tmp}->DESTROY must not fire until
 153         # {each_smsg_done} hits EOF above
 154         if (my $git = delete $self->{git}) {
 155                 $git->async_wait_all;
 156         }
 157         if (my $bref = delete $lei->{ovv_buf}) {
 158                 my $out = $lei->{1} or return;
 159                 my $lk = $self->lock_for_scope;
 160                 print $out $$bref;
 161         }
 162 }
 163
 164 # JSON module ->pretty output wastes too much vertical white space,
 165 # this (IMHO) provides better use of screen real-estate while not
 166 # being excessively compact:
 167 sub _json_pretty {
 168         my ($json, $k, $v) = @_;
 169         if (ref $v eq 'ARRAY') {
 170                 if (@$v) {
 171                         my $sep = ",\n" . (' ' x (length($k) + 7));
 172                         if (ref($v->[0])) { # f/t/c
 173                                 $v = '[' . join($sep, map {
 174                                         my $pair = $json->encode($_);
 175                                         $pair =~ s/(null|"),"/$1, "/g;
 176                                         $pair;
 177                                 } @$v) . ']';
 178                         } else { # references
 179                                 $v = '[' . join($sep, map {
 180                                         substr($json->encode([$_]), 1, -1);
 181                                 } @$v) . ']';
 182                         }
 183                 } else {
 184                         $v = '[]';
 185                 }
 186         }
 187         qq{  "$k": }.$v;
 188 }
 189
 190 sub ovv_each_smsg_cb { # runs in wq worker usually
 191         my ($self, $lei, $ibxish) = @_;
 192         my $json;
 193         $lei->{1}->autoflush(1);
 194         if (my $pkg = $self->{json}) {
 195                 $json = $pkg->new;
 196                 $json->utf8->canonical;
 197                 $json->ascii(1) if $lei->{opt}->{ascii};
 198         }
 199         my $l2m = $lei->{l2m};
 200         if ($l2m && $l2m->{-wq_s1}) {
 201                 my ($lei_ipc, @io) = $lei->atfork_parent_wq($l2m);
 202                 # n.b. $io[0] = qry_status_wr, $io[1] = mbox|stdout,
 203                 # $io[4] becomes a notification pipe that triggers EOF
 204                 # in this wq worker when all outstanding ->write_mail
 205                 # calls are complete
 206                 die "BUG: \$io[4] $io[4] unexpected" if $io[4];
 207                 pipe($l2m->{each_smsg_done}, $io[4]) or die "pipe: $!";
 208                 fcntl($io[4], 1031, 4096) if $^O eq 'linux';
 209                 delete @$lei_ipc{qw(l2m opt mset_opt cmd)};
 210                 my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
 211                 $self->{git} = $git;
 212                 my $git_dir = $git->{git_dir};
 213                 sub {
 214                         my ($smsg, $mitem) = @_;
 215                         my $kw = []; # TODO get from mitem
 216                         $l2m->wq_do('write_mail', \@io, $git_dir,
 217                                         $smsg->{blob}, $lei_ipc, $kw)
 218                 }
 219         } elsif ($l2m) {
 220                 my $wcb = $l2m->write_cb($lei);
 221                 my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
 222                 $self->{git} = $git; # for ovv_atexit_child
 223                 my $g2m = $l2m->can('git_to_mail');
 224                 sub {
 225                         my ($smsg, $mitem) = @_;
 226                         my $kw = []; # TODO get from mitem
 227                         $git->cat_async($smsg->{blob}, $g2m, [ $wcb, $kw ]);
 228                 };
 229         } elsif ($self->{fmt} =~ /\A(concat)?json\z/ && $lei->{opt}->{pretty}) {
 230                 my $EOR = ($1//'') eq 'concat' ? "\n}" : "\n},";
 231                 $lei->{ovv_buf} = \(my $buf = '');
 232                 sub { # DIY prettiness :P
 233                         my ($smsg, $mitem) = @_;
 234                         $smsg = _unbless_smsg($smsg, $mitem);
 235                         $buf .= "{\n";
 236                         $buf .= join(",\n", map {
 237                                 my $v = $smsg->{$_};
 238                                 if (ref($v)) {
 239                                         _json_pretty($json, $_, $v);
 240                                 } else {
 241                                         $v = $json->encode([$v]);
 242                                         qq{  "$_": }.substr($v, 1, -1);
 243                                 }
 244                         } sort keys %$smsg);
 245                         $buf .= $EOR;
 246                         if (length($buf) > 65536) {
 247                                 my $lk = $self->lock_for_scope;
 248                                 print { $lei->{1} } $buf;
 249                                 $buf = '';
 250                         }
 251                 }
 252         } elsif ($json) {
 253                 my $ORS = $self->{fmt} eq 'json' ? ",\n" : "\n"; # JSONL
 254                 $lei->{ovv_buf} = \(my $buf = '');
 255                 sub {
 256                         my ($smsg, $mitem) = @_;
 257                         delete @$smsg{qw(tid num)};
 258                         $buf .= $json->encode(_unbless_smsg(@_)) . $ORS;
 259                         if (length($buf) > 65536) {
 260                                 my $lk = $self->lock_for_scope;
 261                                 print { $lei->{1} } $buf;
 262                                 $buf = '';
 263                         }
 264                 }
 265         } elsif ($self->{fmt} eq 'oid') {
 266                 sub {
 267                         my ($smsg, $mitem) = @_;
 268                 }
 269         } # else { ...
 270 }
 271
 272 no warnings 'once';
 273 *DESTROY = \&ovv_out_lk_cancel;
 274
 275 1;