lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the (for now) unmaintained Danga::Socket 1.61.
   7 # Unused features will be removed, and updates will be made to take
   8 # advantage of newer kernels.
   9 #
  10 # API changes to diverge from Danga::Socket will happen to better
  11 # accomodate new features and improve scalability.  Do not expect
  12 # this to be a stable API like Danga::Socket.
  13 # Bugs encountered (and likely fixed) are reported to
  14 # bug-Danga-Socket@rt.cpan.org and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 package PublicInbox::DS;
  17 use strict;
  18 use bytes;
  19 use POSIX qw(WNOHANG);
  20 use IO::Handle qw();
  21 use Fcntl qw(SEEK_SET :DEFAULT);
  22 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  23 use parent qw(Exporter);
  24 our @EXPORT_OK = qw(now msg_more);
  25 use warnings;
  26 use 5.010_001;
  27 use Scalar::Util qw(blessed);
  28
  29 use PublicInbox::Syscall qw(:epoll);
  30 use PublicInbox::Tmpfile;
  31
  32 use fields ('sock',              # underlying socket
  33             'rbuf',              # scalarref, usually undef
  34             'wbuf',              # arrayref of coderefs or GLOB refs
  35             'wbuf_off',  # offset into first element of wbuf to start writing at
  36             );
  37
  38 use Errno  qw(EAGAIN EINVAL);
  39 use Carp   qw(croak confess carp);
  40 require File::Spec;
  41
  42 my $nextq = []; # queue for next_tick
  43 my $WaitPids = [];               # list of [ pid, callback, callback_arg ]
  44 my $reap_timer;
  45 our (
  46      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  47      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  48      $_io,                       # IO::Handle for Epoll
  49      @ToClose,                   # sockets to close when event loop is done
  50
  51      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  52
  53      $LoopTimeout,               # timeout of event loop in milliseconds
  54      $DoneInit,                  # if we've done the one-time module init yet
  55      @Timers,                    # timers
  56      );
  57
  58 Reset();
  59
  60 #####################################################################
  61 ### C L A S S   M E T H O D S
  62 #####################################################################
  63
  64 =head2 C<< CLASS->Reset() >>
  65
  66 Reset all state
  67
  68 =cut
  69 sub Reset {
  70     %DescriptorMap = ();
  71     $WaitPids = [];
  72     $reap_timer = undef;
  73     @ToClose = ();
  74     $LoopTimeout = -1;  # no timeout by default
  75     @Timers = ();
  76
  77     $PostLoopCallback = undef;
  78     $DoneInit = 0;
  79
  80     $_io = undef; # closes real $Epoll FD
  81     $Epoll = undef; # may call DSKQXS::DESTROY
  82
  83     *EventLoop = *FirstTimeEventLoop;
  84 }
  85
  86 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  87
  88 Set the loop timeout for the event loop to some value in milliseconds.
  89
  90 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  91 immediately.
  92
  93 =cut
  94 sub SetLoopTimeout {
  95     return $LoopTimeout = $_[1] + 0;
  96 }
  97
  98 =head2 C<< CLASS->AddTimer( $seconds, $coderef ) >>
  99
 100 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 101 are not guaranteed to fire at the exact time you ask for.
 102
 103 Returns a timer object which you can call C<< $timer->cancel >> on if you need to.
 104
 105 =cut
 106 sub AddTimer {
 107     my ($class, $secs, $coderef) = @_;
 108
 109     my $fire_time = now() + $secs;
 110
 111     my $timer = bless [$fire_time, $coderef], "PublicInbox::DS::Timer";
 112
 113     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 114         push @Timers, $timer;
 115         return $timer;
 116     }
 117
 118     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 119     # but it was compared against calendar queues, heaps, naive push/sort,
 120     # and a bunch of other versions, and found to be fastest with a large
 121     # variety of datasets.)
 122     for (my $i = 0; $i < @Timers; $i++) {
 123         if ($Timers[$i][0] > $fire_time) {
 124             splice(@Timers, $i, 0, $timer);
 125             return $timer;
 126         }
 127     }
 128
 129     die "Shouldn't get here.";
 130 }
 131
 132 # keeping this around in case we support other FD types for now,
 133 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 134 sub set_cloexec ($) {
 135     my ($fd) = @_;
 136
 137     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 138     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 139     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 140 }
 141
 142 sub _InitPoller
 143 {
 144     return if $DoneInit;
 145     $DoneInit = 1;
 146
 147     if (PublicInbox::Syscall::epoll_defined())  {
 148         $Epoll = epoll_create();
 149         set_cloexec($Epoll) if (defined($Epoll) && $Epoll >= 0);
 150     } else {
 151         my $cls;
 152         for (qw(DSKQXS DSPoll)) {
 153             $cls = "PublicInbox::$_";
 154             last if eval "require $cls";
 155         }
 156         $cls->import(qw(epoll_ctl epoll_wait));
 157         $Epoll = $cls->new;
 158     }
 159     *EventLoop = *EpollEventLoop;
 160 }
 161
 162 =head2 C<< CLASS->EventLoop() >>
 163
 164 Start processing IO events. In most daemon programs this never exits. See
 165 C<PostLoopCallback> below for how to exit the loop.
 166
 167 =cut
 168 sub FirstTimeEventLoop {
 169     my $class = shift;
 170
 171     _InitPoller();
 172
 173     EventLoop($class);
 174 }
 175
 176 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 177
 178 sub next_tick () {
 179     my $q = $nextq;
 180     $nextq = [];
 181     for (@$q) {
 182         # we avoid "ref" on blessed refs to workaround a Perl 5.16.3 leak:
 183         # https://rt.perl.org/Public/Bug/Display.html?id=114340
 184         if (blessed($_)) {
 185             $_->event_step;
 186         } else {
 187             $_->();
 188         }
 189     }
 190 }
 191
 192 # runs timers and returns milliseconds for next one, or next event loop
 193 sub RunTimers {
 194     next_tick();
 195
 196     return ((@$nextq || @ToClose) ? 0 : $LoopTimeout) unless @Timers;
 197
 198     my $now = now();
 199
 200     # Run expired timers
 201     while (@Timers && $Timers[0][0] <= $now) {
 202         my $to_run = shift(@Timers);
 203         $to_run->[1]->($now) if $to_run->[1];
 204     }
 205
 206     # timers may enqueue into nextq:
 207     return 0 if (@$nextq || @ToClose);
 208
 209     return $LoopTimeout unless @Timers;
 210
 211     # convert time to an even number of milliseconds, adding 1
 212     # extra, otherwise floating point fun can occur and we'll
 213     # call RunTimers like 20-30 times, each returning a timeout
 214     # of 0.0000212 seconds
 215     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 216
 217     # -1 is an infinite timeout, so prefer a real timeout
 218     return $timeout     if $LoopTimeout == -1;
 219
 220     # otherwise pick the lower of our regular timeout and time until
 221     # the next timer
 222     return $LoopTimeout if $LoopTimeout < $timeout;
 223     return $timeout;
 224 }
 225
 226 # We can't use waitpid(-1) safely here since it can hit ``, system(),
 227 # and other things.  So we scan the $WaitPids list, which is hopefully
 228 # not too big.
 229 sub reap_pids {
 230     my $tmp = $WaitPids;
 231     $WaitPids = [];
 232     $reap_timer = undef;
 233     foreach my $ary (@$tmp) {
 234         my ($pid, $cb, $arg) = @$ary;
 235         my $ret = waitpid($pid, WNOHANG);
 236         if ($ret == 0) {
 237             push @$WaitPids, $ary;
 238         } elsif ($cb) {
 239             eval { $cb->($arg, $pid) };
 240         }
 241     }
 242     if (@$WaitPids) {
 243         # we may not be donea, and we may miss our
 244         $reap_timer = AddTimer(undef, 1, \&reap_pids);
 245     }
 246 }
 247
 248 # reentrant SIGCHLD handler (since reap_pids is not reentrant)
 249 sub enqueue_reap ($) { push @$nextq, \&reap_pids };
 250
 251 sub EpollEventLoop {
 252     local $SIG{CHLD} = \&enqueue_reap;
 253     while (1) {
 254         my @events;
 255         my $i;
 256         my $timeout = RunTimers();
 257
 258         # get up to 1000 events
 259         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 260         for ($i=0; $i<$evcount; $i++) {
 261             # it's possible epoll_wait returned many events, including some at the end
 262             # that ones in the front triggered unregister-interest actions.  if we
 263             # can't find the %sock entry, it's because we're no longer interested
 264             # in that event.
 265             $DescriptorMap{$events[$i]->[0]}->event_step;
 266         }
 267         return unless PostEventLoop();
 268     }
 269 }
 270
 271 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 272
 273 Sets post loop callback function.  Pass a subref and it will be
 274 called every time the event loop finishes.
 275
 276 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 277 and it will exit.
 278
 279 The callback function will be passed two parameters: \%DescriptorMap
 280
 281 =cut
 282 sub SetPostLoopCallback {
 283     my ($class, $ref) = @_;
 284
 285     # global callback
 286     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 287 }
 288
 289 # Internal function: run the post-event callback, send read events
 290 # for pushed-back data, and close pending connections.  returns 1
 291 # if event loop should continue, or 0 to shut it all down.
 292 sub PostEventLoop {
 293     # now we can close sockets that wanted to close during our event processing.
 294     # (we didn't want to close them during the loop, as we didn't want fd numbers
 295     #  being reused and confused during the event loop)
 296     delete($DescriptorMap{fileno($_)}) for @ToClose;
 297     @ToClose = (); # let refcounting drop everything all at once
 298
 299     # by default we keep running, unless a postloop callback (either per-object
 300     # or global) cancels it
 301     my $keep_running = 1;
 302
 303     # now we're at the very end, call callback if defined
 304     if (defined $PostLoopCallback) {
 305         $keep_running &&= $PostLoopCallback->(\%DescriptorMap);
 306     }
 307
 308     return $keep_running;
 309 }
 310
 311 #####################################################################
 312 ### PublicInbox::DS-the-object code
 313 #####################################################################
 314
 315 =head2 OBJECT METHODS
 316
 317 =head2 C<< CLASS->new( $socket ) >>
 318
 319 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 320 react to events on it during the C<EventLoop>.
 321
 322 This is normally (always?) called from your subclass via:
 323
 324   $class->SUPER::new($socket);
 325
 326 =cut
 327 sub new {
 328     my ($self, $sock, $ev) = @_;
 329     $self = fields::new($self) unless ref $self;
 330
 331     $self->{sock} = $sock;
 332     my $fd = fileno($sock);
 333
 334     Carp::cluck("undef sock and/or fd in PublicInbox::DS->new.  sock=" . ($sock || "") . ", fd=" . ($fd || ""))
 335         unless $sock && $fd;
 336
 337     _InitPoller();
 338
 339     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 340         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 341             $ev &= ~EPOLLEXCLUSIVE;
 342             goto retry;
 343         }
 344         die "couldn't add epoll watch for $fd: $!\n";
 345     }
 346     Carp::cluck("PublicInbox::DS::new blowing away existing descriptor map for fd=$fd ($DescriptorMap{$fd})")
 347         if $DescriptorMap{$fd};
 348
 349     $DescriptorMap{$fd} = $self;
 350     return $self;
 351 }
 352
 353
 354 #####################################################################
 355 ### I N S T A N C E   M E T H O D S
 356 #####################################################################
 357
 358 sub requeue ($) { push @$nextq, $_[0] }
 359
 360 =head2 C<< $obj->close >>
 361
 362 Close the socket.
 363
 364 =cut
 365 sub close {
 366     my ($self) = @_;
 367     my $sock = delete $self->{sock} or return;
 368
 369     # we need to flush our write buffer, as there may
 370     # be self-referential closures (sub { $client->close })
 371     # preventing the object from being destroyed
 372     delete $self->{wbuf};
 373
 374     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 375     # notifications about it
 376     my $fd = fileno($sock);
 377     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 378         confess("EPOLL_CTL_DEL: $!");
 379
 380     # we explicitly don't delete from DescriptorMap here until we
 381     # actually close the socket, as we might be in the middle of
 382     # processing an epoll_wait/etc that returned hundreds of fds, one
 383     # of which is not yet processed and is what we're closing.  if we
 384     # keep it in DescriptorMap, then the event harnesses can just
 385     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 386     # un-accounted for fd, then it (understandably) freak out a bit
 387     # and emit warnings, thinking their state got off.
 388
 389     # defer closing the actual socket until the event loop is done
 390     # processing this round of events.  (otherwise we might reuse fds)
 391     push @ToClose, $sock;
 392
 393     return 0;
 394 }
 395
 396 # portable, non-thread-safe sendfile emulation (no pread, yet)
 397 sub psendfile ($$$) {
 398     my ($sock, $fh, $off) = @_;
 399
 400     seek($fh, $$off, SEEK_SET) or return;
 401     defined(my $to_write = read($fh, my $buf, 16384)) or return;
 402     my $written = 0;
 403     while ($to_write > 0) {
 404         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 405             $written += $w;
 406             $to_write -= $w;
 407         } else {
 408             return if $written == 0;
 409             last;
 410         }
 411     }
 412     $$off += $written;
 413     $written;
 414 }
 415
 416 sub epbit ($$) { # (sock, default)
 417     ref($_[0]) eq 'IO::Socket::SSL' ? PublicInbox::TLS::epollbit() : $_[1];
 418 }
 419
 420 # returns 1 if done, 0 if incomplete
 421 sub flush_write ($) {
 422     my ($self) = @_;
 423     my $wbuf = $self->{wbuf} or return 1;
 424     my $sock = $self->{sock};
 425
 426 next_buf:
 427     while (my $bref = $wbuf->[0]) {
 428         if (ref($bref) ne 'CODE') {
 429             my $off = delete($self->{wbuf_off}) // 0;
 430             while ($sock) {
 431                 my $w = psendfile($sock, $bref, \$off);
 432                 if (defined $w) {
 433                     if ($w == 0) {
 434                         shift @$wbuf;
 435                         goto next_buf;
 436                     }
 437                 } elsif ($! == EAGAIN) {
 438                     epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 439                     $self->{wbuf_off} = $off;
 440                     return 0;
 441                 } else {
 442                     return $self->close;
 443                 }
 444             }
 445         } else { #($ref eq 'CODE') {
 446             shift @$wbuf;
 447             my $before = scalar(@$wbuf);
 448             $bref->($self);
 449
 450             # bref may be enqueueing more CODE to call (see accept_tls_step)
 451             return 0 if (scalar(@$wbuf) > $before);
 452         }
 453     } # while @$wbuf
 454
 455     delete $self->{wbuf};
 456     1; # all done
 457 }
 458
 459 sub rbuf_idle ($$) {
 460     my ($self, $rbuf) = @_;
 461     if ($$rbuf eq '') { # who knows how long till we can read again
 462         delete $self->{rbuf};
 463     } else {
 464         $self->{rbuf} = $rbuf;
 465     }
 466 }
 467
 468 sub do_read ($$$;$) {
 469     my ($self, $rbuf, $len, $off) = @_;
 470     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 471     return ($r == 0 ? $self->close : $r) if defined $r;
 472     # common for clients to break connections without warning,
 473     # would be too noisy to log here:
 474     if ($! == EAGAIN) {
 475         epwait($sock, epbit($sock, EPOLLIN) | EPOLLONESHOT);
 476         rbuf_idle($self, $rbuf);
 477         0;
 478     } else {
 479         $self->close;
 480     }
 481 }
 482
 483 # drop the socket if we hit unrecoverable errors on our system which
 484 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 485 sub drop {
 486     my $self = shift;
 487     carp(@_);
 488     $self->close;
 489 }
 490
 491 # n.b.: use ->write/->read for this buffer to allow compatibility with
 492 # PerlIO::mmap or PerlIO::scalar if needed
 493 sub tmpio ($$$) {
 494     my ($self, $bref, $off) = @_;
 495     my $fh = tmpfile('wbuf', $self->{sock}, 1) or
 496         return drop($self, "tmpfile $!");
 497     $fh->autoflush(1);
 498     my $len = bytes::length($$bref) - $off;
 499     $fh->write($$bref, $len, $off) or return drop($self, "write ($len): $!");
 500     $fh
 501 }
 502
 503 =head2 C<< $obj->write( $data ) >>
 504
 505 Write the specified data to the underlying handle.  I<data> may be scalar,
 506 scalar ref, code ref (to run when there).
 507 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 508 it returns 1, caller should stop waiting for 'writable' events)
 509
 510 =cut
 511 sub write {
 512     my ($self, $data) = @_;
 513
 514     # nobody should be writing to closed sockets, but caller code can
 515     # do two writes within an event, have the first fail and
 516     # disconnect the other side (whose destructor then closes the
 517     # calling object, but it's still in a method), and then the
 518     # now-dead object does its second write.  that is this case.  we
 519     # just lie and say it worked.  it'll be dead soon and won't be
 520     # hurt by this lie.
 521     my $sock = $self->{sock} or return 1;
 522     my $ref = ref $data;
 523     my $bref = $ref ? $data : \$data;
 524     my $wbuf = $self->{wbuf};
 525     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 526         if ($ref eq 'CODE') {
 527             push @$wbuf, $bref;
 528         } else {
 529             my $last = $wbuf->[-1];
 530             if (ref($last) eq 'GLOB') { # append to tmp file buffer
 531                 $last->print($$bref) or return drop($self, "print: $!");
 532             } else {
 533                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 534                 push @$wbuf, $tmpio;
 535             }
 536         }
 537         return 0;
 538     } elsif ($ref eq 'CODE') {
 539         $bref->($self);
 540         return 1;
 541     } else {
 542         my $to_write = bytes::length($$bref);
 543         my $written = syswrite($sock, $$bref, $to_write);
 544
 545         if (defined $written) {
 546             return 1 if $written == $to_write;
 547             requeue($self); # runs: event_step -> flush_write
 548         } elsif ($! == EAGAIN) {
 549             epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 550             $written = 0;
 551         } else {
 552             return $self->close;
 553         }
 554
 555         # deal with EAGAIN or partial write:
 556         my $tmpio = tmpio($self, $bref, $written) or return 0;
 557
 558         # wbuf may be an empty array if we're being called inside
 559         # ->flush_write via CODE bref:
 560         push @{$self->{wbuf} ||= []}, $tmpio;
 561         return 0;
 562     }
 563 }
 564
 565 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 566
 567 sub msg_more ($$) {
 568     my $self = $_[0];
 569     my $sock = $self->{sock} or return 1;
 570
 571     if (MSG_MORE && !$self->{wbuf} && ref($sock) ne 'IO::Socket::SSL') {
 572         my $n = send($sock, $_[1], MSG_MORE);
 573         if (defined $n) {
 574             my $nlen = bytes::length($_[1]) - $n;
 575             return 1 if $nlen == 0; # all done!
 576             # queue up the unwritten substring:
 577             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 578             $self->{wbuf} = [ $tmpio ];
 579             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 580             return 0;
 581         }
 582     }
 583
 584     # don't redispatch into NNTPdeflate::write
 585     PublicInbox::DS::write($self, \($_[1]));
 586 }
 587
 588 sub epwait ($$) {
 589     my ($sock, $ev) = @_;
 590     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 591         confess("EPOLL_CTL_MOD $!");
 592 }
 593
 594 # return true if complete, false if incomplete (or failure)
 595 sub accept_tls_step ($) {
 596     my ($self) = @_;
 597     my $sock = $self->{sock} or return;
 598     return 1 if $sock->accept_SSL;
 599     return $self->close if $! != EAGAIN;
 600     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 601     unshift @{$self->{wbuf} ||= []}, \&accept_tls_step;
 602     0;
 603 }
 604
 605 # return true if complete, false if incomplete (or failure)
 606 sub shutdn_tls_step ($) {
 607     my ($self) = @_;
 608     my $sock = $self->{sock} or return;
 609     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 610     return $self->close if $! != EAGAIN;
 611     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 612     unshift @{$self->{wbuf} ||= []}, \&shutdn_tls_step;
 613     0;
 614 }
 615
 616 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 617 # or fork w/o exec, so no inadvertant socket sharing
 618 sub shutdn ($) {
 619     my ($self) = @_;
 620     my $sock = $self->{sock} or return;
 621     if (ref($sock) eq 'IO::Socket::SSL') {
 622         shutdn_tls_step($self);
 623     } else {
 624         $self->close;
 625     }
 626 }
 627
 628 # must be called with eval, PublicInbox::DS may not be loaded (see t/qspawn.t)
 629 sub dwaitpid ($$$) {
 630     my ($pid, $cb, $arg) = @_;
 631     my $chld = $SIG{CHLD};
 632     if (defined($chld) && $chld eq \&enqueue_reap) {
 633         push @$WaitPids, [ $pid, $cb, $arg ];
 634
 635         # We could've just missed our SIGCHLD, cover it, here:
 636         requeue(\&reap_pids);
 637     } else {
 638         die "Not in EventLoop\n";
 639     }
 640 }
 641
 642 package PublicInbox::DS::Timer;
 643 # [$abs_float_firetime, $coderef];
 644 sub cancel {
 645     $_[0][1] = undef;
 646 }
 647
 648 1;
 649
 650 =head1 AUTHORS (Danga::Socket)
 651
 652 Brad Fitzpatrick <brad@danga.com> - author
 653
 654 Michael Granger <ged@danga.com> - docs, testing
 655
 656 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 657
 658 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits