]> Sergey Matveev's repositories - public-inbox.git/blob - Makefile.PL
Allow images and HTML
[public-inbox.git] / Makefile.PL
1 #!/usr/bin/perl -w
2 # Copyright (C) all contributors <meta@public-inbox.org>
3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
4 use strict;
5 use ExtUtils::MakeMaker;
6 open my $m, '<', 'MANIFEST' or die "open(MANIFEST): $!\n";
7 chomp(my @manifest = (<$m>));
8 push @manifest, 'lib/PublicInbox.pm'; # generated
9 my @EXE_FILES = grep(m!^script/!, @manifest);
10 my $v = {};
11 my $t = {};
12
13 # do not sort
14 my @RELEASES = qw(v1.8.0 v1.7.0 v1.6.1 v1.6.0 v1.5.0 v1.4.0 v1.3.0 v1.2.0
15         v1.1.0-pre1 v1.0.0);
16
17 $v->{news_deps} = [ map { "Documentation/RelNotes/$_.eml" } @RELEASES ];
18 $v->{txt} = [ qw(INSTALL README COPYING TODO HACKING) ];
19 my @dtxt = grep(m!\ADocumentation/[^/]+\.txt\z!, @manifest);
20 push @dtxt, 'Documentation/standards.txt';
21 push @dtxt, 'Documentation/flow.txt';
22 push @dtxt, @{$v->{txt}};
23 for my $txt (@dtxt) {
24         my $html = $txt;
25         $html =~ s/\.txt\z/.html/ or $html .= '.html';
26         $t->{"$html : $txt"} = [ "\$(txt2pre) <$txt", "touch -r $txt \$@" ];
27 }
28 $v->{t_slash_star_dot_t} = [ grep(m!\At/.*\.t\z!, @manifest) ];
29 my @scripts = qw(scripts/ssoma-replay); # legacy
30 my @syn = (@EXE_FILES, grep(m!^lib/.*\.pm$!, @manifest), @scripts);
31 @syn = grep(!/DSKQXS\.pm/, @syn) if !eval { require IO::KQueue };
32 @syn = grep(!/Unsubscribe\.pm/, @syn) if !eval { require Crypt::CBC };
33 @syn = grep(!/SaPlugin/, @syn) if !eval { require Mail::SpamAssasin };
34 $v->{syn_files} = \@syn;
35 $v->{my_syntax} = [map { "$_.syntax" } @syn];
36 my @no_pod;
37 $v->{-m1} = [ map {
38                 my $x = (split('/'))[-1];
39                 my $pod = "Documentation/$x.pod";
40                 if (-f $pod) {
41                         $x;
42                 } else {
43                         warn "W: $pod missing\n";
44                         push @no_pod, $x;
45                         ();
46                 }
47         } @EXE_FILES,
48         qw(
49         lei-add-external lei-add-watch lei-blob lei-config lei-convert
50         lei-daemon-kill lei-daemon-pid lei-edit-search lei-export-kw
51         lei-forget-external lei-forget-mail-sync lei-forget-search
52         lei-import lei-index lei-init lei-inspect lei-lcat
53         lei-ls-external lei-ls-label lei-ls-mail-source lei-ls-mail-sync
54         lei-ls-search lei-ls-watch lei-mail-diff lei-p2q lei-q
55         lei-rediff lei-refresh-mail-sync lei-rm lei-rm-watch lei-tag
56         lei-up)];
57 $v->{-m5} = [ qw(public-inbox-config public-inbox-v1-format
58                 public-inbox-v2-format public-inbox-extindex-format
59                 lei-mail-formats lei-store-format
60                 ) ];
61 $v->{-m7} = [ qw(lei-mail-sync-overview lei-overview lei-security
62                 public-inbox-overview public-inbox-tuning
63                 public-inbox-glossary) ];
64 $v->{-m8} = [ qw(public-inbox-daemon lei-daemon) ];
65 my @sections = (1, 5, 7, 8);
66 $v->{check_80} = [];
67 $v->{manuals} = [];
68 $v->{mantxt} = [];
69 for my $i (@sections) {
70         my $ary = $v->{"-m$i"};
71         $v->{"m$i"} = $ary;
72         for my $m (@$ary) {
73                 my $pod = "Documentation/$m.pod";
74                 my $txt = "Documentation/$m.txt";
75                 $t->{"$m.$i : $pod"} = [ "\$(podman) -s$i $pod \$@" ];
76                 $t->{"$txt : $m.$i"} = [ "\$(man2text) ./$m.$i >\$\@+",
77                                         "touch -r $pod \$\@+ ./$m.$i",
78                                         "mv \$\@+ \$@" ];
79                 $t->{"Documentation/$m.html : $txt"} = [ "\$(txt2pre) <$txt",
80                                                         "touch -r $txt \$@" ];
81                 $t->{".$m.cols : $m.$i"} = [
82                         "\@echo CHECK80 $m.$i;".
83                         "COLUMNS=80 \$(MAN) ./$m.$i | \$(check_man)",
84                         '>$@' ];
85                 $t->{".$m.lexgrog: $m.$i"} = [
86                         "\@echo LEXGROG $m.$i;" .
87                         "\$(LEXGROG) ./$m.$i >\$\@+ && mv \$\@+ \$@" ];
88         }
89         push @{$v->{check_80}}, map { ".$_.cols" } @$ary;
90         push @{$v->{check_lexgrog}}, map { ".$_.lexgrog" } @$ary;
91         my $manuals = $v->{"man$i"} = [ map { "$_.$i" } @$ary ];
92         push @{$v->{manuals}}, @$manuals;
93         push @{$v->{mantxt}}, map { "Documentation/$_.txt" } @$ary;
94 }
95 $v->{docs} = [ @dtxt, 'NEWS' ];
96 $v->{docs_html} = [ map {;
97                 my $x = $_;
98                 $x =~ s/\.txt\z//;
99                 "$x.html"
100         } (@{$v->{docs}}, @{$v->{mantxt}}) ];
101 $v->{gz_docs} = [ map { "$_.gz" } (@{$v->{docs}},@{$v->{docs_html}}) ];
102 $v->{rsync_docs} = [ @{$v->{gz_docs}}, @{$v->{docs}},
103         @{$v->{docs_html}}, qw(NEWS.atom NEWS.atom.gz)];
104
105 my $TGTS = join("\n", map {;
106         my $tgt_prereq = $_;
107         my $cmds = $t->{$_};
108         "$tgt_prereq\n".join('', map { "\t$_\n" } @$cmds);
109 } sort keys %$t);
110
111 my $VARS = join("\n", map {;
112         my $varname = $_;
113         join('', map { "$varname += $_\n" } sort @{$v->{$varname}});
114 } grep(!/^-/, sort keys %$v));
115 $VARS .= "\nRELEASES = ".join(' ', @RELEASES)."\n";
116
117 # Don't waste user's disk space by installing some pods from
118 # imported code or internal use only
119 my %man3 = map {; # semi-colon tells Perl this is a BLOCK (and not EXPR)
120         my $base = $_;
121         my $mod = $base;
122         $mod =~ s!/!::!g;
123         $mod =~ s/\.\w+\z//;
124         "lib/PublicInbox/$_" => "blib/man3/PublicInbox::$mod.\$(MAN3EXT)"
125 } qw(Git.pm Import.pm WWW.pod SaPlugin/ListMirror.pod);
126 my $warn_no_pod = @no_pod ? "\n\t\@echo W: missing .pod: @no_pod\n" : '';
127 chomp(my $lexgrog = `which lexgrog 2>/dev/null`);
128 my $check_lexgrog = $lexgrog ? 'check-lexgrog' : '';
129
130 WriteMakefile(
131         NAME => 'PublicInbox', # n.b. camel-case is not our choice
132
133         # XXX drop "PENDING" in .pod before updating this!
134         VERSION => '1.9.0.PENDING',
135
136         AUTHOR => 'public-inbox hackers <meta@public-inbox.org>',
137         ABSTRACT => 'an "archives first" approach to mailing lists',
138         EXE_FILES => \@EXE_FILES,
139
140         # DO NOT blindly put "use v5.12" in *.pm files, unicode_strings
141         # causes known breakages.  "use v5.10.1" is safe, though
142         MIN_PERL_VERSION => '5.12.0',
143         LICENSE => 'agpl_3', # AGPL-3.0+, CPAN::Meta::Spec doesn't have '+'
144         PREREQ_PM => {
145                 # note: we use spamc(1), NOT the Perl modules
146                 # We also depend on git.
147                 # Keep this sorted and synced to the INSTALL document
148
149                 # perl-modules-5.xx or libperl5.xx in Debian-based
150                 # part of "perl5" on FreeBSD
151                 'Compress::Raw::Zlib' => 0,
152                 'Compress::Zlib' => 0,
153                 'Data::Dumper' => 0,
154                 'Digest::SHA' => 0, # rpm: perl-Digest-SHA
155                 'Encode' => 2.35, # 2.35 shipped with 5.10.1
156                 'IO::Compress::Gzip' => 0,
157                 'IO::Uncompress::Gunzip' => 0,
158                 'Storable' => 0, # rpm: perl-Storable
159                 'Text::ParseWords' => 0, # rpm: perl-Text-ParseWords
160
161                 # Plack is needed for public-inbox-httpd and PublicInbox::WWW
162                 # 'Plack' => 0,
163
164                 'URI' => 0,
165
166                 # We have more test dependencies, but do not force
167                 # users to install them.  See INSTALL
168
169                 # All Perl installs I know about have these, but RH-based
170                 # distros make them separate even though 'perl' pulls them in
171                 'File::Path' => 0,
172                 'File::Temp' => '0.19', # for ->tmpdir support
173                 'Getopt::Long' => 0,
174                 'Exporter' => 0,
175                 # ExtUtils::MakeMaker # this file won't run w/o it...
176         },
177         MAN3PODS => \%man3,
178         clean => {
179                 FILES => 't/home*/setup* t/home*/t* t/home*/.public-inbox '.
180                         't/data-gen/*'
181         },
182         PM => {
183                 map {
184                         s[^lib/][]s;
185                         +('lib/' . $_ => '$(INST_LIB)/' . $_);
186                 } grep {
187                         # Will include *.pod and an *.h file, but so
188                         # would ExtUtils::MakeMaker.
189                         m[^lib/];
190                 } @manifest
191         },
192 );
193
194 sub MY::postamble {
195         my $N = (`{ getconf _NPROCESSORS_ONLN || nproc; } 2>/dev/null` || 1);
196         $N += 1; # account for sleeps in some tests (and makes an IV)
197         <<EOF;
198 PROVE = prove
199 # support using eatmydata to speed up tests (apt-get install eatmydata):
200 # https://www.flamingspork.com/projects/libeatmydata/
201 EATMYDATA =
202 N = $N
203 -include config.mak
204 $VARS
205 -include Documentation/include.mk
206 $TGTS
207
208 check-man :: $check_lexgrog$warn_no_pod
209
210 # syntax checks are currently GNU make only:
211 %.syntax :: %
212         @\$(PERL) -w -I lib -c \$<
213
214 syntax:: \$(my_syntax)
215
216 changed = \$(shell git ls-files -m)
217 dsyn :: \$(addsuffix .syntax, \$(filter \$(changed), \$(syn_files)))
218
219 check_manifest := if test -e .git && git ls-files >MANIFEST.gen 2>&1; then \\
220                 diff -u MANIFEST MANIFEST.gen; fi
221
222 check-manifest : MANIFEST
223         \$(check_manifest)
224
225 # the traditional way running per-*.t processes:
226 check-each :: pure_all
227         \$(EATMYDATA) \$(PROVE) --state=save -bvw -j\$(N)
228         -@\$(check_manifest)
229
230 # lightly-tested way to run tests, relies "--state=save" in check-each
231 # for best performance
232 check-run :: pure_all check-man
233         \$(EATMYDATA) \$(PROVE) -bvw t/run.perl :: -j\$(N)
234         -@\$(check_manifest)
235
236 check :: check-each
237
238 lib/PublicInbox/UserContent.pm :: contrib/css/216dark.css
239         \$(PERL) -I lib \$@ \$?
240
241 # Ensure new .pm files will always be installed by updating
242 # the timestamp of Makefile.PL which forces Makefile to be remade
243 Makefile.PL : MANIFEST
244         touch -r MANIFEST \$@
245         \$(PERLRUN) \$@
246
247 # Install symlinks to ~/bin (which is hopefuly in PATH) which point to
248 # this source tree.
249 # prefix + bindir matches git.git Makefile:
250 prefix = \$(HOME)
251 bindir = \$(prefix)/bin
252 symlink-install : lib/PublicInbox.pm
253         mkdir -p \$(bindir)
254         lei=\$\$(realpath lei.sh) && cd \$(bindir) && \\
255         for x in \$(EXE_FILES); do \\
256                 ln -sf "\$\$lei" \$\$(basename "\$\$x"); \\
257         done
258
259 pure_all :: lib/PublicInbox.pm
260 lib/PublicInbox.pm : FORCE
261         VERSION=\$(VERSION) \$(PERL) -w ./version-gen.perl
262
263 update-copyrights :
264         \@case '\$(GNULIB_PATH)' in '') echo >&2 GNULIB_PATH unset; false;; esac
265         git ls-files | UPDATE_COPYRIGHT_HOLDER='all contributors' \\
266                 UPDATE_COPYRIGHT_USE_INTERVALS=2 \\
267                 xargs \$(GNULIB_PATH)/build-aux/update-copyright
268 EOF
269 }