+# needed when there's multiple IPC workers and the parent forking
+# causes newer siblings to inherit older siblings sockets
+sub ipc_sibling_atfork_child {
+ my ($self) = @_;
+ my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
+ delete(@$self{qw(-ipc_req -ipc_res)});
+ $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
+}
+
+sub recv_and_run {
+ my ($self, $s2, $len, $full_stream) = @_;
+ my @fds = $recv_cmd->($s2, my $buf, $len // $MY_MAX_ARG_STRLEN);
+ return if scalar(@fds) && !defined($fds[0]);
+ my $n = length($buf) or return 0;
+ my $nfd = 0;
+ for my $fd (@fds) {
+ if (open(my $cmdfh, '+<&=', $fd)) {
+ $self->{$nfd++} = $cmdfh;
+ $cmdfh->autoflush(1);
+ } else {
+ die "$$ open(+<&=$fd) (FD:$nfd): $!";
+ }
+ }
+ while ($full_stream && $n < $len) {
+ my $r = sysread($s2, $buf, $len - $n, $n) // croak "read: $!";
+ croak "read EOF after $n/$len bytes" if $r == 0;
+ $n = length($buf);
+ }
+ # Sereal dies on truncated data, Storable returns undef
+ my $args = ipc_thaw($buf) // die "thaw error on buffer of size: $n";
+ undef $buf;
+ my $sub = shift @$args;
+ eval { $self->$sub(@$args) };
+ warn "$$ $0 wq_worker: $sub: $@" if $@;
+ delete @$self{0..($nfd-1)};
+ $n;
+}
+
+sub wq_worker_loop ($$) {
+ my ($self, $bcast2) = @_;
+ my $wqw = PublicInbox::WQWorker->new($self, $self->{-wq_s2});
+ PublicInbox::WQWorker->new($self, $bcast2) if $bcast2;
+ PublicInbox::DS->SetPostLoopCallback(sub { $wqw->{sock} });
+ PublicInbox::DS::event_loop();
+ PublicInbox::DS->Reset;
+}
+
+sub do_sock_stream { # via wq_io_do, for big requests
+ my ($self, $len) = @_;
+ recv_and_run($self, my $s2 = delete $self->{0}, $len, 1);
+}
+
+sub wq_broadcast {
+ my ($self, $sub, @args) = @_;
+ if (my $wkr = $self->{-wq_workers}) {
+ my $buf = ipc_freeze([$sub, @args]);
+ for my $bcast1 (values %$wkr) {
+ my $sock = $bcast1 // $self->{-wq_s1} // next;
+ send($sock, $buf, MSG_EOR) // croak "send: $!";
+ # XXX shouldn't have to deal with EMSGSIZE here...
+ }
+ } else {
+ eval { $self->$sub(@args) };
+ warn "wq_broadcast: $@" if $@;
+ }
+}
+
+sub stream_in_full ($$$) {
+ my ($s1, $fds, $buf) = @_;
+ socketpair(my $r, my $w, AF_UNIX, SOCK_STREAM, 0) or
+ croak "socketpair: $!";
+ my $n = $send_cmd->($s1, [ fileno($r) ],
+ ipc_freeze(['do_sock_stream', length($buf)]),
+ MSG_EOR) // croak "sendmsg: $!";
+ undef $r;
+ $n = $send_cmd->($w, $fds, $buf, 0) // croak "sendmsg: $!";
+ while ($n < length($buf)) {
+ my $x = syswrite($w, $buf, length($buf) - $n, $n) //
+ croak "syswrite: $!";
+ croak "syswrite wrote 0 bytes" if $x == 0;
+ $n += $x;
+ }
+}
+
+sub wq_io_do { # always async
+ my ($self, $sub, $ios, @args) = @_;
+ if (my $s1 = $self->{-wq_s1}) { # run in worker
+ my $fds = [ map { fileno($_) } @$ios ];
+ my $buf = ipc_freeze([$sub, @args]);
+ if (length($buf) > $MY_MAX_ARG_STRLEN) {
+ stream_in_full($s1, $fds, $buf);
+ } else {
+ my $n = $send_cmd->($s1, $fds, $buf, MSG_EOR);
+ return if defined($n); # likely
+ $!{ETOOMANYREFS} and
+ croak "sendmsg: $! (check RLIMIT_NOFILE)";
+ $!{EMSGSIZE} ? stream_in_full($s1, $fds, $buf) :
+ croak("sendmsg: $!");
+ }
+ } else {
+ @$self{0..$#$ios} = @$ios;
+ eval { $self->$sub(@args) };
+ warn "wq_io_do: $@" if $@;
+ delete @$self{0..$#$ios}; # don't close
+ }
+}
+
+sub wq_sync_run {
+ my ($self, $wantarray, $sub, @args) = @_;
+ if ($wantarray) {
+ my @ret = eval { $self->$sub(@args) };
+ ipc_return($self->{0}, \@ret, $@);
+ } else { # '' => wantscalar
+ my $ret = eval { $self->$sub(@args) };
+ ipc_return($self->{0}, \$ret, $@);
+ }
+}
+
+sub wq_do {
+ my ($self, $sub, @args) = @_;
+ if (defined(wantarray)) {
+ pipe(my ($r, $w)) or die "pipe: $!";
+ wq_io_do($self, 'wq_sync_run', [ $w ], wantarray, $sub, @args);
+ undef $w;
+ _wait_return($r, $sub);
+ } else {
+ wq_io_do($self, $sub, [], @args);
+ }
+}
+
+sub prepare_nonblock {
+ ($_[0]->{-wq_s1} // die 'BUG: no {-wq_s1}')->blocking(0);
+ require PublicInbox::WQBlocked;
+}
+
+sub wq_nonblock_do { # always async
+ my ($self, $sub, @args) = @_;
+ my $buf = ipc_freeze([$sub, @args]);
+ if ($self->{wqb}) { # saturated once, assume saturated forever
+ $self->{wqb}->flush_send($buf);
+ } else {
+ $send_cmd->($self->{-wq_s1}, [], $buf, MSG_EOR) //
+ ($!{EAGAIN} ? PublicInbox::WQBlocked->new($self, $buf)
+ : croak("sendmsg: $!"));
+ }
+}
+
+sub _wq_worker_start {
+ my ($self, $oldset, $fields, $one, @cb_args) = @_;
+ my ($bcast1, $bcast2);
+ $one or socketpair($bcast1, $bcast2, AF_UNIX, $SEQPACKET, 0) or
+ die "socketpair: $!";
+ my $seed = rand(0xffffffff);
+ my $pid = fork // die "fork: $!";
+ if ($pid == 0) {
+ srand($seed);
+ eval { Net::SSLeay::randomize() };
+ undef $bcast1;
+ eval { PublicInbox::DS->Reset };
+ delete @$self{qw(-wq_s1 -wq_ppid)};
+ $self->{-wq_worker_nr} =
+ keys %{delete($self->{-wq_workers}) // {}};
+ $SIG{$_} = 'DEFAULT' for (qw(TTOU TTIN TERM QUIT INT CHLD));
+ local $0 = $one ? $self->{-wq_ident} :
+ "$self->{-wq_ident} $self->{-wq_worker_nr}";
+ # ensure we properly exit even if warn() dies:
+ my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
+ eval {
+ $fields //= {};
+ local @$self{keys %$fields} = values(%$fields);
+ my $on_destroy = $self->ipc_atfork_child;
+ local @SIG{keys %SIG} = values %SIG;
+ PublicInbox::DS::sig_setmask($oldset);
+ wq_worker_loop($self, $bcast2);
+ };
+ warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
+ undef $end; # trigger exit
+ } else {
+ $self->{-wq_workers}->{$pid} = $bcast1;
+ awaitpid($pid, \&ipc_worker_reap, $self, @cb_args);
+ }
+}
+
+# starts workqueue workers if Sereal or Storable is installed
+sub wq_workers_start {
+ my ($self, $ident, $nr_workers, $oldset, $fields, @cb_args) = @_;
+ ($send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
+ return if $self->{-wq_s1}; # idempotent
+ $self->{-wq_s1} = $self->{-wq_s2} = undef;
+ socketpair($self->{-wq_s1}, $self->{-wq_s2}, AF_UNIX, $SEQPACKET, 0) or
+ die "socketpair: $!";
+ $self->ipc_atfork_prepare;
+ $nr_workers //= $self->{-wq_nr_workers}; # was set earlier
+ my $sigset = $oldset // PublicInbox::DS::block_signals();
+ $self->{-wq_workers} = {};
+ $self->{-wq_ident} = $ident;
+ my $one = $nr_workers == 1;
+ $self->{-wq_nr_workers} = $nr_workers;
+ for (1..$nr_workers) {
+ _wq_worker_start($self, $sigset, $fields, $one, @cb_args);
+ }
+ PublicInbox::DS::sig_setmask($sigset) unless $oldset;
+ $self->{-wq_ppid} = $$;
+}
+
+sub wq_close {
+ my ($self) = @_;
+ if (my $wqb = delete $self->{wqb}) {
+ $wqb->enq_close;
+ }
+ delete @$self{qw(-wq_s1 -wq_s2)} or return;
+ return if ($self->{-wq_ppid} // -1) != $$;
+ awaitpid($_) for keys %{$self->{-wq_workers}};
+}
+
+sub wq_kill {
+ my ($self, $sig) = @_;
+ kill($sig // 'TERM', keys %{$self->{-wq_workers}});
+}
+
+sub DESTROY {
+ my ($self) = @_;
+ my $ppid = $self->{-wq_ppid};
+ wq_kill($self) if $ppid && $ppid == $$;
+ wq_close($self);
+ ipc_worker_stop($self);
+}
+
+sub detect_nproc () {
+ # _SC_NPROCESSORS_ONLN = 84 on both Linux glibc and musl
+ return POSIX::sysconf(84) if $^O eq 'linux';
+ return POSIX::sysconf(58) if $^O eq 'freebsd';
+ # TODO: more OSes
+
+ # getconf(1) is POSIX, but *NPROCESSORS* vars are not
+ for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
+ `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
+ }
+ for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
+ `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
+ }
+
+ # should we bother with `sysctl hw.ncpu`? Those only give
+ # us total processor count, not online processor count.
+ undef
+}
+