+# used for cross-inbox search
+sub eidx_prep ($) {
+ my ($self) = @_;
+ $self->{-eidx_prep} //= do {
+ my $dbh = $self->dbh;
+ $dbh->do(<<'');
+INSERT OR IGNORE INTO counter (key) VALUES ('eidx_docid')
+
+ $dbh->do(<<'');
+CREATE TABLE IF NOT EXISTS inboxes (
+ ibx_id INTEGER PRIMARY KEY AUTOINCREMENT,
+ eidx_key VARCHAR(255) NOT NULL, /* {newsgroup} // {inboxdir} */
+ UNIQUE (eidx_key)
+)
+
+ $dbh->do(<<'');
+CREATE TABLE IF NOT EXISTS xref3 (
+ docid INTEGER NOT NULL, /* <=> over.num */
+ ibx_id INTEGER NOT NULL, /* <=> inboxes.ibx_id */
+ xnum INTEGER NOT NULL, /* NNTP article number in ibx */
+ oidbin VARBINARY NOT NULL, /* 20-byte SHA-1 or 32-byte SHA-256 */
+ UNIQUE (docid, ibx_id, xnum, oidbin)
+)
+
+ $dbh->do('CREATE INDEX IF NOT EXISTS idx_docid ON xref3 (docid)');
+
+ # performance critical, this is not UNIQUE since we may need to
+ # tolerate some old bugs from indexing mirrors. n.b. we used
+ # to index oidbin here, but leaving it out speeds up reindexing
+ # and "XHDR Xref <$MSGID>" isn't any slower w/o oidbin
+ $dbh->do('CREATE INDEX IF NOT EXISTS idx_reindex ON '.
+ 'xref3 (xnum,ibx_id)');
+
+ $dbh->do('CREATE INDEX IF NOT EXISTS idx_oidbin ON xref3 (oidbin)');
+
+ $dbh->do(<<'');
+CREATE TABLE IF NOT EXISTS eidx_meta (
+ key VARCHAR(255) PRIMARY KEY,
+ val VARCHAR(255) NOT NULL
+)
+
+ # A queue of current docids which need reindexing.
+ # eidxq persists across aborted -extindex invocations
+ # Currently used for "-extindex --reindex" for Xapian
+ # data, but may be used in more places down the line.
+ $dbh->do(<<'');
+CREATE TABLE IF NOT EXISTS eidxq (docid INTEGER PRIMARY KEY NOT NULL)
+
+ 1;
+ };
+}
+
+sub eidx_meta { # requires transaction
+ my ($self, $key, $val) = @_;
+
+ my $sql = 'SELECT val FROM eidx_meta WHERE key = ? LIMIT 1';
+ my $dbh = $self->{dbh};
+ defined($val) or return $dbh->selectrow_array($sql, undef, $key);
+
+ my $prev = $dbh->selectrow_array($sql, undef, $key);
+ if (defined $prev) {
+ $sql = 'UPDATE eidx_meta SET val = ? WHERE key = ?';
+ $dbh->do($sql, undef, $val, $key);
+ } else {
+ $sql = 'INSERT INTO eidx_meta (key,val) VALUES (?,?)';
+ $dbh->do($sql, undef, $key, $val);
+ }
+ $prev;
+}
+
+sub eidx_max {
+ my ($self) = @_;
+ get_counter($self->{dbh}, 'eidx_docid');
+}
+
+sub add_xref3 {
+ my ($self, $docid, $xnum, $oidhex, $eidx_key) = @_;
+ begin_lazy($self);
+ my $ibx_id = ibx_id($self, $eidx_key);
+ my $oidbin = pack('H*', $oidhex);
+ my $sth = $self->{dbh}->prepare_cached(<<'');
+INSERT OR IGNORE INTO xref3 (docid, ibx_id, xnum, oidbin) VALUES (?, ?, ?, ?)
+
+ $sth->bind_param(1, $docid);
+ $sth->bind_param(2, $ibx_id);
+ $sth->bind_param(3, $xnum);
+ $sth->bind_param(4, $oidbin, SQL_BLOB);
+ $sth->execute;
+}
+
+# for when an xref3 goes missing, this does NOT update {ts}
+sub update_blob {
+ my ($self, $smsg, $oidhex) = @_;
+ my $sth = $self->{dbh}->prepare(<<'');
+UPDATE over SET ddd = ? WHERE num = ?
+
+ $smsg->{blob} = $oidhex;
+ $sth->bind_param(1, ddd_for($smsg), SQL_BLOB);
+ $sth->bind_param(2, $smsg->{num});
+ $sth->execute;
+}
+
+sub merge_xref3 { # used for "-extindex --dedupe"
+ my ($self, $keep_docid, $drop_docid, $oidhex) = @_;
+ my $oidbin = pack('H*', $oidhex);
+ my $sth = $self->{dbh}->prepare_cached(<<'');
+UPDATE OR IGNORE xref3 SET docid = ? WHERE docid = ? AND oidbin = ?
+
+ $sth->bind_param(1, $keep_docid);
+ $sth->bind_param(2, $drop_docid);
+ $sth->bind_param(3, $oidbin, SQL_BLOB);
+ $sth->execute;
+
+ # drop anything that conflicted
+ $sth = $self->{dbh}->prepare_cached(<<'');
+DELETE FROM xref3 WHERE docid = ? AND oidbin = ?
+
+ $sth->bind_param(1, $drop_docid);
+ $sth->bind_param(2, $oidbin, SQL_BLOB);
+ $sth->execute;
+}
+
+sub eidxq_add {
+ my ($self, $docid) = @_;
+ $self->dbh->prepare_cached(<<'')->execute($docid);
+INSERT OR IGNORE INTO eidxq (docid) VALUES (?)
+
+}
+
+sub eidxq_del {
+ my ($self, $docid) = @_;
+ $self->dbh->prepare_cached(<<'')->execute($docid);
+DELETE FROM eidxq WHERE docid = ?
+
+}
+
+# returns true if we're vivifying a message for lei/store that was
+# previously external-metadata only
+sub vivify_xvmd {
+ my ($self, $smsg) = @_;
+ my @docids = $self->blob_exists($smsg->{blob});
+ my @vivify_xvmd;
+ for my $id (@docids) {
+ if (my $cur = $self->get_art($id)) {
+ # already indexed if bytes > 0
+ return if $cur->{bytes} > 0;
+ push @vivify_xvmd, $id;
+ } else {
+ warn "W: $smsg->{blob} #$id gone (bug?)\n";
+ }
+ }
+ $smsg->{-vivify_xvmd} = \@vivify_xvmd;
+}
+