Makefile.PL

   1 #!/usr/bin/perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use ExtUtils::MakeMaker;
   6 open my $m, '<', 'MANIFEST' or die "open(MANIFEST): $!\n";
   7 chomp(my @manifest = (<$m>));
   8 push @manifest, 'lib/PublicInbox.pm'; # generated
   9 my @EXE_FILES = grep(m!^script/!, @manifest);
  10 my $v = {};
  11 my $t = {};
  12
  13 # do not sort
  14 my @RELEASES = qw(v1.7.0 v1.6.1 v1.6.0 v1.5.0 v1.4.0 v1.3.0 v1.2.0
  15         v1.1.0-pre1 v1.0.0);
  16
  17 $v->{news_deps} = [ map { "Documentation/RelNotes/$_.eml" } @RELEASES ];
  18 $v->{txt} = [ qw(INSTALL README COPYING TODO HACKING) ];
  19 my @dtxt = grep(m!\ADocumentation/[^/]+\.txt\z!, @manifest);
  20 push @dtxt, 'Documentation/standards.txt';
  21 push @dtxt, 'Documentation/flow.txt';
  22 push @dtxt, @{$v->{txt}};
  23 for my $txt (@dtxt) {
  24         my $html = $txt;
  25         $html =~ s/\.txt\z/.html/ or $html .= '.html';
  26         $t->{"$html : $txt"} = [ "\$(txt2pre) <$txt", "touch -r $txt \$@" ];
  27 }
  28 $v->{t_slash_star_dot_t} = [ grep(m!\At/.*\.t\z!, @manifest) ];
  29 my @scripts = qw(scripts/ssoma-replay); # legacy
  30 my @syn = (@EXE_FILES, grep(m!^lib/.*\.pm$!, @manifest), @scripts);
  31 @syn = grep(!/DSKQXS\.pm/, @syn) if !eval { require IO::KQueue };
  32 @syn = grep(!/Unsubscribe\.pm/, @syn) if !eval { require Crypt::CBC };
  33 @syn = grep(!/SaPlugin/, @syn) if !eval { require Mail::SpamAssasin };
  34 $v->{syn_files} = \@syn;
  35 $v->{my_syntax} = [map { "$_.syntax" } @syn];
  36 my @no_pod;
  37 $v->{-m1} = [ map {
  38                 my $x = (split('/'))[-1];
  39                 my $pod = "Documentation/$x.pod";
  40                 if (-f $pod) {
  41                         $x;
  42                 } else {
  43                         warn "W: $pod missing\n";
  44                         push @no_pod, $x;
  45                         ();
  46                 }
  47         } @EXE_FILES,
  48         qw(
  49         lei-add-external lei-add-watch lei-blob lei-config lei-convert
  50         lei-daemon-kill lei-daemon-pid lei-edit-search lei-export-kw
  51         lei-forget-external lei-forget-mail-sync lei-forget-search
  52         lei-import lei-index lei-init lei-inspect lei-lcat
  53         lei-ls-external lei-ls-label lei-ls-mail-source lei-ls-mail-sync
  54         lei-ls-search lei-ls-watch lei-mail-diff lei-p2q lei-q
  55         lei-rediff lei-refresh-mail-sync lei-rm lei-rm-watch lei-tag
  56         lei-up)];
  57 $v->{-m5} = [ qw(public-inbox-config public-inbox-v1-format
  58                 public-inbox-v2-format public-inbox-extindex-format
  59                 lei-mail-formats lei-store-format
  60                 ) ];
  61 $v->{-m7} = [ qw(lei-mail-sync-overview lei-overview lei-security
  62                 public-inbox-overview public-inbox-tuning
  63                 public-inbox-glossary) ];
  64 $v->{-m8} = [ qw(public-inbox-daemon lei-daemon) ];
  65 my @sections = (1, 5, 7, 8);
  66 $v->{check_80} = [];
  67 $v->{manuals} = [];
  68 $v->{mantxt} = [];
  69 for my $i (@sections) {
  70         my $ary = $v->{"-m$i"};
  71         $v->{"m$i"} = $ary;
  72         for my $m (@$ary) {
  73                 my $pod = "Documentation/$m.pod";
  74                 my $txt = "Documentation/$m.txt";
  75                 $t->{"$m.$i : $pod"} = [ "\$(podman) -s$i $pod \$@" ];
  76                 $t->{"$txt : $m.$i"} = [ "\$(man2text) ./$m.$i >\$\@+",
  77                                         "touch -r $pod \$\@+ ./$m.$i",
  78                                         "mv \$\@+ \$@" ];
  79                 $t->{"Documentation/$m.html : $txt"} = [ "\$(txt2pre) <$txt",
  80                                                         "touch -r $txt \$@" ];
  81                 $t->{".$m.cols : $m.$i"} = [
  82                         "\@echo CHECK80 $m.$i;".
  83                         "COLUMNS=80 \$(MAN) ./$m.$i | \$(check_man)",
  84                         '>$@' ];
  85                 $t->{".$m.lexgrog: $m.$i"} = [
  86                         "\@echo LEXGROG $m.$i;" .
  87                         "\$(LEXGROG) ./$m.$i >\$\@+ && mv \$\@+ \$@" ];
  88         }
  89         push @{$v->{check_80}}, map { ".$_.cols" } @$ary;
  90         push @{$v->{check_lexgrog}}, map { ".$_.lexgrog" } @$ary;
  91         my $manuals = $v->{"man$i"} = [ map { "$_.$i" } @$ary ];
  92         push @{$v->{manuals}}, @$manuals;
  93         push @{$v->{mantxt}}, map { "Documentation/$_.txt" } @$ary;
  94 }
  95 push @dtxt;
  96 $v->{docs} = [ @dtxt, 'NEWS' ];
  97 $v->{docs_html} = [ map {;
  98                 my $x = $_;
  99                 $x =~ s/\.txt\z//;
 100                 "$x.html"
 101         } (@{$v->{docs}}, @{$v->{mantxt}}) ];
 102 $v->{gz_docs} = [ map { "$_.gz" } (@{$v->{docs}},@{$v->{docs_html}}) ];
 103 $v->{rsync_docs} = [ @{$v->{gz_docs}}, @{$v->{docs}},
 104         @{$v->{docs_html}}, qw(NEWS.atom NEWS.atom.gz)];
 105
 106 my $TGTS = join("\n", map {;
 107         my $tgt_prereq = $_;
 108         my $cmds = $t->{$_};
 109         "$tgt_prereq\n".join('', map { "\t$_\n" } @$cmds);
 110 } sort keys %$t);
 111
 112 my $VARS = join("\n", map {;
 113         my $varname = $_;
 114         join('', map { "$varname += $_\n" } sort @{$v->{$varname}});
 115 } grep(!/^-/, sort keys %$v));
 116 $VARS .= "\nRELEASES = ".join(' ', @RELEASES)."\n";
 117
 118 # Don't waste user's disk space by installing some pods from
 119 # imported code or internal use only
 120 my %man3 = map {; # semi-colon tells Perl this is a BLOCK (and not EXPR)
 121         my $base = $_;
 122         my $mod = $base;
 123         $mod =~ s!/!::!g;
 124         $mod =~ s/\.\w+\z//;
 125         "lib/PublicInbox/$_" => "blib/man3/PublicInbox::$mod.\$(MAN3EXT)"
 126 } qw(Git.pm Import.pm WWW.pod SaPlugin/ListMirror.pod);
 127 my $warn_no_pod = @no_pod ? "\n\t\@echo W: missing .pod: @no_pod\n" : '';
 128 chomp(my $lexgrog = `which lexgrog 2>/dev/null`);
 129 my $check_lexgrog = $lexgrog ? 'check-lexgrog' : '';
 130
 131 WriteMakefile(
 132         NAME => 'PublicInbox', # n.b. camel-case is not our choice
 133
 134         # XXX drop "PENDING" in .pod before updating this!
 135         VERSION => '1.7.0',
 136
 137         AUTHOR => 'Eric Wong <e@80x24.org>',
 138         ABSTRACT => 'public-inbox server infrastructure',
 139         EXE_FILES => \@EXE_FILES,
 140         PREREQ_PM => {
 141                 # note: we use spamc(1), NOT the Perl modules
 142                 # We also depend on git.
 143                 # Keep this sorted and synced to the INSTALL document
 144
 145                 # perl-modules-5.xx or libperl5.xx in Debian-based
 146                 # part of "perl5" on FreeBSD
 147                 'Compress::Raw::Zlib' => 0,
 148                 'Compress::Zlib' => 0,
 149                 'Data::Dumper' => 0,
 150                 'Digest::SHA' => 0, # rpm: perl-Digest-SHA
 151                 'Encode' => 2.35, # 2.35 shipped with 5.10.1
 152                 'IO::Compress::Gzip' => 0,
 153                 'IO::Uncompress::Gunzip' => 0,
 154                 'Storable' => 0, # rpm: perl-Storable
 155                 'Text::ParseWords' => 0, # rpm: perl-Text-ParseWords
 156
 157                 # Plack is needed for public-inbox-httpd and PublicInbox::WWW
 158                 # 'Plack' => 0,
 159
 160                 'URI' => 0,
 161
 162                 # We have more test dependencies, but do not force
 163                 # users to install them.  See INSTALL
 164
 165                 # All Perl installs I know about have these, but RH-based
 166                 # distros make them separate even though 'perl' pulls them in
 167                 'File::Path' => 0,
 168                 'File::Temp' => '0.19', # for ->tmpdir support
 169                 'Getopt::Long' => 0,
 170                 'Exporter' => 0,
 171                 # ExtUtils::MakeMaker # this file won't run w/o it...
 172         },
 173         MAN3PODS => \%man3,
 174         clean => {
 175                 FILES => 't/home*/setup* t/home*/t* t/home*/.public-inbox '.
 176                         't/data-gen/*'
 177         },
 178         PM => {
 179                 map {
 180                         s[^lib/][]s;
 181                         +('lib/' . $_ => '$(INST_LIB)/' . $_);
 182                 } grep {
 183                         # Will include *.pod and an *.h file, but so
 184                         # would ExtUtils::MakeMaker.
 185                         m[^lib/];
 186                 } @manifest
 187         },
 188 );
 189
 190 sub MY::postamble {
 191         my $N = (`{ getconf _NPROCESSORS_ONLN || nproc; } 2>/dev/null` || 1);
 192         $N += 1; # account for sleeps in some tests (and makes an IV)
 193         <<EOF;
 194 PROVE = prove
 195 # support using eatmydata to speed up tests (apt-get install eatmydata):
 196 # https://www.flamingspork.com/projects/libeatmydata/
 197 EATMYDATA =
 198 N = $N
 199 -include config.mak
 200 $VARS
 201 -include Documentation/include.mk
 202 $TGTS
 203
 204 check-man :: $check_lexgrog$warn_no_pod
 205
 206 # syntax checks are currently GNU make only:
 207 %.syntax :: %
 208         @\$(PERL) -w -I lib -c \$<
 209
 210 syntax:: \$(my_syntax)
 211
 212 changed = \$(shell git ls-files -m)
 213 dsyn :: \$(addsuffix .syntax, \$(filter \$(changed), \$(syn_files)))
 214
 215 check_manifest := if test -e .git && git ls-files >MANIFEST.gen 2>&1; then \\
 216                 diff -u MANIFEST MANIFEST.gen; fi
 217
 218 check-manifest : MANIFEST
 219         \$(check_manifest)
 220
 221 # the traditional way running per-*.t processes:
 222 check-each :: pure_all
 223         \$(EATMYDATA) \$(PROVE) --state=save -bvw -j\$(N)
 224         -@\$(check_manifest)
 225
 226 # lightly-tested way to run tests, relies "--state=save" in check-each
 227 # for best performance
 228 check-run :: pure_all check-man
 229         \$(EATMYDATA) \$(PROVE) -bvw t/run.perl :: -j\$(N)
 230         -@\$(check_manifest)
 231
 232 check :: check-each
 233
 234 lib/PublicInbox/UserContent.pm :: contrib/css/216dark.css
 235         \$(PERL) -I lib \$@ \$?
 236
 237 # Ensure new .pm files will always be installed by updating
 238 # the timestamp of Makefile.PL which forces Makefile to be remade
 239 Makefile.PL : MANIFEST
 240         touch -r MANIFEST \$@
 241         \$(PERLRUN) \$@
 242
 243 # Install symlinks to ~/bin (which is hopefuly in PATH) which point to
 244 # this source tree.
 245 # prefix + bindir matches git.git Makefile:
 246 prefix = \$(HOME)
 247 bindir = \$(prefix)/bin
 248 symlink-install : lib/PublicInbox.pm
 249         mkdir -p \$(bindir)
 250         lei=\$\$(realpath lei.sh) && cd \$(bindir) && \\
 251         for x in \$(EXE_FILES); do \\
 252                 ln -sf "\$\$lei" \$\$(basename "\$\$x"); \\
 253         done
 254
 255 pure_all :: lib/PublicInbox.pm
 256 lib/PublicInbox.pm : FORCE
 257         VERSION=\$(VERSION) \$(PERL) -w ./version-gen.perl
 258
 259 update-copyrights :
 260         \@case '\$(GNULIB_PATH)' in '') echo >&2 GNULIB_PATH unset; false;; esac
 261         git ls-files | UPDATE_COPYRIGHT_HOLDER='all contributors' \\
 262                 UPDATE_COPYRIGHT_USE_INTERVALS=2 \\
 263                 xargs \$(GNULIB_PATH)/build-aux/update-copyright
 264 EOF
 265 }