Makefile.PL

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2013-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use ExtUtils::MakeMaker;
   6 open my $m, '<', 'MANIFEST' or die "open(MANIFEST): $!\n";
   7 chomp(my @manifest = (<$m>));
   8 push @manifest, 'lib/PublicInbox.pm'; # generated
   9 my @EXE_FILES = grep(m!^script/!, @manifest);
  10 my $v = {};
  11 my $t = {};
  12
  13 # do not sort
  14 my @RELEASES = qw(v1.6.1 v1.6.0 v1.5.0 v1.4.0 v1.3.0 v1.2.0 v1.1.0-pre1 v1.0.0);
  15
  16 $v->{news_deps} = [ map { "Documentation/RelNotes/$_.eml" } @RELEASES ];
  17 $v->{txt} = [ qw(INSTALL README COPYING TODO HACKING) ];
  18 my @dtxt = grep(m!\ADocumentation/[^/]+\.txt\z!, @manifest);
  19 push @dtxt, 'Documentation/standards.txt';
  20 push @dtxt, 'Documentation/flow.txt';
  21 push @dtxt, @{$v->{txt}};
  22 for my $txt (@dtxt) {
  23         my $html = $txt;
  24         $html =~ s/\.txt\z/.html/ or $html .= '.html';
  25         $t->{"$html : $txt"} = [ "\$(txt2pre) <$txt" ];
  26 }
  27 $v->{t_slash_star_dot_t} = [ grep(m!\At/.*\.t\z!, @manifest) ];
  28 my @scripts = qw(scripts/ssoma-replay); # legacy
  29 my @syn = (@EXE_FILES, grep(m!^lib/.*\.pm$!, @manifest), @scripts);
  30 @syn = grep(!/DSKQXS\.pm/, @syn) if !eval { require IO::KQueue };
  31 @syn = grep(!/Unsubscribe\.pm/, @syn) if !eval { require Crypt::CBC };
  32 @syn = grep(!/SaPlugin/, @syn) if !eval { require Mail::SpamAssasin };
  33 $v->{syn_files} = \@syn;
  34 $v->{my_syntax} = [map { "$_.syntax" } @syn];
  35 my @no_pod;
  36 $v->{-m1} = [ map {
  37                 my $x = (split('/'))[-1];
  38                 my $pod = "Documentation/$x.pod";
  39                 if (-f $pod) {
  40                         $x;
  41                 } else {
  42                         warn "W: $pod missing\n";
  43                         push @no_pod, $x;
  44                         ();
  45                 }
  46         } @EXE_FILES,
  47         qw(
  48         lei-add-external lei-blob lei-config lei-convert lei-daemon-kill
  49         lei-daemon-pid lei-forget-external lei-import lei-init lei-ls-external
  50         lei-ls-label lei-p2q lei-q lei-tag)];
  51 $v->{-m5} = [ qw(public-inbox-config public-inbox-v1-format
  52                 public-inbox-v2-format public-inbox-extindex-format
  53                 lei-mail-formats lei-store-format
  54                 ) ];
  55 $v->{-m7} = [ qw(lei-overview public-inbox-overview public-inbox-tuning
  56                 public-inbox-glossary) ];
  57 $v->{-m8} = [ qw(public-inbox-daemon) ];
  58 my @sections = (1, 5, 7, 8);
  59 $v->{check_80} = [];
  60 $v->{manuals} = [];
  61 $v->{mantxt} = [];
  62 for my $i (@sections) {
  63         my $ary = $v->{"-m$i"};
  64         $v->{"m$i"} = $ary;
  65         for my $m (@$ary) {
  66                 my $pod = "Documentation/$m.pod";
  67                 my $txt = "Documentation/$m.txt";
  68                 $t->{"$m.$i : $pod"} = [ "\$(podman) -s$i $pod \$@" ];
  69                 $t->{"$txt : $pod"} = [ "\$(podtext) $pod \$\@+",
  70                                         "touch -r $pod \$\@+",
  71                                         "mv \$\@+ \$@" ];
  72                 $t->{"Documentation/$m.html : $txt"} = [ "\$(txt2pre) <$txt" ];
  73                 $t->{".$m.cols : $m.$i"} = [
  74                         "\@echo CHECK80 $m.$i;".
  75                         "COLUMNS=80 \$(MAN) ./$m.$i | \$(check_man)",
  76                         '>$@' ];
  77                 $t->{".$m.lexgrog: $m.$i"} = [
  78                         "\@echo LEXGROG $m.$i;" .
  79                         "\$(LEXGROG) ./$m.$i >\$\@+ && mv \$\@+ \$@" ];
  80         }
  81         push @{$v->{check_80}}, map { ".$_.cols" } @$ary;
  82         push @{$v->{check_lexgrog}}, map { ".$_.lexgrog" } @$ary;
  83         my $manuals = $v->{"man$i"} = [ map { "$_.$i" } @$ary ];
  84         push @{$v->{manuals}}, @$manuals;
  85         push @{$v->{mantxt}}, map { "Documentation/$_.txt" } @$ary;
  86 }
  87 push @dtxt, @{$v->{mantxt}};
  88 $v->{docs} = [ @dtxt, 'NEWS' ];
  89 $v->{docs_html} = [ map {;
  90                 my $x = $_;
  91                 $x =~ s/\.txt\z//;
  92                 "$x.html"
  93         } @{$v->{docs}} ];
  94 $v->{gz_docs} = [ map { "$_.gz" } (@{$v->{docs}},@{$v->{docs_html}}) ];
  95 $v->{rsync_docs} = [ @{$v->{gz_docs}}, @{$v->{docs}},
  96         @{$v->{docs_html}}, qw(NEWS.atom NEWS.atom.gz)];
  97
  98 # external manpages which we host ourselves, since some packages
  99 # (currently just Xapian) doesn't host manpages themselves.
 100 my @xman = qw(copydatabase.1 xapian-compact.1);
 101 $v->{xdocs} = [ map { "Documentation/.$_.txt" } @xman ];
 102 $v->{xdocs_html} = [ map { "Documentation/.$_.html" } @xman ];
 103 for (@{$v->{xdocs}}) {
 104         $t->{"$_:"} = [
 105                 '$(PERL) -w Documentation/extman.perl $@ >$@+',
 106                 'mv $@+ $@'
 107         ];
 108         my $html = $_;
 109         $html =~ s/\.txt\z/.html/;
 110         $t->{"$html : $_"} = [ "\$(txt2pre) <$_" ];
 111 }
 112 $v->{gz_xdocs} = [ map { "$_.gz" } (@{$v->{xdocs_html}}, @{$v->{xdocs}}) ];
 113 $v->{rsync_xdocs} = [ @{$v->{gz_xdocs}}, @{$v->{xdocs_html}}, @{$v->{xdocs}} ];
 114
 115 my $TGTS = join("\n", map {;
 116         my $tgt_prereq = $_;
 117         my $cmds = $t->{$_};
 118         "$tgt_prereq\n".join('', map { "\t$_\n" } @$cmds);
 119 } sort keys %$t);
 120
 121 my $VARS = join("\n", map {;
 122         my $varname = $_;
 123         join('', map { "$varname += $_\n" } sort @{$v->{$varname}});
 124 } grep(!/^-/, sort keys %$v));
 125 $VARS .= "\nRELEASES = ".join(' ', @RELEASES)."\n";
 126
 127 # Don't waste user's disk space by installing some pods from
 128 # imported code or internal use only
 129 my %man3 = map {; # semi-colon tells Perl this is a BLOCK (and not EXPR)
 130         my $base = $_;
 131         my $mod = $base;
 132         $mod =~ s!/!::!g;
 133         $mod =~ s/\.\w+\z//;
 134         "lib/PublicInbox/$_" => "blib/man3/PublicInbox::$mod.\$(MAN3EXT)"
 135 } qw(Git.pm Import.pm WWW.pod SaPlugin/ListMirror.pod);
 136 my $warn_no_pod = @no_pod ? "\n\t\@echo W: missing .pod: @no_pod\n" : '';
 137 chomp(my $lexgrog = `which lexgrog 2>/dev/null`);
 138 my $check_lexgrog = $lexgrog ? 'check-lexgrog' : '';
 139
 140 WriteMakefile(
 141         NAME => 'PublicInbox', # n.b. camel-case is not our choice
 142
 143         # XXX drop "PENDING" in .pod before updating this!
 144         VERSION => '1.7.0.PENDING',
 145
 146         AUTHOR => 'Eric Wong <e@80x24.org>',
 147         ABSTRACT => 'public-inbox server infrastructure',
 148         EXE_FILES => \@EXE_FILES,
 149         PREREQ_PM => {
 150                 # note: we use spamc(1), NOT the Perl modules
 151                 # We also depend on git.
 152                 # Keep this sorted and synced to the INSTALL document
 153
 154                 # perl-modules-5.xx or libperl5.xx in Debian-based
 155                 # part of "perl5" on FreeBSD
 156                 'Compress::Raw::Zlib' => 0,
 157                 'Compress::Zlib' => 0,
 158                 'Data::Dumper' => 0,
 159                 'Digest::SHA' => 0, # rpm: perl-Digest-SHA
 160                 'Encode' => 2.35, # 2.35 shipped with 5.10.1
 161                 'IO::Compress::Gzip' => 0,
 162                 'IO::Uncompress::Gunzip' => 0,
 163                 'Storable' => 0, # rpm: perl-Storable
 164                 'Text::ParseWords' => 0, # rpm: perl-Text-ParseWords
 165
 166                 # Plack is needed for public-inbox-httpd and PublicInbox::WWW
 167                 # 'Plack' => 0,
 168
 169                 'URI::Escape' => 0,
 170
 171                 # We have more test dependencies, but do not force
 172                 # users to install them.  See INSTALL
 173
 174                 # All Perl installs I know about have these, but RH-based
 175                 # distros make them separate even though 'perl' pulls them in
 176                 'File::Path' => 0,
 177                 'File::Temp' => '0.19', # for ->tmpdir support
 178                 'Getopt::Long' => 0,
 179                 'Exporter' => 0,
 180                 # ExtUtils::MakeMaker # this file won't run w/o it...
 181         },
 182         MAN3PODS => \%man3,
 183         clean => {
 184                 FILES => 't/home*/setup* t/home*/t* t/home*/.public-inbox '.
 185                         't/data-gen/*'
 186         },
 187 );
 188
 189 sub MY::postamble {
 190         my $N = (`{ getconf _NPROCESSORS_ONLN || nproc; } 2>/dev/null` || 1);
 191         $N += 1; # account for sleeps in some tests (and makes an IV)
 192         <<EOF;
 193 PROVE = prove
 194 # support using eatmydata to speed up tests (apt-get install eatmydata):
 195 # https://www.flamingspork.com/projects/libeatmydata/
 196 EATMYDATA =
 197 N = $N
 198 -include config.mak
 199 $VARS
 200 -include Documentation/include.mk
 201 $TGTS
 202
 203 check-man :: $check_lexgrog$warn_no_pod
 204
 205 # syntax checks are currently GNU make only:
 206 %.syntax :: %
 207         @\$(PERL) -w -I lib -c \$<
 208
 209 syntax:: \$(my_syntax)
 210
 211 changed = \$(shell git ls-files -m)
 212 dsyn :: \$(addsuffix .syntax, \$(filter \$(changed), \$(syn_files)))
 213
 214 check_manifest := if test -e .git && git ls-files >MANIFEST.gen 2>&1; then \\
 215                 diff -u MANIFEST MANIFEST.gen; fi
 216
 217 check-manifest : MANIFEST
 218         \$(check_manifest)
 219
 220 # the traditional way running per-*.t processes:
 221 check-each :: pure_all
 222         \$(EATMYDATA) \$(PROVE) --state=save -bvw -j\$(N)
 223         -@\$(check_manifest)
 224
 225 # lightly-tested way to run tests, relies "--state=save" in check-each
 226 # for best performance
 227 check-run :: pure_all check-man
 228         \$(EATMYDATA) \$(PROVE) -bvw t/run.perl :: -j\$(N)
 229         -@\$(check_manifest)
 230
 231 check :: check-each
 232
 233 lib/PublicInbox/UserContent.pm :: contrib/css/216dark.css
 234         \$(PERL) -I lib \$@ \$?
 235
 236 # Ensure new .pm files will always be installed by updating
 237 # the timestamp of Makefile.PL which forces Makefile to be remade
 238 Makefile.PL : MANIFEST
 239         touch -r MANIFEST \$@
 240         \$(PERLRUN) \$@
 241
 242 # Install symlinks to ~/bin (which is hopefuly in PATH) which point to
 243 # this source tree.
 244 # prefix + bindir matches git.git Makefile:
 245 prefix = \$(HOME)
 246 bindir = \$(prefix)/bin
 247 symlink-install : lib/PublicInbox.pm
 248         mkdir -p \$(bindir)
 249         lei=\$\$(realpath lei.sh) && cd \$(bindir) && \\
 250         for x in \$(EXE_FILES); do \\
 251                 ln -sf "\$\$lei" \$\$(basename "\$\$x"); \\
 252         done
 253
 254 pure_all :: lib/PublicInbox.pm
 255 lib/PublicInbox.pm : FORCE
 256         VERSION=\$(VERSION) \$(PERL) -w ./version-gen.perl
 257
 258 update-copyrights :
 259         \@case '\$(GNULIB_PATH)' in '') echo >&2 GNULIB_PATH unset; false;; esac
 260         git ls-files | UPDATE_COPYRIGHT_HOLDER='all contributors' \\
 261                 UPDATE_COPYRIGHT_USE_INTERVALS=2 \\
 262                 xargs \$(GNULIB_PATH)/build-aux/update-copyright
 263 EOF
 264 }