lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the unmaintained Danga::Socket (1.61) with
   7 # significant changes.  See Documentation/technical/ds.txt in our
   8 # source for details.
   9 #
  10 # Do not expect this to be a stable API like Danga::Socket,
  11 # but it will evolve to suite our needs and to take advantage of
  12 # newer Linux and *BSD features.
  13 # Bugs encountered were reported to bug-Danga-Socket@rt.cpan.org,
  14 # fixed in Danga::Socket 1.62 and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 package PublicInbox::DS;
  17 use strict;
  18 use bytes;
  19 use POSIX qw(WNOHANG);
  20 use IO::Handle qw();
  21 use Fcntl qw(SEEK_SET :DEFAULT);
  22 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  23 use parent qw(Exporter);
  24 our @EXPORT_OK = qw(now msg_more);
  25 use warnings;
  26 use 5.010_001;
  27 use Scalar::Util qw(blessed);
  28
  29 use PublicInbox::Syscall qw(:epoll);
  30 use PublicInbox::Tmpfile;
  31
  32 use fields ('sock',              # underlying socket
  33             'rbuf',              # scalarref, usually undef
  34             'wbuf', # arrayref of coderefs or GLOB refs (autovivified)
  35             'wbuf_off',  # offset into first element of wbuf to start writing at
  36             );
  37
  38 use Errno qw(EAGAIN EINVAL);
  39 use Carp qw(confess carp);
  40
  41 my $nextq; # queue for next_tick
  42 my $wait_pids; # list of [ pid, callback, callback_arg ]
  43 my $later_queue; # list of callbacks to run at some later interval
  44 my $EXPMAP; # fd -> idle_time
  45 our $EXPTIME = 180; # 3 minutes
  46 my ($later_timer, $reap_timer, $exp_timer);
  47 my $ToClose; # sockets to close when event loop is done
  48 our (
  49      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  50      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  51      $_io,                       # IO::Handle for Epoll
  52
  53      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  54
  55      $LoopTimeout,               # timeout of event loop in milliseconds
  56      $DoneInit,                  # if we've done the one-time module init yet
  57      @Timers,                    # timers
  58      $in_loop,
  59      );
  60
  61 Reset();
  62
  63 #####################################################################
  64 ### C L A S S   M E T H O D S
  65 #####################################################################
  66
  67 =head2 C<< CLASS->Reset() >>
  68
  69 Reset all state
  70
  71 =cut
  72 sub Reset {
  73     %DescriptorMap = ();
  74     $wait_pids = $later_queue = undef;
  75     $EXPMAP = {};
  76     $nextq = $ToClose = $reap_timer = $later_timer = $exp_timer = undef;
  77     $LoopTimeout = -1;  # no timeout by default
  78     @Timers = ();
  79
  80     $PostLoopCallback = undef;
  81     $DoneInit = 0;
  82
  83     $_io = undef; # closes real $Epoll FD
  84     $Epoll = undef; # may call DSKQXS::DESTROY
  85
  86     *EventLoop = *FirstTimeEventLoop;
  87 }
  88
  89 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  90
  91 Set the loop timeout for the event loop to some value in milliseconds.
  92
  93 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  94 immediately.
  95
  96 =cut
  97 sub SetLoopTimeout {
  98     return $LoopTimeout = $_[1] + 0;
  99 }
 100
 101 =head2 C<< PublicInbox::DS::add_timer( $seconds, $coderef ) >>
 102
 103 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 104 are not guaranteed to fire at the exact time you ask for.
 105
 106 =cut
 107 sub add_timer ($$) {
 108     my ($secs, $coderef) = @_;
 109
 110     my $fire_time = now() + $secs;
 111
 112     my $timer = [$fire_time, $coderef];
 113
 114     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 115         push @Timers, $timer;
 116         return $timer;
 117     }
 118
 119     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 120     # but it was compared against calendar queues, heaps, naive push/sort,
 121     # and a bunch of other versions, and found to be fastest with a large
 122     # variety of datasets.)
 123     for (my $i = 0; $i < @Timers; $i++) {
 124         if ($Timers[$i][0] > $fire_time) {
 125             splice(@Timers, $i, 0, $timer);
 126             return $timer;
 127         }
 128     }
 129
 130     die "Shouldn't get here.";
 131 }
 132
 133 # keeping this around in case we support other FD types for now,
 134 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 135 sub set_cloexec ($) {
 136     my ($fd) = @_;
 137
 138     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 139     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 140     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 141 }
 142
 143 sub _InitPoller
 144 {
 145     return if $DoneInit;
 146     $DoneInit = 1;
 147
 148     if (PublicInbox::Syscall::epoll_defined())  {
 149         $Epoll = epoll_create();
 150         set_cloexec($Epoll) if (defined($Epoll) && $Epoll >= 0);
 151     } else {
 152         my $cls;
 153         for (qw(DSKQXS DSPoll)) {
 154             $cls = "PublicInbox::$_";
 155             last if eval "require $cls";
 156         }
 157         $cls->import(qw(epoll_ctl epoll_wait));
 158         $Epoll = $cls->new;
 159     }
 160     *EventLoop = *EpollEventLoop;
 161 }
 162
 163 =head2 C<< CLASS->EventLoop() >>
 164
 165 Start processing IO events. In most daemon programs this never exits. See
 166 C<PostLoopCallback> below for how to exit the loop.
 167
 168 =cut
 169 sub FirstTimeEventLoop {
 170     my $class = shift;
 171
 172     _InitPoller();
 173
 174     EventLoop($class);
 175 }
 176
 177 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 178
 179 sub next_tick () {
 180     my $q = $nextq or return;
 181     $nextq = undef;
 182     for (@$q) {
 183         # we avoid "ref" on blessed refs to workaround a Perl 5.16.3 leak:
 184         # https://rt.perl.org/Public/Bug/Display.html?id=114340
 185         if (blessed($_)) {
 186             $_->event_step;
 187         } else {
 188             $_->();
 189         }
 190     }
 191 }
 192
 193 # runs timers and returns milliseconds for next one, or next event loop
 194 sub RunTimers {
 195     next_tick();
 196
 197     return (($nextq || $ToClose) ? 0 : $LoopTimeout) unless @Timers;
 198
 199     my $now = now();
 200
 201     # Run expired timers
 202     while (@Timers && $Timers[0][0] <= $now) {
 203         my $to_run = shift(@Timers);
 204         $to_run->[1]->($now) if $to_run->[1];
 205     }
 206
 207     # timers may enqueue into nextq:
 208     return 0 if ($nextq || $ToClose);
 209
 210     return $LoopTimeout unless @Timers;
 211
 212     # convert time to an even number of milliseconds, adding 1
 213     # extra, otherwise floating point fun can occur and we'll
 214     # call RunTimers like 20-30 times, each returning a timeout
 215     # of 0.0000212 seconds
 216     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 217
 218     # -1 is an infinite timeout, so prefer a real timeout
 219     return $timeout     if $LoopTimeout == -1;
 220
 221     # otherwise pick the lower of our regular timeout and time until
 222     # the next timer
 223     return $LoopTimeout if $LoopTimeout < $timeout;
 224     return $timeout;
 225 }
 226
 227 # We can't use waitpid(-1) safely here since it can hit ``, system(),
 228 # and other things.  So we scan the $wait_pids list, which is hopefully
 229 # not too big.  We keep $wait_pids small by not calling dwaitpid()
 230 # until we've hit EOF when reading the stdout of the child.
 231 sub reap_pids {
 232     my $tmp = $wait_pids or return;
 233     $wait_pids = $reap_timer = undef;
 234     foreach my $ary (@$tmp) {
 235         my ($pid, $cb, $arg) = @$ary;
 236         my $ret = waitpid($pid, WNOHANG);
 237         if ($ret == 0) {
 238             push @$wait_pids, $ary; # autovivifies @$wait_pids
 239         } elsif ($cb) {
 240             eval { $cb->($arg, $pid) };
 241         }
 242     }
 243     # we may not be done, yet, and could've missed/masked a SIGCHLD:
 244     $reap_timer = add_timer(1, \&reap_pids) if $wait_pids;
 245 }
 246
 247 # reentrant SIGCHLD handler (since reap_pids is not reentrant)
 248 sub enqueue_reap ($) { push @$nextq, \&reap_pids }; # autovivifies
 249
 250 sub in_loop () { $in_loop }
 251
 252 # Internal function: run the post-event callback, send read events
 253 # for pushed-back data, and close pending connections.  returns 1
 254 # if event loop should continue, or 0 to shut it all down.
 255 sub PostEventLoop () {
 256         # now we can close sockets that wanted to close during our event
 257         # processing.  (we didn't want to close them during the loop, as we
 258         # didn't want fd numbers being reused and confused during the event
 259         # loop)
 260         if (my $close_now = $ToClose) {
 261                 $ToClose = undef; # will be autovivified on push
 262                 @$close_now = map { fileno($_) } @$close_now;
 263
 264                 # order matters, destroy expiry times, first:
 265                 delete @$EXPMAP{@$close_now};
 266
 267                 # ->DESTROY methods may populate ToClose
 268                 delete @DescriptorMap{@$close_now};
 269         }
 270
 271         # by default we keep running, unless a postloop callback cancels it
 272         $PostLoopCallback ? $PostLoopCallback->(\%DescriptorMap) : 1;
 273 }
 274
 275 sub EpollEventLoop {
 276     local $in_loop = 1;
 277     do {
 278         my @events;
 279         my $i;
 280         my $timeout = RunTimers();
 281
 282         # get up to 1000 events
 283         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 284         for ($i=0; $i<$evcount; $i++) {
 285             # it's possible epoll_wait returned many events, including some at the end
 286             # that ones in the front triggered unregister-interest actions.  if we
 287             # can't find the %sock entry, it's because we're no longer interested
 288             # in that event.
 289             $DescriptorMap{$events[$i]->[0]}->event_step;
 290         }
 291     } while (PostEventLoop());
 292     _run_later();
 293 }
 294
 295 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 296
 297 Sets post loop callback function.  Pass a subref and it will be
 298 called every time the event loop finishes.
 299
 300 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 301 and it will exit.
 302
 303 The callback function will be passed two parameters: \%DescriptorMap
 304
 305 =cut
 306 sub SetPostLoopCallback {
 307     my ($class, $ref) = @_;
 308
 309     # global callback
 310     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 311 }
 312
 313 #####################################################################
 314 ### PublicInbox::DS-the-object code
 315 #####################################################################
 316
 317 =head2 OBJECT METHODS
 318
 319 =head2 C<< CLASS->new( $socket ) >>
 320
 321 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 322 react to events on it during the C<EventLoop>.
 323
 324 This is normally (always?) called from your subclass via:
 325
 326   $class->SUPER::new($socket);
 327
 328 =cut
 329 sub new {
 330     my ($self, $sock, $ev) = @_;
 331     $self = fields::new($self) unless ref $self;
 332
 333     $self->{sock} = $sock;
 334     my $fd = fileno($sock);
 335
 336     _InitPoller();
 337
 338     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 339         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 340             $ev &= ~EPOLLEXCLUSIVE;
 341             goto retry;
 342         }
 343         die "couldn't add epoll watch for $fd: $!\n";
 344     }
 345     confess("DescriptorMap{$fd} defined ($DescriptorMap{$fd})")
 346         if defined($DescriptorMap{$fd});
 347
 348     $DescriptorMap{$fd} = $self;
 349 }
 350
 351
 352 #####################################################################
 353 ### I N S T A N C E   M E T H O D S
 354 #####################################################################
 355
 356 sub requeue ($) { push @$nextq, $_[0] } # autovivifies
 357
 358 =head2 C<< $obj->close >>
 359
 360 Close the socket.
 361
 362 =cut
 363 sub close {
 364     my ($self) = @_;
 365     my $sock = delete $self->{sock} or return;
 366
 367     # we need to flush our write buffer, as there may
 368     # be self-referential closures (sub { $client->close })
 369     # preventing the object from being destroyed
 370     delete $self->{wbuf};
 371
 372     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 373     # notifications about it
 374     my $fd = fileno($sock);
 375     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 376         confess("EPOLL_CTL_DEL: $!");
 377
 378     # we explicitly don't delete from DescriptorMap here until we
 379     # actually close the socket, as we might be in the middle of
 380     # processing an epoll_wait/etc that returned hundreds of fds, one
 381     # of which is not yet processed and is what we're closing.  if we
 382     # keep it in DescriptorMap, then the event harnesses can just
 383     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 384     # un-accounted for fd, then it (understandably) freak out a bit
 385     # and emit warnings, thinking their state got off.
 386
 387     # defer closing the actual socket until the event loop is done
 388     # processing this round of events.  (otherwise we might reuse fds)
 389     push @$ToClose, $sock; # autovivifies $ToClose
 390
 391     return 0;
 392 }
 393
 394 # portable, non-thread-safe sendfile emulation (no pread, yet)
 395 sub psendfile ($$$) {
 396     my ($sock, $fh, $off) = @_;
 397
 398     seek($fh, $$off, SEEK_SET) or return;
 399     defined(my $to_write = read($fh, my $buf, 16384)) or return;
 400     my $written = 0;
 401     while ($to_write > 0) {
 402         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 403             $written += $w;
 404             $to_write -= $w;
 405         } else {
 406             return if $written == 0;
 407             last;
 408         }
 409     }
 410     $$off += $written;
 411     $written;
 412 }
 413
 414 sub epbit ($$) { # (sock, default)
 415     ref($_[0]) eq 'IO::Socket::SSL' ? PublicInbox::TLS::epollbit() : $_[1];
 416 }
 417
 418 # returns 1 if done, 0 if incomplete
 419 sub flush_write ($) {
 420     my ($self) = @_;
 421     my $wbuf = $self->{wbuf} or return 1;
 422     my $sock = $self->{sock};
 423
 424 next_buf:
 425     while (my $bref = $wbuf->[0]) {
 426         if (ref($bref) ne 'CODE') {
 427             my $off = delete($self->{wbuf_off}) // 0;
 428             while ($sock) {
 429                 my $w = psendfile($sock, $bref, \$off);
 430                 if (defined $w) {
 431                     if ($w == 0) {
 432                         shift @$wbuf;
 433                         goto next_buf;
 434                     }
 435                 } elsif ($! == EAGAIN) {
 436                     epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 437                     $self->{wbuf_off} = $off;
 438                     return 0;
 439                 } else {
 440                     return $self->close;
 441                 }
 442             }
 443         } else { #($ref eq 'CODE') {
 444             shift @$wbuf;
 445             my $before = scalar(@$wbuf);
 446             $bref->($self);
 447
 448             # bref may be enqueueing more CODE to call (see accept_tls_step)
 449             return 0 if (scalar(@$wbuf) > $before);
 450         }
 451     } # while @$wbuf
 452
 453     delete $self->{wbuf};
 454     1; # all done
 455 }
 456
 457 sub rbuf_idle ($$) {
 458     my ($self, $rbuf) = @_;
 459     if ($$rbuf eq '') { # who knows how long till we can read again
 460         delete $self->{rbuf};
 461     } else {
 462         $self->{rbuf} = $rbuf;
 463     }
 464 }
 465
 466 sub do_read ($$$;$) {
 467     my ($self, $rbuf, $len, $off) = @_;
 468     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 469     return ($r == 0 ? $self->close : $r) if defined $r;
 470     # common for clients to break connections without warning,
 471     # would be too noisy to log here:
 472     if ($! == EAGAIN) {
 473         epwait($sock, epbit($sock, EPOLLIN) | EPOLLONESHOT);
 474         rbuf_idle($self, $rbuf);
 475         0;
 476     } else {
 477         $self->close;
 478     }
 479 }
 480
 481 # drop the socket if we hit unrecoverable errors on our system which
 482 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 483 sub drop {
 484     my $self = shift;
 485     carp(@_);
 486     $self->close;
 487 }
 488
 489 # n.b.: use ->write/->read for this buffer to allow compatibility with
 490 # PerlIO::mmap or PerlIO::scalar if needed
 491 sub tmpio ($$$) {
 492     my ($self, $bref, $off) = @_;
 493     my $fh = tmpfile('wbuf', $self->{sock}, 1) or
 494         return drop($self, "tmpfile $!");
 495     $fh->autoflush(1);
 496     my $len = bytes::length($$bref) - $off;
 497     $fh->write($$bref, $len, $off) or return drop($self, "write ($len): $!");
 498     $fh
 499 }
 500
 501 =head2 C<< $obj->write( $data ) >>
 502
 503 Write the specified data to the underlying handle.  I<data> may be scalar,
 504 scalar ref, code ref (to run when there).
 505 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 506 it returns 1, caller should stop waiting for 'writable' events)
 507
 508 =cut
 509 sub write {
 510     my ($self, $data) = @_;
 511
 512     # nobody should be writing to closed sockets, but caller code can
 513     # do two writes within an event, have the first fail and
 514     # disconnect the other side (whose destructor then closes the
 515     # calling object, but it's still in a method), and then the
 516     # now-dead object does its second write.  that is this case.  we
 517     # just lie and say it worked.  it'll be dead soon and won't be
 518     # hurt by this lie.
 519     my $sock = $self->{sock} or return 1;
 520     my $ref = ref $data;
 521     my $bref = $ref ? $data : \$data;
 522     my $wbuf = $self->{wbuf};
 523     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 524         if ($ref eq 'CODE') {
 525             push @$wbuf, $bref;
 526         } else {
 527             my $last = $wbuf->[-1];
 528             if (ref($last) eq 'GLOB') { # append to tmp file buffer
 529                 $last->print($$bref) or return drop($self, "print: $!");
 530             } else {
 531                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 532                 push @$wbuf, $tmpio;
 533             }
 534         }
 535         return 0;
 536     } elsif ($ref eq 'CODE') {
 537         $bref->($self);
 538         return 1;
 539     } else {
 540         my $to_write = bytes::length($$bref);
 541         my $written = syswrite($sock, $$bref, $to_write);
 542
 543         if (defined $written) {
 544             return 1 if $written == $to_write;
 545             requeue($self); # runs: event_step -> flush_write
 546         } elsif ($! == EAGAIN) {
 547             epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 548             $written = 0;
 549         } else {
 550             return $self->close;
 551         }
 552
 553         # deal with EAGAIN or partial write:
 554         my $tmpio = tmpio($self, $bref, $written) or return 0;
 555
 556         # wbuf may be an empty array if we're being called inside
 557         # ->flush_write via CODE bref:
 558         push @{$self->{wbuf}}, $tmpio; # autovivifies
 559         return 0;
 560     }
 561 }
 562
 563 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 564
 565 sub msg_more ($$) {
 566     my $self = $_[0];
 567     my $sock = $self->{sock} or return 1;
 568     my $wbuf = $self->{wbuf};
 569
 570     if (MSG_MORE && (!defined($wbuf) || !scalar(@$wbuf)) &&
 571                 ref($sock) ne 'IO::Socket::SSL') {
 572         my $n = send($sock, $_[1], MSG_MORE);
 573         if (defined $n) {
 574             my $nlen = bytes::length($_[1]) - $n;
 575             return 1 if $nlen == 0; # all done!
 576             # queue up the unwritten substring:
 577             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 578             push @{$self->{wbuf}}, $tmpio; # autovivifies
 579             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 580             return 0;
 581         }
 582     }
 583
 584     # don't redispatch into NNTPdeflate::write
 585     PublicInbox::DS::write($self, \($_[1]));
 586 }
 587
 588 sub epwait ($$) {
 589     my ($sock, $ev) = @_;
 590     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 591         confess("EPOLL_CTL_MOD $!");
 592 }
 593
 594 # return true if complete, false if incomplete (or failure)
 595 sub accept_tls_step ($) {
 596     my ($self) = @_;
 597     my $sock = $self->{sock} or return;
 598     return 1 if $sock->accept_SSL;
 599     return $self->close if $! != EAGAIN;
 600     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 601     unshift(@{$self->{wbuf}}, \&accept_tls_step); # autovivifies
 602     0;
 603 }
 604
 605 # return true if complete, false if incomplete (or failure)
 606 sub shutdn_tls_step ($) {
 607     my ($self) = @_;
 608     my $sock = $self->{sock} or return;
 609     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 610     return $self->close if $! != EAGAIN;
 611     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 612     unshift(@{$self->{wbuf}}, \&shutdn_tls_step); # autovivifies
 613     0;
 614 }
 615
 616 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 617 # or fork w/o exec, so no inadvertant socket sharing
 618 sub shutdn ($) {
 619     my ($self) = @_;
 620     my $sock = $self->{sock} or return;
 621     if (ref($sock) eq 'IO::Socket::SSL') {
 622         shutdn_tls_step($self);
 623     } else {
 624         $self->close;
 625     }
 626 }
 627
 628 # must be called with eval, PublicInbox::DS may not be loaded (see t/qspawn.t)
 629 sub dwaitpid ($$$) {
 630         die "Not in EventLoop\n" unless $in_loop;
 631         push @$wait_pids, [ @_ ]; # [ $pid, $cb, $arg ]
 632
 633         # We could've just missed our SIGCHLD, cover it, here:
 634         requeue(\&reap_pids);
 635 }
 636
 637 sub _run_later () {
 638         my $run = $later_queue or return;
 639         $later_timer = $later_queue = undef;
 640         $_->() for @$run;
 641 }
 642
 643 sub later ($) {
 644         push @$later_queue, $_[0]; # autovivifies @$later_queue
 645         $later_timer //= add_timer(60, \&_run_later);
 646 }
 647
 648 sub expire_old () {
 649         my $now = now();
 650         my $exp = $EXPTIME;
 651         my $old = $now - $exp;
 652         my %new;
 653         while (my ($fd, $idle_at) = each %$EXPMAP) {
 654                 if ($idle_at < $old) {
 655                         my $ds_obj = $DescriptorMap{$fd};
 656                         $new{$fd} = $idle_at if !$ds_obj->shutdn;
 657                 } else {
 658                         $new{$fd} = $idle_at;
 659                 }
 660         }
 661         $EXPMAP = \%new;
 662         $exp_timer = scalar(keys %new) ? later(\&expire_old) : undef;
 663 }
 664
 665 sub update_idle_time {
 666         my ($self) = @_;
 667         my $sock = $self->{sock} or return;
 668         $EXPMAP->{fileno($sock)} = now();
 669         $exp_timer //= later(\&expire_old);
 670 }
 671
 672 sub not_idle_long {
 673         my ($self, $now) = @_;
 674         my $sock = $self->{sock} or return;
 675         my $idle_at = $EXPMAP->{fileno($sock)} or return;
 676         ($idle_at + $EXPTIME) > $now;
 677 }
 678
 679 1;
 680
 681 =head1 AUTHORS (Danga::Socket)
 682
 683 Brad Fitzpatrick <brad@danga.com> - author
 684
 685 Michael Granger <ged@danga.com> - docs, testing
 686
 687 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 688
 689 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits