Makefile.PL

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2013-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use ExtUtils::MakeMaker;
   6 open my $m, '<', 'MANIFEST' or die "open(MANIFEST): $!\n";
   7 chomp(my @manifest = (<$m>));
   8 my @EXE_FILES = grep(m!^script/!, @manifest);
   9 my $v = {};
  10 my $t = {};
  11
  12 # do not sort
  13 my @RELEASES = qw(v1.5.0 v1.4.0 v1.3.0 v1.2.0 v1.1.0-pre1 v1.0.0);
  14
  15 $v->{news_deps} = [ map { "Documentation/RelNotes/$_.eml" } @RELEASES ];
  16 $v->{txt} = [ qw(INSTALL README COPYING TODO HACKING) ];
  17 my @dtxt = grep(m!\ADocumentation/[^/]+\.txt\z!, @manifest);
  18 push @dtxt, 'Documentation/standards.txt';
  19 push @dtxt, 'Documentation/flow.txt';
  20 push @dtxt, @{$v->{txt}};
  21 for my $txt (@dtxt) {
  22         my $html = $txt;
  23         $html =~ s/\.txt\z/.html/ or $html .= '.html';
  24         $t->{"$html : $txt"} = [ "\$(txt2pre) <$txt" ];
  25 }
  26 $v->{t_slash_star_dot_t} = [ grep(m!\At/.*\.t\z!, @manifest) ];
  27 my @scripts = qw(scripts/ssoma-replay); # legacy
  28 my @syn = (@EXE_FILES, grep(m!^lib/.*\.pm$!, @manifest), @scripts);
  29 @syn = grep(!/DSKQXS\.pm/, @syn) if !eval { require IO::KQueue };
  30 @syn = grep(!/Unsubscribe\.pm/, @syn) if !eval { require Crypt::CBC };
  31 @syn = grep(!/SaPlugin/, @syn) if !eval { require Mail::SpamAssasin };
  32 $v->{syn_files} = \@syn;
  33 $v->{my_syntax} = [map { "$_.syntax" } @syn];
  34 $v->{-m1} = [ map { (split('/'))[-1] } @EXE_FILES ];
  35 $v->{-m5} = [ qw(public-inbox-config public-inbox-v1-format
  36                 public-inbox-v2-format) ];
  37 $v->{-m7} = [ qw(public-inbox-overview) ];
  38 $v->{-m8} = [ qw(public-inbox-daemon) ];
  39 my @sections = (1, 5, 7, 8);
  40 $v->{check_80} = [];
  41 $v->{manuals} = [];
  42 $v->{mantxt} = [];
  43 for my $i (@sections) {
  44         my $ary = $v->{"-m$i"};
  45         $v->{"m$i"} = $ary;
  46         for my $m (@$ary) {
  47                 my $pod = "Documentation/$m.pod";
  48                 my $txt = "Documentation/$m.txt";
  49                 $t->{"$m.$i : $pod"} = [ "\$(podman) -s$i $pod \$@" ];
  50                 $t->{"$txt : $pod"} = [ "\$(podtext) $pod \$\@+",
  51                                         "touch -r $pod \$\@+",
  52                                         "mv \$\@+ \$@" ];
  53                 $t->{"Documentation/$m.html : $txt"} = [ "\$(txt2pre) <$txt" ];
  54                 $t->{".$m.cols : $m.$i"} = [
  55                         "\@echo CHECK80 $m.$i;".
  56                         "COLUMNS=80 \$(MAN) ./$m.$i | \$(check_man)" ];
  57         }
  58         push @{$v->{check_80}}, map { ".$_.cols" } @$ary;
  59         my $manuals = $v->{"man$i"} = [ map { "$_.$i" } @$ary ];
  60         push @{$v->{manuals}}, @$manuals;
  61         push @{$v->{mantxt}}, map { "Documentation/$_.txt" } @$ary;
  62 }
  63 push @dtxt, @{$v->{mantxt}};
  64 $v->{docs} = [ @dtxt, 'NEWS' ];
  65 $v->{docs_html} = [ map {;
  66                 my $x = $_;
  67                 $x =~ s/\.txt\z//;
  68                 "$x.html"
  69         } @{$v->{docs}} ];
  70 $v->{gz_docs} = [ map { "$_.gz" } (@{$v->{docs}},@{$v->{docs_html}}) ];
  71 $v->{rsync_docs} = [ @{$v->{gz_docs}}, @{$v->{docs}},
  72         @{$v->{docs_html}}, qw(NEWS.atom NEWS.atom.gz)];
  73
  74 # external manpages which we host ourselves, since some packages
  75 # (currently just Xapian) doesn't host manpages themselves.
  76 my @xman = qw(copydatabase.1 xapian-compact.1);
  77 $v->{xdocs} = [ map { "Documentation/.$_.txt" } @xman ];
  78 $v->{xdocs_html} = [ map { "Documentation/.$_.html" } @xman ];
  79 for (@{$v->{xdocs}}) {
  80         $t->{"$_:"} = [
  81                 '$(PERL) -w Documentation/extman.perl $@ >$@+',
  82                 'mv $@+ $@'
  83         ];
  84         my $html = $_;
  85         $html =~ s/\.txt\z/.html/;
  86         $t->{"$html : $_"} = [ "\$(txt2pre) <$_" ];
  87 }
  88 $v->{gz_xdocs} = [ map { "$_.gz" } (@{$v->{xdocs_html}}, @{$v->{xdocs}}) ];
  89 $v->{rsync_xdocs} = [ @{$v->{gz_xdocs}}, @{$v->{xdocs_html}}, @{$v->{xdocs}} ];
  90
  91 my $TGTS = join("\n", map {;
  92         my $tgt_prereq = $_;
  93         my $cmds = $t->{$_};
  94         "$tgt_prereq\n".join('', map { "\t$_\n" } @$cmds);
  95 } sort keys %$t);
  96
  97 my $VARS = join("\n", map {;
  98         my $varname = $_;
  99         join('', map { "$varname += $_\n" } sort @{$v->{$varname}});
 100 } grep(!/^-/, sort keys %$v));
 101 $VARS .= "\nRELEASES = ".join(' ', @RELEASES)."\n";
 102
 103 # Don't waste user's disk space by installing some pods from
 104 # imported code or internal use only
 105 my %man3 = map {; # semi-colon tells Perl this is a BLOCK (and not EXPR)
 106         my $base = $_;
 107         my $mod = $base;
 108         $mod =~ s!/!::!g;
 109         $mod =~ s/\.\w+\z//;
 110         "lib/PublicInbox/$_" => "blib/man3/PublicInbox::$mod.3"
 111 } qw(Git.pm Import.pm WWW.pod SaPlugin/ListMirror.pod);
 112
 113 WriteMakefile(
 114         NAME => 'PublicInbox',
 115         VERSION => '1.5.0',
 116         AUTHOR => 'Eric Wong <e@yhbt.net>',
 117         ABSTRACT => 'public-inbox server infrastructure',
 118         EXE_FILES => \@EXE_FILES,
 119         PREREQ_PM => {
 120                 # note: we use spamc(1), NOT the Perl modules
 121                 # We also depend on git.
 122                 # Keep this sorted and synced to the INSTALL document
 123
 124                 # libperl$PERL_VERSION,
 125                 # `perl5' on FreeBSD
 126                 # perl-Digest-SHA on RH-based
 127                 'Digest::SHA' => 0,
 128
 129                 # libperl$PERL_VERSION or libencode-perl on Debian,
 130                 # `perl5' on FreeBSD
 131                 'Encode' => 2.35, # 2.35 shipped with 5.10.1
 132
 133                 # libperl$PERL_VERSION + perl-modules-$PERL_VERSION
 134                 'Compress::Raw::Zlib' => 0,
 135                 'Compress::Zlib' => 0,
 136                 'IO::Compress::Gzip' => 0,
 137
 138                 # Plack is needed for public-inbox-httpd and PublicInbox::WWW
 139                 # 'Plack' => 0,
 140
 141                 # Filesys::Notify::Simple is pulled in by Plack, but also
 142                 # needed by public-inbox-watch (for now)
 143                 # 'Filesys::Notify::Simple' => 0,
 144
 145                 # TODO: this should really be made optional...
 146                 'URI::Escape' => 0,
 147
 148                 # We have more test dependencies, but do not force
 149                 # users to install them.  See INSTALL
 150
 151                 # All Perl installs I know about have these, but RH-based
 152                 # distros make them separate even though 'perl' pulls them in
 153                 'File::Path' => 0,
 154                 'File::Temp' => '0.19', # for ->tmpdir support
 155                 'Getopt::Long' => 0,
 156                 'Exporter' => 0,
 157                 # ExtUtils::MakeMaker # this file won't run w/o it...
 158         },
 159         MAN3PODS => \%man3,
 160 );
 161
 162 sub MY::postamble {
 163   <<EOF;
 164 PROVE = prove
 165 # support using eatmydata to speed up tests (apt-get install eatmydata):
 166 # https://www.flamingspork.com/projects/libeatmydata/
 167 EATMYDATA =
 168 N = \$\$(( \$\$(nproc 2>/dev/null || gnproc 2>/dev/null || echo 2) + 1 ))
 169 -include config.mak
 170 $VARS
 171 -include Documentation/include.mk
 172 $TGTS
 173
 174 # syntax checks are currently GNU make only:
 175 %.syntax :: %
 176         @\$(PERL) -w -I lib -c \$<
 177
 178 syntax:: \$(my_syntax)
 179
 180 changed = \$(shell git ls-files -m)
 181 dsyn :: \$(addsuffix .syntax, \$(filter \$(changed), \$(syn_files)))
 182
 183 check-manifest :: MANIFEST
 184         if test -e .git && git ls-files >\$?.gen 2>&1; then \\
 185                 diff -u \$? \$?.gen; fi
 186
 187 # the traditional way running per-*.t processes:
 188 check-each :: pure_all check-manifest
 189         \$(EATMYDATA) \$(PROVE) --state=save -bvw -j\$(N)
 190
 191 # lightly-tested way to run tests, relies "--state=save" in check-each
 192 # for best performance
 193 check-run :: pure_all check-manifest
 194         \$(EATMYDATA) \$(PROVE) -bvw t/run.perl :: -j\$(N)
 195
 196 check :: check-each
 197
 198 lib/PublicInbox/UserContent.pm :: contrib/css/216dark.css
 199         \$(PERL) -I lib \$@ \$?
 200
 201 # Ensure new .pm files will always be installed by updating
 202 # the timestamp of Makefile.PL which forces Makefile to be remade
 203 Makefile.PL : MANIFEST
 204         touch -r MANIFEST \$@
 205         \$(PERLRUN) \$@
 206
 207 EOF
 208 }