+our ($err_skip, $lei_opt, $lei_out, $lei_err);
+# favor lei() or lei_ok() over $lei for new code
+sub lei (@) {
+ my ($cmd, $env, $xopt) = @_;
+ $lei_out = $lei_err = '';
+ if (!ref($cmd)) {
+ ($env, $xopt) = grep { (!defined) || ref } @_;
+ $cmd = [ grep { defined && !ref } @_ ];
+ }
+ my $res = run_script(['lei', @$cmd], $env, $xopt // $lei_opt);
+ $err_skip and
+ $lei_err = join('', grep(!/$err_skip/, split(/^/m, $lei_err)));
+ if ($lei_err ne '') {
+ if ($lei_err =~ /Use of uninitialized/ ||
+ $lei_err =~ m!\bArgument .*? isn't numeric in !) {
+ fail "lei_err=$lei_err";
+ } else {
+ diag "lei_err=$lei_err" if $lei_loud;
+ }
+ }
+ $res;
+};
+
+sub lei_ok (@) {
+ state $PWD = $ENV{PWD} // Cwd::getcwd();
+ my $msg = ref($_[-1]) eq 'SCALAR' ? pop(@_) : undef;
+ my $tmpdir = quotemeta(File::Spec->tmpdir);
+ # filter out anything that looks like a path name for consistent logs
+ my @msg = ref($_[0]) eq 'ARRAY' ? @{$_[0]} : @_;
+ if (!$lei_loud) {
+ for (@msg) {
+ s!\A([a-z0-9]+://)[^/]+/!$1\$HOST_PORT/!;
+ s!$tmpdir\b/(?:[^/]+/)?!\$TMPDIR/!g;
+ s!\Q$PWD\E\b!\$PWD!g;
+ }
+ }
+ ok(lei(@_), "lei @msg". ($msg ? " ($$msg)" : '')) or diag $lei_err;
+}
+
+sub json_utf8 () {
+ state $x = ref(PublicInbox::Config->json)->new->utf8->canonical;
+}
+
+sub test_lei {
+SKIP: {
+ my ($cb) = pop @_;
+ my $test_opt = shift // {};
+ require_git(2.6, 1) or skip('git 2.6+ required for lei test', 2);
+ require_mods(qw(json DBD::SQLite Search::Xapian), 2);
+ require PublicInbox::Config;
+ local %ENV = %ENV;
+ delete $ENV{XDG_DATA_HOME};
+ delete $ENV{XDG_CONFIG_HOME};
+ $ENV{GIT_COMMITTER_EMAIL} = 'lei@example.com';
+ $ENV{GIT_COMMITTER_NAME} = 'lei user';
+ my (undef, $fn, $lineno) = caller(0);
+ my $t = "$fn:$lineno";
+ require PublicInbox::Spawn;
+ state $lei_daemon = PublicInbox::Spawn->can('send_cmd4') ||
+ eval { require Socket::MsgHdr; 1 };
+ # XXX fix and move this inside daemon-only before 1.7 release
+ skip <<'EOM', 1 unless $lei_daemon;
+Socket::MsgHdr missing or Inline::C is unconfigured/missing
+EOM
+ $lei_opt = { 1 => \$lei_out, 2 => \$lei_err };
+ my ($daemon_pid, $for_destroy, $daemon_xrd);
+ my $tmpdir = $test_opt->{tmpdir};
+ ($tmpdir, $for_destroy) = tmpdir unless $tmpdir;
+ state $persist_xrd = $ENV{TEST_LEI_DAEMON_PERSIST_DIR};
+ SKIP: {
+ skip 'TEST_LEI_ONESHOT set', 1 if $ENV{TEST_LEI_ONESHOT};
+ my $home = "$tmpdir/lei-daemon";
+ mkdir($home, 0700) or BAIL_OUT "mkdir: $!";
+ local $ENV{HOME} = $home;
+ my $persist;
+ if ($persist_xrd && !$test_opt->{daemon_only}) {
+ $persist = $daemon_xrd = $persist_xrd;
+ } else {
+ $daemon_xrd = "$home/xdg_run";
+ mkdir($daemon_xrd, 0700) or BAIL_OUT "mkdir: $!";
+ }
+ local $ENV{XDG_RUNTIME_DIR} = $daemon_xrd;
+ $cb->();
+ unless ($persist) {
+ lei_ok(qw(daemon-pid), \"daemon-pid after $t");
+ chomp($daemon_pid = $lei_out);
+ if (!$daemon_pid) {
+ fail("daemon not running after $t");
+ skip 'daemon died unexpectedly', 2;
+ }
+ ok(kill(0, $daemon_pid), "daemon running after $t");
+ lei_ok(qw(daemon-kill), \"daemon-kill after $t");
+ }
+ }; # SKIP for lei_daemon
+ unless ($test_opt->{daemon_only}) {
+ $ENV{TEST_LEI_DAEMON_ONLY} and
+ skip 'TEST_LEI_DAEMON_ONLY set', 1;
+ require_ok 'PublicInbox::LEI';
+ my $home = "$tmpdir/lei-oneshot";
+ mkdir($home, 0700) or BAIL_OUT "mkdir: $!";
+ local $ENV{HOME} = $home;
+ # force sun_path[108] overflow:
+ my $xrd = "$home/1shot-test".('.sun_path' x 108);
+ local $err_skip = qr!\Q$xrd!; # for lei() filtering
+ local $ENV{XDG_RUNTIME_DIR} = $xrd;
+ $cb->();
+ }
+ if ($daemon_pid) {
+ for (0..10) {
+ kill(0, $daemon_pid) or last;
+ tick;
+ }
+ ok(!kill(0, $daemon_pid), "$t daemon stopped after oneshot");
+ my $f = "$daemon_xrd/lei/errors.log";
+ open my $fh, '<', $f or BAIL_OUT "$f: $!";
+ my @l = <$fh>;
+ is_deeply(\@l, [],
+ "$t daemon XDG_RUNTIME_DIR/lei/errors.log empty");
+ }
+}; # SKIP if missing git 2.6+ || Xapian || SQLite || json
+} # /test_lei
+
+# returns the pathname to a ~/.public-inbox/config in scalar context,
+# ($test_home, $pi_config_pathname) in list context
+sub setup_public_inboxes () {
+ my $test_home = "t/home2";
+ my $pi_config = "$test_home/.public-inbox/config";
+ my $stamp = "$test_home/setup-stamp";
+ my @ret = ($test_home, $pi_config);
+ return @ret if -f $stamp;
+
+ require PublicInbox::Lock;
+ my $lk = bless { lock_path => "$test_home/setup.lock" },
+ 'PublicInbox::Lock';
+ my $end = $lk->lock_for_scope;
+ return @ret if -f $stamp;
+
+ local $ENV{PI_CONFIG} = $pi_config;
+ for my $V (1, 2) {
+ run_script([qw(-init --skip-docdata), "-V$V",
+ '--newsgroup', "t.v$V", "t$V",
+ "$test_home/t$V", "http://example.com/t$V",
+ "t$V\@example.com" ]) or BAIL_OUT "init v$V";
+ }
+ require PublicInbox::Config;
+ require PublicInbox::InboxWritable;
+ my $cfg = PublicInbox::Config->new;
+ my $seen = 0;
+ $cfg->each_inbox(sub {
+ my ($ibx) = @_;
+ $ibx->{-no_fsync} = 1;
+ my $im = PublicInbox::InboxWritable->new($ibx)->importer(0);
+ my $V = $ibx->version;
+ my @eml = (glob('t/*.eml'), 't/data/0001.patch');
+ for (@eml) {
+ next if $_ eq 't/psgi_v2-old.eml'; # dup mid
+ $im->add(eml_load($_)) or BAIL_OUT "v$V add $_";
+ $seen++;
+ }
+ $im->done;
+ });
+ $seen or BAIL_OUT 'no imports';
+ open my $fh, '>', $stamp or BAIL_OUT "open $stamp: $!";
+ @ret;
+}
+
+sub create_inbox ($$;@) {
+ my $ident = shift;
+ my $cb = pop;
+ my %opt = @_;
+ require PublicInbox::Lock;
+ require PublicInbox::InboxWritable;
+ my ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
+ my $dir = "t/data-gen/$base.$ident";
+ my $new = !-d $dir;
+ if ($new) {
+ mkdir $dir; # may race
+ -d $dir or BAIL_OUT "$dir could not be created: $!";
+ }
+ my $lk = bless { lock_path => "$dir/creat.lock" }, 'PublicInbox::Lock';
+ $opt{inboxdir} = File::Spec->rel2abs($dir);
+ $opt{name} //= $ident;
+ my $scope = $lk->lock_for_scope;
+ my $pre_cb = delete $opt{pre_cb};
+ $pre_cb->($dir) if $pre_cb && $new;
+ $opt{-no_fsync} = 1;
+ my $no_gc = delete $opt{-no_gc};
+ my $tmpdir = delete $opt{tmpdir};
+ my $addr = $opt{address} // [];
+ $opt{-primary_address} //= $addr->[0] // "$ident\@example.com";
+ my $parallel = delete($opt{importer_parallel}) // 0;
+ my $creat_opt = { nproc => delete($opt{nproc}) // 1 };
+ my $ibx = PublicInbox::InboxWritable->new({ %opt }, $creat_opt);
+ if (!-f "$dir/creat.stamp") {
+ my $im = $ibx->importer($parallel);
+ $cb->($im, $ibx);
+ $im->done if $im;
+ unless ($no_gc) {
+ my @to_gc = $ibx->version == 1 ? ($ibx->{inboxdir}) :
+ glob("$ibx->{inboxdir}/git/*.git");
+ for my $dir (@to_gc) {
+ xsys_e([ qw(git gc -q) ], { GIT_DIR => $dir });
+ }
+ }
+ open my $s, '>', "$dir/creat.stamp" or
+ BAIL_OUT "error creating $dir/creat.stamp: $!";
+ }
+ if ($tmpdir) {
+ undef $ibx;
+ xsys([qw(/bin/cp -Rp), $dir, $tmpdir]) == 0 or
+ BAIL_OUT "cp $dir $tmpdir";
+ $opt{inboxdir} = $tmpdir;
+ $ibx = PublicInbox::InboxWritable->new(\%opt);
+ }
+ $ibx;
+}
+
+sub test_httpd ($$;$) {
+ my ($env, $client, $skip) = @_;
+ for (qw(PI_CONFIG TMPDIR)) {
+ $env->{$_} or BAIL_OUT "$_ unset";
+ }
+ SKIP: {
+ require_mods(qw(Plack::Test::ExternalServer), $skip // 1);
+ my $sock = tcp_server() or die;
+ my ($out, $err) = map { "$env->{TMPDIR}/std$_.log" } qw(out err);
+ my $cmd = [ qw(-httpd -W0), "--stdout=$out", "--stderr=$err" ];
+ my $td = start_script($cmd, $env, { 3 => $sock });
+ my ($h, $p) = tcp_host_port($sock);
+ local $ENV{PLACK_TEST_EXTERNALSERVER_URI} = "http://$h:$p";
+ Plack::Test::ExternalServer::test_psgi(client => $client);
+ $td->join('TERM');
+ open my $fh, '<', $err or BAIL_OUT $!;
+ my $e = do { local $/; <$fh> };
+ if ($e =~ s/^Plack::Middleware::ReverseProxy missing,\n//gms) {
+ $e =~ s/^URL generation for redirects .*\n//gms;
+ }
+ is($e, '', 'no errors');
+ }
+};
+
+