lib/PublicInbox/ContentHash.pm

   1 # Copyright (C) 2018-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Unstable internal API.
   5 # Used for on-the-fly duplicate detection in V2 inboxes.
   6 # This is not stored in any database anywhere and may change
   7 # as changes in duplicate detection are needed.
   8 # See L<public-inbox-v2-format(5)> manpage for more details.
   9 package PublicInbox::ContentHash;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(Exporter);
  13 our @EXPORT_OK = qw(content_hash content_digest git_sha);
  14 use PublicInbox::MID qw(mids references);
  15 use PublicInbox::MsgIter;
  16
  17 # not sure if less-widely supported hash families are worth bothering with
  18 use Digest::SHA;
  19
  20 sub digest_addr ($$$) {
  21         my ($dig, $h, $v) = @_;
  22         $v =~ tr/"//d;
  23         $v =~ s/@([a-z0-9\_\.\-\(\)]*([A-Z])\S*)/'@'.lc($1)/ge;
  24         utf8::encode($v);
  25         $dig->add("$h\0$v\0");
  26 }
  27
  28 sub content_dig_i {
  29         my ($dig) = $_[1];
  30         my ($part, $depth, @idx) = @{$_[0]};
  31         $dig->add("\0$depth:".join('.', @idx)."\0");
  32         my $fn = $part->filename;
  33         if (defined $fn) {
  34                 utf8::encode($fn);
  35                 $dig->add("fn\0$fn\0");
  36         }
  37         my @d = $part->header('Content-Description');
  38         foreach my $d (@d) {
  39                 utf8::encode($d);
  40                 $dig->add("d\0$d\0");
  41         }
  42         $dig->add("b\0");
  43         my $ct = $part->content_type || 'text/plain';
  44         my ($s, undef) = msg_part_text($part, $ct);
  45         if (defined $s) {
  46                 $s =~ s/\r\n/\n/gs;
  47                 $s =~ s/\s*\z//s;
  48                 utf8::encode($s);
  49         } else {
  50                 $s = $part->body;
  51         }
  52         $dig->add($s);
  53 }
  54
  55 sub content_digest ($;$) {
  56         my ($eml, $dig) = @_;
  57         $dig //= Digest::SHA->new(256);
  58
  59         # References: and In-Reply-To: get used interchangeably
  60         # in some "duplicates" in LKML.  We treat them the same
  61         # in SearchIdx, so treat them the same for this:
  62         # do NOT consider the Message-ID as part of the content_hash
  63         # if we got here, we've already got Message-ID reuse
  64         my %seen = map { $_ => 1 } @{mids($eml)};
  65         foreach my $mid (@{references($eml)}) {
  66                 $dig->add("ref\0$mid\0") unless $seen{$mid}++;
  67         }
  68
  69         # Only use Sender: if From is not present
  70         foreach my $h (qw(From Sender)) {
  71                 my @v = $eml->header($h) or next;
  72                 digest_addr($dig, $h, $_) foreach @v;
  73                 last;
  74         }
  75         foreach my $h (qw(Subject Date)) {
  76                 my @v = $eml->header($h);
  77                 foreach my $v (@v) {
  78                         utf8::encode($v);
  79                         $dig->add("$h\0$v\0");
  80                 }
  81         }
  82         # Some mail processors will add " to unquoted names that were
  83         # not in the original message.  For the purposes of deduplication,
  84         # do not take it into account:
  85         foreach my $h (qw(To Cc)) {
  86                 my @v = $eml->header($h);
  87                 digest_addr($dig, $h, $_) foreach @v;
  88         }
  89         msg_iter($eml, \&content_dig_i, $dig);
  90         $dig;
  91 }
  92
  93 sub content_hash ($) {
  94         content_digest($_[0])->digest;
  95 }
  96
  97 sub git_sha ($$) {
  98         my ($n, $eml) = @_;
  99         my $dig = Digest::SHA->new($n);
 100         my $bref = ref($eml) eq 'SCALAR' ? $eml : \($eml->as_string);
 101         $dig->add('blob '.length($$bref)."\0");
 102         $dig->add($$bref);
 103         $dig;
 104 }
 105
 106 1;