lib/PublicInbox/SolverGit.pm

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "Solve" blobs which don't exist in git code repositories by
   5 # searching inboxes for post-image blobs.
   6
   7 # this emits a lot of debugging/tracing information which may be
   8 # publicly viewed over HTTP(S).  Be careful not to expose
   9 # local filesystem layouts in the process.
  10 package PublicInbox::SolverGit;
  11 use strict;
  12 use v5.10.1;
  13 use File::Temp 0.19 (); # 0.19 for ->newdir
  14 use Fcntl qw(SEEK_SET);
  15 use PublicInbox::Git qw(git_unquote git_quote);
  16 use PublicInbox::MsgIter qw(msg_part_text);
  17 use PublicInbox::Qspawn;
  18 use PublicInbox::Tmpfile;
  19 use PublicInbox::GitAsyncCat;
  20 use PublicInbox::Eml;
  21 use URI::Escape qw(uri_escape_utf8);
  22
  23 # POSIX requires _POSIX_ARG_MAX >= 4096, and xargs is required to
  24 # subtract 2048 bytes.  We also don't factor in environment variable
  25 # headroom into this.
  26 use POSIX qw(sysconf _SC_ARG_MAX);
  27 my $ARG_SIZE_MAX = (sysconf(_SC_ARG_MAX) || 4096) - 2048;
  28 my $OID_MIN = 7;
  29
  30 # By default, "git format-patch" generates filenames with a four-digit
  31 # prefix, so that means 9999 patch series are OK, right? :>
  32 # Maybe we can make this configurable, main concern is disk space overhead
  33 # for uncompressed patch fragments.  Aside from space, public-inbox-httpd
  34 # is otherwise unaffected by having many patches, here, as it can share
  35 # work fairly.  Other PSGI servers may have trouble, though.
  36 my $MAX_PATCH = 9999;
  37
  38 my $LF = qr!\r?\n!;
  39 my $ANY = qr![^\r\n]+!;
  40 my $MODE = '100644|120000|100755';
  41 my $FN = qr!(?:("?[^/\n]+/[^\r\n]+)|/dev/null)!;
  42 my %BAD_COMPONENT = ('' => 1, '.' => 1, '..' => 1);
  43
  44 # di = diff info / a hashref with information about a diff ($di):
  45 # {
  46 #       oid_a => abbreviated pre-image oid,
  47 #       oid_b => abbreviated post-image oid,
  48 #       tmp => anonymous file handle with the diff,
  49 #       hdr_lines => string of various header lines for mode information
  50 #       mode_a => original mode of oid_a (string, not integer),
  51 #       ibx => PublicInbox::Inbox object containing the diff
  52 #       smsg => PublicInbox::Smsg object containing diff
  53 #       path_a => pre-image path
  54 #       path_b => post-image path
  55 #       n => numeric path of the patch (relative to worktree)
  56 # }
  57
  58 sub dbg ($$) {
  59         print { $_[0]->{out} } $_[1], "\n" or ERR($_[0], "print(dbg): $!");
  60 }
  61
  62 sub done ($$) {
  63         my ($self, $res) = @_;
  64         my $ucb = delete($self->{user_cb}) or return;
  65         $ucb->($res, $self->{uarg});
  66 }
  67
  68 sub ERR ($$) {
  69         my ($self, $err) = @_;
  70         print { $self->{out} } $err, "\n";
  71         eval { done($self, $err) };
  72         die $err;
  73 }
  74
  75 # look for existing objects already in git repos, returns arrayref
  76 # if found, number of remaining git coderepos to try if not.
  77 sub solve_existing ($$) {
  78         my ($self, $want) = @_;
  79         my $try = $want->{try_gits} //= [ @{$self->{gits}} ]; # array copy
  80         my $git = shift @$try or die 'BUG {try_gits} empty';
  81         my $oid_b = $want->{oid_b};
  82         my ($oid_full, $type, $size) = $git->check($oid_b);
  83
  84         # other than {oid_b, try_gits, try_ibxs}
  85         my $have_hints = scalar keys %$want > 3;
  86         if (defined($type) && (!$have_hints || $type eq 'blob')) {
  87                 delete $want->{try_gits};
  88                 return [ $git, $oid_full, $type, int($size) ]; # done, success
  89         }
  90
  91         # TODO: deal with 40-char "abbreviations" with future SHA-256 git
  92         return scalar(@$try) if length($oid_b) >= 40;
  93
  94         # parse stderr of "git cat-file --batch-check"
  95         my $err = $git->last_check_err;
  96         my (@oids) = ($err =~ /\b([a-f0-9]{40,})\s+blob\b/g);
  97         return scalar(@$try) unless scalar(@oids);
  98
  99         # TODO: do something with the ambiguous array?
 100         # push @ambiguous, [ $git, @oids ];
 101
 102         dbg($self, "`$oid_b' ambiguous in " .
 103                         join("\n\t", $git->pub_urls($self->{psgi_env}))
 104                         . "\n" .
 105                         join('', map { "$_ blob\n" } @oids));
 106         scalar(@$try);
 107 }
 108
 109 sub extract_diff ($$) {
 110         my ($p, $arg) = @_;
 111         my ($self, $want, $smsg) = @$arg;
 112         my ($part) = @$p; # ignore $depth and @idx;
 113         my $ct = $part->content_type || 'text/plain';
 114         my ($s, undef) = msg_part_text($part, $ct);
 115         defined $s or return;
 116         my $post = $want->{oid_b};
 117         my $pre = $want->{oid_a};
 118         if (!defined($pre) || $pre !~ /\A[a-f0-9]+\z/) {
 119                 $pre = '[a-f0-9]{7}'; # for RE below
 120         }
 121
 122         # Email::MIME::Encodings forces QP to be CRLF upon decoding,
 123         # change it back to LF:
 124         my $cte = $part->header('Content-Transfer-Encoding') || '';
 125         if ($cte =~ /\bquoted-printable\b/i && $part->crlf eq "\n") {
 126                 $s =~ s/\r\n/\n/sg;
 127         }
 128
 129
 130         $s =~ m!( # $1 start header lines we save for debugging:
 131
 132                 # everything before ^index is optional, but we don't
 133                 # want to match ^(old|copy|rename|deleted|...) unless
 134                 # we match /^diff --git/ first:
 135                 (?: # begin optional stuff:
 136
 137                 # try to get the pre-and-post filenames as $2 and $3
 138                 (?:^diff\x20--git\x20$FN\x20$FN$LF)
 139
 140                 (?:^(?: # pass all this to git-apply:
 141                         # old mode $4
 142                         (?:old\x20mode\x20($MODE))
 143                         |
 144                         # new mode (possibly new file) ($5)
 145                         (?:new\x20(?:file\x20)?mode\x20($MODE))
 146                         |
 147                         (?:(?:copy|rename|deleted|
 148                                 dissimilarity|similarity)$ANY)
 149                 )$LF)*
 150
 151                 )? # end of optional stuff, everything below is required
 152
 153                 # match the pre and post-image OIDs as $6 $7
 154                 ^index\x20(${pre}[a-f0-9]*)\.\.(${post}[a-f0-9]*)
 155                         # mode if unchanged $8
 156                         (?:\x20(100644|120000|100755))?$LF
 157         ) # end of header lines ($1)
 158         ( # $9 is the patch body
 159                 # "--- a/foo.c" sets pre-filename ($10) in case
 160                 # $2 is missing
 161                 (?:^---\x20$FN$LF)
 162
 163                 # "+++ b/foo.c" sets post-filename ($11) in case
 164                 # $3 is missing
 165                 (?:^\+{3}\x20$FN$LF)
 166
 167                 # the meat of the diff, including "^\\No newline ..."
 168                 # We also allow for totally blank lines w/o leading spaces,
 169                 # because git-apply(1) handles that case, too
 170                 (?:^(?:[\@\+\x20\-\\][^\n]*|)$LF)+
 171         )!smx or return;
 172
 173         my $di = {
 174                 hdr_lines => $1,
 175                 oid_a => $6,
 176                 oid_b => $7,
 177                 mode_a => $5 // $8 // $4, # new (file) // unchanged // old
 178         };
 179         my $path_a = $2 // $10;
 180         my $path_b = $3 // $11;
 181         my $patch = $9;
 182
 183         # don't care for leading 'a/' and 'b/'
 184         my (undef, @a) = split(m{/}, git_unquote($path_a)) if defined($path_a);
 185         my (undef, @b) = split(m{/}, git_unquote($path_b));
 186
 187         # get rid of path-traversal attempts and junk patches:
 188         # it's junk at best, an attack attempt at worse:
 189         foreach (@a, @b) { return if $BAD_COMPONENT{$_} }
 190
 191         $di->{path_a} = join('/', @a) if @a;
 192         $di->{path_b} = join('/', @b);
 193
 194         my $path = ++$self->{tot};
 195         $di->{n} = $path;
 196         open(my $tmp, '>:utf8', $self->{tmp}->dirname . "/$path") or
 197                 die "open(tmp): $!";
 198         print $tmp $di->{hdr_lines}, $patch or die "print(tmp): $!";
 199         close $tmp or die "close(tmp): $!";
 200
 201         # for debugging/diagnostics:
 202         $di->{ibx} = $want->{cur_ibx};
 203         $di->{smsg} = $smsg;
 204
 205         push @{$self->{tmp_diffs}}, $di;
 206 }
 207
 208 sub path_searchable ($) { defined($_[0]) && $_[0] =~ m!\A[\w/\. \-]+\z! }
 209
 210 # ".." appears in path names, which confuses Xapian into treating
 211 # it as a range query.  So we split on ".." since Xapian breaks
 212 # on punctuation anyways:
 213 sub filename_query ($) {
 214         join('', map { qq( dfn:"$_") } split(/\.\./, $_[0]));
 215 }
 216
 217 sub find_smsgs ($$$) {
 218         my ($self, $ibx, $want) = @_;
 219         my $srch = $ibx->search or return;
 220
 221         my $post = $want->{oid_b} or die 'BUG: no {oid_b}';
 222         $post =~ /\A[a-f0-9]+\z/ or die "BUG: oid_b not hex: $post";
 223
 224         my $q = "dfpost:$post";
 225         my $pre = $want->{oid_a};
 226         if (defined $pre && $pre =~ /\A[a-f0-9]+\z/) {
 227                 $q .= " dfpre:$pre";
 228         }
 229
 230         my $path_b = $want->{path_b};
 231         if (path_searchable($path_b)) {
 232                 $q .= filename_query($path_b);
 233
 234                 my $path_a = $want->{path_a};
 235                 if (path_searchable($path_a) && $path_a ne $path_b) {
 236                         $q .= filename_query($path_a);
 237                 }
 238         }
 239         my $mset = $srch->mset($q, { relevance => 1 });
 240         $mset->size ? $srch->mset_to_smsg($ibx, $mset) : undef;
 241 }
 242
 243 sub update_index_result ($$) {
 244         my ($bref, $self) = @_;
 245         my ($qsp, $msg) = delete @$self{qw(-qsp -msg)};
 246         if (my $err = $qsp->{err}) {
 247                 ERR($self, "git update-index error: $err");
 248         }
 249         dbg($self, $msg);
 250         next_step($self); # onto do_git_apply
 251 }
 252
 253 sub prepare_index ($) {
 254         my ($self) = @_;
 255         my $patches = $self->{patches};
 256         $self->{nr} = 0;
 257
 258         my $di = $patches->[0] or die 'no patches';
 259         my $oid_a = $di->{oid_a} or die '{oid_a} unset';
 260         my $existing = $self->{found}->{$oid_a};
 261
 262         # no index creation for added files
 263         $oid_a =~ /\A0+\z/ and return next_step($self);
 264
 265         die "BUG: $oid_a not found" unless $existing;
 266
 267         my $oid_full = $existing->[1];
 268         my $path_a = $di->{path_a} or die "BUG: path_a missing for $oid_full";
 269         my $mode_a = $di->{mode_a} // '100644';
 270
 271         my $in = tmpfile("update-index.$oid_full") or die "tmpfile: $!";
 272         print $in "$mode_a $oid_full\t$path_a\0" or die "print: $!";
 273         $in->flush or die "flush: $!";
 274         sysseek($in, 0, SEEK_SET) or die "seek: $!";
 275
 276         dbg($self, 'preparing index');
 277         my $rdr = { 0 => $in };
 278         my $cmd = [ qw(git update-index -z --index-info) ];
 279         my $qsp = PublicInbox::Qspawn->new($cmd, $self->{git_env}, $rdr);
 280         $path_a = git_quote($path_a);
 281         $self->{-qsp} = $qsp;
 282         $self->{-msg} = "index prepared:\n$mode_a $oid_full\t$path_a";
 283         $qsp->psgi_qx($self->{psgi_env}, undef, \&update_index_result, $self);
 284 }
 285
 286 # pure Perl "git init"
 287 sub do_git_init ($) {
 288         my ($self) = @_;
 289         my $dir = $self->{tmp}->dirname;
 290         my $git_dir = "$dir/git";
 291
 292         foreach ('', qw(objects refs objects/info refs/heads)) {
 293                 mkdir("$git_dir/$_") or die "mkdir $_: $!";
 294         }
 295         open my $fh, '>', "$git_dir/config" or die "open git/config: $!";
 296         print $fh <<'EOF' or die "print git/config $!";
 297 [core]
 298         repositoryFormatVersion = 0
 299         filemode = true
 300         bare = false
 301         fsyncObjectfiles = false
 302         logAllRefUpdates = false
 303 EOF
 304         close $fh or die "close git/config: $!";
 305
 306         open $fh, '>', "$git_dir/HEAD" or die "open git/HEAD: $!";
 307         print $fh "ref: refs/heads/master\n" or die "print git/HEAD: $!";
 308         close $fh or die "close git/HEAD: $!";
 309
 310         my $f = 'objects/info/alternates';
 311         open $fh, '>', "$git_dir/$f" or die "open: $f: $!";
 312         foreach my $git (@{$self->{gits}}) {
 313                 print $fh $git->git_path('objects'),"\n" or die "print $f: $!";
 314         }
 315         close $fh or die "close: $f: $!";
 316         my $tmp_git = $self->{tmp_git} = PublicInbox::Git->new($git_dir);
 317         $tmp_git->{-tmp} = $self->{tmp};
 318         $self->{git_env} = {
 319                 GIT_DIR => $git_dir,
 320                 GIT_INDEX_FILE => "$git_dir/index",
 321         };
 322         prepare_index($self);
 323 }
 324
 325 sub do_finish ($) {
 326         my ($self) = @_;
 327         my ($found, $oid_want) = @$self{qw(found oid_want)};
 328         if (my $exists = $found->{$oid_want}) {
 329                 return done($self, $exists);
 330         }
 331
 332         # let git disambiguate if oid_want was too short,
 333         # but long enough to be unambiguous:
 334         my $tmp_git = $self->{tmp_git};
 335         if (my @res = $tmp_git->check($oid_want)) {
 336                 return done($self, $found->{$res[0]});
 337         }
 338         if (my $err = $tmp_git->last_check_err) {
 339                 dbg($self, $err);
 340         }
 341         done($self, undef);
 342 }
 343
 344 sub event_step ($) {
 345         my ($self) = @_;
 346         eval {
 347                 # step 1: resolve blobs to patches in the todo queue
 348                 if (my $want = pop @{$self->{todo}}) {
 349                         # this populates {patches} and {todo}
 350                         resolve_patch($self, $want);
 351
 352                 # step 2: then we instantiate a working tree once
 353                 # the todo queue is finally empty:
 354                 } elsif (!defined($self->{tmp_git})) {
 355                         do_git_init($self);
 356
 357                 # step 3: apply each patch in the stack
 358                 } elsif (scalar @{$self->{patches}}) {
 359                         do_git_apply($self);
 360
 361                 # step 4: execute the user-supplied callback with
 362                 # our result: (which may be undef)
 363                 # Other steps may call user_cb to terminate prematurely
 364                 # on error
 365                 } elsif (exists $self->{user_cb}) {
 366                         do_finish($self);
 367                 } else {
 368                         die 'about to call user_cb twice'; # Oops :x
 369                 }
 370         }; # eval
 371         my $err = $@;
 372         if ($err) {
 373                 $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 374                 dbg($self, "E: $err");
 375                 eval { done($self, $err) };
 376         }
 377 }
 378
 379 sub next_step ($) {
 380         my ($self) = @_;
 381         # if outside of public-inbox-httpd, caller is expected to be
 382         # looping event_step, anyways
 383         my $async = $self->{psgi_env}->{'pi-httpd.async'} or return;
 384         # PublicInbox::HTTPD::Async->new
 385         $async->(undef, undef, $self);
 386 }
 387
 388 sub mark_found ($$$) {
 389         my ($self, $oid, $found_info) = @_;
 390         my $found = $self->{found};
 391         $found->{$oid} = $found_info;
 392         my $oid_cur = $found_info->[1];
 393         while ($oid_cur ne $oid && length($oid_cur) > $OID_MIN) {
 394                 $found->{$oid_cur} = $found_info;
 395                 chop($oid_cur);
 396         }
 397 }
 398
 399 sub parse_ls_files ($$) {
 400         my ($self, $bref) = @_;
 401         my ($qsp, $di) = delete @$self{qw(-qsp -cur_di)};
 402         if (my $err = $qsp->{err}) {
 403                 die "git ls-files error: $err";
 404         }
 405
 406         my ($line, @extra) = split(/\0/, $$bref);
 407         scalar(@extra) and die "BUG: extra files in index: <",
 408                                 join('> <', @extra), ">";
 409
 410         my ($info, $file) = split(/\t/, $line, 2);
 411         my ($mode_b, $oid_b_full, $stage) = split(/ /, $info);
 412         if ($file ne $di->{path_b}) {
 413                 die
 414 "BUG: index mismatch: file=$file != path_b=$di->{path_b}";
 415         }
 416
 417         my $tmp_git = $self->{tmp_git} or die 'no git working tree';
 418         my (undef, undef, $size) = $tmp_git->check($oid_b_full);
 419         defined($size) or die "check $oid_b_full failed";
 420
 421         dbg($self, "index at:\n$mode_b $oid_b_full\t$file");
 422         my $created = [ $tmp_git, $oid_b_full, 'blob', $size, $di ];
 423         mark_found($self, $di->{oid_b}, $created);
 424         next_step($self); # onto the next patch
 425 }
 426
 427 sub ls_files_result {
 428         my ($bref, $self) = @_;
 429         eval { parse_ls_files($self, $bref) };
 430         ERR($self, $@) if $@;
 431 }
 432
 433 sub oids_same_ish ($$) {
 434         (index($_[0], $_[1]) == 0) || (index($_[1], $_[0]) == 0);
 435 }
 436
 437 sub skip_identical ($$$) {
 438         my ($self, $patches, $cur_oid_b) = @_;
 439         while (my $nxt = $patches->[0]) {
 440                 if (oids_same_ish($cur_oid_b, $nxt->{oid_b})) {
 441                         dbg($self, 'skipping '.di_url($self, $nxt).
 442                                 " for $cur_oid_b");
 443                         shift @$patches;
 444                 } else {
 445                         return;
 446                 }
 447         }
 448 }
 449
 450 sub apply_result ($$) {
 451         my ($bref, $self) = @_;
 452         my ($qsp, $di) = delete @$self{qw(-qsp -cur_di)};
 453         dbg($self, $$bref);
 454         my $patches = $self->{patches};
 455         if (my $err = $qsp->{err}) {
 456                 my $msg = "git apply error: $err";
 457                 my $nxt = $patches->[0];
 458                 if ($nxt && oids_same_ish($nxt->{oid_b}, $di->{oid_b})) {
 459                         dbg($self, $msg);
 460                         dbg($self, 'trying '.di_url($self, $nxt));
 461                         return do_git_apply($self);
 462                 } else {
 463                         ERR($self, $msg);
 464                 }
 465         } else {
 466                 skip_identical($self, $patches, $di->{oid_b});
 467         }
 468
 469         my @cmd = qw(git ls-files -s -z);
 470         $qsp = PublicInbox::Qspawn->new(\@cmd, $self->{git_env});
 471         $self->{-cur_di} = $di;
 472         $self->{-qsp} = $qsp;
 473         $qsp->psgi_qx($self->{psgi_env}, undef, \&ls_files_result, $self);
 474 }
 475
 476 sub do_git_apply ($) {
 477         my ($self) = @_;
 478         my $dn = $self->{tmp}->dirname;
 479         my $patches = $self->{patches};
 480
 481         # we need --ignore-whitespace because some patches are CRLF
 482         my @cmd = (qw(git apply --cached --ignore-whitespace
 483                         --unidiff-zero --whitespace=warn --verbose));
 484         my $len = length(join(' ', @cmd));
 485         my $total = $self->{tot};
 486         my $di; # keep track of the last one for "git ls-files"
 487         my $prv_oid_b;
 488
 489         do {
 490                 my $i = ++$self->{nr};
 491                 $di = shift @$patches;
 492                 dbg($self, "\napplying [$i/$total] " . di_url($self, $di) .
 493                         "\n" . $di->{hdr_lines});
 494                 my $path = $di->{n};
 495                 $len += length($path) + 1;
 496                 push @cmd, $path;
 497                 $prv_oid_b = $di->{oid_b};
 498         } while (@$patches && $len < $ARG_SIZE_MAX &&
 499                  !oids_same_ish($patches->[0]->{oid_b}, $prv_oid_b));
 500
 501         my $opt = { 2 => 1, -C => $dn, quiet => 1 };
 502         my $qsp = PublicInbox::Qspawn->new(\@cmd, $self->{git_env}, $opt);
 503         $self->{-cur_di} = $di;
 504         $self->{-qsp} = $qsp;
 505         $qsp->psgi_qx($self->{psgi_env}, undef, \&apply_result, $self);
 506 }
 507
 508 sub di_url ($$) {
 509         my ($self, $di) = @_;
 510         # note: we don't pass the PSGI env unconditionally, here,
 511         # different inboxes can have different HTTP_HOST on the same instance.
 512         my $ibx = $di->{ibx};
 513         my $env = $self->{psgi_env} if $ibx eq $self->{inboxes}->[0];
 514         my $url = $ibx->base_url($env);
 515         my $mid = $di->{smsg}->{mid};
 516         defined($url) ? "$url$mid/" : "<$mid>";
 517 }
 518
 519 sub retry_current {
 520         my ($self, $want) = @_;
 521         push @{$self->{todo}}, $want;
 522         next_step($self); # retry solve_existing
 523 }
 524
 525 sub try_harder ($$) {
 526         my ($self, $want) = @_;
 527
 528         # do we have more inboxes to try?
 529         return retry_current($self, $want) if scalar @{$want->{try_ibxs}};
 530
 531         my $cur_want = $want->{oid_b};
 532         if (length($cur_want) > $OID_MIN) { # maybe a shorter OID will work
 533                 delete $want->{try_ibxs}; # drop empty arrayref
 534                 chop($cur_want);
 535                 dbg($self, "retrying $want->{oid_b} as $cur_want");
 536                 $want->{oid_b} = $cur_want;
 537                 return retry_current($self, $want); # retry with shorter abbrev
 538         }
 539
 540         dbg($self, "could not find $cur_want");
 541         eval { done($self, undef) };
 542         die "E: $@" if $@;
 543 }
 544
 545 sub extract_diffs_done {
 546         my ($self, $want) = @_;
 547
 548         delete $want->{try_smsgs};
 549         delete $want->{cur_ibx};
 550
 551         my $diffs = delete $self->{tmp_diffs};
 552         if (scalar @$diffs) {
 553                 unshift @{$self->{patches}}, @$diffs;
 554                 dbg($self, "found $want->{oid_b} in " .  join(" ||\n\t",
 555                         map { di_url($self, $_) } @$diffs));
 556
 557                 # good, we can find a path to the oid we $want, now
 558                 # lets see if we need to apply more patches:
 559                 my $di = $diffs->[0];
 560                 my $src = $di->{oid_a};
 561
 562                 unless ($src =~ /\A0+\z/) {
 563                         # we have to solve it using another oid, fine:
 564                         my $job = { oid_b => $src, path_b => $di->{path_a} };
 565                         push @{$self->{todo}}, $job;
 566                 }
 567                 return next_step($self); # onto the next todo item
 568         }
 569         try_harder($self, $want);
 570 }
 571
 572 sub extract_diff_async {
 573         my ($bref, $oid, $type, $size, $x) = @_;
 574         my ($self, $want, $smsg) = @$x;
 575         if (defined($oid)) {
 576                 $smsg->{blob} eq $oid or
 577                                 ERR($self, "BUG: $smsg->{blob} != $oid");
 578                 PublicInbox::Eml->new($bref)->each_part(\&extract_diff, $x, 1);
 579         }
 580
 581         scalar(@{$want->{try_smsgs}}) ? retry_current($self, $want)
 582                                         : extract_diffs_done($self, $want);
 583 }
 584
 585 sub resolve_patch ($$) {
 586         my ($self, $want) = @_;
 587
 588         my $cur_want = $want->{oid_b};
 589         if (scalar(@{$self->{patches}}) > $MAX_PATCH) {
 590                 die "Aborting, too many steps to $self->{oid_want}";
 591         }
 592
 593         if (my $msgs = $want->{try_smsgs}) {
 594                 my $smsg = shift @$msgs;
 595                 if ($self->{psgi_env}->{'pi-httpd.async'}) {
 596                         return git_async_cat($want->{cur_ibx}->git,
 597                                                 $smsg->{blob},
 598                                                 \&extract_diff_async,
 599                                                 [$self, $want, $smsg]);
 600                 } else {
 601                         if (my $eml = $want->{cur_ibx}->smsg_eml($smsg)) {
 602                                 $eml->each_part(\&extract_diff,
 603                                                 [ $self, $want, $smsg ], 1);
 604                         }
 605                 }
 606
 607                 return scalar(@$msgs) ? retry_current($self, $want)
 608                                         : extract_diffs_done($self, $want);
 609         }
 610
 611         # see if we can find the blob in an existing git repo:
 612         if (!$want->{try_ibxs} && $self->{seen_oid}->{$cur_want}++) {
 613                 die "Loop detected solving $cur_want\n";
 614         }
 615         $want->{try_ibxs} //= [ @{$self->{inboxes}} ]; # array copy
 616         my $existing = solve_existing($self, $want);
 617         if (ref $existing) {
 618                 my ($found_git, undef, $type, undef) = @$existing;
 619                 dbg($self, "found $cur_want in " .
 620                         join(" ||\n\t",
 621                                 $found_git->pub_urls($self->{psgi_env})));
 622
 623                 if ($cur_want eq $self->{oid_want} || $type ne 'blob') {
 624                         eval { done($self, $existing) };
 625                         die "E: $@" if $@;
 626                         return;
 627                 }
 628                 mark_found($self, $cur_want, $existing);
 629                 return next_step($self); # onto patch application
 630         } elsif ($existing > 0) {
 631                 return retry_current($self, $want);
 632         } else { # $existing == 0: we may retry if inbox scan (below) fails
 633                 delete $want->{try_gits};
 634         }
 635
 636         # scan through inboxes to look for emails which results in
 637         # the oid we want:
 638         my $ibx = shift(@{$want->{try_ibxs}}) or die 'BUG: {try_ibxs} empty';
 639         if (my $msgs = find_smsgs($self, $ibx, $want)) {
 640                 $want->{try_smsgs} = $msgs;
 641                 $want->{cur_ibx} = $ibx;
 642                 $self->{tmp_diffs} = [];
 643                 return retry_current($self, $want);
 644         }
 645         try_harder($self, $want);
 646 }
 647
 648 # this API is designed to avoid creating self-referential structures;
 649 # so user_cb never references the SolverGit object
 650 sub new {
 651         my ($class, $ibx, $user_cb, $uarg) = @_;
 652
 653         bless {
 654                 gits => $ibx->{-repo_objs},
 655                 user_cb => $user_cb,
 656                 uarg => $uarg,
 657                 # -cur_di, -qsp, -msg => temporary fields for Qspawn callbacks
 658
 659                 # TODO: config option for searching related inboxes
 660                 inboxes => [ $ibx ],
 661         }, $class;
 662 }
 663
 664 # recreate $oid_want using $hints
 665 # hints keys: path_a, path_b, oid_a (note: `oid_b' is NOT a hint)
 666 # Calls {user_cb} with: [ ::Git object, oid_full, type, size, di (diff_info) ]
 667 # with found object, or undef if nothing was found
 668 # Calls {user_cb} with a string error on fatal errors
 669 sub solve ($$$$$) {
 670         my ($self, $env, $out, $oid_want, $hints) = @_;
 671
 672         # should we even get here? Probably not, but somebody
 673         # could be manually typing URLs:
 674         return done($self, undef) if $oid_want =~ /\A0+\z/;
 675
 676         $self->{oid_want} = $oid_want;
 677         $self->{out} = $out;
 678         $self->{seen_oid} = {};
 679         $self->{tot} = 0;
 680         $self->{psgi_env} = $env;
 681         $self->{todo} = [ { %$hints, oid_b => $oid_want } ];
 682         $self->{patches} = []; # [ $di, $di, ... ]
 683         $self->{found} = {}; # { abbr => [ ::Git, oid, type, size, $di ] }
 684         $self->{tmp} = File::Temp->newdir("solver.$oid_want-XXXXXXXX", TMPDIR => 1);
 685
 686         dbg($self, "solving $oid_want ...");
 687         if (my $async = $env->{'pi-httpd.async'}) {
 688                 # PublicInbox::HTTPD::Async->new
 689                 $async->(undef, undef, $self);
 690         } else {
 691                 event_step($self) while $self->{user_cb};
 692         }
 693 }
 694
 695 1;