lib/PublicInbox/Config.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used throughout the project for reading configuration
   5 #
   6 # Note: I hate camelCase; but git-config(1) uses it, but it's better
   7 # than alllowercasewithoutunderscores, so use lc('configKey') where
   8 # applicable for readability
   9
  10 package PublicInbox::Config;
  11 use strict;
  12 use warnings;
  13 require PublicInbox::Inbox;
  14 use PublicInbox::Spawn qw(popen_rd);
  15
  16 sub _array ($) { ref($_[0]) eq 'ARRAY' ? $_[0] : [ $_[0] ] }
  17
  18 # returns key-value pairs of config directives in a hash
  19 # if keys may be multi-value, the value is an array ref containing all values
  20 sub new {
  21         my ($class, $file) = @_;
  22         $file = default_file() unless defined($file);
  23         $file = ref $file ? $file : git_config_dump($file);
  24         my $self = bless $file, $class;
  25
  26         # caches
  27         $self->{-by_addr} ||= {};
  28         $self->{-by_name} ||= {};
  29         $self->{-by_newsgroup} ||= {};
  30         $self->{-no_obfuscate} ||= {};
  31         $self->{-limiters} ||= {};
  32         $self->{-code_repos} ||= {}; # nick => PublicInbox::Git object
  33
  34         if (my $no = delete $self->{'publicinbox.noobfuscate'}) {
  35                 $no = _array($no);
  36                 my @domains;
  37                 foreach my $n (@$no) {
  38                         my @n = split(/\s+/, $n);
  39                         foreach (@n) {
  40                                 if (/\S+@\S+/) { # full address
  41                                         $self->{-no_obfuscate}->{lc $_} = 1;
  42                                 } else {
  43                                         # allow "example.com" or "@example.com"
  44                                         s/\A@//;
  45                                         push @domains, quotemeta($_);
  46                                 }
  47                         }
  48                 }
  49                 my $nod = join('|', @domains);
  50                 $self->{-no_obfuscate_re} = qr/(?:$nod)\z/i;
  51         }
  52         if (my $css = delete $self->{'publicinbox.css'}) {
  53                 $self->{css} = _array($css);
  54         }
  55
  56         $self;
  57 }
  58
  59 sub lookup {
  60         my ($self, $recipient) = @_;
  61         my $addr = lc($recipient);
  62         my $inbox = $self->{-by_addr}->{$addr};
  63         return $inbox if $inbox;
  64
  65         my $pfx;
  66
  67         foreach my $k (keys %$self) {
  68                 $k =~ m!\A(publicinbox\.[^/]+)\.address\z! or next;
  69                 my $v = $self->{$k};
  70                 if (ref($v) eq "ARRAY") {
  71                         foreach my $alias (@$v) {
  72                                 (lc($alias) eq $addr) or next;
  73                                 $pfx = $1;
  74                                 last;
  75                         }
  76                 } else {
  77                         (lc($v) eq $addr) or next;
  78                         $pfx = $1;
  79                         last;
  80                 }
  81         }
  82         defined $pfx or return;
  83         _fill($self, $pfx);
  84 }
  85
  86 sub lookup_name ($$) {
  87         my ($self, $name) = @_;
  88         $self->{-by_name}->{$name} || _fill($self, "publicinbox.$name");
  89 }
  90
  91 sub each_inbox {
  92         my ($self, $cb) = @_;
  93         if (my $section_order = $self->{-section_order}) {
  94                 foreach my $section (@$section_order) {
  95                         next if $section !~ m!\Apublicinbox\.([^/]+)\z!;
  96                         $self->{"publicinbox.$1.mainrepo"} or next;
  97                         my $ibx = lookup_name($self, $1) or next;
  98                         $cb->($ibx);
  99                 }
 100         } else {
 101                 my %seen;
 102                 foreach my $k (keys %$self) {
 103                         $k =~ m!\Apublicinbox\.([^/]+)\.mainrepo\z! or next;
 104                         next if $seen{$1};
 105                         $seen{$1} = 1;
 106                         my $ibx = lookup_name($self, $1) or next;
 107                         $cb->($ibx);
 108                 }
 109         }
 110 }
 111
 112 sub lookup_newsgroup {
 113         my ($self, $ng) = @_;
 114         $ng = lc($ng);
 115         my $rv = $self->{-by_newsgroup}->{$ng};
 116         return $rv if $rv;
 117
 118         foreach my $k (keys %$self) {
 119                 $k =~ m!\A(publicinbox\.[^/]+)\.newsgroup\z! or next;
 120                 my $v = $self->{$k};
 121                 my $pfx = $1;
 122                 if ($v eq $ng) {
 123                         $rv = _fill($self, $pfx);
 124                         return $rv;
 125                 }
 126         }
 127         undef;
 128 }
 129
 130 sub limiter {
 131         my ($self, $name) = @_;
 132         $self->{-limiters}->{$name} ||= do {
 133                 require PublicInbox::Qspawn;
 134                 my $max = $self->{"publicinboxlimiter.$name.max"};
 135                 PublicInbox::Qspawn::Limiter->new($max);
 136         };
 137 }
 138
 139 sub config_dir { $ENV{PI_DIR} || "$ENV{HOME}/.public-inbox" }
 140
 141 sub default_file {
 142         my $f = $ENV{PI_CONFIG};
 143         return $f if defined $f;
 144         config_dir() . '/config';
 145 }
 146
 147 sub git_config_dump {
 148         my ($file) = @_;
 149         my (%section_seen, @section_order);
 150         my @cmd = (qw/git config/, "--file=$file", '-l');
 151         my $cmd = join(' ', @cmd);
 152         my $fh = popen_rd(\@cmd) or die "popen_rd failed for $file: $!\n";
 153         my %rv;
 154         local $/ = "\n";
 155         while (defined(my $line = <$fh>)) {
 156                 chomp $line;
 157                 my ($k, $v) = split(/=/, $line, 2);
 158
 159                 my ($section) = ($k =~ /\A(\S+)\.[^\.]+\z/);
 160                 unless (defined $section_seen{$section}) {
 161                         $section_seen{$section} = 1;
 162                         push @section_order, $section;
 163                 }
 164
 165                 my $cur = $rv{$k};
 166                 if (defined $cur) {
 167                         if (ref($cur) eq "ARRAY") {
 168                                 push @$cur, $v;
 169                         } else {
 170                                 $rv{$k} = [ $cur, $v ];
 171                         }
 172                 } else {
 173                         $rv{$k} = $v;
 174                 }
 175         }
 176         close $fh or die "failed to close ($cmd) pipe: $?";
 177         $rv{-section_order} = \@section_order;
 178
 179         \%rv;
 180 }
 181
 182 sub valid_inbox_name ($) {
 183         my ($name) = @_;
 184
 185         # Similar rules found in git.git/remote.c::valid_remote_nick
 186         # and git.git/refs.c::check_refname_component
 187         # We don't reject /\.lock\z/, however, since we don't lock refs
 188         if ($name eq '' || $name =~ /\@\{/ ||
 189             $name =~ /\.\./ || $name =~ m![/:\?\[\]\^~\s\f[:cntrl:]\*]! ||
 190             $name =~ /\A\./ || $name =~ /\.\z/) {
 191                 return 0;
 192         }
 193
 194         # Note: we allow URL-unfriendly characters; users may configure
 195         # non-HTTP-accessible inboxes
 196         1;
 197 }
 198
 199 # parse a code repo
 200 # Only git is supported at the moment, but SVN and Hg are possibilities
 201 sub _fill_code_repo {
 202         my ($self, $nick) = @_;
 203         my $pfx = "coderepo.$nick";
 204
 205         my $dir = $self->{"$pfx.dir"}; # aka "GIT_DIR"
 206         unless (defined $dir) {
 207                 warn "$pfx.repodir unset";
 208                 return;
 209         }
 210
 211         my $git = PublicInbox::Git->new($dir);
 212         foreach my $t (qw(blob commit tree tag)) {
 213                 $git->{$t.'_url_format'} =
 214                                 _array($self->{lc("$pfx.${t}UrlFormat")});
 215         }
 216
 217         if (my $cgits = $self->{lc("$pfx.cgitUrl")}) {
 218                 $git->{cgit_url} = $cgits = _array($cgits);
 219
 220                 # cgit supports "/blob/?id=%s", but it's only a plain-text
 221                 # display and requires an unabbreviated id=
 222                 foreach my $t (qw(blob commit tag)) {
 223                         $git->{$t.'_url_format'} ||= map {
 224                                 "$_/$t/?id=%s"
 225                         } @$cgits;
 226                 }
 227         }
 228         # TODO: support gitweb and other repository viewers?
 229         # TODO: parse cgitrc
 230
 231         $git;
 232 }
 233
 234 sub _fill {
 235         my ($self, $pfx) = @_;
 236         my $rv = {};
 237
 238         foreach my $k (qw(mainrepo filter url newsgroup
 239                         infourl watch watchheader httpbackendmax
 240                         replyto feedmax nntpserver indexlevel)) {
 241                 my $v = $self->{"$pfx.$k"};
 242                 $rv->{$k} = $v if defined $v;
 243         }
 244         foreach my $k (qw(obfuscate)) {
 245                 my $v = $self->{"$pfx.$k"};
 246                 defined $v or next;
 247                 if ($v =~ /\A(?:false|no|off|0)\z/) {
 248                         $rv->{$k} = 0;
 249                 } elsif ($v =~ /\A(?:true|yes|on|1)\z/) {
 250                         $rv->{$k} = 1;
 251                 } else {
 252                         warn "Ignoring $pfx.$k=$v in config, not boolean\n";
 253                 }
 254         }
 255         # TODO: more arrays, we should support multi-value for
 256         # more things to encourage decentralization
 257         foreach my $k (qw(address altid nntpmirror coderepo)) {
 258                 if (defined(my $v = $self->{"$pfx.$k"})) {
 259                         $rv->{$k} = _array($v);
 260                 }
 261         }
 262
 263         return unless $rv->{mainrepo};
 264         my $name = $pfx;
 265         $name =~ s/\Apublicinbox\.//;
 266
 267         if (!valid_inbox_name($name)) {
 268                 warn "invalid inbox name: '$name'\n";
 269                 return;
 270         }
 271
 272         $rv->{name} = $name;
 273         $rv->{-pi_config} = $self;
 274         $rv = PublicInbox::Inbox->new($rv);
 275         foreach (@{$rv->{address}}) {
 276                 my $lc_addr = lc($_);
 277                 $self->{-by_addr}->{$lc_addr} = $rv;
 278                 $self->{-no_obfuscate}->{$lc_addr} = 1;
 279         }
 280         if (my $ng = $rv->{newsgroup}) {
 281                 $self->{-by_newsgroup}->{$ng} = $rv;
 282         }
 283         $self->{-by_name}->{$name} = $rv;
 284         if ($rv->{obfuscate}) {
 285                 $rv->{-no_obfuscate} = $self->{-no_obfuscate};
 286                 $rv->{-no_obfuscate_re} = $self->{-no_obfuscate_re};
 287                 each_inbox($self, sub {}); # noop to populate -no_obfuscate
 288         }
 289
 290         if (my $ibx_code_repos = $rv->{coderepo}) {
 291                 my $code_repos = $self->{-code_repos};
 292                 my $repo_objs = $rv->{-repo_objs} = [];
 293                 foreach my $nick (@$ibx_code_repos) {
 294                         valid_inbox_name($nick) or next;
 295                         my $repo = $code_repos->{$nick} ||=
 296                                                 _fill_code_repo($self, $nick);
 297                         push @$repo_objs, $repo if $repo;
 298                 }
 299         }
 300
 301         $rv
 302 }
 303
 304 1;