Makefile.PL

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2013-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use ExtUtils::MakeMaker;
   6 open my $m, '<', 'MANIFEST' or die "open(MANIFEST): $!\n";
   7 chomp(my @manifest = (<$m>));
   8 my @EXE_FILES = grep(m!^script/!, @manifest);
   9 my $v = {};
  10 my $t = {};
  11
  12 # do not sort
  13 my @RELEASES = qw(v1.6.1 v1.6.0 v1.5.0 v1.4.0 v1.3.0 v1.2.0 v1.1.0-pre1 v1.0.0);
  14
  15 $v->{news_deps} = [ map { "Documentation/RelNotes/$_.eml" } @RELEASES ];
  16 $v->{txt} = [ qw(INSTALL README COPYING TODO HACKING) ];
  17 my @dtxt = grep(m!\ADocumentation/[^/]+\.txt\z!, @manifest);
  18 push @dtxt, 'Documentation/standards.txt';
  19 push @dtxt, 'Documentation/flow.txt';
  20 push @dtxt, @{$v->{txt}};
  21 for my $txt (@dtxt) {
  22         my $html = $txt;
  23         $html =~ s/\.txt\z/.html/ or $html .= '.html';
  24         $t->{"$html : $txt"} = [ "\$(txt2pre) <$txt" ];
  25 }
  26 $v->{t_slash_star_dot_t} = [ grep(m!\At/.*\.t\z!, @manifest) ];
  27 my @scripts = qw(scripts/ssoma-replay); # legacy
  28 my @syn = (@EXE_FILES, grep(m!^lib/.*\.pm$!, @manifest), @scripts);
  29 @syn = grep(!/DSKQXS\.pm/, @syn) if !eval { require IO::KQueue };
  30 @syn = grep(!/Unsubscribe\.pm/, @syn) if !eval { require Crypt::CBC };
  31 @syn = grep(!/SaPlugin/, @syn) if !eval { require Mail::SpamAssasin };
  32 $v->{syn_files} = \@syn;
  33 $v->{my_syntax} = [map { "$_.syntax" } @syn];
  34 my @no_pod;
  35 $v->{-m1} = [ map {
  36                 my $x = (split('/'))[-1];
  37                 my $pod = "Documentation/$x.pod";
  38                 if (-f $pod) {
  39                         $x;
  40                 } else {
  41                         warn "W: $pod missing\n";
  42                         push @no_pod, $x;
  43                         ();
  44                 }
  45         } @EXE_FILES ];
  46 $v->{-m5} = [ qw(public-inbox-config public-inbox-v1-format
  47                 public-inbox-v2-format public-inbox-extindex-format) ];
  48 $v->{-m7} = [ qw(public-inbox-overview public-inbox-tuning) ];
  49 $v->{-m8} = [ qw(public-inbox-daemon) ];
  50 my @sections = (1, 5, 7, 8);
  51 $v->{check_80} = [];
  52 $v->{manuals} = [];
  53 $v->{mantxt} = [];
  54 for my $i (@sections) {
  55         my $ary = $v->{"-m$i"};
  56         $v->{"m$i"} = $ary;
  57         for my $m (@$ary) {
  58                 my $pod = "Documentation/$m.pod";
  59                 my $txt = "Documentation/$m.txt";
  60                 $t->{"$m.$i : $pod"} = [ "\$(podman) -s$i $pod \$@" ];
  61                 $t->{"$txt : $pod"} = [ "\$(podtext) $pod \$\@+",
  62                                         "touch -r $pod \$\@+",
  63                                         "mv \$\@+ \$@" ];
  64                 $t->{"Documentation/$m.html : $txt"} = [ "\$(txt2pre) <$txt" ];
  65                 $t->{".$m.cols : $m.$i"} = [
  66                         "\@echo CHECK80 $m.$i;".
  67                         "COLUMNS=80 \$(MAN) ./$m.$i | \$(check_man)" ];
  68                 $t->{".$m.lexgrog: $m.$i"} = [
  69                         "\@echo LEXGROG $m.$i;" .
  70                         "\$(LEXGROG) ./$m.$i >\$\@+ && mv \$\@+ \$@" ];
  71         }
  72         push @{$v->{check_80}}, map { ".$_.cols" } @$ary;
  73         push @{$v->{check_lexgrog}}, map { ".$_.lexgrog" } @$ary;
  74         my $manuals = $v->{"man$i"} = [ map { "$_.$i" } @$ary ];
  75         push @{$v->{manuals}}, @$manuals;
  76         push @{$v->{mantxt}}, map { "Documentation/$_.txt" } @$ary;
  77 }
  78 push @dtxt, @{$v->{mantxt}};
  79 $v->{docs} = [ @dtxt, 'NEWS' ];
  80 $v->{docs_html} = [ map {;
  81                 my $x = $_;
  82                 $x =~ s/\.txt\z//;
  83                 "$x.html"
  84         } @{$v->{docs}} ];
  85 $v->{gz_docs} = [ map { "$_.gz" } (@{$v->{docs}},@{$v->{docs_html}}) ];
  86 $v->{rsync_docs} = [ @{$v->{gz_docs}}, @{$v->{docs}},
  87         @{$v->{docs_html}}, qw(NEWS.atom NEWS.atom.gz)];
  88
  89 # external manpages which we host ourselves, since some packages
  90 # (currently just Xapian) doesn't host manpages themselves.
  91 my @xman = qw(copydatabase.1 xapian-compact.1);
  92 $v->{xdocs} = [ map { "Documentation/.$_.txt" } @xman ];
  93 $v->{xdocs_html} = [ map { "Documentation/.$_.html" } @xman ];
  94 for (@{$v->{xdocs}}) {
  95         $t->{"$_:"} = [
  96                 '$(PERL) -w Documentation/extman.perl $@ >$@+',
  97                 'mv $@+ $@'
  98         ];
  99         my $html = $_;
 100         $html =~ s/\.txt\z/.html/;
 101         $t->{"$html : $_"} = [ "\$(txt2pre) <$_" ];
 102 }
 103 $v->{gz_xdocs} = [ map { "$_.gz" } (@{$v->{xdocs_html}}, @{$v->{xdocs}}) ];
 104 $v->{rsync_xdocs} = [ @{$v->{gz_xdocs}}, @{$v->{xdocs_html}}, @{$v->{xdocs}} ];
 105
 106 my $TGTS = join("\n", map {;
 107         my $tgt_prereq = $_;
 108         my $cmds = $t->{$_};
 109         "$tgt_prereq\n".join('', map { "\t$_\n" } @$cmds);
 110 } sort keys %$t);
 111
 112 my $VARS = join("\n", map {;
 113         my $varname = $_;
 114         join('', map { "$varname += $_\n" } sort @{$v->{$varname}});
 115 } grep(!/^-/, sort keys %$v));
 116 $VARS .= "\nRELEASES = ".join(' ', @RELEASES)."\n";
 117
 118 # Don't waste user's disk space by installing some pods from
 119 # imported code or internal use only
 120 my %man3 = map {; # semi-colon tells Perl this is a BLOCK (and not EXPR)
 121         my $base = $_;
 122         my $mod = $base;
 123         $mod =~ s!/!::!g;
 124         $mod =~ s/\.\w+\z//;
 125         "lib/PublicInbox/$_" => "blib/man3/PublicInbox::$mod.\$(MAN3EXT)"
 126 } qw(Git.pm Import.pm WWW.pod SaPlugin/ListMirror.pod);
 127 my $warn_no_pod = @no_pod ? "\n\t\@echo W: missing .pod: @no_pod\n" : '';
 128 chomp(my $lexgrog = `which lexgrog 2>/dev/null`);
 129 my $check_lexgrog = $lexgrog ? 'check-lexgrog' : '';
 130
 131 WriteMakefile(
 132         NAME => 'PublicInbox', # n.b. camel-case is not our choice
 133
 134         # XXX drop "PENDING" in .pod before updating this!
 135         VERSION => '1.6.1',
 136
 137         AUTHOR => 'Eric Wong <e@80x24.org>',
 138         ABSTRACT => 'public-inbox server infrastructure',
 139         EXE_FILES => \@EXE_FILES,
 140         PREREQ_PM => {
 141                 # note: we use spamc(1), NOT the Perl modules
 142                 # We also depend on git.
 143                 # Keep this sorted and synced to the INSTALL document
 144
 145                 # libperl$PERL_VERSION,
 146                 # `perl5' on FreeBSD
 147                 # perl-Digest-SHA on RH-based
 148                 'Digest::SHA' => 0,
 149
 150                 # libperl$PERL_VERSION or libencode-perl on Debian,
 151                 # `perl5' on FreeBSD
 152                 'Encode' => 2.35, # 2.35 shipped with 5.10.1
 153
 154                 # libperl$PERL_VERSION + perl-modules-$PERL_VERSION
 155                 'Compress::Raw::Zlib' => 0,
 156                 'Compress::Zlib' => 0,
 157                 'IO::Compress::Gzip' => 0,
 158
 159                 # Plack is needed for public-inbox-httpd and PublicInbox::WWW
 160                 # 'Plack' => 0,
 161
 162                 # TODO: this should really be made optional...
 163                 'URI::Escape' => 0,
 164
 165                 # We have more test dependencies, but do not force
 166                 # users to install them.  See INSTALL
 167
 168                 # All Perl installs I know about have these, but RH-based
 169                 # distros make them separate even though 'perl' pulls them in
 170                 'File::Path' => 0,
 171                 'File::Temp' => '0.19', # for ->tmpdir support
 172                 'Getopt::Long' => 0,
 173                 'Exporter' => 0,
 174                 # ExtUtils::MakeMaker # this file won't run w/o it...
 175         },
 176         MAN3PODS => \%man3,
 177 );
 178
 179 sub MY::postamble {
 180         my $N = (`{ getconf _NPROCESSORS_ONLN || nproc; } 2>/dev/null` || 1);
 181         $N += 1; # account for sleeps in some tests (and makes an IV)
 182         <<EOF;
 183 PROVE = prove
 184 # support using eatmydata to speed up tests (apt-get install eatmydata):
 185 # https://www.flamingspork.com/projects/libeatmydata/
 186 EATMYDATA =
 187 N = $N
 188 -include config.mak
 189 $VARS
 190 -include Documentation/include.mk
 191 $TGTS
 192
 193 check-man :: $check_lexgrog$warn_no_pod
 194
 195 # syntax checks are currently GNU make only:
 196 %.syntax :: %
 197         @\$(PERL) -w -I lib -c \$<
 198
 199 syntax:: \$(my_syntax)
 200
 201 changed = \$(shell git ls-files -m)
 202 dsyn :: \$(addsuffix .syntax, \$(filter \$(changed), \$(syn_files)))
 203
 204 check_manifest := if test -e .git && git ls-files >MANIFEST.gen 2>&1; then \\
 205                 diff -u MANIFEST MANIFEST.gen; fi
 206
 207 check-manifest : MANIFEST
 208         \$(check_manifest)
 209
 210 # the traditional way running per-*.t processes:
 211 check-each :: pure_all
 212         \$(EATMYDATA) \$(PROVE) --state=save -bvw -j\$(N)
 213         -@\$(check_manifest)
 214
 215 # lightly-tested way to run tests, relies "--state=save" in check-each
 216 # for best performance
 217 check-run :: pure_all check-man
 218         \$(EATMYDATA) \$(PROVE) -bvw t/run.perl :: -j\$(N)
 219         -@\$(check_manifest)
 220
 221 check :: check-each
 222
 223 lib/PublicInbox/UserContent.pm :: contrib/css/216dark.css
 224         \$(PERL) -I lib \$@ \$?
 225
 226 # Ensure new .pm files will always be installed by updating
 227 # the timestamp of Makefile.PL which forces Makefile to be remade
 228 Makefile.PL : MANIFEST
 229         touch -r MANIFEST \$@
 230         \$(PERLRUN) \$@
 231
 232 # Install symlinks to ~/bin (which is hopefuly in PATH) which point to
 233 # this source tree.
 234 # prefix + bindir matches git.git Makefile:
 235 prefix = \$(HOME)
 236 bindir = \$(prefix)/bin
 237 symlink-install :
 238         mkdir -p \$(bindir)
 239         lei=\$\$(realpath lei.sh) && cd \$(bindir) && \\
 240         for x in \$(EXE_FILES); do \\
 241                 ln -sf "\$\$lei" \$\$(basename "\$\$x"); \\
 242         done
 243
 244 update-copyrights :
 245         \@case '\$(GNULIB_PATH)' in '') echo >&2 GNULIB_PATH unset; false;; esac
 246         git ls-files | UPDATE_COPYRIGHT_HOLDER='all contributors' \\
 247                 UPDATE_COPYRIGHT_USE_INTERVALS=2 \\
 248                 xargs \$(GNULIB_PATH)/build-aux/update-copyright
 249 EOF
 250 }