Documentation/txt2pre

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2014-2019 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Stupid script to make HTML from preformatted, utf-8 text versions,
   6 # only generating links for http(s).  Markdown does too much
   7 # and requires indentation to output preformatted text.
   8 use strict;
   9 use warnings;
  10 use PublicInbox::Linkify;
  11 use PublicInbox::Hval qw(ascii_html);
  12 my %xurls;
  13 for (qw[public-inbox.cgi(1)
  14         public-inbox-compact(1)
  15         public-inbox-config(5)
  16         public-inbox-convert(1)
  17         public-inbox-daemon(8)
  18         public-inbox-edit(1)
  19         public-inbox-httpd(1)
  20         public-inbox-index(1)
  21         public-inbox-init(1)
  22         public-inbox-learn(1)
  23         public-inbox-mda(1)
  24         public-inbox-nntpd(1)
  25         public-inbox-overview(7)
  26         public-inbox-purge(1)
  27         public-inbox-v1-format(5)
  28         public-inbox-v2-format(5)
  29         public-inbox-watch(1)
  30         public-inbox-xcpdb(1)
  31 ]) {
  32         my ($n) = (/([\w\-\.]+)/);
  33         $xurls{$_} = "$n.html";
  34         $xurls{$n} = "$n.html";
  35 }
  36
  37 for (qw[copydatabase(1) xapian-compact(1)]) {
  38         my ($n) = (/([\w\-\.]+)/);
  39         $xurls{$_} = ".$n.1.html"
  40 }
  41
  42 for (qw[flock(2) setrlimit(2) vfork(2)]) {
  43         my ($n, $s) = (/([\w\-]+)\((\d)\)/);
  44         $xurls{$_} = "http://www.man7.org/linux/man-pages/man2/$n.$s.html";
  45 }
  46
  47 for (qw[git(1)
  48         git-am(1)
  49         git-config(1)
  50         git-daemon(1)
  51         git-fetch(1)
  52         git-filter-branch(1)
  53         git-format-patch(1)
  54         git-gc(1)
  55         git-http-backend(1)
  56         git-imap-send(1)
  57         git-init(1)
  58         git-send-email(1)
  59         gitrepository-layout(5)
  60 ]) {
  61         my ($n) = (/([\w\-\.]+)/);
  62         $xurls{$_} = "https://kernel.org/pub/software/scm/git/docs/$n.html"
  63 }
  64
  65 for (qw[
  66         sd_listen_fds(3)
  67         systemd(1)
  68         systemd.unit(5)
  69         systemd.socket(5)
  70 ]) {
  71         my ($n) = (/([\w\-\.]+)/);
  72         $xurls{$_} = "https://www.freedesktop.org/software/systemd/man/$n.html";
  73 }
  74
  75 $xurls{'spamc(1)'} =
  76         'https://spamassassin.apache.org/full/3.4.x/doc/spamc.html';
  77 $xurls{'grok-pull'} =
  78         'https://git.kernel.org/pub/scm/utils/grokmirror/grokmirror.git' .
  79         '/tree/man/grok-pull.1.rst';
  80 $xurls{'git-filter-repo(1)'} = 'https://github.com/newren/git-filter-repo'.
  81                         './blob/master/Documentation/git-filter-repo.txt';
  82 $xurls{'ssoma(1)'} = 'https://ssoma.public-inbox.org/ssoma.txt';
  83 $xurls{'cgitrc(5)'} = 'https://git.zx2c4.com/cgit/tree/cgitrc.5.txt';
  84
  85 my $str = do { local $/; <STDIN> };
  86 my ($title) = ($str =~ /\A([^\n]+)/);
  87 if ($str =~ /^NAME\n\s+([^\n]+)/sm) {
  88         # don't link to ourselves
  89         $title = $1;
  90         if ($title =~ /([\w\.\-]+)/) {
  91                 delete $xurls{$1};
  92         }
  93 }
  94 $title = ascii_html($title);
  95 my $l = PublicInbox::Linkify->new;
  96 $str = $l->linkify_1($str);
  97 $str = ascii_html($str);
  98
  99 # longest matches, first
 100 my @keys = sort { length($b) <=> length($a) } keys %xurls;
 101 my $xkeys = join('|', map { quotemeta } @keys);
 102 $str =~ s,(?<![>\w_])($xkeys)(?!(?:[\w<\-]|\.html)),
 103         qq(<a\nhref=").$xurls{$1}.qq(">$1).($2//'').'</a>',sge;
 104
 105 $str = $l->linkify_2($str);
 106
 107 print '<html><head>',
 108   qq(<meta\nhttp-equiv="Content-Type"\ncontent="text/html; charset=utf-8"\n/>),
 109   "<title>$title</title>",
 110   "</head><body><pre>",  $str , '</pre></body></html>';
 111 STDOUT->flush;
 112
 113 # keep mtime on website consistent so clients can cache
 114 if (-f STDIN && -f STDOUT) {
 115         my @st = stat(STDIN);
 116         utime($st[8], $st[9], \*STDOUT);
 117 }