lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the unmaintained Danga::Socket (1.61) with
   7 # significant changes.  See Documentation/technical/ds.txt in our
   8 # source for details.
   9 #
  10 # Do not expect this to be a stable API like Danga::Socket,
  11 # but it will evolve to suite our needs and to take advantage of
  12 # newer Linux and *BSD features.
  13 # Bugs encountered were reported to bug-Danga-Socket@rt.cpan.org,
  14 # fixed in Danga::Socket 1.62 and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 #
  17 # fields:
  18 # sock: underlying socket
  19 # rbuf: scalarref, usually undef
  20 # wbuf: arrayref of coderefs or tmpio (autovivified))
  21 #        (tmpio = [ GLOB, offset, [ length ] ])
  22 package PublicInbox::DS;
  23 use strict;
  24 use bytes;
  25 use POSIX qw(WNOHANG);
  26 use IO::Handle qw();
  27 use Fcntl qw(SEEK_SET :DEFAULT O_APPEND);
  28 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  29 use parent qw(Exporter);
  30 our @EXPORT_OK = qw(now msg_more);
  31 use 5.010_001;
  32 use Scalar::Util qw(blessed);
  33 use PublicInbox::Syscall qw(:epoll);
  34 use PublicInbox::Tmpfile;
  35 use Errno qw(EAGAIN EINVAL);
  36 use Carp qw(confess carp);
  37
  38 my $nextq; # queue for next_tick
  39 my $wait_pids; # list of [ pid, callback, callback_arg ]
  40 my $later_queue; # list of callbacks to run at some later interval
  41 my $EXPMAP; # fd -> idle_time
  42 our $EXPTIME = 180; # 3 minutes
  43 my ($later_timer, $reap_armed, $exp_timer);
  44 my $ToClose; # sockets to close when event loop is done
  45 our (
  46      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  47      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  48      $_io,                       # IO::Handle for Epoll
  49
  50      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  51
  52      $LoopTimeout,               # timeout of event loop in milliseconds
  53      $DoneInit,                  # if we've done the one-time module init yet
  54      @Timers,                    # timers
  55      $in_loop,
  56      );
  57
  58 Reset();
  59
  60 #####################################################################
  61 ### C L A S S   M E T H O D S
  62 #####################################################################
  63
  64 =head2 C<< CLASS->Reset() >>
  65
  66 Reset all state
  67
  68 =cut
  69 sub Reset {
  70     %DescriptorMap = ();
  71     $in_loop = $wait_pids = $later_queue = $reap_armed = undef;
  72     $EXPMAP = {};
  73     $nextq = $ToClose = $later_timer = $exp_timer = undef;
  74     $LoopTimeout = -1;  # no timeout by default
  75     @Timers = ();
  76
  77     $PostLoopCallback = undef;
  78     $DoneInit = 0;
  79
  80     $_io = undef; # closes real $Epoll FD
  81     $Epoll = undef; # may call DSKQXS::DESTROY
  82
  83     *EventLoop = *FirstTimeEventLoop;
  84 }
  85
  86 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  87
  88 Set the loop timeout for the event loop to some value in milliseconds.
  89
  90 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  91 immediately.
  92
  93 =cut
  94 sub SetLoopTimeout {
  95     return $LoopTimeout = $_[1] + 0;
  96 }
  97
  98 =head2 C<< PublicInbox::DS::add_timer( $seconds, $coderef, $arg) >>
  99
 100 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 101 are not guaranteed to fire at the exact time you ask for.
 102
 103 =cut
 104 sub add_timer ($$;$) {
 105     my ($secs, $coderef, $arg) = @_;
 106
 107     my $fire_time = now() + $secs;
 108
 109     my $timer = [$fire_time, $coderef, $arg];
 110
 111     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 112         push @Timers, $timer;
 113         return $timer;
 114     }
 115
 116     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 117     # but it was compared against calendar queues, heaps, naive push/sort,
 118     # and a bunch of other versions, and found to be fastest with a large
 119     # variety of datasets.)
 120     for (my $i = 0; $i < @Timers; $i++) {
 121         if ($Timers[$i][0] > $fire_time) {
 122             splice(@Timers, $i, 0, $timer);
 123             return $timer;
 124         }
 125     }
 126
 127     die "Shouldn't get here.";
 128 }
 129
 130 # keeping this around in case we support other FD types for now,
 131 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 132 sub set_cloexec ($) {
 133     my ($fd) = @_;
 134
 135     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 136     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 137     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 138 }
 139
 140 sub _InitPoller
 141 {
 142     return if $DoneInit;
 143     $DoneInit = 1;
 144
 145     if (PublicInbox::Syscall::epoll_defined())  {
 146         $Epoll = epoll_create();
 147         set_cloexec($Epoll) if (defined($Epoll) && $Epoll >= 0);
 148     } else {
 149         my $cls;
 150         for (qw(DSKQXS DSPoll)) {
 151             $cls = "PublicInbox::$_";
 152             last if eval "require $cls";
 153         }
 154         $cls->import(qw(epoll_ctl epoll_wait));
 155         $Epoll = $cls->new;
 156     }
 157     *EventLoop = *EpollEventLoop;
 158 }
 159
 160 =head2 C<< CLASS->EventLoop() >>
 161
 162 Start processing IO events. In most daemon programs this never exits. See
 163 C<PostLoopCallback> below for how to exit the loop.
 164
 165 =cut
 166 sub FirstTimeEventLoop {
 167     my $class = shift;
 168
 169     _InitPoller();
 170
 171     EventLoop($class);
 172 }
 173
 174 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 175
 176 sub next_tick () {
 177     my $q = $nextq or return;
 178     $nextq = undef;
 179     for (@$q) {
 180         # we avoid "ref" on blessed refs to workaround a Perl 5.16.3 leak:
 181         # https://rt.perl.org/Public/Bug/Display.html?id=114340
 182         if (blessed($_)) {
 183             $_->event_step;
 184         } else {
 185             $_->();
 186         }
 187     }
 188 }
 189
 190 # runs timers and returns milliseconds for next one, or next event loop
 191 sub RunTimers {
 192     next_tick();
 193
 194     return (($nextq || $ToClose) ? 0 : $LoopTimeout) unless @Timers;
 195
 196     my $now = now();
 197
 198     # Run expired timers
 199     while (@Timers && $Timers[0][0] <= $now) {
 200         my $to_run = shift(@Timers);
 201         $to_run->[1]->($to_run->[2]);
 202     }
 203
 204     # timers may enqueue into nextq:
 205     return 0 if ($nextq || $ToClose);
 206
 207     return $LoopTimeout unless @Timers;
 208
 209     # convert time to an even number of milliseconds, adding 1
 210     # extra, otherwise floating point fun can occur and we'll
 211     # call RunTimers like 20-30 times, each returning a timeout
 212     # of 0.0000212 seconds
 213     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 214
 215     # -1 is an infinite timeout, so prefer a real timeout
 216     return $timeout     if $LoopTimeout == -1;
 217
 218     # otherwise pick the lower of our regular timeout and time until
 219     # the next timer
 220     return $LoopTimeout if $LoopTimeout < $timeout;
 221     return $timeout;
 222 }
 223
 224 # We can't use waitpid(-1) safely here since it can hit ``, system(),
 225 # and other things.  So we scan the $wait_pids list, which is hopefully
 226 # not too big.  We keep $wait_pids small by not calling dwaitpid()
 227 # until we've hit EOF when reading the stdout of the child.
 228
 229 sub reap_pids {
 230         $reap_armed = undef;
 231         my $tmp = $wait_pids or return;
 232         $wait_pids = undef;
 233         foreach my $ary (@$tmp) {
 234                 my ($pid, $cb, $arg) = @$ary;
 235                 my $ret = waitpid($pid, WNOHANG);
 236                 if ($ret == 0) {
 237                         push @$wait_pids, $ary; # autovivifies @$wait_pids
 238                 } elsif ($cb) {
 239                         eval { $cb->($arg, $pid) };
 240                 }
 241         }
 242         # we may not be done, yet, and could've missed/masked a SIGCHLD:
 243         $reap_armed //= requeue(\&reap_pids) if $wait_pids;
 244 }
 245
 246 # reentrant SIGCHLD handler (since reap_pids is not reentrant)
 247 sub enqueue_reap { $reap_armed //= requeue(\&reap_pids) }
 248
 249 sub in_loop () { $in_loop }
 250
 251 # Internal function: run the post-event callback, send read events
 252 # for pushed-back data, and close pending connections.  returns 1
 253 # if event loop should continue, or 0 to shut it all down.
 254 sub PostEventLoop () {
 255         # now we can close sockets that wanted to close during our event
 256         # processing.  (we didn't want to close them during the loop, as we
 257         # didn't want fd numbers being reused and confused during the event
 258         # loop)
 259         if (my $close_now = $ToClose) {
 260                 $ToClose = undef; # will be autovivified on push
 261                 @$close_now = map { fileno($_) } @$close_now;
 262
 263                 # order matters, destroy expiry times, first:
 264                 delete @$EXPMAP{@$close_now};
 265
 266                 # ->DESTROY methods may populate ToClose
 267                 delete @DescriptorMap{@$close_now};
 268         }
 269
 270         # by default we keep running, unless a postloop callback cancels it
 271         $PostLoopCallback ? $PostLoopCallback->(\%DescriptorMap) : 1;
 272 }
 273
 274 sub EpollEventLoop {
 275     local $in_loop = 1;
 276     do {
 277         my @events;
 278         my $i;
 279         my $timeout = RunTimers();
 280
 281         # get up to 1000 events
 282         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 283         for ($i=0; $i<$evcount; $i++) {
 284             # it's possible epoll_wait returned many events, including some at the end
 285             # that ones in the front triggered unregister-interest actions.  if we
 286             # can't find the %sock entry, it's because we're no longer interested
 287             # in that event.
 288             $DescriptorMap{$events[$i]->[0]}->event_step;
 289         }
 290     } while (PostEventLoop());
 291     _run_later();
 292 }
 293
 294 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 295
 296 Sets post loop callback function.  Pass a subref and it will be
 297 called every time the event loop finishes.
 298
 299 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 300 and it will exit.
 301
 302 The callback function will be passed two parameters: \%DescriptorMap
 303
 304 =cut
 305 sub SetPostLoopCallback {
 306     my ($class, $ref) = @_;
 307
 308     # global callback
 309     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 310 }
 311
 312 #####################################################################
 313 ### PublicInbox::DS-the-object code
 314 #####################################################################
 315
 316 =head2 OBJECT METHODS
 317
 318 =head2 C<< CLASS->new( $socket ) >>
 319
 320 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 321 react to events on it during the C<EventLoop>.
 322
 323 This is normally (always?) called from your subclass via:
 324
 325   $class->SUPER::new($socket);
 326
 327 =cut
 328 sub new {
 329     my ($self, $sock, $ev) = @_;
 330     $self->{sock} = $sock;
 331     my $fd = fileno($sock);
 332
 333     _InitPoller();
 334
 335     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 336         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 337             $ev &= ~EPOLLEXCLUSIVE;
 338             goto retry;
 339         }
 340         die "couldn't add epoll watch for $fd: $!\n";
 341     }
 342     confess("DescriptorMap{$fd} defined ($DescriptorMap{$fd})")
 343         if defined($DescriptorMap{$fd});
 344
 345     $DescriptorMap{$fd} = $self;
 346 }
 347
 348
 349 #####################################################################
 350 ### I N S T A N C E   M E T H O D S
 351 #####################################################################
 352
 353 sub requeue ($) { push @$nextq, $_[0] } # autovivifies
 354
 355 =head2 C<< $obj->close >>
 356
 357 Close the socket.
 358
 359 =cut
 360 sub close {
 361     my ($self) = @_;
 362     my $sock = delete $self->{sock} or return;
 363
 364     # we need to flush our write buffer, as there may
 365     # be self-referential closures (sub { $client->close })
 366     # preventing the object from being destroyed
 367     delete $self->{wbuf};
 368
 369     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 370     # notifications about it
 371     my $fd = fileno($sock);
 372     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 373         confess("EPOLL_CTL_DEL: $!");
 374
 375     # we explicitly don't delete from DescriptorMap here until we
 376     # actually close the socket, as we might be in the middle of
 377     # processing an epoll_wait/etc that returned hundreds of fds, one
 378     # of which is not yet processed and is what we're closing.  if we
 379     # keep it in DescriptorMap, then the event harnesses can just
 380     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 381     # un-accounted for fd, then it (understandably) freak out a bit
 382     # and emit warnings, thinking their state got off.
 383
 384     # defer closing the actual socket until the event loop is done
 385     # processing this round of events.  (otherwise we might reuse fds)
 386     push @$ToClose, $sock; # autovivifies $ToClose
 387
 388     return 0;
 389 }
 390
 391 # portable, non-thread-safe sendfile emulation (no pread, yet)
 392 sub send_tmpio ($$) {
 393     my ($sock, $tmpio) = @_;
 394
 395     sysseek($tmpio->[0], $tmpio->[1], SEEK_SET) or return;
 396     my $n = $tmpio->[2] // 65536;
 397     $n = 65536 if $n > 65536;
 398     defined(my $to_write = sysread($tmpio->[0], my $buf, $n)) or return;
 399     my $written = 0;
 400     while ($to_write > 0) {
 401         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 402             $written += $w;
 403             $to_write -= $w;
 404         } else {
 405             return if $written == 0;
 406             last;
 407         }
 408     }
 409     $tmpio->[1] += $written; # offset
 410     $tmpio->[2] -= $written if defined($tmpio->[2]); # length
 411     $written;
 412 }
 413
 414 sub epbit ($$) { # (sock, default)
 415         $_[0]->can('stop_SSL') ? PublicInbox::TLS::epollbit() : $_[1];
 416 }
 417
 418 # returns 1 if done, 0 if incomplete
 419 sub flush_write ($) {
 420     my ($self) = @_;
 421     my $sock = $self->{sock} or return;
 422     my $wbuf = $self->{wbuf} or return 1;
 423
 424 next_buf:
 425     while (my $bref = $wbuf->[0]) {
 426         if (ref($bref) ne 'CODE') {
 427             while ($sock) {
 428                 my $w = send_tmpio($sock, $bref); # bref is tmpio
 429                 if (defined $w) {
 430                     if ($w == 0) {
 431                         shift @$wbuf;
 432                         goto next_buf;
 433                     }
 434                 } elsif ($! == EAGAIN) {
 435                     epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 436                     return 0;
 437                 } else {
 438                     return $self->close;
 439                 }
 440             }
 441         } else { #(ref($bref) eq 'CODE') {
 442             shift @$wbuf;
 443             my $before = scalar(@$wbuf);
 444             $bref->($self);
 445
 446             # bref may be enqueueing more CODE to call (see accept_tls_step)
 447             return 0 if (scalar(@$wbuf) > $before);
 448         }
 449     } # while @$wbuf
 450
 451     delete $self->{wbuf};
 452     1; # all done
 453 }
 454
 455 sub rbuf_idle ($$) {
 456     my ($self, $rbuf) = @_;
 457     if ($$rbuf eq '') { # who knows how long till we can read again
 458         delete $self->{rbuf};
 459     } else {
 460         $self->{rbuf} = $rbuf;
 461     }
 462 }
 463
 464 sub do_read ($$$;$) {
 465     my ($self, $rbuf, $len, $off) = @_;
 466     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 467     return ($r == 0 ? $self->close : $r) if defined $r;
 468     # common for clients to break connections without warning,
 469     # would be too noisy to log here:
 470     if ($! == EAGAIN) {
 471         epwait($sock, epbit($sock, EPOLLIN) | EPOLLONESHOT);
 472         rbuf_idle($self, $rbuf);
 473         0;
 474     } else {
 475         $self->close;
 476     }
 477 }
 478
 479 # drop the socket if we hit unrecoverable errors on our system which
 480 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 481 sub drop {
 482     my $self = shift;
 483     carp(@_);
 484     $self->close;
 485 }
 486
 487 # n.b.: use ->write/->read for this buffer to allow compatibility with
 488 # PerlIO::mmap or PerlIO::scalar if needed
 489 sub tmpio ($$$) {
 490     my ($self, $bref, $off) = @_;
 491     my $fh = tmpfile('wbuf', $self->{sock}, O_APPEND) or
 492         return drop($self, "tmpfile $!");
 493     $fh->autoflush(1);
 494     my $len = bytes::length($$bref) - $off;
 495     $fh->write($$bref, $len, $off) or return drop($self, "write ($len): $!");
 496     [ $fh, 0 ] # [1] = offset, [2] = length, not set by us
 497 }
 498
 499 =head2 C<< $obj->write( $data ) >>
 500
 501 Write the specified data to the underlying handle.  I<data> may be scalar,
 502 scalar ref, code ref (to run when there).
 503 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 504 it returns 1, caller should stop waiting for 'writable' events)
 505
 506 =cut
 507 sub write {
 508     my ($self, $data) = @_;
 509
 510     # nobody should be writing to closed sockets, but caller code can
 511     # do two writes within an event, have the first fail and
 512     # disconnect the other side (whose destructor then closes the
 513     # calling object, but it's still in a method), and then the
 514     # now-dead object does its second write.  that is this case.  we
 515     # just lie and say it worked.  it'll be dead soon and won't be
 516     # hurt by this lie.
 517     my $sock = $self->{sock} or return 1;
 518     my $ref = ref $data;
 519     my $bref = $ref ? $data : \$data;
 520     my $wbuf = $self->{wbuf};
 521     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 522         if ($ref eq 'CODE') {
 523             push @$wbuf, $bref;
 524         } else {
 525             my $tmpio = $wbuf->[-1];
 526             if ($tmpio && !defined($tmpio->[2])) { # append to tmp file buffer
 527                 $tmpio->[0]->print($$bref) or return drop($self, "print: $!");
 528             } else {
 529                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 530                 push @$wbuf, $tmpio;
 531             }
 532         }
 533         return 0;
 534     } elsif ($ref eq 'CODE') {
 535         $bref->($self);
 536         return 1;
 537     } else {
 538         my $to_write = bytes::length($$bref);
 539         my $written = syswrite($sock, $$bref, $to_write);
 540
 541         if (defined $written) {
 542             return 1 if $written == $to_write;
 543             requeue($self); # runs: event_step -> flush_write
 544         } elsif ($! == EAGAIN) {
 545             epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 546             $written = 0;
 547         } else {
 548             return $self->close;
 549         }
 550
 551         # deal with EAGAIN or partial write:
 552         my $tmpio = tmpio($self, $bref, $written) or return 0;
 553
 554         # wbuf may be an empty array if we're being called inside
 555         # ->flush_write via CODE bref:
 556         push @{$self->{wbuf}}, $tmpio; # autovivifies
 557         return 0;
 558     }
 559 }
 560
 561 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 562
 563 sub msg_more ($$) {
 564     my $self = $_[0];
 565     my $sock = $self->{sock} or return 1;
 566     my $wbuf = $self->{wbuf};
 567
 568     if (MSG_MORE && (!defined($wbuf) || !scalar(@$wbuf)) &&
 569                 !$sock->can('stop_SSL')) {
 570         my $n = send($sock, $_[1], MSG_MORE);
 571         if (defined $n) {
 572             my $nlen = bytes::length($_[1]) - $n;
 573             return 1 if $nlen == 0; # all done!
 574             # queue up the unwritten substring:
 575             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 576             push @{$self->{wbuf}}, $tmpio; # autovivifies
 577             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 578             return 0;
 579         }
 580     }
 581
 582     # don't redispatch into NNTPdeflate::write
 583     PublicInbox::DS::write($self, \($_[1]));
 584 }
 585
 586 sub epwait ($$) {
 587     my ($sock, $ev) = @_;
 588     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 589         confess("EPOLL_CTL_MOD $!");
 590 }
 591
 592 # return true if complete, false if incomplete (or failure)
 593 sub accept_tls_step ($) {
 594     my ($self) = @_;
 595     my $sock = $self->{sock} or return;
 596     return 1 if $sock->accept_SSL;
 597     return $self->close if $! != EAGAIN;
 598     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 599     unshift(@{$self->{wbuf}}, \&accept_tls_step); # autovivifies
 600     0;
 601 }
 602
 603 # return true if complete, false if incomplete (or failure)
 604 sub shutdn_tls_step ($) {
 605     my ($self) = @_;
 606     my $sock = $self->{sock} or return;
 607     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 608     return $self->close if $! != EAGAIN;
 609     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 610     unshift(@{$self->{wbuf}}, \&shutdn_tls_step); # autovivifies
 611     0;
 612 }
 613
 614 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 615 # or fork w/o exec, so no inadvertent socket sharing
 616 sub shutdn ($) {
 617     my ($self) = @_;
 618     my $sock = $self->{sock} or return;
 619     if ($sock->can('stop_SSL')) {
 620         shutdn_tls_step($self);
 621     } else {
 622         $self->close;
 623     }
 624 }
 625
 626 # must be called with eval, PublicInbox::DS may not be loaded (see t/qspawn.t)
 627 sub dwaitpid ($$$) {
 628         die "Not in EventLoop\n" unless $in_loop;
 629         push @$wait_pids, [ @_ ]; # [ $pid, $cb, $arg ]
 630
 631         # We could've just missed our SIGCHLD, cover it, here:
 632         goto &enqueue_reap; # tail recursion
 633 }
 634
 635 sub _run_later () {
 636         my $run = $later_queue or return;
 637         $later_timer = $later_queue = undef;
 638         $_->() for @$run;
 639 }
 640
 641 sub later ($) {
 642         push @$later_queue, $_[0]; # autovivifies @$later_queue
 643         $later_timer //= add_timer(60, \&_run_later);
 644 }
 645
 646 sub expire_old () {
 647         my $now = now();
 648         my $exp = $EXPTIME;
 649         my $old = $now - $exp;
 650         my %new;
 651         while (my ($fd, $idle_at) = each %$EXPMAP) {
 652                 if ($idle_at < $old) {
 653                         my $ds_obj = $DescriptorMap{$fd};
 654                         $new{$fd} = $idle_at if !$ds_obj->shutdn;
 655                 } else {
 656                         $new{$fd} = $idle_at;
 657                 }
 658         }
 659         $EXPMAP = \%new;
 660         $exp_timer = scalar(keys %new) ? later(\&expire_old) : undef;
 661 }
 662
 663 sub update_idle_time {
 664         my ($self) = @_;
 665         my $sock = $self->{sock} or return;
 666         $EXPMAP->{fileno($sock)} = now();
 667         $exp_timer //= later(\&expire_old);
 668 }
 669
 670 sub not_idle_long {
 671         my ($self, $now) = @_;
 672         my $sock = $self->{sock} or return;
 673         my $idle_at = $EXPMAP->{fileno($sock)} or return;
 674         ($idle_at + $EXPTIME) > $now;
 675 }
 676
 677 1;
 678
 679 =head1 AUTHORS (Danga::Socket)
 680
 681 Brad Fitzpatrick <brad@danga.com> - author
 682
 683 Michael Granger <ged@danga.com> - docs, testing
 684
 685 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 686
 687 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits