+sub ipc_async {
+ my ($self, $sub, $sub_args, $cb, $cb_arg) = @_;
+ if (my $w_req = $self->{-ipc_req}) { # run in worker
+ my $rec = _pack_rec([ 1, $sub, @$sub_args ]);
+ my $cur_bytes = \($self->{-async_inflight_bytes} //= 0);
+ while (($$cur_bytes + length($rec)) > PIPE_BUF) {
+ ipc_async_wait($self, 1);
+ }
+ my $ipc_lock = $self->{-ipc_lock};
+ my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
+ print $w_req $rec or croak "print: $!";
+ $$cur_bytes += length($rec);
+ push @{$self->{-async_inflight}},
+ $sub, length($rec), $cb, $cb_arg;
+ } else {
+ my $ret = [ eval { $self->$sub(@$sub_args) } ];
+ if (my $exc = $@) {
+ $ret = ( bless(\$exc, 'PublicInbox::IPC::Die') );
+ }
+ eval { $cb->($cb_arg, $ret) };
+ warn "E: $sub callback error: $@\n" if $@;
+ }
+}
+
+# needed when there's multiple IPC workers and the parent forking
+# causes newer siblings to inherit older siblings sockets
+sub ipc_sibling_atfork_child {
+ my ($self) = @_;
+ my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
+ delete(@$self{qw(-ipc_req -ipc_res)});
+ $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
+}
+
+sub recv_and_run {
+ my ($self, $s2, $len, $full_stream) = @_;
+ my @fds = $recv_cmd->($s2, my $buf, $len);
+ return if scalar(@fds) && !defined($fds[0]);
+ my $n = length($buf) or return 0;
+ my $nfd = 0;
+ for my $fd (@fds) {
+ if (open(my $cmdfh, '+<&=', $fd)) {
+ $self->{$nfd++} = $cmdfh;
+ $cmdfh->autoflush(1);
+ } else {
+ die "$$ open(+<&=$fd) (FD:$nfd): $!";
+ }
+ }
+ while ($full_stream && $n < $len) {
+ my $r = sysread($s2, $buf, $len - $n, $n) // croak "read: $!";
+ croak "read EOF after $n/$len bytes" if $r == 0;
+ $n = length($buf);
+ }
+ # Sereal dies on truncated data, Storable returns undef
+ my $args = ipc_thaw($buf) // die "thaw error on buffer of size: $n";
+ undef $buf;
+ my $sub = shift @$args;
+ eval { $self->$sub(@$args) };
+ warn "$$ wq_worker: $@" if $@;
+ delete @$self{0..($nfd-1)};
+ $n;
+}
+
+sub wq_worker_loop ($) {
+ my ($self) = @_;
+ my $wqw = PublicInbox::WQWorker->new($self);
+ PublicInbox::DS->SetPostLoopCallback(sub { $wqw->{sock} });
+ PublicInbox::DS->EventLoop;
+ PublicInbox::DS->Reset;
+}
+
+sub do_sock_stream { # via wq_do, for big requests
+ my ($self, $len) = @_;
+ recv_and_run($self, delete $self->{0}, $len, 1);
+}
+
+sub wq_do { # always async
+ my ($self, $sub, $ios, @args) = @_;
+ if (my $s1 = $self->{-wq_s1}) { # run in worker
+ my $fds = [ map { fileno($_) } @$ios ];
+ my $buf = ipc_freeze([$sub, @args]);
+ my $n = $send_cmd->($s1, $fds, $buf, MSG_EOR);
+ return if defined($n); # likely
+ croak "sendmsg: $! (check RLIMIT_NOFILE)" if $!{ETOOMANYREFS};
+ croak "sendmsg: $!" if !$!{EMSGSIZE};
+ socketpair(my $r, my $w, AF_UNIX, SOCK_STREAM, 0) or
+ croak "socketpair: $!";
+ $n = $send_cmd->($s1, [ fileno($r) ],
+ ipc_freeze(['do_sock_stream', length($buf)]),
+ MSG_EOR) // croak "sendmsg: $!";
+ undef $r;
+ $n = $send_cmd->($w, $fds, $buf, 0) // croak "sendmsg: $!";
+ while ($n < length($buf)) {
+ my $x = syswrite($w, $buf, length($buf) - $n, $n) //
+ croak "syswrite: $!";
+ croak "syswrite wrote 0 bytes" if $x == 0;
+ $n += $x;
+ }
+ } else {
+ @$self{0..$#$ios} = @$ios;
+ eval { $self->$sub(@args) };
+ warn "wq_do: $@" if $@;
+ delete @$self{0..$#$ios}; # don't close
+ }
+}
+
+sub _wq_worker_start ($$$) {
+ my ($self, $oldset, $fields) = @_;
+ my $seed = rand(0xffffffff);
+ my $pid = fork // die "fork: $!";
+ if ($pid == 0) {
+ srand($seed);
+ eval { PublicInbox::DS->Reset };
+ delete @$self{qw(-wq_s1 -wq_workers -wq_ppid)};
+ @$self{keys %$fields} = values(%$fields) if $fields;
+ $SIG{$_} = 'IGNORE' for (qw(PIPE));
+ $SIG{$_} = 'DEFAULT' for (qw(TTOU TTIN TERM QUIT INT CHLD));
+ local $0 = $self->{-wq_ident};
+ PublicInbox::DS::sig_setmask($oldset);
+ # ensure we properly exit even if warn() dies:
+ my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
+ eval {
+ my $on_destroy = $self->ipc_atfork_child;
+ local %SIG = %SIG;
+ wq_worker_loop($self);
+ };
+ warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
+ undef $end; # trigger exit
+ } else {
+ $self->{-wq_workers}->{$pid} = \undef;
+ }
+}
+
+# starts workqueue workers if Sereal or Storable is installed
+sub wq_workers_start {
+ my ($self, $ident, $nr_workers, $oldset, $fields) = @_;
+ ($enc && $send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
+ return if $self->{-wq_s1}; # idempotent
+ $self->{-wq_s1} = $self->{-wq_s2} = undef;
+ socketpair($self->{-wq_s1}, $self->{-wq_s2}, AF_UNIX, $SEQPACKET, 0) or
+ die "socketpair: $!";
+ $self->ipc_atfork_prepare;
+ $nr_workers //= 4;
+ $nr_workers = $WQ_MAX_WORKERS if $nr_workers > $WQ_MAX_WORKERS;
+ my $sigset = $oldset // PublicInbox::DS::block_signals();
+ $self->{-wq_workers} = {};
+ $self->{-wq_ident} = $ident;
+ _wq_worker_start($self, $sigset, $fields) for (1..$nr_workers);
+ PublicInbox::DS::sig_setmask($sigset) unless $oldset;
+ $self->{-wq_ppid} = $$;
+}
+
+sub wq_worker_incr { # SIGTTIN handler
+ my ($self, $oldset, $fields) = @_;
+ $self->{-wq_s2} or return;
+ return if wq_workers($self) >= $WQ_MAX_WORKERS;
+ $self->ipc_atfork_prepare;
+ my $sigset = $oldset // PublicInbox::DS::block_signals();
+ _wq_worker_start($self, $sigset, $fields);
+ PublicInbox::DS::sig_setmask($sigset) unless $oldset;
+}
+
+sub wq_exit { # wakes up wq_worker_decr_wait
+ send($_[0]->{-wq_s2}, $$, MSG_EOR) // die "$$ send: $!";
+ exit;
+}
+
+sub wq_worker_decr { # SIGTTOU handler, kills first idle worker
+ my ($self) = @_;
+ return unless wq_workers($self);
+ my $s2 = $self->{-wq_s2} // die 'BUG: no wq_s2';
+ $self->wq_do('wq_exit', [ $s2, $s2, $s2 ]);
+ # caller must call wq_worker_decr_wait in main loop
+}
+
+sub wq_worker_decr_wait {
+ my ($self, $timeout) = @_;
+ return if $self->{-wq_ppid} != $$; # can't reap siblings or parents
+ my $s1 = $self->{-wq_s1} // croak 'BUG: no wq_s1';
+ vec(my $rin = '', fileno($s1), 1) = 1;
+ select(my $rout = $rin, undef, undef, $timeout) or
+ croak 'timed out waiting for wq_exit';
+ recv($s1, my $pid, 64, 0) // croak "recv: $!";
+ my $workers = $self->{-wq_workers} // croak 'BUG: no wq_workers';
+ delete $workers->{$pid} // croak "BUG: PID:$pid invalid";
+ dwaitpid($pid, \&ipc_worker_reap, $self);
+}
+
+# set or retrieve number of workers
+sub wq_workers {
+ my ($self, $nr) = @_;
+ my $cur = $self->{-wq_workers} or return;
+ if (defined $nr) {
+ while (scalar(keys(%$cur)) > $nr) {
+ $self->wq_worker_decr;
+ $self->wq_worker_decr_wait;
+ }
+ $self->wq_worker_incr while scalar(keys(%$cur)) < $nr;
+ }
+ scalar(keys(%$cur));
+}
+
+sub wq_close {
+ my ($self, $nohang) = @_;
+ delete @$self{qw(-wq_s1 -wq_s2)} or return;
+ my $ppid = delete $self->{-wq_ppid} or return;
+ my $workers = delete $self->{-wq_workers} // die 'BUG: no wq_workers';
+ return if $ppid != $$; # can't reap siblings or parents
+ my @pids = map { $_ + 0 } keys %$workers;
+ if ($nohang) {
+ push @{$self->{"-wq_old_pids.$$"}}, @pids;
+ } else {
+ dwaitpid($_, \&ipc_worker_reap, $self) for @pids;
+ }
+}
+
+sub wq_kill_old {
+ my ($self) = @_;
+ my $pids = $self->{"-wq_old_pids.$$"} or return;
+ kill 'TERM', @$pids;
+}
+
+sub wq_kill {
+ my ($self, $sig) = @_;
+ my $workers = $self->{-wq_workers} or return;
+ kill($sig // 'TERM', keys %$workers);
+}
+
+sub WQ_MAX_WORKERS { $WQ_MAX_WORKERS }
+
+sub DESTROY {
+ my ($self) = @_;
+ my $ppid = $self->{-wq_ppid};
+ wq_kill($self) if $ppid && $ppid == $$;
+ wq_close($self);
+ wq_wait_old($self);
+ ipc_worker_stop($self);
+}
+
+# Sereal doesn't have dclone
+sub deep_clone { ipc_thaw(ipc_freeze($_[-1])) }
+