lib/PublicInbox/Config.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Used throughout the project for reading configuration
   5 package PublicInbox::Config;
   6 use strict;
   7 use warnings;
   8 require PublicInbox::Inbox;
   9 use PublicInbox::Spawn qw(popen_rd);
  10
  11 # returns key-value pairs of config directives in a hash
  12 # if keys may be multi-value, the value is an array ref containing all values
  13 sub new {
  14         my ($class, $file) = @_;
  15         $file = default_file() unless defined($file);
  16         $file = ref $file ? $file : git_config_dump($file);
  17         my $self = bless $file, $class;
  18
  19         # caches
  20         $self->{-by_addr} ||= {};
  21         $self->{-by_name} ||= {};
  22         $self->{-by_newsgroup} ||= {};
  23         $self->{-limiters} ||= {};
  24         $self;
  25 }
  26
  27 sub lookup {
  28         my ($self, $recipient) = @_;
  29         my $addr = lc($recipient);
  30         my $inbox = $self->{-by_addr}->{$addr};
  31         return $inbox if $inbox;
  32
  33         my $pfx;
  34
  35         foreach my $k (keys %$self) {
  36                 $k =~ /\A(publicinbox\.[\w-]+)\.address\z/ or next;
  37                 my $v = $self->{$k};
  38                 if (ref($v) eq "ARRAY") {
  39                         foreach my $alias (@$v) {
  40                                 (lc($alias) eq $addr) or next;
  41                                 $pfx = $1;
  42                                 last;
  43                         }
  44                 } else {
  45                         (lc($v) eq $addr) or next;
  46                         $pfx = $1;
  47                         last;
  48                 }
  49         }
  50         defined $pfx or return;
  51         _fill($self, $pfx);
  52 }
  53
  54 sub lookup_name ($$) {
  55         my ($self, $name) = @_;
  56         $self->{-by_name}->{$name} || _fill($self, "publicinbox.$name");
  57 }
  58
  59 sub each_inbox {
  60         my ($self, $cb) = @_;
  61         my %seen;
  62         foreach my $k (keys %$self) {
  63                 $k =~ /\Apublicinbox\.([A-Z0-9a-z-]+)\.mainrepo\z/ or next;
  64                 next if $seen{$1};
  65                 $seen{$1} = 1;
  66                 my $ibx = lookup_name($self, $1) or next;
  67                 $cb->($ibx);
  68         }
  69 }
  70
  71 sub lookup_newsgroup {
  72         my ($self, $ng) = @_;
  73         $ng = lc($ng);
  74         my $rv = $self->{-by_newsgroup}->{$ng};
  75         return $rv if $rv;
  76
  77         foreach my $k (keys %$self) {
  78                 $k =~ /\A(publicinbox\.[\w-]+)\.newsgroup\z/ or next;
  79                 my $v = $self->{$k};
  80                 my $pfx = $1;
  81                 if ($v eq $ng) {
  82                         $rv = _fill($self, $pfx);
  83                         return $rv;
  84                 }
  85         }
  86         undef;
  87 }
  88
  89 sub limiter {
  90         my ($self, $name) = @_;
  91         $self->{-limiters}->{$name} ||= do {
  92                 require PublicInbox::Qspawn;
  93                 my $max = $self->{"publicinboxlimiter.$name.max"};
  94                 PublicInbox::Qspawn::Limiter->new($max);
  95         };
  96 }
  97
  98 sub config_dir { $ENV{PI_DIR} || "$ENV{HOME}/.public-inbox" }
  99
 100 sub default_file {
 101         my $f = $ENV{PI_CONFIG};
 102         return $f if defined $f;
 103         config_dir() . '/config';
 104 }
 105
 106 sub git_config_dump {
 107         my ($file) = @_;
 108         my ($in, $out);
 109         my @cmd = (qw/git config/, "--file=$file", '-l');
 110         my $cmd = join(' ', @cmd);
 111         my $fh = popen_rd(\@cmd) or die "popen_rd failed for $file: $!\n";
 112         my %rv;
 113         local $/ = "\n";
 114         while (defined(my $line = <$fh>)) {
 115                 chomp $line;
 116                 my ($k, $v) = split(/=/, $line, 2);
 117                 my $cur = $rv{$k};
 118
 119                 if (defined $cur) {
 120                         if (ref($cur) eq "ARRAY") {
 121                                 push @$cur, $v;
 122                         } else {
 123                                 $rv{$k} = [ $cur, $v ];
 124                         }
 125                 } else {
 126                         $rv{$k} = $v;
 127                 }
 128         }
 129         close $fh or die "failed to close ($cmd) pipe: $?";
 130         \%rv;
 131 }
 132
 133 sub _fill {
 134         my ($self, $pfx) = @_;
 135         my $rv = {};
 136
 137         foreach my $k (qw(mainrepo address filter url newsgroup
 138                         infourl watch watchheader httpbackendmax
 139                         replyto feedmax nntpserver)) {
 140                 my $v = $self->{"$pfx.$k"};
 141                 $rv->{$k} = $v if defined $v;
 142         }
 143         foreach my $k (qw(obfuscate)) {
 144                 my $v = $self->{"$pfx.$k"};
 145                 defined $v or next;
 146                 if ($v =~ /\A(?:false|no|off|0)\z/) {
 147                         $rv->{$k} = 0;
 148                 } elsif ($v =~ /\A(?:true|yes|on|1)\z/) {
 149                         $rv->{$k} = 1;
 150                 } else {
 151                         warn "Ignoring $pfx.$k=$v in config, not boolean\n";
 152                 }
 153         }
 154
 155         # TODO: more arrays, we should support multi-value for
 156         # more things to encourage decentralization
 157         foreach my $k (qw(altid nntpmirror)) {
 158                 if (defined(my $v = $self->{"$pfx.$k"})) {
 159                         $rv->{$k} = ref($v) eq 'ARRAY' ? $v : [ $v ];
 160                 }
 161         }
 162
 163         return unless $rv->{mainrepo};
 164         my $name = $pfx;
 165         $name =~ s/\Apublicinbox\.//;
 166         $rv->{name} = $name;
 167         $rv->{-pi_config} = $self;
 168         $rv = PublicInbox::Inbox->new($rv);
 169         my $v = $rv->{address};
 170         if (ref($v) eq 'ARRAY') {
 171                 $self->{-by_addr}->{lc($_)} = $rv foreach @$v;
 172         } else {
 173                 $self->{-by_addr}->{lc($v)} = $rv;
 174         }
 175         if (my $ng = $rv->{newsgroup}) {
 176                 $self->{-by_newsgroup}->{$ng} = $rv;
 177         }
 178         $self->{-by_name}->{$name} = $rv;
 179 }
 180
 181 1;