lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the (for now) unmaintained Danga::Socket 1.61.
   7 # Unused features will be removed, and updates will be made to take
   8 # advantage of newer kernels.
   9 #
  10 # API changes to diverge from Danga::Socket will happen to better
  11 # accomodate new features and improve scalability.  Do not expect
  12 # this to be a stable API like Danga::Socket.
  13 # Bugs encountered (and likely fixed) are reported to
  14 # bug-Danga-Socket@rt.cpan.org and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 package PublicInbox::DS;
  17 use strict;
  18 use bytes;
  19 use POSIX qw(WNOHANG);
  20 use IO::Handle qw();
  21 use Fcntl qw(SEEK_SET :DEFAULT);
  22 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  23 use parent qw(Exporter);
  24 our @EXPORT_OK = qw(now msg_more);
  25 use warnings;
  26 use 5.010_001;
  27 use Scalar::Util qw(blessed);
  28
  29 use PublicInbox::Syscall qw(:epoll);
  30 use PublicInbox::Tmpfile;
  31
  32 use fields ('sock',              # underlying socket
  33             'rbuf',              # scalarref, usually undef
  34             'wbuf',              # arrayref of coderefs or GLOB refs
  35             'wbuf_off',  # offset into first element of wbuf to start writing at
  36             );
  37
  38 use Errno  qw(EAGAIN EINVAL);
  39 use Carp   qw(croak confess carp);
  40 require File::Spec;
  41
  42 my $nextq; # queue for next_tick
  43 my $WaitPids; # list of [ pid, callback, callback_arg ]
  44 my $reap_timer;
  45 our (
  46      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  47      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  48      $_io,                       # IO::Handle for Epoll
  49      @ToClose,                   # sockets to close when event loop is done
  50
  51      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  52
  53      $LoopTimeout,               # timeout of event loop in milliseconds
  54      $DoneInit,                  # if we've done the one-time module init yet
  55      @Timers,                    # timers
  56      $in_loop,
  57      );
  58
  59 Reset();
  60
  61 #####################################################################
  62 ### C L A S S   M E T H O D S
  63 #####################################################################
  64
  65 =head2 C<< CLASS->Reset() >>
  66
  67 Reset all state
  68
  69 =cut
  70 sub Reset {
  71     %DescriptorMap = ();
  72     $nextq = [];
  73     $WaitPids = [];
  74     $reap_timer = undef;
  75     @ToClose = ();
  76     $LoopTimeout = -1;  # no timeout by default
  77     @Timers = ();
  78
  79     $PostLoopCallback = undef;
  80     $DoneInit = 0;
  81
  82     $_io = undef; # closes real $Epoll FD
  83     $Epoll = undef; # may call DSKQXS::DESTROY
  84
  85     *EventLoop = *FirstTimeEventLoop;
  86 }
  87
  88 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  89
  90 Set the loop timeout for the event loop to some value in milliseconds.
  91
  92 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  93 immediately.
  94
  95 =cut
  96 sub SetLoopTimeout {
  97     return $LoopTimeout = $_[1] + 0;
  98 }
  99
 100 =head2 C<< CLASS->AddTimer( $seconds, $coderef ) >>
 101
 102 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 103 are not guaranteed to fire at the exact time you ask for.
 104
 105 Returns a timer object which you can call C<< $timer->cancel >> on if you need to.
 106
 107 =cut
 108 sub AddTimer {
 109     my ($class, $secs, $coderef) = @_;
 110
 111     my $fire_time = now() + $secs;
 112
 113     my $timer = bless [$fire_time, $coderef], "PublicInbox::DS::Timer";
 114
 115     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 116         push @Timers, $timer;
 117         return $timer;
 118     }
 119
 120     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 121     # but it was compared against calendar queues, heaps, naive push/sort,
 122     # and a bunch of other versions, and found to be fastest with a large
 123     # variety of datasets.)
 124     for (my $i = 0; $i < @Timers; $i++) {
 125         if ($Timers[$i][0] > $fire_time) {
 126             splice(@Timers, $i, 0, $timer);
 127             return $timer;
 128         }
 129     }
 130
 131     die "Shouldn't get here.";
 132 }
 133
 134 # keeping this around in case we support other FD types for now,
 135 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 136 sub set_cloexec ($) {
 137     my ($fd) = @_;
 138
 139     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 140     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 141     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 142 }
 143
 144 sub _InitPoller
 145 {
 146     return if $DoneInit;
 147     $DoneInit = 1;
 148
 149     if (PublicInbox::Syscall::epoll_defined())  {
 150         $Epoll = epoll_create();
 151         set_cloexec($Epoll) if (defined($Epoll) && $Epoll >= 0);
 152     } else {
 153         my $cls;
 154         for (qw(DSKQXS DSPoll)) {
 155             $cls = "PublicInbox::$_";
 156             last if eval "require $cls";
 157         }
 158         $cls->import(qw(epoll_ctl epoll_wait));
 159         $Epoll = $cls->new;
 160     }
 161     *EventLoop = *EpollEventLoop;
 162 }
 163
 164 =head2 C<< CLASS->EventLoop() >>
 165
 166 Start processing IO events. In most daemon programs this never exits. See
 167 C<PostLoopCallback> below for how to exit the loop.
 168
 169 =cut
 170 sub FirstTimeEventLoop {
 171     my $class = shift;
 172
 173     _InitPoller();
 174
 175     EventLoop($class);
 176 }
 177
 178 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 179
 180 sub next_tick () {
 181     my $q = $nextq;
 182     $nextq = [];
 183     for (@$q) {
 184         # we avoid "ref" on blessed refs to workaround a Perl 5.16.3 leak:
 185         # https://rt.perl.org/Public/Bug/Display.html?id=114340
 186         if (blessed($_)) {
 187             $_->event_step;
 188         } else {
 189             $_->();
 190         }
 191     }
 192 }
 193
 194 # runs timers and returns milliseconds for next one, or next event loop
 195 sub RunTimers {
 196     next_tick();
 197
 198     return ((@$nextq || @ToClose) ? 0 : $LoopTimeout) unless @Timers;
 199
 200     my $now = now();
 201
 202     # Run expired timers
 203     while (@Timers && $Timers[0][0] <= $now) {
 204         my $to_run = shift(@Timers);
 205         $to_run->[1]->($now) if $to_run->[1];
 206     }
 207
 208     # timers may enqueue into nextq:
 209     return 0 if (@$nextq || @ToClose);
 210
 211     return $LoopTimeout unless @Timers;
 212
 213     # convert time to an even number of milliseconds, adding 1
 214     # extra, otherwise floating point fun can occur and we'll
 215     # call RunTimers like 20-30 times, each returning a timeout
 216     # of 0.0000212 seconds
 217     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 218
 219     # -1 is an infinite timeout, so prefer a real timeout
 220     return $timeout     if $LoopTimeout == -1;
 221
 222     # otherwise pick the lower of our regular timeout and time until
 223     # the next timer
 224     return $LoopTimeout if $LoopTimeout < $timeout;
 225     return $timeout;
 226 }
 227
 228 # We can't use waitpid(-1) safely here since it can hit ``, system(),
 229 # and other things.  So we scan the $WaitPids list, which is hopefully
 230 # not too big.
 231 sub reap_pids {
 232     my $tmp = $WaitPids;
 233     $WaitPids = [];
 234     $reap_timer = undef;
 235     foreach my $ary (@$tmp) {
 236         my ($pid, $cb, $arg) = @$ary;
 237         my $ret = waitpid($pid, WNOHANG);
 238         if ($ret == 0) {
 239             push @$WaitPids, $ary;
 240         } elsif ($cb) {
 241             eval { $cb->($arg, $pid) };
 242         }
 243     }
 244     if (@$WaitPids) {
 245         # we may not be donea, and we may miss our
 246         $reap_timer = AddTimer(undef, 1, \&reap_pids);
 247     }
 248 }
 249
 250 # reentrant SIGCHLD handler (since reap_pids is not reentrant)
 251 sub enqueue_reap ($) { push @$nextq, \&reap_pids };
 252
 253 sub EpollEventLoop {
 254     local $in_loop = 1;
 255     while (1) {
 256         my @events;
 257         my $i;
 258         my $timeout = RunTimers();
 259
 260         # get up to 1000 events
 261         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 262         for ($i=0; $i<$evcount; $i++) {
 263             # it's possible epoll_wait returned many events, including some at the end
 264             # that ones in the front triggered unregister-interest actions.  if we
 265             # can't find the %sock entry, it's because we're no longer interested
 266             # in that event.
 267             $DescriptorMap{$events[$i]->[0]}->event_step;
 268         }
 269         return unless PostEventLoop();
 270     }
 271 }
 272
 273 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 274
 275 Sets post loop callback function.  Pass a subref and it will be
 276 called every time the event loop finishes.
 277
 278 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 279 and it will exit.
 280
 281 The callback function will be passed two parameters: \%DescriptorMap
 282
 283 =cut
 284 sub SetPostLoopCallback {
 285     my ($class, $ref) = @_;
 286
 287     # global callback
 288     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 289 }
 290
 291 # Internal function: run the post-event callback, send read events
 292 # for pushed-back data, and close pending connections.  returns 1
 293 # if event loop should continue, or 0 to shut it all down.
 294 sub PostEventLoop {
 295     # now we can close sockets that wanted to close during our event processing.
 296     # (we didn't want to close them during the loop, as we didn't want fd numbers
 297     #  being reused and confused during the event loop)
 298     delete($DescriptorMap{fileno($_)}) for @ToClose;
 299     @ToClose = (); # let refcounting drop everything all at once
 300
 301     # by default we keep running, unless a postloop callback (either per-object
 302     # or global) cancels it
 303     my $keep_running = 1;
 304
 305     # now we're at the very end, call callback if defined
 306     if (defined $PostLoopCallback) {
 307         $keep_running &&= $PostLoopCallback->(\%DescriptorMap);
 308     }
 309
 310     return $keep_running;
 311 }
 312
 313 #####################################################################
 314 ### PublicInbox::DS-the-object code
 315 #####################################################################
 316
 317 =head2 OBJECT METHODS
 318
 319 =head2 C<< CLASS->new( $socket ) >>
 320
 321 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 322 react to events on it during the C<EventLoop>.
 323
 324 This is normally (always?) called from your subclass via:
 325
 326   $class->SUPER::new($socket);
 327
 328 =cut
 329 sub new {
 330     my ($self, $sock, $ev) = @_;
 331     $self = fields::new($self) unless ref $self;
 332
 333     $self->{sock} = $sock;
 334     my $fd = fileno($sock);
 335
 336     Carp::cluck("undef sock and/or fd in PublicInbox::DS->new.  sock=" . ($sock || "") . ", fd=" . ($fd || ""))
 337         unless $sock && $fd;
 338
 339     _InitPoller();
 340
 341     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 342         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 343             $ev &= ~EPOLLEXCLUSIVE;
 344             goto retry;
 345         }
 346         die "couldn't add epoll watch for $fd: $!\n";
 347     }
 348     Carp::cluck("PublicInbox::DS::new blowing away existing descriptor map for fd=$fd ($DescriptorMap{$fd})")
 349         if $DescriptorMap{$fd};
 350
 351     $DescriptorMap{$fd} = $self;
 352     return $self;
 353 }
 354
 355
 356 #####################################################################
 357 ### I N S T A N C E   M E T H O D S
 358 #####################################################################
 359
 360 sub requeue ($) { push @$nextq, $_[0] }
 361
 362 =head2 C<< $obj->close >>
 363
 364 Close the socket.
 365
 366 =cut
 367 sub close {
 368     my ($self) = @_;
 369     my $sock = delete $self->{sock} or return;
 370
 371     # we need to flush our write buffer, as there may
 372     # be self-referential closures (sub { $client->close })
 373     # preventing the object from being destroyed
 374     delete $self->{wbuf};
 375
 376     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 377     # notifications about it
 378     my $fd = fileno($sock);
 379     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 380         confess("EPOLL_CTL_DEL: $!");
 381
 382     # we explicitly don't delete from DescriptorMap here until we
 383     # actually close the socket, as we might be in the middle of
 384     # processing an epoll_wait/etc that returned hundreds of fds, one
 385     # of which is not yet processed and is what we're closing.  if we
 386     # keep it in DescriptorMap, then the event harnesses can just
 387     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 388     # un-accounted for fd, then it (understandably) freak out a bit
 389     # and emit warnings, thinking their state got off.
 390
 391     # defer closing the actual socket until the event loop is done
 392     # processing this round of events.  (otherwise we might reuse fds)
 393     push @ToClose, $sock;
 394
 395     return 0;
 396 }
 397
 398 # portable, non-thread-safe sendfile emulation (no pread, yet)
 399 sub psendfile ($$$) {
 400     my ($sock, $fh, $off) = @_;
 401
 402     seek($fh, $$off, SEEK_SET) or return;
 403     defined(my $to_write = read($fh, my $buf, 16384)) or return;
 404     my $written = 0;
 405     while ($to_write > 0) {
 406         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 407             $written += $w;
 408             $to_write -= $w;
 409         } else {
 410             return if $written == 0;
 411             last;
 412         }
 413     }
 414     $$off += $written;
 415     $written;
 416 }
 417
 418 sub epbit ($$) { # (sock, default)
 419     ref($_[0]) eq 'IO::Socket::SSL' ? PublicInbox::TLS::epollbit() : $_[1];
 420 }
 421
 422 # returns 1 if done, 0 if incomplete
 423 sub flush_write ($) {
 424     my ($self) = @_;
 425     my $wbuf = $self->{wbuf} or return 1;
 426     my $sock = $self->{sock};
 427
 428 next_buf:
 429     while (my $bref = $wbuf->[0]) {
 430         if (ref($bref) ne 'CODE') {
 431             my $off = delete($self->{wbuf_off}) // 0;
 432             while ($sock) {
 433                 my $w = psendfile($sock, $bref, \$off);
 434                 if (defined $w) {
 435                     if ($w == 0) {
 436                         shift @$wbuf;
 437                         goto next_buf;
 438                     }
 439                 } elsif ($! == EAGAIN) {
 440                     epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 441                     $self->{wbuf_off} = $off;
 442                     return 0;
 443                 } else {
 444                     return $self->close;
 445                 }
 446             }
 447         } else { #($ref eq 'CODE') {
 448             shift @$wbuf;
 449             my $before = scalar(@$wbuf);
 450             $bref->($self);
 451
 452             # bref may be enqueueing more CODE to call (see accept_tls_step)
 453             return 0 if (scalar(@$wbuf) > $before);
 454         }
 455     } # while @$wbuf
 456
 457     delete $self->{wbuf};
 458     1; # all done
 459 }
 460
 461 sub rbuf_idle ($$) {
 462     my ($self, $rbuf) = @_;
 463     if ($$rbuf eq '') { # who knows how long till we can read again
 464         delete $self->{rbuf};
 465     } else {
 466         $self->{rbuf} = $rbuf;
 467     }
 468 }
 469
 470 sub do_read ($$$;$) {
 471     my ($self, $rbuf, $len, $off) = @_;
 472     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 473     return ($r == 0 ? $self->close : $r) if defined $r;
 474     # common for clients to break connections without warning,
 475     # would be too noisy to log here:
 476     if ($! == EAGAIN) {
 477         epwait($sock, epbit($sock, EPOLLIN) | EPOLLONESHOT);
 478         rbuf_idle($self, $rbuf);
 479         0;
 480     } else {
 481         $self->close;
 482     }
 483 }
 484
 485 # drop the socket if we hit unrecoverable errors on our system which
 486 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 487 sub drop {
 488     my $self = shift;
 489     carp(@_);
 490     $self->close;
 491 }
 492
 493 # n.b.: use ->write/->read for this buffer to allow compatibility with
 494 # PerlIO::mmap or PerlIO::scalar if needed
 495 sub tmpio ($$$) {
 496     my ($self, $bref, $off) = @_;
 497     my $fh = tmpfile('wbuf', $self->{sock}, 1) or
 498         return drop($self, "tmpfile $!");
 499     $fh->autoflush(1);
 500     my $len = bytes::length($$bref) - $off;
 501     $fh->write($$bref, $len, $off) or return drop($self, "write ($len): $!");
 502     $fh
 503 }
 504
 505 =head2 C<< $obj->write( $data ) >>
 506
 507 Write the specified data to the underlying handle.  I<data> may be scalar,
 508 scalar ref, code ref (to run when there).
 509 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 510 it returns 1, caller should stop waiting for 'writable' events)
 511
 512 =cut
 513 sub write {
 514     my ($self, $data) = @_;
 515
 516     # nobody should be writing to closed sockets, but caller code can
 517     # do two writes within an event, have the first fail and
 518     # disconnect the other side (whose destructor then closes the
 519     # calling object, but it's still in a method), and then the
 520     # now-dead object does its second write.  that is this case.  we
 521     # just lie and say it worked.  it'll be dead soon and won't be
 522     # hurt by this lie.
 523     my $sock = $self->{sock} or return 1;
 524     my $ref = ref $data;
 525     my $bref = $ref ? $data : \$data;
 526     my $wbuf = $self->{wbuf};
 527     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 528         if ($ref eq 'CODE') {
 529             push @$wbuf, $bref;
 530         } else {
 531             my $last = $wbuf->[-1];
 532             if (ref($last) eq 'GLOB') { # append to tmp file buffer
 533                 $last->print($$bref) or return drop($self, "print: $!");
 534             } else {
 535                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 536                 push @$wbuf, $tmpio;
 537             }
 538         }
 539         return 0;
 540     } elsif ($ref eq 'CODE') {
 541         $bref->($self);
 542         return 1;
 543     } else {
 544         my $to_write = bytes::length($$bref);
 545         my $written = syswrite($sock, $$bref, $to_write);
 546
 547         if (defined $written) {
 548             return 1 if $written == $to_write;
 549             requeue($self); # runs: event_step -> flush_write
 550         } elsif ($! == EAGAIN) {
 551             epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 552             $written = 0;
 553         } else {
 554             return $self->close;
 555         }
 556
 557         # deal with EAGAIN or partial write:
 558         my $tmpio = tmpio($self, $bref, $written) or return 0;
 559
 560         # wbuf may be an empty array if we're being called inside
 561         # ->flush_write via CODE bref:
 562         push @{$self->{wbuf} ||= []}, $tmpio;
 563         return 0;
 564     }
 565 }
 566
 567 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 568
 569 sub msg_more ($$) {
 570     my $self = $_[0];
 571     my $sock = $self->{sock} or return 1;
 572
 573     if (MSG_MORE && !$self->{wbuf} && ref($sock) ne 'IO::Socket::SSL') {
 574         my $n = send($sock, $_[1], MSG_MORE);
 575         if (defined $n) {
 576             my $nlen = bytes::length($_[1]) - $n;
 577             return 1 if $nlen == 0; # all done!
 578             # queue up the unwritten substring:
 579             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 580             $self->{wbuf} = [ $tmpio ];
 581             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 582             return 0;
 583         }
 584     }
 585
 586     # don't redispatch into NNTPdeflate::write
 587     PublicInbox::DS::write($self, \($_[1]));
 588 }
 589
 590 sub epwait ($$) {
 591     my ($sock, $ev) = @_;
 592     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 593         confess("EPOLL_CTL_MOD $!");
 594 }
 595
 596 # return true if complete, false if incomplete (or failure)
 597 sub accept_tls_step ($) {
 598     my ($self) = @_;
 599     my $sock = $self->{sock} or return;
 600     return 1 if $sock->accept_SSL;
 601     return $self->close if $! != EAGAIN;
 602     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 603     unshift @{$self->{wbuf} ||= []}, \&accept_tls_step;
 604     0;
 605 }
 606
 607 # return true if complete, false if incomplete (or failure)
 608 sub shutdn_tls_step ($) {
 609     my ($self) = @_;
 610     my $sock = $self->{sock} or return;
 611     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 612     return $self->close if $! != EAGAIN;
 613     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 614     unshift @{$self->{wbuf} ||= []}, \&shutdn_tls_step;
 615     0;
 616 }
 617
 618 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 619 # or fork w/o exec, so no inadvertant socket sharing
 620 sub shutdn ($) {
 621     my ($self) = @_;
 622     my $sock = $self->{sock} or return;
 623     if (ref($sock) eq 'IO::Socket::SSL') {
 624         shutdn_tls_step($self);
 625     } else {
 626         $self->close;
 627     }
 628 }
 629
 630 # must be called with eval, PublicInbox::DS may not be loaded (see t/qspawn.t)
 631 sub dwaitpid ($$$) {
 632     my ($pid, $cb, $arg) = @_;
 633     if ($in_loop) {
 634         push @$WaitPids, [ $pid, $cb, $arg ];
 635
 636         # We could've just missed our SIGCHLD, cover it, here:
 637         requeue(\&reap_pids);
 638     } else {
 639         die "Not in EventLoop\n";
 640     }
 641 }
 642
 643 package PublicInbox::DS::Timer;
 644 # [$abs_float_firetime, $coderef];
 645 sub cancel {
 646     $_[0][1] = undef;
 647 }
 648
 649 1;
 650
 651 =head1 AUTHORS (Danga::Socket)
 652
 653 Brad Fitzpatrick <brad@danga.com> - author
 654
 655 Michael Granger <ged@danga.com> - docs, testing
 656
 657 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 658
 659 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits