lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the (for now) unmaintained Danga::Socket 1.61.
   7 # Unused features will be removed, and updates will be made to take
   8 # advantage of newer kernels.
   9 #
  10 # API changes to diverge from Danga::Socket will happen to better
  11 # accomodate new features and improve scalability.  Do not expect
  12 # this to be a stable API like Danga::Socket.
  13 # Bugs encountered (and likely fixed) are reported to
  14 # bug-Danga-Socket@rt.cpan.org and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 package PublicInbox::DS;
  17 use strict;
  18 use bytes;
  19 use POSIX qw(WNOHANG);
  20 use IO::Handle qw();
  21 use Fcntl qw(SEEK_SET :DEFAULT);
  22 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  23 use parent qw(Exporter);
  24 our @EXPORT_OK = qw(now msg_more);
  25 use warnings;
  26 use 5.010_001;
  27 use Scalar::Util qw(blessed);
  28
  29 use PublicInbox::Syscall qw(:epoll);
  30 use PublicInbox::Tmpfile;
  31
  32 use fields ('sock',              # underlying socket
  33             'rbuf',              # scalarref, usually undef
  34             'wbuf',              # arrayref of coderefs or GLOB refs
  35             'wbuf_off',  # offset into first element of wbuf to start writing at
  36             );
  37
  38 use Errno  qw(EAGAIN EINVAL);
  39 use Carp   qw(croak confess carp);
  40 require File::Spec;
  41
  42 my $nextq; # queue for next_tick
  43 my $WaitPids; # list of [ pid, callback, callback_arg ]
  44 my $later_queue; # callbacks
  45 my ($later_timer, $reap_timer);
  46 our (
  47      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  48      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  49      $_io,                       # IO::Handle for Epoll
  50      @ToClose,                   # sockets to close when event loop is done
  51
  52      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  53
  54      $LoopTimeout,               # timeout of event loop in milliseconds
  55      $DoneInit,                  # if we've done the one-time module init yet
  56      @Timers,                    # timers
  57      $in_loop,
  58      );
  59
  60 Reset();
  61
  62 #####################################################################
  63 ### C L A S S   M E T H O D S
  64 #####################################################################
  65
  66 =head2 C<< CLASS->Reset() >>
  67
  68 Reset all state
  69
  70 =cut
  71 sub Reset {
  72     %DescriptorMap = ();
  73     $nextq = [];
  74     $WaitPids = [];
  75     $later_queue = [];
  76     $reap_timer = $later_timer = undef;
  77     @ToClose = ();
  78     $LoopTimeout = -1;  # no timeout by default
  79     @Timers = ();
  80
  81     $PostLoopCallback = undef;
  82     $DoneInit = 0;
  83
  84     $_io = undef; # closes real $Epoll FD
  85     $Epoll = undef; # may call DSKQXS::DESTROY
  86
  87     *EventLoop = *FirstTimeEventLoop;
  88 }
  89
  90 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  91
  92 Set the loop timeout for the event loop to some value in milliseconds.
  93
  94 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  95 immediately.
  96
  97 =cut
  98 sub SetLoopTimeout {
  99     return $LoopTimeout = $_[1] + 0;
 100 }
 101
 102 =head2 C<< CLASS->AddTimer( $seconds, $coderef ) >>
 103
 104 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 105 are not guaranteed to fire at the exact time you ask for.
 106
 107 Returns a timer object which you can call C<< $timer->cancel >> on if you need to.
 108
 109 =cut
 110 sub AddTimer {
 111     my ($class, $secs, $coderef) = @_;
 112
 113     my $fire_time = now() + $secs;
 114
 115     my $timer = bless [$fire_time, $coderef], "PublicInbox::DS::Timer";
 116
 117     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 118         push @Timers, $timer;
 119         return $timer;
 120     }
 121
 122     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 123     # but it was compared against calendar queues, heaps, naive push/sort,
 124     # and a bunch of other versions, and found to be fastest with a large
 125     # variety of datasets.)
 126     for (my $i = 0; $i < @Timers; $i++) {
 127         if ($Timers[$i][0] > $fire_time) {
 128             splice(@Timers, $i, 0, $timer);
 129             return $timer;
 130         }
 131     }
 132
 133     die "Shouldn't get here.";
 134 }
 135
 136 # keeping this around in case we support other FD types for now,
 137 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 138 sub set_cloexec ($) {
 139     my ($fd) = @_;
 140
 141     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 142     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 143     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 144 }
 145
 146 sub _InitPoller
 147 {
 148     return if $DoneInit;
 149     $DoneInit = 1;
 150
 151     if (PublicInbox::Syscall::epoll_defined())  {
 152         $Epoll = epoll_create();
 153         set_cloexec($Epoll) if (defined($Epoll) && $Epoll >= 0);
 154     } else {
 155         my $cls;
 156         for (qw(DSKQXS DSPoll)) {
 157             $cls = "PublicInbox::$_";
 158             last if eval "require $cls";
 159         }
 160         $cls->import(qw(epoll_ctl epoll_wait));
 161         $Epoll = $cls->new;
 162     }
 163     *EventLoop = *EpollEventLoop;
 164 }
 165
 166 =head2 C<< CLASS->EventLoop() >>
 167
 168 Start processing IO events. In most daemon programs this never exits. See
 169 C<PostLoopCallback> below for how to exit the loop.
 170
 171 =cut
 172 sub FirstTimeEventLoop {
 173     my $class = shift;
 174
 175     _InitPoller();
 176
 177     EventLoop($class);
 178 }
 179
 180 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 181
 182 sub next_tick () {
 183     my $q = $nextq;
 184     $nextq = [];
 185     for (@$q) {
 186         # we avoid "ref" on blessed refs to workaround a Perl 5.16.3 leak:
 187         # https://rt.perl.org/Public/Bug/Display.html?id=114340
 188         if (blessed($_)) {
 189             $_->event_step;
 190         } else {
 191             $_->();
 192         }
 193     }
 194 }
 195
 196 # runs timers and returns milliseconds for next one, or next event loop
 197 sub RunTimers {
 198     next_tick();
 199
 200     return ((@$nextq || @ToClose) ? 0 : $LoopTimeout) unless @Timers;
 201
 202     my $now = now();
 203
 204     # Run expired timers
 205     while (@Timers && $Timers[0][0] <= $now) {
 206         my $to_run = shift(@Timers);
 207         $to_run->[1]->($now) if $to_run->[1];
 208     }
 209
 210     # timers may enqueue into nextq:
 211     return 0 if (@$nextq || @ToClose);
 212
 213     return $LoopTimeout unless @Timers;
 214
 215     # convert time to an even number of milliseconds, adding 1
 216     # extra, otherwise floating point fun can occur and we'll
 217     # call RunTimers like 20-30 times, each returning a timeout
 218     # of 0.0000212 seconds
 219     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 220
 221     # -1 is an infinite timeout, so prefer a real timeout
 222     return $timeout     if $LoopTimeout == -1;
 223
 224     # otherwise pick the lower of our regular timeout and time until
 225     # the next timer
 226     return $LoopTimeout if $LoopTimeout < $timeout;
 227     return $timeout;
 228 }
 229
 230 # We can't use waitpid(-1) safely here since it can hit ``, system(),
 231 # and other things.  So we scan the $WaitPids list, which is hopefully
 232 # not too big.
 233 sub reap_pids {
 234     my $tmp = $WaitPids;
 235     $WaitPids = [];
 236     $reap_timer = undef;
 237     foreach my $ary (@$tmp) {
 238         my ($pid, $cb, $arg) = @$ary;
 239         my $ret = waitpid($pid, WNOHANG);
 240         if ($ret == 0) {
 241             push @$WaitPids, $ary;
 242         } elsif ($cb) {
 243             eval { $cb->($arg, $pid) };
 244         }
 245     }
 246     if (@$WaitPids) {
 247         # we may not be donea, and we may miss our
 248         $reap_timer = AddTimer(undef, 1, \&reap_pids);
 249     }
 250 }
 251
 252 # reentrant SIGCHLD handler (since reap_pids is not reentrant)
 253 sub enqueue_reap ($) { push @$nextq, \&reap_pids };
 254
 255 sub running () { ($SIG{CHLD} // '') eq \&enqueue_reap }
 256
 257 sub EpollEventLoop {
 258     local $in_loop = 1;
 259     do {
 260         my @events;
 261         my $i;
 262         my $timeout = RunTimers();
 263
 264         # get up to 1000 events
 265         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 266         for ($i=0; $i<$evcount; $i++) {
 267             # it's possible epoll_wait returned many events, including some at the end
 268             # that ones in the front triggered unregister-interest actions.  if we
 269             # can't find the %sock entry, it's because we're no longer interested
 270             # in that event.
 271             $DescriptorMap{$events[$i]->[0]}->event_step;
 272         }
 273     } while (PostEventLoop());
 274     _run_later();
 275 }
 276
 277 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 278
 279 Sets post loop callback function.  Pass a subref and it will be
 280 called every time the event loop finishes.
 281
 282 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 283 and it will exit.
 284
 285 The callback function will be passed two parameters: \%DescriptorMap
 286
 287 =cut
 288 sub SetPostLoopCallback {
 289     my ($class, $ref) = @_;
 290
 291     # global callback
 292     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 293 }
 294
 295 # Internal function: run the post-event callback, send read events
 296 # for pushed-back data, and close pending connections.  returns 1
 297 # if event loop should continue, or 0 to shut it all down.
 298 sub PostEventLoop {
 299     # now we can close sockets that wanted to close during our event processing.
 300     # (we didn't want to close them during the loop, as we didn't want fd numbers
 301     #  being reused and confused during the event loop)
 302     delete($DescriptorMap{fileno($_)}) for @ToClose;
 303     @ToClose = (); # let refcounting drop everything all at once
 304
 305     # by default we keep running, unless a postloop callback (either per-object
 306     # or global) cancels it
 307     my $keep_running = 1;
 308
 309     # now we're at the very end, call callback if defined
 310     if (defined $PostLoopCallback) {
 311         $keep_running &&= $PostLoopCallback->(\%DescriptorMap);
 312     }
 313
 314     return $keep_running;
 315 }
 316
 317 #####################################################################
 318 ### PublicInbox::DS-the-object code
 319 #####################################################################
 320
 321 =head2 OBJECT METHODS
 322
 323 =head2 C<< CLASS->new( $socket ) >>
 324
 325 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 326 react to events on it during the C<EventLoop>.
 327
 328 This is normally (always?) called from your subclass via:
 329
 330   $class->SUPER::new($socket);
 331
 332 =cut
 333 sub new {
 334     my ($self, $sock, $ev) = @_;
 335     $self = fields::new($self) unless ref $self;
 336
 337     $self->{sock} = $sock;
 338     my $fd = fileno($sock);
 339
 340     Carp::cluck("undef sock and/or fd in PublicInbox::DS->new.  sock=" . ($sock || "") . ", fd=" . ($fd || ""))
 341         unless $sock && $fd;
 342
 343     _InitPoller();
 344
 345     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 346         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 347             $ev &= ~EPOLLEXCLUSIVE;
 348             goto retry;
 349         }
 350         die "couldn't add epoll watch for $fd: $!\n";
 351     }
 352     Carp::cluck("PublicInbox::DS::new blowing away existing descriptor map for fd=$fd ($DescriptorMap{$fd})")
 353         if $DescriptorMap{$fd};
 354
 355     $DescriptorMap{$fd} = $self;
 356     return $self;
 357 }
 358
 359
 360 #####################################################################
 361 ### I N S T A N C E   M E T H O D S
 362 #####################################################################
 363
 364 sub requeue ($) { push @$nextq, $_[0] }
 365
 366 =head2 C<< $obj->close >>
 367
 368 Close the socket.
 369
 370 =cut
 371 sub close {
 372     my ($self) = @_;
 373     my $sock = delete $self->{sock} or return;
 374
 375     # we need to flush our write buffer, as there may
 376     # be self-referential closures (sub { $client->close })
 377     # preventing the object from being destroyed
 378     delete $self->{wbuf};
 379
 380     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 381     # notifications about it
 382     my $fd = fileno($sock);
 383     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 384         confess("EPOLL_CTL_DEL: $!");
 385
 386     # we explicitly don't delete from DescriptorMap here until we
 387     # actually close the socket, as we might be in the middle of
 388     # processing an epoll_wait/etc that returned hundreds of fds, one
 389     # of which is not yet processed and is what we're closing.  if we
 390     # keep it in DescriptorMap, then the event harnesses can just
 391     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 392     # un-accounted for fd, then it (understandably) freak out a bit
 393     # and emit warnings, thinking their state got off.
 394
 395     # defer closing the actual socket until the event loop is done
 396     # processing this round of events.  (otherwise we might reuse fds)
 397     push @ToClose, $sock;
 398
 399     return 0;
 400 }
 401
 402 # portable, non-thread-safe sendfile emulation (no pread, yet)
 403 sub psendfile ($$$) {
 404     my ($sock, $fh, $off) = @_;
 405
 406     seek($fh, $$off, SEEK_SET) or return;
 407     defined(my $to_write = read($fh, my $buf, 16384)) or return;
 408     my $written = 0;
 409     while ($to_write > 0) {
 410         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 411             $written += $w;
 412             $to_write -= $w;
 413         } else {
 414             return if $written == 0;
 415             last;
 416         }
 417     }
 418     $$off += $written;
 419     $written;
 420 }
 421
 422 sub epbit ($$) { # (sock, default)
 423     ref($_[0]) eq 'IO::Socket::SSL' ? PublicInbox::TLS::epollbit() : $_[1];
 424 }
 425
 426 # returns 1 if done, 0 if incomplete
 427 sub flush_write ($) {
 428     my ($self) = @_;
 429     my $wbuf = $self->{wbuf} or return 1;
 430     my $sock = $self->{sock};
 431
 432 next_buf:
 433     while (my $bref = $wbuf->[0]) {
 434         if (ref($bref) ne 'CODE') {
 435             my $off = delete($self->{wbuf_off}) // 0;
 436             while ($sock) {
 437                 my $w = psendfile($sock, $bref, \$off);
 438                 if (defined $w) {
 439                     if ($w == 0) {
 440                         shift @$wbuf;
 441                         goto next_buf;
 442                     }
 443                 } elsif ($! == EAGAIN) {
 444                     epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 445                     $self->{wbuf_off} = $off;
 446                     return 0;
 447                 } else {
 448                     return $self->close;
 449                 }
 450             }
 451         } else { #($ref eq 'CODE') {
 452             shift @$wbuf;
 453             my $before = scalar(@$wbuf);
 454             $bref->($self);
 455
 456             # bref may be enqueueing more CODE to call (see accept_tls_step)
 457             return 0 if (scalar(@$wbuf) > $before);
 458         }
 459     } # while @$wbuf
 460
 461     delete $self->{wbuf};
 462     1; # all done
 463 }
 464
 465 sub rbuf_idle ($$) {
 466     my ($self, $rbuf) = @_;
 467     if ($$rbuf eq '') { # who knows how long till we can read again
 468         delete $self->{rbuf};
 469     } else {
 470         $self->{rbuf} = $rbuf;
 471     }
 472 }
 473
 474 sub do_read ($$$;$) {
 475     my ($self, $rbuf, $len, $off) = @_;
 476     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 477     return ($r == 0 ? $self->close : $r) if defined $r;
 478     # common for clients to break connections without warning,
 479     # would be too noisy to log here:
 480     if ($! == EAGAIN) {
 481         epwait($sock, epbit($sock, EPOLLIN) | EPOLLONESHOT);
 482         rbuf_idle($self, $rbuf);
 483         0;
 484     } else {
 485         $self->close;
 486     }
 487 }
 488
 489 # drop the socket if we hit unrecoverable errors on our system which
 490 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 491 sub drop {
 492     my $self = shift;
 493     carp(@_);
 494     $self->close;
 495 }
 496
 497 # n.b.: use ->write/->read for this buffer to allow compatibility with
 498 # PerlIO::mmap or PerlIO::scalar if needed
 499 sub tmpio ($$$) {
 500     my ($self, $bref, $off) = @_;
 501     my $fh = tmpfile('wbuf', $self->{sock}, 1) or
 502         return drop($self, "tmpfile $!");
 503     $fh->autoflush(1);
 504     my $len = bytes::length($$bref) - $off;
 505     $fh->write($$bref, $len, $off) or return drop($self, "write ($len): $!");
 506     $fh
 507 }
 508
 509 =head2 C<< $obj->write( $data ) >>
 510
 511 Write the specified data to the underlying handle.  I<data> may be scalar,
 512 scalar ref, code ref (to run when there).
 513 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 514 it returns 1, caller should stop waiting for 'writable' events)
 515
 516 =cut
 517 sub write {
 518     my ($self, $data) = @_;
 519
 520     # nobody should be writing to closed sockets, but caller code can
 521     # do two writes within an event, have the first fail and
 522     # disconnect the other side (whose destructor then closes the
 523     # calling object, but it's still in a method), and then the
 524     # now-dead object does its second write.  that is this case.  we
 525     # just lie and say it worked.  it'll be dead soon and won't be
 526     # hurt by this lie.
 527     my $sock = $self->{sock} or return 1;
 528     my $ref = ref $data;
 529     my $bref = $ref ? $data : \$data;
 530     my $wbuf = $self->{wbuf};
 531     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 532         if ($ref eq 'CODE') {
 533             push @$wbuf, $bref;
 534         } else {
 535             my $last = $wbuf->[-1];
 536             if (ref($last) eq 'GLOB') { # append to tmp file buffer
 537                 $last->print($$bref) or return drop($self, "print: $!");
 538             } else {
 539                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 540                 push @$wbuf, $tmpio;
 541             }
 542         }
 543         return 0;
 544     } elsif ($ref eq 'CODE') {
 545         $bref->($self);
 546         return 1;
 547     } else {
 548         my $to_write = bytes::length($$bref);
 549         my $written = syswrite($sock, $$bref, $to_write);
 550
 551         if (defined $written) {
 552             return 1 if $written == $to_write;
 553             requeue($self); # runs: event_step -> flush_write
 554         } elsif ($! == EAGAIN) {
 555             epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 556             $written = 0;
 557         } else {
 558             return $self->close;
 559         }
 560
 561         # deal with EAGAIN or partial write:
 562         my $tmpio = tmpio($self, $bref, $written) or return 0;
 563
 564         # wbuf may be an empty array if we're being called inside
 565         # ->flush_write via CODE bref:
 566         push @{$self->{wbuf} ||= []}, $tmpio;
 567         return 0;
 568     }
 569 }
 570
 571 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 572
 573 sub msg_more ($$) {
 574     my $self = $_[0];
 575     my $sock = $self->{sock} or return 1;
 576
 577     if (MSG_MORE && !$self->{wbuf} && ref($sock) ne 'IO::Socket::SSL') {
 578         my $n = send($sock, $_[1], MSG_MORE);
 579         if (defined $n) {
 580             my $nlen = bytes::length($_[1]) - $n;
 581             return 1 if $nlen == 0; # all done!
 582             # queue up the unwritten substring:
 583             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 584             $self->{wbuf} = [ $tmpio ];
 585             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 586             return 0;
 587         }
 588     }
 589
 590     # don't redispatch into NNTPdeflate::write
 591     PublicInbox::DS::write($self, \($_[1]));
 592 }
 593
 594 sub epwait ($$) {
 595     my ($sock, $ev) = @_;
 596     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 597         confess("EPOLL_CTL_MOD $!");
 598 }
 599
 600 # return true if complete, false if incomplete (or failure)
 601 sub accept_tls_step ($) {
 602     my ($self) = @_;
 603     my $sock = $self->{sock} or return;
 604     return 1 if $sock->accept_SSL;
 605     return $self->close if $! != EAGAIN;
 606     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 607     unshift @{$self->{wbuf} ||= []}, \&accept_tls_step;
 608     0;
 609 }
 610
 611 # return true if complete, false if incomplete (or failure)
 612 sub shutdn_tls_step ($) {
 613     my ($self) = @_;
 614     my $sock = $self->{sock} or return;
 615     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 616     return $self->close if $! != EAGAIN;
 617     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 618     unshift @{$self->{wbuf} ||= []}, \&shutdn_tls_step;
 619     0;
 620 }
 621
 622 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 623 # or fork w/o exec, so no inadvertant socket sharing
 624 sub shutdn ($) {
 625     my ($self) = @_;
 626     my $sock = $self->{sock} or return;
 627     if (ref($sock) eq 'IO::Socket::SSL') {
 628         shutdn_tls_step($self);
 629     } else {
 630         $self->close;
 631     }
 632 }
 633
 634 # must be called with eval, PublicInbox::DS may not be loaded (see t/qspawn.t)
 635 sub dwaitpid ($$$) {
 636     my ($pid, $cb, $arg) = @_;
 637     if ($in_loop) {
 638         push @$WaitPids, [ $pid, $cb, $arg ];
 639
 640         # We could've just missed our SIGCHLD, cover it, here:
 641         requeue(\&reap_pids);
 642     } else {
 643         die "Not in EventLoop\n";
 644     }
 645 }
 646
 647 sub _run_later () {
 648     my $run = $later_queue;
 649     $later_timer = undef;
 650     $later_queue = [];
 651     $_->() for @$run;
 652 }
 653
 654 sub later ($) {
 655     my ($cb) = @_;
 656     push @$later_queue, $cb;
 657     $later_timer //= AddTimer(undef, 60, \&_run_later);
 658 }
 659
 660 package PublicInbox::DS::Timer;
 661 # [$abs_float_firetime, $coderef];
 662 sub cancel {
 663     $_[0][1] = undef;
 664 }
 665
 666 1;
 667
 668 =head1 AUTHORS (Danga::Socket)
 669
 670 Brad Fitzpatrick <brad@danga.com> - author
 671
 672 Michael Granger <ged@danga.com> - docs, testing
 673
 674 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 675
 676 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits