lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the (for now) unmaintained Danga::Socket 1.61.
   7 # Unused features will be removed, and updates will be made to take
   8 # advantage of newer kernels.
   9 #
  10 # API changes to diverge from Danga::Socket will happen to better
  11 # accomodate new features and improve scalability.  Do not expect
  12 # this to be a stable API like Danga::Socket.
  13 # Bugs encountered (and likely fixed) are reported to
  14 # bug-Danga-Socket@rt.cpan.org and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 package PublicInbox::DS;
  17 use strict;
  18 use bytes;
  19 use POSIX ();
  20 use IO::Handle qw();
  21 use Fcntl qw(SEEK_SET :DEFAULT);
  22 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  23 use parent qw(Exporter);
  24 our @EXPORT_OK = qw(now msg_more);
  25 use warnings;
  26 use 5.010_001;
  27
  28 use PublicInbox::Syscall qw(:epoll);
  29
  30 use fields ('sock',              # underlying socket
  31             'rbuf',              # scalarref, usually undef
  32             'wbuf',              # arrayref of coderefs or GLOB refs
  33             'wbuf_off',  # offset into first element of wbuf to start writing at
  34             );
  35
  36 use Errno  qw(EAGAIN EINVAL EEXIST);
  37 use Carp   qw(croak confess carp);
  38 require File::Spec;
  39
  40 my $nextq = []; # queue for next_tick
  41 our (
  42      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  43      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  44      $_io,                       # IO::Handle for Epoll
  45      @ToClose,                   # sockets to close when event loop is done
  46
  47      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  48
  49      $LoopTimeout,               # timeout of event loop in milliseconds
  50      $DoneInit,                  # if we've done the one-time module init yet
  51      @Timers,                    # timers
  52      );
  53
  54 Reset();
  55
  56 #####################################################################
  57 ### C L A S S   M E T H O D S
  58 #####################################################################
  59
  60 =head2 C<< CLASS->Reset() >>
  61
  62 Reset all state
  63
  64 =cut
  65 sub Reset {
  66     %DescriptorMap = ();
  67     @ToClose = ();
  68     $LoopTimeout = -1;  # no timeout by default
  69     @Timers = ();
  70
  71     $PostLoopCallback = undef;
  72     $DoneInit = 0;
  73
  74     $_io = undef; # closes real $Epoll FD
  75     $Epoll = undef; # may call DSKQXS::DESTROY
  76
  77     *EventLoop = *FirstTimeEventLoop;
  78 }
  79
  80 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  81
  82 Set the loop timeout for the event loop to some value in milliseconds.
  83
  84 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  85 immediately.
  86
  87 =cut
  88 sub SetLoopTimeout {
  89     return $LoopTimeout = $_[1] + 0;
  90 }
  91
  92 =head2 C<< CLASS->AddTimer( $seconds, $coderef ) >>
  93
  94 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
  95 are not guaranteed to fire at the exact time you ask for.
  96
  97 Returns a timer object which you can call C<< $timer->cancel >> on if you need to.
  98
  99 =cut
 100 sub AddTimer {
 101     my ($class, $secs, $coderef) = @_;
 102
 103     my $fire_time = now() + $secs;
 104
 105     my $timer = bless [$fire_time, $coderef], "PublicInbox::DS::Timer";
 106
 107     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 108         push @Timers, $timer;
 109         return $timer;
 110     }
 111
 112     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 113     # but it was compared against calendar queues, heaps, naive push/sort,
 114     # and a bunch of other versions, and found to be fastest with a large
 115     # variety of datasets.)
 116     for (my $i = 0; $i < @Timers; $i++) {
 117         if ($Timers[$i][0] > $fire_time) {
 118             splice(@Timers, $i, 0, $timer);
 119             return $timer;
 120         }
 121     }
 122
 123     die "Shouldn't get here.";
 124 }
 125
 126 # keeping this around in case we support other FD types for now,
 127 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 128 sub set_cloexec ($) {
 129     my ($fd) = @_;
 130
 131     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 132     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 133     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 134 }
 135
 136 sub _InitPoller
 137 {
 138     return if $DoneInit;
 139     $DoneInit = 1;
 140
 141     if (PublicInbox::Syscall::epoll_defined())  {
 142         $Epoll = epoll_create();
 143         set_cloexec($Epoll) if (defined($Epoll) && $Epoll >= 0);
 144     } else {
 145         my $cls;
 146         for (qw(DSKQXS DSPoll)) {
 147             $cls = "PublicInbox::$_";
 148             last if eval "require $cls";
 149         }
 150         $cls->import(qw(epoll_ctl epoll_wait));
 151         $Epoll = $cls->new;
 152     }
 153     *EventLoop = *EpollEventLoop;
 154 }
 155
 156 =head2 C<< CLASS->EventLoop() >>
 157
 158 Start processing IO events. In most daemon programs this never exits. See
 159 C<PostLoopCallback> below for how to exit the loop.
 160
 161 =cut
 162 sub FirstTimeEventLoop {
 163     my $class = shift;
 164
 165     _InitPoller();
 166
 167     EventLoop($class);
 168 }
 169
 170 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 171
 172 sub next_tick () {
 173     my $q = $nextq;
 174     $nextq = [];
 175     for (@$q) {
 176         if (ref($_) eq 'CODE') {
 177             $_->();
 178         } else {
 179             $_->event_step;
 180         }
 181     }
 182 }
 183
 184 # runs timers and returns milliseconds for next one, or next event loop
 185 sub RunTimers {
 186     next_tick();
 187
 188     return ((@$nextq || @ToClose) ? 0 : $LoopTimeout) unless @Timers;
 189
 190     my $now = now();
 191
 192     # Run expired timers
 193     while (@Timers && $Timers[0][0] <= $now) {
 194         my $to_run = shift(@Timers);
 195         $to_run->[1]->($now) if $to_run->[1];
 196     }
 197
 198     # timers may enqueue into nextq:
 199     return 0 if (@$nextq || @ToClose);
 200
 201     return $LoopTimeout unless @Timers;
 202
 203     # convert time to an even number of milliseconds, adding 1
 204     # extra, otherwise floating point fun can occur and we'll
 205     # call RunTimers like 20-30 times, each returning a timeout
 206     # of 0.0000212 seconds
 207     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 208
 209     # -1 is an infinite timeout, so prefer a real timeout
 210     return $timeout     if $LoopTimeout == -1;
 211
 212     # otherwise pick the lower of our regular timeout and time until
 213     # the next timer
 214     return $LoopTimeout if $LoopTimeout < $timeout;
 215     return $timeout;
 216 }
 217
 218 sub EpollEventLoop {
 219     while (1) {
 220         my @events;
 221         my $i;
 222         my $timeout = RunTimers();
 223
 224         # get up to 1000 events
 225         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 226         for ($i=0; $i<$evcount; $i++) {
 227             # it's possible epoll_wait returned many events, including some at the end
 228             # that ones in the front triggered unregister-interest actions.  if we
 229             # can't find the %sock entry, it's because we're no longer interested
 230             # in that event.
 231             $DescriptorMap{$events[$i]->[0]}->event_step;
 232         }
 233         return unless PostEventLoop();
 234     }
 235 }
 236
 237 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 238
 239 Sets post loop callback function.  Pass a subref and it will be
 240 called every time the event loop finishes.
 241
 242 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 243 and it will exit.
 244
 245 The callback function will be passed two parameters: \%DescriptorMap
 246
 247 =cut
 248 sub SetPostLoopCallback {
 249     my ($class, $ref) = @_;
 250
 251     # global callback
 252     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 253 }
 254
 255 # Internal function: run the post-event callback, send read events
 256 # for pushed-back data, and close pending connections.  returns 1
 257 # if event loop should continue, or 0 to shut it all down.
 258 sub PostEventLoop {
 259     # now we can close sockets that wanted to close during our event processing.
 260     # (we didn't want to close them during the loop, as we didn't want fd numbers
 261     #  being reused and confused during the event loop)
 262     delete($DescriptorMap{fileno($_)}) for @ToClose;
 263     @ToClose = (); # let refcounting drop everything all at once
 264
 265     # by default we keep running, unless a postloop callback (either per-object
 266     # or global) cancels it
 267     my $keep_running = 1;
 268
 269     # now we're at the very end, call callback if defined
 270     if (defined $PostLoopCallback) {
 271         $keep_running &&= $PostLoopCallback->(\%DescriptorMap);
 272     }
 273
 274     return $keep_running;
 275 }
 276
 277 #####################################################################
 278 ### PublicInbox::DS-the-object code
 279 #####################################################################
 280
 281 =head2 OBJECT METHODS
 282
 283 =head2 C<< CLASS->new( $socket ) >>
 284
 285 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 286 react to events on it during the C<EventLoop>.
 287
 288 This is normally (always?) called from your subclass via:
 289
 290   $class->SUPER::new($socket);
 291
 292 =cut
 293 sub new {
 294     my ($self, $sock, $ev) = @_;
 295     $self = fields::new($self) unless ref $self;
 296
 297     $self->{sock} = $sock;
 298     my $fd = fileno($sock);
 299
 300     Carp::cluck("undef sock and/or fd in PublicInbox::DS->new.  sock=" . ($sock || "") . ", fd=" . ($fd || ""))
 301         unless $sock && $fd;
 302
 303     _InitPoller();
 304
 305     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 306         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 307             $ev &= ~EPOLLEXCLUSIVE;
 308             goto retry;
 309         }
 310         die "couldn't add epoll watch for $fd: $!\n";
 311     }
 312     Carp::cluck("PublicInbox::DS::new blowing away existing descriptor map for fd=$fd ($DescriptorMap{$fd})")
 313         if $DescriptorMap{$fd};
 314
 315     $DescriptorMap{$fd} = $self;
 316     return $self;
 317 }
 318
 319
 320 #####################################################################
 321 ### I N S T A N C E   M E T H O D S
 322 #####################################################################
 323
 324 sub requeue ($) { push @$nextq, $_[0] }
 325
 326 =head2 C<< $obj->close >>
 327
 328 Close the socket.
 329
 330 =cut
 331 sub close {
 332     my ($self) = @_;
 333     my $sock = delete $self->{sock} or return;
 334
 335     # we need to flush our write buffer, as there may
 336     # be self-referential closures (sub { $client->close })
 337     # preventing the object from being destroyed
 338     delete $self->{wbuf};
 339
 340     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 341     # notifications about it
 342     my $fd = fileno($sock);
 343     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 344         confess("EPOLL_CTL_DEL: $!");
 345
 346     # we explicitly don't delete from DescriptorMap here until we
 347     # actually close the socket, as we might be in the middle of
 348     # processing an epoll_wait/etc that returned hundreds of fds, one
 349     # of which is not yet processed and is what we're closing.  if we
 350     # keep it in DescriptorMap, then the event harnesses can just
 351     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 352     # un-accounted for fd, then it (understandably) freak out a bit
 353     # and emit warnings, thinking their state got off.
 354
 355     # defer closing the actual socket until the event loop is done
 356     # processing this round of events.  (otherwise we might reuse fds)
 357     push @ToClose, $sock;
 358
 359     return 0;
 360 }
 361
 362 # portable, non-thread-safe sendfile emulation (no pread, yet)
 363 sub psendfile ($$$) {
 364     my ($sock, $fh, $off) = @_;
 365
 366     seek($fh, $$off, SEEK_SET) or return;
 367     defined(my $to_write = read($fh, my $buf, 16384)) or return;
 368     my $written = 0;
 369     while ($to_write > 0) {
 370         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 371             $written += $w;
 372             $to_write -= $w;
 373         } else {
 374             return if $written == 0;
 375             last;
 376         }
 377     }
 378     $$off += $written;
 379     $written;
 380 }
 381
 382 sub epbit ($$) { # (sock, default)
 383     ref($_[0]) eq 'IO::Socket::SSL' ? PublicInbox::TLS::epollbit() : $_[1];
 384 }
 385
 386 # returns 1 if done, 0 if incomplete
 387 sub flush_write ($) {
 388     my ($self) = @_;
 389     my $wbuf = $self->{wbuf} or return 1;
 390     my $sock = $self->{sock};
 391
 392 next_buf:
 393     while (my $bref = $wbuf->[0]) {
 394         if (ref($bref) ne 'CODE') {
 395             my $off = delete($self->{wbuf_off}) // 0;
 396             while ($sock) {
 397                 my $w = psendfile($sock, $bref, \$off);
 398                 if (defined $w) {
 399                     if ($w == 0) {
 400                         shift @$wbuf;
 401                         goto next_buf;
 402                     }
 403                 } elsif ($! == EAGAIN) {
 404                     epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 405                     $self->{wbuf_off} = $off;
 406                     return 0;
 407                 } else {
 408                     return $self->close;
 409                 }
 410             }
 411         } else { #($ref eq 'CODE') {
 412             shift @$wbuf;
 413             my $before = scalar(@$wbuf);
 414             $bref->($self);
 415
 416             # bref may be enqueueing more CODE to call (see accept_tls_step)
 417             return 0 if (scalar(@$wbuf) > $before);
 418         }
 419     } # while @$wbuf
 420
 421     delete $self->{wbuf};
 422     1; # all done
 423 }
 424
 425 sub rbuf_idle ($$) {
 426     my ($self, $rbuf) = @_;
 427     if ($$rbuf eq '') { # who knows how long till we can read again
 428         delete $self->{rbuf};
 429     } else {
 430         $self->{rbuf} = $rbuf;
 431     }
 432 }
 433
 434 sub do_read ($$$;$) {
 435     my ($self, $rbuf, $len, $off) = @_;
 436     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 437     return ($r == 0 ? $self->close : $r) if defined $r;
 438     # common for clients to break connections without warning,
 439     # would be too noisy to log here:
 440     if ($! == EAGAIN) {
 441         epwait($sock, epbit($sock, EPOLLIN) | EPOLLONESHOT);
 442         rbuf_idle($self, $rbuf);
 443         0;
 444     } else {
 445         $self->close;
 446     }
 447 }
 448
 449 # drop the socket if we hit unrecoverable errors on our system which
 450 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 451 sub drop {
 452     my $self = shift;
 453     carp(@_);
 454     $self->close;
 455 }
 456
 457 # n.b.: use ->write/->read for this buffer to allow compatibility with
 458 # PerlIO::mmap or PerlIO::scalar if needed
 459 sub tmpio ($$$) {
 460     my ($self, $bref, $off) = @_;
 461     my $fh; # open(my $fh, '+>>', undef) doesn't set O_APPEND
 462     do {
 463         my $fn = File::Spec->tmpdir . '/wbuf-' . rand;
 464         if (sysopen($fh, $fn, O_RDWR|O_CREAT|O_EXCL|O_APPEND, 0600)) { # likely
 465             unlink($fn) or return drop($self, "unlink($fn) $!");
 466         } elsif ($! != EEXIST) { # EMFILE/ENFILE/ENOSPC/ENOMEM
 467             return drop($self, "open: $!");
 468         }
 469     } until (defined $fh);
 470     $fh->autoflush(1);
 471     my $len = bytes::length($$bref) - $off;
 472     $fh->write($$bref, $len, $off) or return drop($self, "write ($len): $!");
 473     $fh
 474 }
 475
 476 =head2 C<< $obj->write( $data ) >>
 477
 478 Write the specified data to the underlying handle.  I<data> may be scalar,
 479 scalar ref, code ref (to run when there).
 480 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 481 it returns 1, caller should stop waiting for 'writable' events)
 482
 483 =cut
 484 sub write {
 485     my ($self, $data) = @_;
 486
 487     # nobody should be writing to closed sockets, but caller code can
 488     # do two writes within an event, have the first fail and
 489     # disconnect the other side (whose destructor then closes the
 490     # calling object, but it's still in a method), and then the
 491     # now-dead object does its second write.  that is this case.  we
 492     # just lie and say it worked.  it'll be dead soon and won't be
 493     # hurt by this lie.
 494     my $sock = $self->{sock} or return 1;
 495     my $ref = ref $data;
 496     my $bref = $ref ? $data : \$data;
 497     my $wbuf = $self->{wbuf};
 498     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 499         if ($ref eq 'CODE') {
 500             push @$wbuf, $bref;
 501         } else {
 502             my $last = $wbuf->[-1];
 503             if (ref($last) eq 'GLOB') { # append to tmp file buffer
 504                 $last->print($$bref) or return drop($self, "print: $!");
 505             } else {
 506                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 507                 push @$wbuf, $tmpio;
 508             }
 509         }
 510         return 0;
 511     } elsif ($ref eq 'CODE') {
 512         $bref->($self);
 513         return 1;
 514     } else {
 515         my $to_write = bytes::length($$bref);
 516         my $written = syswrite($sock, $$bref, $to_write);
 517
 518         if (defined $written) {
 519             return 1 if $written == $to_write;
 520             requeue($self); # runs: event_step -> flush_write
 521         } elsif ($! == EAGAIN) {
 522             epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 523             $written = 0;
 524         } else {
 525             return $self->close;
 526         }
 527
 528         # deal with EAGAIN or partial write:
 529         my $tmpio = tmpio($self, $bref, $written) or return 0;
 530
 531         # wbuf may be an empty array if we're being called inside
 532         # ->flush_write via CODE bref:
 533         push @{$self->{wbuf} ||= []}, $tmpio;
 534         return 0;
 535     }
 536 }
 537
 538 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 539
 540 sub msg_more ($$) {
 541     my $self = $_[0];
 542     my $sock = $self->{sock} or return 1;
 543
 544     if (MSG_MORE && !$self->{wbuf} && ref($sock) ne 'IO::Socket::SSL') {
 545         my $n = send($sock, $_[1], MSG_MORE);
 546         if (defined $n) {
 547             my $nlen = bytes::length($_[1]) - $n;
 548             return 1 if $nlen == 0; # all done!
 549             # queue up the unwritten substring:
 550             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 551             $self->{wbuf} = [ $tmpio ];
 552             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 553             return 0;
 554         }
 555     }
 556
 557     # don't redispatch into NNTPdeflate::write
 558     PublicInbox::DS::write($self, \($_[1]));
 559 }
 560
 561 sub epwait ($$) {
 562     my ($sock, $ev) = @_;
 563     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 564         confess("EPOLL_CTL_MOD $!");
 565 }
 566
 567 # return true if complete, false if incomplete (or failure)
 568 sub accept_tls_step ($) {
 569     my ($self) = @_;
 570     my $sock = $self->{sock} or return;
 571     return 1 if $sock->accept_SSL;
 572     return $self->close if $! != EAGAIN;
 573     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 574     unshift @{$self->{wbuf} ||= []}, \&accept_tls_step;
 575     0;
 576 }
 577
 578 # return true if complete, false if incomplete (or failure)
 579 sub shutdn_tls_step ($) {
 580     my ($self) = @_;
 581     my $sock = $self->{sock} or return;
 582     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 583     return $self->close if $! != EAGAIN;
 584     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 585     unshift @{$self->{wbuf} ||= []}, \&shutdn_tls_step;
 586     0;
 587 }
 588
 589 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 590 # or fork w/o exec, so no inadvertant socket sharing
 591 sub shutdn ($) {
 592     my ($self) = @_;
 593     my $sock = $self->{sock} or return;
 594     if (ref($sock) eq 'IO::Socket::SSL') {
 595         shutdn_tls_step($self);
 596     } else {
 597         $self->close;
 598     }
 599 }
 600 package PublicInbox::DS::Timer;
 601 # [$abs_float_firetime, $coderef];
 602 sub cancel {
 603     $_[0][1] = undef;
 604 }
 605
 606 1;
 607
 608 =head1 AUTHORS (Danga::Socket)
 609
 610 Brad Fitzpatrick <brad@danga.com> - author
 611
 612 Michael Granger <ged@danga.com> - docs, testing
 613
 614 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 615
 616 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits