+ # we use Capitalized and ALLCAPS for compatibility with old Inline::C
+ eval <<'EOM';
+use Inline C => Config => %CFG, BOOT => q[git_libgit2_init();];
+use Inline C => $c_src, BUILD_NOISY => 1;
+EOM
+ $err = $@;
+ open(STDERR, '>&', $olderr) or warn "restore stderr: $!";
+ open(STDOUT, '>&', $oldout) or warn "restore stdout: $!";
+ if ($err) {
+ seek($fh, 0, SEEK_SET);
+ my @msg = <$fh>;
+ die "Inline::C Gcf2 build failed:\n", $err, "\n", @msg;
+ }
+}
+
+sub add_alt ($$) {
+ my ($gcf2, $git_dir) = @_;
+ my $objdir = PublicInbox::Git->new($git_dir)->git_path('objects');
+
+ # libgit2 (tested 0.27.7+dfsg.1-0.2 and 0.28.3+dfsg.1-1~bpo10+1
+ # in Debian) doesn't handle relative epochs properly when nested
+ # multiple levels. Add all the absolute paths to workaround it,
+ # since $EXTINDEX_DIR/ALL.git/objects/info/alternates uses absolute
+ # paths to reference $V2INBOX_DIR/all.git/objects and
+ # $V2INBOX_DIR/all.git/objects/info/alternates uses relative paths
+ # to refer to $V2INBOX_DIR/git/$EPOCH.git/objects
+ #
+ # See https://bugs.debian.org/975607
+ if (open(my $fh, '<', "$objdir/info/alternates")) {
+ chomp(my @abs_alt = grep(m!^/!, <$fh>));
+ $gcf2->add_alternate($_) for @abs_alt;
+ }
+ $gcf2->add_alternate($objdir);
+ 1;
+}
+
+sub have_unlinked_files () {
+ # FIXME: port gcf2-like over to git.git so we won't need to
+ # deal with libgit2
+ return 1 if $^O ne 'linux';
+ open my $fh, '<', "/proc/$$/maps" or return;
+ while (<$fh>) { return 1 if /\.(?:idx|pack) \(deleted\)$/ }
+ undef;
+}
+
+# Usage: $^X -MPublicInbox::Gcf2 -e PublicInbox::Gcf2::loop [EXPIRE-TIMEOUT]
+# (see lib/PublicInbox/Gcf2Client.pm)
+sub loop (;$) {
+ my $exp = $_[0] || $ARGV[0] || 60; # seconds
+ my $gcf2 = new();
+ my (%seen, $check_at);
+ STDERR->autoflush(1);
+ STDOUT->autoflush(1);
+
+ while (<STDIN>) {
+ chomp;
+ my ($oid, $git_dir) = split(/ /, $_, 2);
+ $seen{$git_dir} //= add_alt($gcf2, $git_dir);
+ if (!$gcf2->cat_oid(1, $oid)) {
+ # retry once if missing. We only get unabbreviated OIDs
+ # from SQLite or Xapian DBs, here, so malicious clients
+ # can't trigger excessive retries:
+ warn "# $$ $oid missing, retrying in $git_dir\n";
+
+ $gcf2 = new();
+ %seen = ($git_dir => add_alt($gcf2, $git_dir));
+ $check_at = clock_gettime(CLOCK_MONOTONIC) + $exp;
+
+ if ($gcf2->cat_oid(1, $oid)) {
+ warn "# $$ $oid found after retry\n";
+ } else {
+ warn "W: $$ $oid missing after retry\n";
+ print "$oid missing\n"; # mimic git-cat-file
+ }
+ } else { # check expiry to deal with deleted pack files
+ my $now = clock_gettime(CLOCK_MONOTONIC);
+ $check_at //= $now + $exp;
+ if ($now > $check_at) {
+ undef $check_at;
+ if (have_unlinked_files()) {
+ $gcf2 = new();
+ %seen = ();
+ }
+ }
+ }
+ }