lib/PublicInbox/Admin.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common stuff for administrative command-line tools
   5 # Unstable internal API
   6 package PublicInbox::Admin;
   7 use strict;
   8 use warnings;
   9 use Cwd 'abs_path';
  10 use base qw(Exporter);
  11 our @EXPORT_OK = qw(resolve_repo_dir);
  12
  13 sub resolve_repo_dir {
  14         my ($cd, $ver) = @_;
  15         my $prefix = defined $cd ? $cd : './';
  16         if (-d $prefix && -f "$prefix/inbox.lock") { # v2
  17                 $$ver = 2 if $ver;
  18                 return abs_path($prefix);
  19         }
  20
  21         my @cmd = qw(git rev-parse --git-dir);
  22         my $cmd = join(' ', @cmd);
  23         my $pid = open my $fh, '-|';
  24         defined $pid or die "forking $cmd failed: $!\n";
  25         if ($pid == 0) {
  26                 if (defined $cd) {
  27                         chdir $cd or die "chdir $cd failed: $!\n";
  28                 }
  29                 exec @cmd;
  30                 die "Failed to exec $cmd: $!\n";
  31         } else {
  32                 my $dir = eval {
  33                         local $/;
  34                         <$fh>;
  35                 };
  36                 close $fh or die "error in $cmd: $!\n";
  37                 chomp $dir;
  38                 $$ver = 1 if $ver;
  39                 return abs_path($cd) if ($dir eq '.' && defined $cd);
  40                 abs_path($dir);
  41         }
  42 }
  43
  44 # for unconfigured inboxes
  45 sub detect_indexlevel ($) {
  46         my ($ibx) = @_;
  47
  48         # brand new or never before indexed inboxes default to full
  49         return 'full' unless $ibx->over;
  50         delete $ibx->{over}; # don't leave open FD lying around
  51
  52         my $l = 'basic';
  53         my $srch = $ibx->search or return $l;
  54         delete $ibx->{search}; # don't leave open FD lying around
  55         if (my $xdb = $srch->xdb) {
  56                 $l = 'full';
  57                 my $m = $xdb->get_metadata('indexlevel');
  58                 if ($m eq 'medium') {
  59                         $l = $m;
  60                 } elsif ($m ne '') {
  61                         warn <<"";
  62 $ibx->{mainrepo} has unexpected indexlevel in Xapian: $m
  63
  64                 }
  65         }
  66         $l;
  67 }
  68
  69 sub resolve_inboxes {
  70         my ($argv, $warn_on_unconfigured) = @_;
  71         require PublicInbox::Config;
  72         require PublicInbox::Inbox;
  73
  74         my @ibxs = map { resolve_repo_dir($_) } @$argv;
  75         push(@ibxs, resolve_repo_dir()) unless @ibxs;
  76
  77         my %dir2ibx;
  78         if (my $config = eval { PublicInbox::Config->new }) {
  79                 $config->each_inbox(sub {
  80                         my ($ibx) = @_;
  81                         $dir2ibx{abs_path($ibx->{mainrepo})} = $ibx;
  82                 });
  83         } elsif ($warn_on_unconfigured) {
  84                 # do we really care about this?  It's annoying...
  85                 warn $warn_on_unconfigured, "\n";
  86         }
  87         for my $i (0..$#ibxs) {
  88                 my $dir = $ibxs[$i];
  89                 $ibxs[$i] = $dir2ibx{$dir} ||= do {
  90                         my $name = "unconfigured-$i";
  91                         PublicInbox::Inbox->new({
  92                                 name => $name,
  93                                 address => [ "$name\@example.com" ],
  94                                 mainrepo => $dir,
  95                                 # TODO: consumers may want to warn on this:
  96                                 #-unconfigured => 1,
  97                         });
  98                 };
  99         }
 100         @ibxs;
 101 }
 102
 103 # TODO: make Devel::Peek optional, only used for daemon
 104 my @base_mod = qw(Email::MIME Date::Parse Devel::Peek);
 105 my @over_mod = qw(DBD::SQLite DBI);
 106 my %mod_groups = (
 107         -index => [ @base_mod, @over_mod ],
 108         -base => \@base_mod,
 109         -search => [ @base_mod, @over_mod, 'Search::Xapian' ],
 110 );
 111
 112 sub scan_ibx_modules ($$) {
 113         my ($mods, $ibx) = @_;
 114         if (!$ibx->{indexlevel} || $ibx->{indexlevel} ne 'basic') {
 115                 $mods->{'Search::Xapian'} = 1;
 116         } else {
 117                 $mods->{$_} = 1 foreach @over_mod;
 118         }
 119 }
 120
 121 sub check_require {
 122         my (@mods) = @_;
 123         my $err = {};
 124         while (my $mod = shift @mods) {
 125                 if (my $groups = $mod_groups{$mod}) {
 126                         push @mods, @$groups;
 127                 } else {
 128                         eval "require $mod";
 129                         $err->{$mod} = $@ if $@;
 130                 }
 131         }
 132         scalar keys %$err ? $err : undef;
 133 }
 134
 135 sub missing_mod_msg {
 136         my ($err) = @_;
 137         my @mods = map { "`$_'" } sort keys %$err;
 138         my $last = pop @mods;
 139         @mods ? (join(', ', @mods)."' and $last") : $last
 140 }
 141
 142 sub require_or_die {
 143         my $err = check_require(@_) or return;
 144         die missing_mod_msg($err)." required for $0\n";
 145 }
 146
 147 sub indexlevel_ok_or_die ($) {
 148         my ($indexlevel) = @_;
 149         my $req;
 150         if ($indexlevel eq 'basic') {
 151                 $req = '-index';
 152         } elsif ($indexlevel =~ /\A(?:medium|full)\z/) {
 153                 $req = '-search';
 154         } else {
 155                 die <<"";
 156 invalid indexlevel=$indexlevel (must be `basic', `medium', or `full')
 157
 158         }
 159         my $err = check_require($req) or return;
 160         die missing_mod_msg($err) ." required for indexlevel=$indexlevel\n";
 161 }
 162
 163 sub index_inbox {
 164         my ($ibx, $opt) = @_;
 165         my $jobs = delete $opt->{jobs} if $opt;
 166         if (ref($ibx) && ($ibx->{version} || 1) == 2) {
 167                 eval { require PublicInbox::V2Writable };
 168                 die "v2 requirements not met: $@\n" if $@;
 169                 my $v2w = eval { $ibx->importer(0) } || eval {
 170                         PublicInbox::V2Writable->new($ibx, {nproc=>$jobs});
 171                 };
 172                 if (defined $jobs) {
 173                         if ($jobs == 0) {
 174                                 $v2w->{parallel} = 0;
 175                         } else {
 176                                 my $n = $v2w->{partitions};
 177                                 if ($jobs != ($n + 1)) {
 178                                         warn
 179 "Unable to respect --jobs=$jobs, inbox was created with $n partitions\n";
 180                                 }
 181                         }
 182                 }
 183                 my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 184                 local $SIG{__WARN__} = sub {
 185                         $warn_cb->($v2w->{current_info}, ': ', @_);
 186                 };
 187                 $v2w->index_sync($opt);
 188         } else {
 189                 require PublicInbox::SearchIdx;
 190                 my $s = PublicInbox::SearchIdx->new($ibx, 1);
 191                 $s->index_sync($opt);
 192         }
 193 }
 194
 195 sub progress_prepare ($) {
 196         my ($opt) = @_;
 197
 198         # public-inbox-index defaults to quiet, -xcpdb and -compact do not
 199         if (defined($opt->{quiet}) && $opt->{quiet} < 0) {
 200                 $opt->{quiet} = !$opt->{verbose};
 201         }
 202         if ($opt->{quiet}) {
 203                 open my $null, '>', '/dev/null' or
 204                         die "failed to open /dev/null: $!\n";
 205                 $opt->{1} = fileno($null); # suitable for spawn() redirect
 206                 $opt->{-dev_null} = $null;
 207         } else {
 208                 $opt->{verbose} ||= 1;
 209                 $opt->{-progress} = sub { print STDERR @_ };
 210         }
 211 }
 212
 213 1;