lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the (for now) unmaintained Danga::Socket 1.61.
   7 # Unused features will be removed, and updates will be made to take
   8 # advantage of newer kernels.
   9 #
  10 # API changes to diverge from Danga::Socket will happen to better
  11 # accomodate new features and improve scalability.  Do not expect
  12 # this to be a stable API like Danga::Socket.
  13 # Bugs encountered (and likely fixed) are reported to
  14 # bug-Danga-Socket@rt.cpan.org and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 package PublicInbox::DS;
  17 use strict;
  18 use bytes;
  19 use POSIX qw(WNOHANG);
  20 use IO::Handle qw();
  21 use Fcntl qw(SEEK_SET :DEFAULT);
  22 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  23 use parent qw(Exporter);
  24 our @EXPORT_OK = qw(now msg_more);
  25 use warnings;
  26 use 5.010_001;
  27 use Scalar::Util qw(blessed);
  28
  29 use PublicInbox::Syscall qw(:epoll);
  30 use PublicInbox::Tmpfile;
  31
  32 use fields ('sock',              # underlying socket
  33             'rbuf',              # scalarref, usually undef
  34             'wbuf',              # arrayref of coderefs or GLOB refs
  35             'wbuf_off',  # offset into first element of wbuf to start writing at
  36             );
  37
  38 use Errno  qw(EAGAIN EINVAL);
  39 use Carp   qw(croak confess carp);
  40 require File::Spec;
  41
  42 my $nextq; # queue for next_tick
  43 my $WaitPids; # list of [ pid, callback, callback_arg ]
  44 my $later_queue; # callbacks
  45 my $EXPMAP; # fd -> [ idle_time, $self ]
  46 our $EXPTIME = 180; # 3 minutes
  47 my ($later_timer, $reap_timer, $exp_timer);
  48 our (
  49      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  50      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  51      $_io,                       # IO::Handle for Epoll
  52      @ToClose,                   # sockets to close when event loop is done
  53
  54      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  55
  56      $LoopTimeout,               # timeout of event loop in milliseconds
  57      $DoneInit,                  # if we've done the one-time module init yet
  58      @Timers,                    # timers
  59      $in_loop,
  60      );
  61
  62 Reset();
  63
  64 #####################################################################
  65 ### C L A S S   M E T H O D S
  66 #####################################################################
  67
  68 =head2 C<< CLASS->Reset() >>
  69
  70 Reset all state
  71
  72 =cut
  73 sub Reset {
  74     %DescriptorMap = ();
  75     $nextq = [];
  76     $WaitPids = [];
  77     $later_queue = [];
  78     $EXPMAP = {};
  79     $reap_timer = $later_timer = $exp_timer = undef;
  80     @ToClose = ();
  81     $LoopTimeout = -1;  # no timeout by default
  82     @Timers = ();
  83
  84     $PostLoopCallback = undef;
  85     $DoneInit = 0;
  86
  87     $_io = undef; # closes real $Epoll FD
  88     $Epoll = undef; # may call DSKQXS::DESTROY
  89
  90     *EventLoop = *FirstTimeEventLoop;
  91 }
  92
  93 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  94
  95 Set the loop timeout for the event loop to some value in milliseconds.
  96
  97 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  98 immediately.
  99
 100 =cut
 101 sub SetLoopTimeout {
 102     return $LoopTimeout = $_[1] + 0;
 103 }
 104
 105 =head2 C<< CLASS->AddTimer( $seconds, $coderef ) >>
 106
 107 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 108 are not guaranteed to fire at the exact time you ask for.
 109
 110 Returns a timer object which you can call C<< $timer->cancel >> on if you need to.
 111
 112 =cut
 113 sub AddTimer {
 114     my ($class, $secs, $coderef) = @_;
 115
 116     my $fire_time = now() + $secs;
 117
 118     my $timer = bless [$fire_time, $coderef], "PublicInbox::DS::Timer";
 119
 120     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 121         push @Timers, $timer;
 122         return $timer;
 123     }
 124
 125     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 126     # but it was compared against calendar queues, heaps, naive push/sort,
 127     # and a bunch of other versions, and found to be fastest with a large
 128     # variety of datasets.)
 129     for (my $i = 0; $i < @Timers; $i++) {
 130         if ($Timers[$i][0] > $fire_time) {
 131             splice(@Timers, $i, 0, $timer);
 132             return $timer;
 133         }
 134     }
 135
 136     die "Shouldn't get here.";
 137 }
 138
 139 # keeping this around in case we support other FD types for now,
 140 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 141 sub set_cloexec ($) {
 142     my ($fd) = @_;
 143
 144     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 145     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 146     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 147 }
 148
 149 sub _InitPoller
 150 {
 151     return if $DoneInit;
 152     $DoneInit = 1;
 153
 154     if (PublicInbox::Syscall::epoll_defined())  {
 155         $Epoll = epoll_create();
 156         set_cloexec($Epoll) if (defined($Epoll) && $Epoll >= 0);
 157     } else {
 158         my $cls;
 159         for (qw(DSKQXS DSPoll)) {
 160             $cls = "PublicInbox::$_";
 161             last if eval "require $cls";
 162         }
 163         $cls->import(qw(epoll_ctl epoll_wait));
 164         $Epoll = $cls->new;
 165     }
 166     *EventLoop = *EpollEventLoop;
 167 }
 168
 169 =head2 C<< CLASS->EventLoop() >>
 170
 171 Start processing IO events. In most daemon programs this never exits. See
 172 C<PostLoopCallback> below for how to exit the loop.
 173
 174 =cut
 175 sub FirstTimeEventLoop {
 176     my $class = shift;
 177
 178     _InitPoller();
 179
 180     EventLoop($class);
 181 }
 182
 183 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 184
 185 sub next_tick () {
 186     my $q = $nextq;
 187     $nextq = [];
 188     for (@$q) {
 189         # we avoid "ref" on blessed refs to workaround a Perl 5.16.3 leak:
 190         # https://rt.perl.org/Public/Bug/Display.html?id=114340
 191         if (blessed($_)) {
 192             $_->event_step;
 193         } else {
 194             $_->();
 195         }
 196     }
 197 }
 198
 199 # runs timers and returns milliseconds for next one, or next event loop
 200 sub RunTimers {
 201     next_tick();
 202
 203     return ((@$nextq || @ToClose) ? 0 : $LoopTimeout) unless @Timers;
 204
 205     my $now = now();
 206
 207     # Run expired timers
 208     while (@Timers && $Timers[0][0] <= $now) {
 209         my $to_run = shift(@Timers);
 210         $to_run->[1]->($now) if $to_run->[1];
 211     }
 212
 213     # timers may enqueue into nextq:
 214     return 0 if (@$nextq || @ToClose);
 215
 216     return $LoopTimeout unless @Timers;
 217
 218     # convert time to an even number of milliseconds, adding 1
 219     # extra, otherwise floating point fun can occur and we'll
 220     # call RunTimers like 20-30 times, each returning a timeout
 221     # of 0.0000212 seconds
 222     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 223
 224     # -1 is an infinite timeout, so prefer a real timeout
 225     return $timeout     if $LoopTimeout == -1;
 226
 227     # otherwise pick the lower of our regular timeout and time until
 228     # the next timer
 229     return $LoopTimeout if $LoopTimeout < $timeout;
 230     return $timeout;
 231 }
 232
 233 # We can't use waitpid(-1) safely here since it can hit ``, system(),
 234 # and other things.  So we scan the $WaitPids list, which is hopefully
 235 # not too big.
 236 sub reap_pids {
 237     my $tmp = $WaitPids;
 238     $WaitPids = [];
 239     $reap_timer = undef;
 240     foreach my $ary (@$tmp) {
 241         my ($pid, $cb, $arg) = @$ary;
 242         my $ret = waitpid($pid, WNOHANG);
 243         if ($ret == 0) {
 244             push @$WaitPids, $ary;
 245         } elsif ($cb) {
 246             eval { $cb->($arg, $pid) };
 247         }
 248     }
 249     if (@$WaitPids) {
 250         # we may not be donea, and we may miss our
 251         $reap_timer = AddTimer(undef, 1, \&reap_pids);
 252     }
 253 }
 254
 255 # reentrant SIGCHLD handler (since reap_pids is not reentrant)
 256 sub enqueue_reap ($) { push @$nextq, \&reap_pids };
 257
 258 sub running () { ($SIG{CHLD} // '') eq \&enqueue_reap }
 259
 260 sub EpollEventLoop {
 261     local $in_loop = 1;
 262     do {
 263         my @events;
 264         my $i;
 265         my $timeout = RunTimers();
 266
 267         # get up to 1000 events
 268         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 269         for ($i=0; $i<$evcount; $i++) {
 270             # it's possible epoll_wait returned many events, including some at the end
 271             # that ones in the front triggered unregister-interest actions.  if we
 272             # can't find the %sock entry, it's because we're no longer interested
 273             # in that event.
 274             $DescriptorMap{$events[$i]->[0]}->event_step;
 275         }
 276     } while (PostEventLoop());
 277     _run_later();
 278 }
 279
 280 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 281
 282 Sets post loop callback function.  Pass a subref and it will be
 283 called every time the event loop finishes.
 284
 285 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 286 and it will exit.
 287
 288 The callback function will be passed two parameters: \%DescriptorMap
 289
 290 =cut
 291 sub SetPostLoopCallback {
 292     my ($class, $ref) = @_;
 293
 294     # global callback
 295     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 296 }
 297
 298 # Internal function: run the post-event callback, send read events
 299 # for pushed-back data, and close pending connections.  returns 1
 300 # if event loop should continue, or 0 to shut it all down.
 301 sub PostEventLoop {
 302     # now we can close sockets that wanted to close during our event processing.
 303     # (we didn't want to close them during the loop, as we didn't want fd numbers
 304     #  being reused and confused during the event loop)
 305     delete($DescriptorMap{fileno($_)}) for @ToClose;
 306     @ToClose = (); # let refcounting drop everything all at once
 307
 308     # by default we keep running, unless a postloop callback (either per-object
 309     # or global) cancels it
 310     my $keep_running = 1;
 311
 312     # now we're at the very end, call callback if defined
 313     if (defined $PostLoopCallback) {
 314         $keep_running &&= $PostLoopCallback->(\%DescriptorMap);
 315     }
 316
 317     return $keep_running;
 318 }
 319
 320 #####################################################################
 321 ### PublicInbox::DS-the-object code
 322 #####################################################################
 323
 324 =head2 OBJECT METHODS
 325
 326 =head2 C<< CLASS->new( $socket ) >>
 327
 328 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 329 react to events on it during the C<EventLoop>.
 330
 331 This is normally (always?) called from your subclass via:
 332
 333   $class->SUPER::new($socket);
 334
 335 =cut
 336 sub new {
 337     my ($self, $sock, $ev) = @_;
 338     $self = fields::new($self) unless ref $self;
 339
 340     $self->{sock} = $sock;
 341     my $fd = fileno($sock);
 342
 343     Carp::cluck("undef sock and/or fd in PublicInbox::DS->new.  sock=" . ($sock || "") . ", fd=" . ($fd || ""))
 344         unless $sock && $fd;
 345
 346     _InitPoller();
 347
 348     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 349         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 350             $ev &= ~EPOLLEXCLUSIVE;
 351             goto retry;
 352         }
 353         die "couldn't add epoll watch for $fd: $!\n";
 354     }
 355     Carp::cluck("PublicInbox::DS::new blowing away existing descriptor map for fd=$fd ($DescriptorMap{$fd})")
 356         if $DescriptorMap{$fd};
 357
 358     $DescriptorMap{$fd} = $self;
 359     return $self;
 360 }
 361
 362
 363 #####################################################################
 364 ### I N S T A N C E   M E T H O D S
 365 #####################################################################
 366
 367 sub requeue ($) { push @$nextq, $_[0] }
 368
 369 =head2 C<< $obj->close >>
 370
 371 Close the socket.
 372
 373 =cut
 374 sub close {
 375     my ($self) = @_;
 376     my $sock = delete $self->{sock} or return;
 377
 378     # we need to flush our write buffer, as there may
 379     # be self-referential closures (sub { $client->close })
 380     # preventing the object from being destroyed
 381     delete $self->{wbuf};
 382
 383     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 384     # notifications about it
 385     my $fd = fileno($sock);
 386     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 387         confess("EPOLL_CTL_DEL: $!");
 388
 389     # we explicitly don't delete from DescriptorMap here until we
 390     # actually close the socket, as we might be in the middle of
 391     # processing an epoll_wait/etc that returned hundreds of fds, one
 392     # of which is not yet processed and is what we're closing.  if we
 393     # keep it in DescriptorMap, then the event harnesses can just
 394     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 395     # un-accounted for fd, then it (understandably) freak out a bit
 396     # and emit warnings, thinking their state got off.
 397
 398     # defer closing the actual socket until the event loop is done
 399     # processing this round of events.  (otherwise we might reuse fds)
 400     push @ToClose, $sock;
 401
 402     return 0;
 403 }
 404
 405 # portable, non-thread-safe sendfile emulation (no pread, yet)
 406 sub psendfile ($$$) {
 407     my ($sock, $fh, $off) = @_;
 408
 409     seek($fh, $$off, SEEK_SET) or return;
 410     defined(my $to_write = read($fh, my $buf, 16384)) or return;
 411     my $written = 0;
 412     while ($to_write > 0) {
 413         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 414             $written += $w;
 415             $to_write -= $w;
 416         } else {
 417             return if $written == 0;
 418             last;
 419         }
 420     }
 421     $$off += $written;
 422     $written;
 423 }
 424
 425 sub epbit ($$) { # (sock, default)
 426     ref($_[0]) eq 'IO::Socket::SSL' ? PublicInbox::TLS::epollbit() : $_[1];
 427 }
 428
 429 # returns 1 if done, 0 if incomplete
 430 sub flush_write ($) {
 431     my ($self) = @_;
 432     my $wbuf = $self->{wbuf} or return 1;
 433     my $sock = $self->{sock};
 434
 435 next_buf:
 436     while (my $bref = $wbuf->[0]) {
 437         if (ref($bref) ne 'CODE') {
 438             my $off = delete($self->{wbuf_off}) // 0;
 439             while ($sock) {
 440                 my $w = psendfile($sock, $bref, \$off);
 441                 if (defined $w) {
 442                     if ($w == 0) {
 443                         shift @$wbuf;
 444                         goto next_buf;
 445                     }
 446                 } elsif ($! == EAGAIN) {
 447                     epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 448                     $self->{wbuf_off} = $off;
 449                     return 0;
 450                 } else {
 451                     return $self->close;
 452                 }
 453             }
 454         } else { #($ref eq 'CODE') {
 455             shift @$wbuf;
 456             my $before = scalar(@$wbuf);
 457             $bref->($self);
 458
 459             # bref may be enqueueing more CODE to call (see accept_tls_step)
 460             return 0 if (scalar(@$wbuf) > $before);
 461         }
 462     } # while @$wbuf
 463
 464     delete $self->{wbuf};
 465     1; # all done
 466 }
 467
 468 sub rbuf_idle ($$) {
 469     my ($self, $rbuf) = @_;
 470     if ($$rbuf eq '') { # who knows how long till we can read again
 471         delete $self->{rbuf};
 472     } else {
 473         $self->{rbuf} = $rbuf;
 474     }
 475 }
 476
 477 sub do_read ($$$;$) {
 478     my ($self, $rbuf, $len, $off) = @_;
 479     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 480     return ($r == 0 ? $self->close : $r) if defined $r;
 481     # common for clients to break connections without warning,
 482     # would be too noisy to log here:
 483     if ($! == EAGAIN) {
 484         epwait($sock, epbit($sock, EPOLLIN) | EPOLLONESHOT);
 485         rbuf_idle($self, $rbuf);
 486         0;
 487     } else {
 488         $self->close;
 489     }
 490 }
 491
 492 # drop the socket if we hit unrecoverable errors on our system which
 493 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 494 sub drop {
 495     my $self = shift;
 496     carp(@_);
 497     $self->close;
 498 }
 499
 500 # n.b.: use ->write/->read for this buffer to allow compatibility with
 501 # PerlIO::mmap or PerlIO::scalar if needed
 502 sub tmpio ($$$) {
 503     my ($self, $bref, $off) = @_;
 504     my $fh = tmpfile('wbuf', $self->{sock}, 1) or
 505         return drop($self, "tmpfile $!");
 506     $fh->autoflush(1);
 507     my $len = bytes::length($$bref) - $off;
 508     $fh->write($$bref, $len, $off) or return drop($self, "write ($len): $!");
 509     $fh
 510 }
 511
 512 =head2 C<< $obj->write( $data ) >>
 513
 514 Write the specified data to the underlying handle.  I<data> may be scalar,
 515 scalar ref, code ref (to run when there).
 516 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 517 it returns 1, caller should stop waiting for 'writable' events)
 518
 519 =cut
 520 sub write {
 521     my ($self, $data) = @_;
 522
 523     # nobody should be writing to closed sockets, but caller code can
 524     # do two writes within an event, have the first fail and
 525     # disconnect the other side (whose destructor then closes the
 526     # calling object, but it's still in a method), and then the
 527     # now-dead object does its second write.  that is this case.  we
 528     # just lie and say it worked.  it'll be dead soon and won't be
 529     # hurt by this lie.
 530     my $sock = $self->{sock} or return 1;
 531     my $ref = ref $data;
 532     my $bref = $ref ? $data : \$data;
 533     my $wbuf = $self->{wbuf};
 534     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 535         if ($ref eq 'CODE') {
 536             push @$wbuf, $bref;
 537         } else {
 538             my $last = $wbuf->[-1];
 539             if (ref($last) eq 'GLOB') { # append to tmp file buffer
 540                 $last->print($$bref) or return drop($self, "print: $!");
 541             } else {
 542                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 543                 push @$wbuf, $tmpio;
 544             }
 545         }
 546         return 0;
 547     } elsif ($ref eq 'CODE') {
 548         $bref->($self);
 549         return 1;
 550     } else {
 551         my $to_write = bytes::length($$bref);
 552         my $written = syswrite($sock, $$bref, $to_write);
 553
 554         if (defined $written) {
 555             return 1 if $written == $to_write;
 556             requeue($self); # runs: event_step -> flush_write
 557         } elsif ($! == EAGAIN) {
 558             epwait($sock, epbit($sock, EPOLLOUT) | EPOLLONESHOT);
 559             $written = 0;
 560         } else {
 561             return $self->close;
 562         }
 563
 564         # deal with EAGAIN or partial write:
 565         my $tmpio = tmpio($self, $bref, $written) or return 0;
 566
 567         # wbuf may be an empty array if we're being called inside
 568         # ->flush_write via CODE bref:
 569         push @{$self->{wbuf} ||= []}, $tmpio;
 570         return 0;
 571     }
 572 }
 573
 574 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 575
 576 sub msg_more ($$) {
 577     my $self = $_[0];
 578     my $sock = $self->{sock} or return 1;
 579
 580     if (MSG_MORE && !$self->{wbuf} && ref($sock) ne 'IO::Socket::SSL') {
 581         my $n = send($sock, $_[1], MSG_MORE);
 582         if (defined $n) {
 583             my $nlen = bytes::length($_[1]) - $n;
 584             return 1 if $nlen == 0; # all done!
 585             # queue up the unwritten substring:
 586             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 587             $self->{wbuf} = [ $tmpio ];
 588             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 589             return 0;
 590         }
 591     }
 592
 593     # don't redispatch into NNTPdeflate::write
 594     PublicInbox::DS::write($self, \($_[1]));
 595 }
 596
 597 sub epwait ($$) {
 598     my ($sock, $ev) = @_;
 599     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 600         confess("EPOLL_CTL_MOD $!");
 601 }
 602
 603 # return true if complete, false if incomplete (or failure)
 604 sub accept_tls_step ($) {
 605     my ($self) = @_;
 606     my $sock = $self->{sock} or return;
 607     return 1 if $sock->accept_SSL;
 608     return $self->close if $! != EAGAIN;
 609     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 610     unshift @{$self->{wbuf} ||= []}, \&accept_tls_step;
 611     0;
 612 }
 613
 614 # return true if complete, false if incomplete (or failure)
 615 sub shutdn_tls_step ($) {
 616     my ($self) = @_;
 617     my $sock = $self->{sock} or return;
 618     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 619     return $self->close if $! != EAGAIN;
 620     epwait($sock, PublicInbox::TLS::epollbit() | EPOLLONESHOT);
 621     unshift @{$self->{wbuf} ||= []}, \&shutdn_tls_step;
 622     0;
 623 }
 624
 625 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 626 # or fork w/o exec, so no inadvertant socket sharing
 627 sub shutdn ($) {
 628     my ($self) = @_;
 629     my $sock = $self->{sock} or return;
 630     if (ref($sock) eq 'IO::Socket::SSL') {
 631         shutdn_tls_step($self);
 632     } else {
 633         $self->close;
 634     }
 635 }
 636
 637 # must be called with eval, PublicInbox::DS may not be loaded (see t/qspawn.t)
 638 sub dwaitpid ($$$) {
 639     my ($pid, $cb, $arg) = @_;
 640     if ($in_loop) {
 641         push @$WaitPids, [ $pid, $cb, $arg ];
 642
 643         # We could've just missed our SIGCHLD, cover it, here:
 644         requeue(\&reap_pids);
 645     } else {
 646         die "Not in EventLoop\n";
 647     }
 648 }
 649
 650 sub _run_later () {
 651     my $run = $later_queue;
 652     $later_timer = undef;
 653     $later_queue = [];
 654     $_->() for @$run;
 655 }
 656
 657 sub later ($) {
 658     my ($cb) = @_;
 659     push @$later_queue, $cb;
 660     $later_timer //= AddTimer(undef, 60, \&_run_later);
 661 }
 662
 663 sub expire_old () {
 664     my $now = now();
 665     my $exp = $EXPTIME;
 666     my $old = $now - $exp;
 667     my %new;
 668     while (my ($fd, $v) = each %$EXPMAP) {
 669         my ($idle_time, $ds_obj) = @$v;
 670         if ($idle_time < $old) {
 671             if (!$ds_obj->shutdn) {
 672                 $new{$fd} = $v;
 673             }
 674         } else {
 675             $new{$fd} = $v;
 676         }
 677     }
 678     $EXPMAP = \%new;
 679     $exp_timer = scalar(keys %new) ? later(\&expire_old) : undef;
 680 }
 681
 682 sub update_idle_time {
 683     my ($self) = @_;
 684     my $sock = $self->{sock} or return;
 685     $EXPMAP->{fileno($sock)} = [ now(), $self ];
 686     $exp_timer //= later(\&expire_old);
 687 }
 688
 689 sub not_idle_long {
 690     my ($self, $now) = @_;
 691     my $sock = $self->{sock} or return;
 692     my $ary = $EXPMAP->{fileno($sock)} or return;
 693     my $exp_at = $ary->[0] + $EXPTIME;
 694     $exp_at > $now;
 695 }
 696
 697 package PublicInbox::DS::Timer;
 698 # [$abs_float_firetime, $coderef];
 699 sub cancel {
 700     $_[0][1] = undef;
 701 }
 702
 703 1;
 704
 705 =head1 AUTHORS (Danga::Socket)
 706
 707 Brad Fitzpatrick <brad@danga.com> - author
 708
 709 Michael Granger <ged@danga.com> - docs, testing
 710
 711 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 712
 713 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits