Makefile.PL

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2013-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use ExtUtils::MakeMaker;
   6 open my $m, '<', 'MANIFEST' or die "open(MANIFEST): $!\n";
   7 chomp(my @manifest = (<$m>));
   8 my @EXE_FILES = grep(m!^script/!, @manifest);
   9 my $v = {};
  10 my $t = {};
  11
  12 # do not sort
  13 my @RELEASES = qw(v1.6.1 v1.6.0 v1.5.0 v1.4.0 v1.3.0 v1.2.0 v1.1.0-pre1 v1.0.0);
  14
  15 $v->{news_deps} = [ map { "Documentation/RelNotes/$_.eml" } @RELEASES ];
  16 $v->{txt} = [ qw(INSTALL README COPYING TODO HACKING) ];
  17 my @dtxt = grep(m!\ADocumentation/[^/]+\.txt\z!, @manifest);
  18 push @dtxt, 'Documentation/standards.txt';
  19 push @dtxt, 'Documentation/flow.txt';
  20 push @dtxt, @{$v->{txt}};
  21 for my $txt (@dtxt) {
  22         my $html = $txt;
  23         $html =~ s/\.txt\z/.html/ or $html .= '.html';
  24         $t->{"$html : $txt"} = [ "\$(txt2pre) <$txt" ];
  25 }
  26 $v->{t_slash_star_dot_t} = [ grep(m!\At/.*\.t\z!, @manifest) ];
  27 my @scripts = qw(scripts/ssoma-replay); # legacy
  28 my @syn = (@EXE_FILES, grep(m!^lib/.*\.pm$!, @manifest), @scripts);
  29 @syn = grep(!/DSKQXS\.pm/, @syn) if !eval { require IO::KQueue };
  30 @syn = grep(!/Unsubscribe\.pm/, @syn) if !eval { require Crypt::CBC };
  31 @syn = grep(!/SaPlugin/, @syn) if !eval { require Mail::SpamAssasin };
  32 $v->{syn_files} = \@syn;
  33 $v->{my_syntax} = [map { "$_.syntax" } @syn];
  34 my @no_pod;
  35 $v->{-m1} = [ map {
  36                 my $x = (split('/'))[-1];
  37                 my $pod = "Documentation/$x.pod";
  38                 if (-f $pod) {
  39                         $x;
  40                 } else {
  41                         warn "W: $pod missing\n";
  42                         push @no_pod, $x;
  43                         ();
  44                 }
  45         } @EXE_FILES,
  46         qw(
  47         lei-add-external lei-blob lei-config lei-daemon-kill lei-daemon-pid
  48         lei-forget-external lei-import lei-init lei-ls-external lei-ls-label
  49         lei-tag lei-p2q lei-q)];
  50 $v->{-m5} = [ qw(public-inbox-config public-inbox-v1-format
  51                 public-inbox-v2-format public-inbox-extindex-format) ];
  52 $v->{-m7} = [ qw(lei-overview public-inbox-overview public-inbox-tuning
  53                 public-inbox-glossary) ];
  54 $v->{-m8} = [ qw(public-inbox-daemon) ];
  55 my @sections = (1, 5, 7, 8);
  56 $v->{check_80} = [];
  57 $v->{manuals} = [];
  58 $v->{mantxt} = [];
  59 for my $i (@sections) {
  60         my $ary = $v->{"-m$i"};
  61         $v->{"m$i"} = $ary;
  62         for my $m (@$ary) {
  63                 my $pod = "Documentation/$m.pod";
  64                 my $txt = "Documentation/$m.txt";
  65                 $t->{"$m.$i : $pod"} = [ "\$(podman) -s$i $pod \$@" ];
  66                 $t->{"$txt : $pod"} = [ "\$(podtext) $pod \$\@+",
  67                                         "touch -r $pod \$\@+",
  68                                         "mv \$\@+ \$@" ];
  69                 $t->{"Documentation/$m.html : $txt"} = [ "\$(txt2pre) <$txt" ];
  70                 $t->{".$m.cols : $m.$i"} = [
  71                         "\@echo CHECK80 $m.$i;".
  72                         "COLUMNS=80 \$(MAN) ./$m.$i | \$(check_man)" ];
  73                 $t->{".$m.lexgrog: $m.$i"} = [
  74                         "\@echo LEXGROG $m.$i;" .
  75                         "\$(LEXGROG) ./$m.$i >\$\@+ && mv \$\@+ \$@" ];
  76         }
  77         push @{$v->{check_80}}, map { ".$_.cols" } @$ary;
  78         push @{$v->{check_lexgrog}}, map { ".$_.lexgrog" } @$ary;
  79         my $manuals = $v->{"man$i"} = [ map { "$_.$i" } @$ary ];
  80         push @{$v->{manuals}}, @$manuals;
  81         push @{$v->{mantxt}}, map { "Documentation/$_.txt" } @$ary;
  82 }
  83 push @dtxt, @{$v->{mantxt}};
  84 $v->{docs} = [ @dtxt, 'NEWS' ];
  85 $v->{docs_html} = [ map {;
  86                 my $x = $_;
  87                 $x =~ s/\.txt\z//;
  88                 "$x.html"
  89         } @{$v->{docs}} ];
  90 $v->{gz_docs} = [ map { "$_.gz" } (@{$v->{docs}},@{$v->{docs_html}}) ];
  91 $v->{rsync_docs} = [ @{$v->{gz_docs}}, @{$v->{docs}},
  92         @{$v->{docs_html}}, qw(NEWS.atom NEWS.atom.gz)];
  93
  94 # external manpages which we host ourselves, since some packages
  95 # (currently just Xapian) doesn't host manpages themselves.
  96 my @xman = qw(copydatabase.1 xapian-compact.1);
  97 $v->{xdocs} = [ map { "Documentation/.$_.txt" } @xman ];
  98 $v->{xdocs_html} = [ map { "Documentation/.$_.html" } @xman ];
  99 for (@{$v->{xdocs}}) {
 100         $t->{"$_:"} = [
 101                 '$(PERL) -w Documentation/extman.perl $@ >$@+',
 102                 'mv $@+ $@'
 103         ];
 104         my $html = $_;
 105         $html =~ s/\.txt\z/.html/;
 106         $t->{"$html : $_"} = [ "\$(txt2pre) <$_" ];
 107 }
 108 $v->{gz_xdocs} = [ map { "$_.gz" } (@{$v->{xdocs_html}}, @{$v->{xdocs}}) ];
 109 $v->{rsync_xdocs} = [ @{$v->{gz_xdocs}}, @{$v->{xdocs_html}}, @{$v->{xdocs}} ];
 110
 111 my $TGTS = join("\n", map {;
 112         my $tgt_prereq = $_;
 113         my $cmds = $t->{$_};
 114         "$tgt_prereq\n".join('', map { "\t$_\n" } @$cmds);
 115 } sort keys %$t);
 116
 117 my $VARS = join("\n", map {;
 118         my $varname = $_;
 119         join('', map { "$varname += $_\n" } sort @{$v->{$varname}});
 120 } grep(!/^-/, sort keys %$v));
 121 $VARS .= "\nRELEASES = ".join(' ', @RELEASES)."\n";
 122
 123 # Don't waste user's disk space by installing some pods from
 124 # imported code or internal use only
 125 my %man3 = map {; # semi-colon tells Perl this is a BLOCK (and not EXPR)
 126         my $base = $_;
 127         my $mod = $base;
 128         $mod =~ s!/!::!g;
 129         $mod =~ s/\.\w+\z//;
 130         "lib/PublicInbox/$_" => "blib/man3/PublicInbox::$mod.\$(MAN3EXT)"
 131 } qw(Git.pm Import.pm WWW.pod SaPlugin/ListMirror.pod);
 132 my $warn_no_pod = @no_pod ? "\n\t\@echo W: missing .pod: @no_pod\n" : '';
 133 chomp(my $lexgrog = `which lexgrog 2>/dev/null`);
 134 my $check_lexgrog = $lexgrog ? 'check-lexgrog' : '';
 135
 136 WriteMakefile(
 137         NAME => 'PublicInbox', # n.b. camel-case is not our choice
 138
 139         # XXX drop "PENDING" in .pod before updating this!
 140         VERSION => '1.6.1',
 141
 142         AUTHOR => 'Eric Wong <e@80x24.org>',
 143         ABSTRACT => 'public-inbox server infrastructure',
 144         EXE_FILES => \@EXE_FILES,
 145         PREREQ_PM => {
 146                 # note: we use spamc(1), NOT the Perl modules
 147                 # We also depend on git.
 148                 # Keep this sorted and synced to the INSTALL document
 149
 150                 # perl-modules-5.xx or libperl5.xx in Debian-based
 151                 # part of "perl5" on FreeBSD
 152                 'Compress::Raw::Zlib' => 0,
 153                 'Compress::Zlib' => 0,
 154                 'Data::Dumper' => 0,
 155                 'Digest::SHA' => 0, # rpm: perl-Digest-SHA
 156                 'Encode' => 2.35, # 2.35 shipped with 5.10.1
 157                 'IO::Compress::Gzip' => 0,
 158                 'IO::Uncompress::Gunzip' => 0,
 159                 'Storable' => 0, # rpm: perl-Storable
 160                 'Text::ParseWords' => 0, # rpm: perl-Text-ParseWords
 161
 162                 # Plack is needed for public-inbox-httpd and PublicInbox::WWW
 163                 # 'Plack' => 0,
 164
 165                 'URI::Escape' => 0,
 166
 167                 # We have more test dependencies, but do not force
 168                 # users to install them.  See INSTALL
 169
 170                 # All Perl installs I know about have these, but RH-based
 171                 # distros make them separate even though 'perl' pulls them in
 172                 'File::Path' => 0,
 173                 'File::Temp' => '0.19', # for ->tmpdir support
 174                 'Getopt::Long' => 0,
 175                 'Exporter' => 0,
 176                 # ExtUtils::MakeMaker # this file won't run w/o it...
 177         },
 178         MAN3PODS => \%man3,
 179         clean => {
 180                 FILES => 't/home*/setup* t/home*/t* t/home*/.public-inbox '.
 181                         't/data-gen/*'
 182         },
 183 );
 184
 185 sub MY::postamble {
 186         my $N = (`{ getconf _NPROCESSORS_ONLN || nproc; } 2>/dev/null` || 1);
 187         $N += 1; # account for sleeps in some tests (and makes an IV)
 188         <<EOF;
 189 PROVE = prove
 190 # support using eatmydata to speed up tests (apt-get install eatmydata):
 191 # https://www.flamingspork.com/projects/libeatmydata/
 192 EATMYDATA =
 193 N = $N
 194 -include config.mak
 195 $VARS
 196 -include Documentation/include.mk
 197 $TGTS
 198
 199 check-man :: $check_lexgrog$warn_no_pod
 200
 201 # syntax checks are currently GNU make only:
 202 %.syntax :: %
 203         @\$(PERL) -w -I lib -c \$<
 204
 205 syntax:: \$(my_syntax)
 206
 207 changed = \$(shell git ls-files -m)
 208 dsyn :: \$(addsuffix .syntax, \$(filter \$(changed), \$(syn_files)))
 209
 210 check_manifest := if test -e .git && git ls-files >MANIFEST.gen 2>&1; then \\
 211                 diff -u MANIFEST MANIFEST.gen; fi
 212
 213 check-manifest : MANIFEST
 214         \$(check_manifest)
 215
 216 # the traditional way running per-*.t processes:
 217 check-each :: pure_all
 218         \$(EATMYDATA) \$(PROVE) --state=save -bvw -j\$(N)
 219         -@\$(check_manifest)
 220
 221 # lightly-tested way to run tests, relies "--state=save" in check-each
 222 # for best performance
 223 check-run :: pure_all check-man
 224         \$(EATMYDATA) \$(PROVE) -bvw t/run.perl :: -j\$(N)
 225         -@\$(check_manifest)
 226
 227 check :: check-each
 228
 229 lib/PublicInbox/UserContent.pm :: contrib/css/216dark.css
 230         \$(PERL) -I lib \$@ \$?
 231
 232 # Ensure new .pm files will always be installed by updating
 233 # the timestamp of Makefile.PL which forces Makefile to be remade
 234 Makefile.PL : MANIFEST
 235         touch -r MANIFEST \$@
 236         \$(PERLRUN) \$@
 237
 238 # Install symlinks to ~/bin (which is hopefuly in PATH) which point to
 239 # this source tree.
 240 # prefix + bindir matches git.git Makefile:
 241 prefix = \$(HOME)
 242 bindir = \$(prefix)/bin
 243 symlink-install :
 244         mkdir -p \$(bindir)
 245         lei=\$\$(realpath lei.sh) && cd \$(bindir) && \\
 246         for x in \$(EXE_FILES); do \\
 247                 ln -sf "\$\$lei" \$\$(basename "\$\$x"); \\
 248         done
 249
 250 update-copyrights :
 251         \@case '\$(GNULIB_PATH)' in '') echo >&2 GNULIB_PATH unset; false;; esac
 252         git ls-files | UPDATE_COPYRIGHT_HOLDER='all contributors' \\
 253                 UPDATE_COPYRIGHT_USE_INTERVALS=2 \\
 254                 xargs \$(GNULIB_PATH)/build-aux/update-copyright
 255 EOF
 256 }