lib/PublicInbox/Config.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used throughout the project for reading configuration
   5 #
   6 # Note: I hate camelCase; but git-config(1) uses it, but it's better
   7 # than alllowercasewithoutunderscores, so use lc('configKey') where
   8 # applicable for readability
   9
  10 package PublicInbox::Config;
  11 use strict;
  12 use v5.10.1;
  13 use PublicInbox::Inbox;
  14 use PublicInbox::Spawn qw(popen_rd);
  15
  16 sub _array ($) { ref($_[0]) eq 'ARRAY' ? $_[0] : [ $_[0] ] }
  17
  18 # returns key-value pairs of config directives in a hash
  19 # if keys may be multi-value, the value is an array ref containing all values
  20 sub new {
  21         my ($class, $file) = @_;
  22         $file //= default_file();
  23         my $self;
  24         if (ref($file) eq 'SCALAR') { # used by some tests
  25                 open my $fh, '<', $file or die;  # PerlIO::scalar
  26                 $self = config_fh_parse($fh, "\n", '=');
  27         } else {
  28                 $self = git_config_dump($file);
  29         }
  30         bless $self, $class;
  31         # caches
  32         $self->{-by_addr} = {};
  33         $self->{-by_list_id} = {};
  34         $self->{-by_name} = {};
  35         $self->{-by_newsgroup} = {};
  36         $self->{-no_obfuscate} = {};
  37         $self->{-limiters} = {};
  38         $self->{-code_repos} = {}; # nick => PublicInbox::Git object
  39         $self->{-cgitrc_unparsed} = $self->{'publicinbox.cgitrc'};
  40
  41         if (my $no = delete $self->{'publicinbox.noobfuscate'}) {
  42                 $no = _array($no);
  43                 my @domains;
  44                 foreach my $n (@$no) {
  45                         my @n = split(/\s+/, $n);
  46                         foreach (@n) {
  47                                 if (/\S+@\S+/) { # full address
  48                                         $self->{-no_obfuscate}->{lc $_} = 1;
  49                                 } else {
  50                                         # allow "example.com" or "@example.com"
  51                                         s/\A@//;
  52                                         push @domains, quotemeta($_);
  53                                 }
  54                         }
  55                 }
  56                 my $nod = join('|', @domains);
  57                 $self->{-no_obfuscate_re} = qr/(?:$nod)\z/i;
  58         }
  59         if (my $css = delete $self->{'publicinbox.css'}) {
  60                 $self->{css} = _array($css);
  61         }
  62
  63         $self;
  64 }
  65
  66 sub noop {}
  67 sub fill_all ($) { each_inbox($_[0], \&noop) }
  68
  69 sub _lookup_fill ($$$) {
  70         my ($self, $cache, $key) = @_;
  71         $self->{$cache}->{$key} // do {
  72                 fill_all($self);
  73                 $self->{$cache}->{$key};
  74         }
  75 }
  76
  77 sub lookup {
  78         my ($self, $recipient) = @_;
  79         _lookup_fill($self, '-by_addr', lc($recipient));
  80 }
  81
  82 sub lookup_list_id {
  83         my ($self, $list_id) = @_;
  84         _lookup_fill($self, '-by_list_id', lc($list_id));
  85 }
  86
  87 sub lookup_name ($$) {
  88         my ($self, $name) = @_;
  89         $self->{-by_name}->{$name} // _fill($self, "publicinbox.$name");
  90 }
  91
  92 sub lookup_ei {
  93         my ($self, $name) = @_;
  94         $self->{-ei_by_name}->{$name} //= _fill_ei($self, "extindex.$name");
  95 }
  96
  97 # special case for [extindex "all"]
  98 sub ALL { lookup_ei($_[0], 'all') }
  99
 100 sub each_inbox {
 101         my ($self, $cb, @arg) = @_;
 102         # may auto-vivify if config file is non-existent:
 103         foreach my $section (@{$self->{-section_order}}) {
 104                 next if $section !~ m!\Apublicinbox\.([^/]+)\z!;
 105                 my $ibx = lookup_name($self, $1) or next;
 106                 $cb->($ibx, @arg);
 107         }
 108 }
 109
 110 sub lookup_newsgroup {
 111         my ($self, $ng) = @_;
 112         _lookup_fill($self, '-by_newsgroup', lc($ng));
 113 }
 114
 115 sub limiter {
 116         my ($self, $name) = @_;
 117         $self->{-limiters}->{$name} //= do {
 118                 require PublicInbox::Qspawn;
 119                 my $max = $self->{"publicinboxlimiter.$name.max"} || 1;
 120                 my $limiter = PublicInbox::Qspawn::Limiter->new($max);
 121                 $limiter->setup_rlimit($name, $self);
 122                 $limiter;
 123         };
 124 }
 125
 126 sub config_dir { $ENV{PI_DIR} // "$ENV{HOME}/.public-inbox" }
 127
 128 sub default_file {
 129         $ENV{PI_CONFIG} // (config_dir() . '/config');
 130 }
 131
 132 sub config_fh_parse ($$$) {
 133         my ($fh, $rs, $fs) = @_;
 134         my %rv;
 135         my (%section_seen, @section_order);
 136         local $/ = $rs;
 137         while (defined(my $line = <$fh>)) {
 138                 chomp $line;
 139                 my ($k, $v) = split($fs, $line, 2);
 140                 my ($section) = ($k =~ /\A(\S+)\.[^\.]+\z/);
 141                 unless (defined $section_seen{$section}) {
 142                         $section_seen{$section} = 1;
 143                         push @section_order, $section;
 144                 }
 145
 146                 my $cur = $rv{$k};
 147                 if (defined $cur) {
 148                         if (ref($cur) eq "ARRAY") {
 149                                 push @$cur, $v;
 150                         } else {
 151                                 $rv{$k} = [ $cur, $v ];
 152                         }
 153                 } else {
 154                         $rv{$k} = $v;
 155                 }
 156         }
 157         $rv{-section_order} = \@section_order;
 158
 159         \%rv;
 160 }
 161
 162 sub git_config_dump {
 163         my ($file) = @_;
 164         return {} unless -e $file;
 165         my @cmd = (qw/git config -z -l --includes/, "--file=$file");
 166         my $cmd = join(' ', @cmd);
 167         my $fh = popen_rd(\@cmd);
 168         my $rv = config_fh_parse($fh, "\0", "\n");
 169         close $fh or die "failed to close ($cmd) pipe: $?";
 170         $rv;
 171 }
 172
 173 sub valid_inbox_name ($) {
 174         my ($name) = @_;
 175
 176         # Similar rules found in git.git/remote.c::valid_remote_nick
 177         # and git.git/refs.c::check_refname_component
 178         # We don't reject /\.lock\z/, however, since we don't lock refs
 179         if ($name eq '' || $name =~ /\@\{/ ||
 180             $name =~ /\.\./ || $name =~ m![/:\?\[\]\^~\s\f[:cntrl:]\*]! ||
 181             $name =~ /\A\./ || $name =~ /\.\z/) {
 182                 return 0;
 183         }
 184
 185         # Note: we allow URL-unfriendly characters; users may configure
 186         # non-HTTP-accessible inboxes
 187         1;
 188 }
 189
 190 # XXX needs testing for cgit compatibility
 191 # cf. cgit/scan-tree.c::add_repo
 192 sub cgit_repo_merge ($$$) {
 193         my ($self, $base, $repo) = @_;
 194         my $path = $repo->{dir};
 195         if (defined(my $se = $self->{-cgit_strict_export})) {
 196                 return unless -e "$path/$se";
 197         }
 198         return if -e "$path/noweb";
 199         # this comes from the cgit config, and AFAIK cgit only allows
 200         # repos to have one URL, but that's just the PATH_INFO component,
 201         # not the Host: portion
 202         # $repo = { url => 'foo.git', dir => '/path/to/foo.git' }
 203         my $rel = $repo->{url};
 204         unless (defined $rel) {
 205                 my $off = index($path, $base, 0);
 206                 if ($off != 0) {
 207                         $rel = $path;
 208                 } else {
 209                         $rel = substr($path, length($base) + 1);
 210                 }
 211
 212                 $rel =~ s!/\.git\z!! or
 213                         $rel =~ s!/+\z!!;
 214
 215                 $self->{-cgit_remove_suffix} and
 216                         $rel =~ s!/?\.git\z!!;
 217         }
 218         $self->{"coderepo.$rel.dir"} //= $path;
 219         $self->{"coderepo.$rel.cgiturl"} //= _array($rel);
 220 }
 221
 222 sub is_git_dir ($) {
 223         my ($git_dir) = @_;
 224         -d "$git_dir/objects" && -f "$git_dir/HEAD";
 225 }
 226
 227 # XXX needs testing for cgit compatibility
 228 sub scan_path_coderepo {
 229         my ($self, $base, $path) = @_;
 230         opendir(my $dh, $path) or do {
 231                 warn "error opening directory: $path\n";
 232                 return
 233         };
 234         my $git_dir = $path;
 235         if (is_git_dir($git_dir) || is_git_dir($git_dir .= '/.git')) {
 236                 my $repo = { dir => $git_dir };
 237                 cgit_repo_merge($self, $base, $repo);
 238                 return;
 239         }
 240         while (defined(my $dn = readdir $dh)) {
 241                 next if $dn eq '.' || $dn eq '..';
 242                 if (index($dn, '.') == 0 && !$self->{-cgit_scan_hidden_path}) {
 243                         next;
 244                 }
 245                 my $dir = "$path/$dn";
 246                 scan_path_coderepo($self, $base, $dir) if -d $dir;
 247         }
 248 }
 249
 250 sub scan_tree_coderepo ($$) {
 251         my ($self, $path) = @_;
 252         scan_path_coderepo($self, $path, $path);
 253 }
 254
 255 sub scan_projects_coderepo ($$$) {
 256         my ($self, $list, $path) = @_;
 257         open my $fh, '<', $list or do {
 258                 warn "failed to open cgit projectlist=$list: $!\n";
 259                 return;
 260         };
 261         while (<$fh>) {
 262                 chomp;
 263                 scan_path_coderepo($self, $path, "$path/$_");
 264         }
 265 }
 266
 267 sub parse_cgitrc {
 268         my ($self, $cgitrc, $nesting) = @_;
 269         if ($nesting == 0) {
 270                 # defaults:
 271                 my %s = map { $_ => 1 } qw(/cgit.css /cgit.png
 272                                                 /favicon.ico /robots.txt);
 273                 $self->{-cgit_static} = \%s;
 274         }
 275
 276         # same limit as cgit/configfile.c::parse_configfile
 277         return if $nesting > 8;
 278
 279         open my $fh, '<', $cgitrc or do {
 280                 warn "failed to open cgitrc=$cgitrc: $!\n";
 281                 return;
 282         };
 283
 284         # FIXME: this doesn't support macro expansion via $VARS, yet
 285         my $repo;
 286         while (<$fh>) {
 287                 chomp;
 288                 if (m!\Arepo\.url=(.+?)/*\z!) {
 289                         my $nick = $1;
 290                         cgit_repo_merge($self, $repo->{dir}, $repo) if $repo;
 291                         $repo = { url => $nick };
 292                 } elsif (m!\Arepo\.path=(.+)\z!) {
 293                         if (defined $repo) {
 294                                 $repo->{dir} = $1;
 295                         } else {
 296                                 warn "$_ without repo.url\n";
 297                         }
 298                 } elsif (m!\Ainclude=(.+)\z!) {
 299                         parse_cgitrc($self, $1, $nesting + 1);
 300                 } elsif (m!\A(scan-hidden-path|remove-suffix)=([0-9]+)\z!) {
 301                         my ($k, $v) = ($1, $2);
 302                         $k =~ tr/-/_/;
 303                         $self->{"-cgit_$k"} = $v;
 304                 } elsif (m!\A(project-list|strict-export)=(.+)\z!) {
 305                         my ($k, $v) = ($1, $2);
 306                         $k =~ tr/-/_/;
 307                         $self->{"-cgit_$k"} = $v;
 308                 } elsif (m!\Ascan-path=(.+)\z!) {
 309                         if (defined(my $list = $self->{-cgit_project_list})) {
 310                                 scan_projects_coderepo($self, $list, $1);
 311                         } else {
 312                                 scan_tree_coderepo($self, $1);
 313                         }
 314                 } elsif (m!\A(?:css|favicon|logo|repo\.logo)=(/.+)\z!) {
 315                         # absolute paths for static files via PublicInbox::Cgit
 316                         $self->{-cgit_static}->{$1} = 1;
 317                 }
 318         }
 319         cgit_repo_merge($self, $repo->{dir}, $repo) if $repo;
 320 }
 321
 322 # parse a code repo
 323 # Only git is supported at the moment, but SVN and Hg are possibilities
 324 sub _fill_code_repo {
 325         my ($self, $nick) = @_;
 326         my $pfx = "coderepo.$nick";
 327
 328         # TODO: support gitweb and other repository viewers?
 329         if (defined(my $cgitrc = delete $self->{-cgitrc_unparsed})) {
 330                 parse_cgitrc($self, $cgitrc, 0);
 331         }
 332         my $dir = $self->{"$pfx.dir"}; # aka "GIT_DIR"
 333         unless (defined $dir) {
 334                 warn "$pfx.dir unset\n";
 335                 return;
 336         }
 337
 338         my $git = PublicInbox::Git->new($dir);
 339         foreach my $t (qw(blob commit tree tag)) {
 340                 $git->{$t.'_url_format'} =
 341                                 _array($self->{lc("$pfx.${t}UrlFormat")});
 342         }
 343
 344         if (defined(my $cgits = $self->{"$pfx.cgiturl"})) {
 345                 $git->{cgit_url} = $cgits = _array($cgits);
 346                 $self->{"$pfx.cgiturl"} = $cgits;
 347
 348                 # cgit supports "/blob/?id=%s", but it's only a plain-text
 349                 # display and requires an unabbreviated id=
 350                 foreach my $t (qw(blob commit tag)) {
 351                         $git->{$t.'_url_format'} //= map {
 352                                 "$_/$t/?id=%s"
 353                         } @$cgits;
 354                 }
 355         }
 356
 357         $git;
 358 }
 359
 360 sub git_bool {
 361         my ($val) = $_[-1]; # $_[0] may be $self, or $val
 362         if ($val =~ /\A(?:false|no|off|[\-\+]?(?:0x)?0+)\z/i) {
 363                 0;
 364         } elsif ($val =~ /\A(?:true|yes|on|[\-\+]?(?:0x)?[0-9]+)\z/i) {
 365                 1;
 366         } else {
 367                 undef;
 368         }
 369 }
 370
 371 sub _fill {
 372         my ($self, $pfx) = @_;
 373         my $ibx = {};
 374
 375         for my $k (qw(watch nntpserver)) {
 376                 my $v = $self->{"$pfx.$k"};
 377                 $ibx->{$k} = $v if defined $v;
 378         }
 379         for my $k (qw(filter inboxdir newsgroup replyto httpbackendmax feedmax
 380                         indexlevel indexsequentialshard)) {
 381                 if (defined(my $v = $self->{"$pfx.$k"})) {
 382                         if (ref($v) eq 'ARRAY') {
 383                                 warn <<EOF;
 384 W: $pfx.$k has multiple values, only using `$v->[-1]'
 385 EOF
 386                                 $ibx->{$k} = $v->[-1];
 387                         } else {
 388                                 $ibx->{$k} = $v;
 389                         }
 390                 }
 391         }
 392
 393         # backwards compatibility:
 394         $ibx->{inboxdir} //= $self->{"$pfx.mainrepo"};
 395         if (($ibx->{inboxdir} // '') =~ /\n/s) {
 396                 warn "E: `$ibx->{inboxdir}' must not contain `\\n'\n";
 397                 return;
 398         }
 399         foreach my $k (qw(obfuscate)) {
 400                 my $v = $self->{"$pfx.$k"};
 401                 defined $v or next;
 402                 if (defined(my $bval = git_bool($v))) {
 403                         $ibx->{$k} = $bval;
 404                 } else {
 405                         warn "Ignoring $pfx.$k=$v in config, not boolean\n";
 406                 }
 407         }
 408         # TODO: more arrays, we should support multi-value for
 409         # more things to encourage decentralization
 410         foreach my $k (qw(address altid nntpmirror coderepo hide listid url
 411                         infourl watchheader)) {
 412                 if (defined(my $v = $self->{"$pfx.$k"})) {
 413                         $ibx->{$k} = _array($v);
 414                 }
 415         }
 416
 417         return unless defined($ibx->{inboxdir});
 418         my $name = $pfx;
 419         $name =~ s/\Apublicinbox\.//;
 420
 421         if (!valid_inbox_name($name)) {
 422                 warn "invalid inbox name: '$name'\n";
 423                 return;
 424         }
 425
 426         $ibx->{name} = $name;
 427         $ibx->{-pi_config} = $self;
 428         $ibx = PublicInbox::Inbox->new($ibx);
 429         foreach (@{$ibx->{address}}) {
 430                 my $lc_addr = lc($_);
 431                 $self->{-by_addr}->{$lc_addr} = $ibx;
 432                 $self->{-no_obfuscate}->{$lc_addr} = 1;
 433         }
 434         if (my $listids = $ibx->{listid}) {
 435                 # RFC2919 section 6 stipulates "case insensitive equality"
 436                 foreach my $list_id (@$listids) {
 437                         $self->{-by_list_id}->{lc($list_id)} = $ibx;
 438                 }
 439         }
 440         if (my $ngname = $ibx->{newsgroup}) {
 441                 if (ref($ngname)) {
 442                         delete $ibx->{newsgroup};
 443                         warn 'multiple newsgroups not supported: '.
 444                                 join(', ', @$ngname). "\n";
 445                 # Newsgroup name needs to be compatible with RFC 3977
 446                 # wildmat-exact and RFC 3501 (IMAP) ATOM-CHAR.
 447                 # Leave out a few chars likely to cause problems or conflicts:
 448                 # '|', '<', '>', ';', '#', '$', '&',
 449                 } elsif ($ngname =~ m![^A-Za-z0-9/_\.\-\~\@\+\=:]!) {
 450                         delete $ibx->{newsgroup};
 451                         warn "newsgroup name invalid: `$ngname'\n";
 452                 } else {
 453                         # PublicInbox::NNTPD does stricter ->nntp_usable
 454                         # checks, keep this lean for startup speed
 455                         $self->{-by_newsgroup}->{$ngname} = $ibx;
 456                 }
 457         }
 458         $self->{-by_name}->{$name} = $ibx;
 459         if ($ibx->{obfuscate}) {
 460                 $ibx->{-no_obfuscate} = $self->{-no_obfuscate};
 461                 $ibx->{-no_obfuscate_re} = $self->{-no_obfuscate_re};
 462                 fill_all($self); # noop to populate -no_obfuscate
 463         }
 464
 465         if (my $ibx_code_repos = $ibx->{coderepo}) {
 466                 my $code_repos = $self->{-code_repos};
 467                 my $repo_objs = $ibx->{-repo_objs} = [];
 468                 foreach my $nick (@$ibx_code_repos) {
 469                         my @parts = split(m!/!, $nick);
 470                         my $valid = 0;
 471                         $valid += valid_inbox_name($_) foreach (@parts);
 472                         $valid == scalar(@parts) or next;
 473
 474                         my $repo = $code_repos->{$nick} //=
 475                                                 _fill_code_repo($self, $nick);
 476                         push @$repo_objs, $repo if $repo;
 477                 }
 478         }
 479
 480         $ibx
 481 }
 482
 483 sub _fill_ei ($$) {
 484         my ($self, $pfx) = @_;
 485         require PublicInbox::ExtSearch;
 486         my $d = $self->{"$pfx.topdir"};
 487         defined($d) && -d $d ? PublicInbox::ExtSearch->new($d) : undef;
 488 }
 489
 490 sub urlmatch {
 491         my ($self, $key, $url) = @_;
 492         state $urlmatch_broken; # requires git 1.8.5
 493         return if $urlmatch_broken;
 494         my $file = default_file();
 495         my $cmd = [qw/git config -z --includes --get-urlmatch/,
 496                 "--file=$file", $key, $url ];
 497         my $fh = popen_rd($cmd);
 498         local $/ = "\0";
 499         my $val = <$fh>;
 500         if (close($fh)) {
 501                 chomp($val);
 502                 $val;
 503         } else {
 504                 $urlmatch_broken = 1 if (($? >> 8) != 1);
 505                 undef;
 506         }
 507 }
 508
 509 sub json {
 510         state $json;
 511         $json //= do {
 512                 for my $mod (qw(Cpanel::JSON::XS JSON::MaybeXS JSON JSON::PP)) {
 513                         eval "require $mod" or next;
 514                         # ->ascii encodes non-ASCII to "\uXXXX"
 515                         $json = $mod->new->ascii(1) and last;
 516                 }
 517                 $json;
 518         };
 519 }
 520
 521 1;