lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the (for now) unmaintained Danga::Socket 1.61.
   7 # Unused features will be removed, and updates will be made to take
   8 # advantage of newer kernels.
   9 #
  10 # API changes to diverge from Danga::Socket will happen to better
  11 # accomodate new features and improve scalability.  Do not expect
  12 # this to be a stable API like Danga::Socket.
  13 # Bugs encountered (and likely fixed) are reported to
  14 # bug-Danga-Socket@rt.cpan.org and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 package PublicInbox::DS;
  17 use strict;
  18 use bytes;
  19 use POSIX ();
  20 use IO::Handle qw();
  21 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD SEEK_SET);
  22 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  23 use parent qw(Exporter);
  24 our @EXPORT_OK = qw(now msg_more write_in_full);
  25 use warnings;
  26
  27 use PublicInbox::Syscall qw(:epoll);
  28
  29 use fields ('sock',              # underlying socket
  30             'wbuf',              # arrayref of coderefs or GLOB refs
  31             'wbuf_off',  # offset into first element of wbuf to start writing at
  32             'event_watch',       # bitmask of events the client is interested in
  33                                  # (EPOLLIN,OUT,etc.)
  34             );
  35
  36 use Errno  qw(EAGAIN EINVAL);
  37 use Carp   qw(croak confess);
  38 use File::Temp qw(tempfile);
  39
  40 our $HAVE_KQUEUE = eval { require IO::KQueue; 1 };
  41
  42 our (
  43      $HaveEpoll,                 # Flag -- is epoll available?  initially undefined.
  44      $HaveKQueue,
  45      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  46      $Epoll,                     # Global epoll fd (for epoll mode only)
  47      $KQueue,                    # Global kqueue fd ref (for kqueue mode only)
  48      $_io,                       # IO::Handle for Epoll
  49      @ToClose,                   # sockets to close when event loop is done
  50
  51      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  52
  53      $LoopTimeout,               # timeout of event loop in milliseconds
  54      $DoneInit,                  # if we've done the one-time module init yet
  55      @Timers,                    # timers
  56      );
  57
  58 Reset();
  59
  60 #####################################################################
  61 ### C L A S S   M E T H O D S
  62 #####################################################################
  63
  64 =head2 C<< CLASS->Reset() >>
  65
  66 Reset all state
  67
  68 =cut
  69 sub Reset {
  70     %DescriptorMap = ();
  71     @ToClose = ();
  72     $LoopTimeout = -1;  # no timeout by default
  73     @Timers = ();
  74
  75     $PostLoopCallback = undef;
  76     $DoneInit = 0;
  77
  78     # NOTE kqueue is close-on-fork, and we don't account for it, yet
  79     # OTOH, we (public-inbox) don't need this sub outside of tests...
  80     POSIX::close($$KQueue) if !$_io && $KQueue && $$KQueue >= 0;
  81     $KQueue = undef;
  82
  83     $_io = undef; # close $Epoll
  84     $Epoll = undef;
  85
  86     *EventLoop = *FirstTimeEventLoop;
  87 }
  88
  89 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  90
  91 Set the loop timeout for the event loop to some value in milliseconds.
  92
  93 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  94 immediately.
  95
  96 =cut
  97 sub SetLoopTimeout {
  98     return $LoopTimeout = $_[1] + 0;
  99 }
 100
 101 =head2 C<< CLASS->AddTimer( $seconds, $coderef ) >>
 102
 103 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 104 are not guaranteed to fire at the exact time you ask for.
 105
 106 Returns a timer object which you can call C<< $timer->cancel >> on if you need to.
 107
 108 =cut
 109 sub AddTimer {
 110     my ($class, $secs, $coderef) = @_;
 111
 112     if (!$secs) {
 113         my $timer = bless([0, $coderef], 'PublicInbox::DS::Timer');
 114         unshift(@Timers, $timer);
 115         return $timer;
 116     }
 117
 118     my $fire_time = now() + $secs;
 119
 120     my $timer = bless [$fire_time, $coderef], "PublicInbox::DS::Timer";
 121
 122     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 123         push @Timers, $timer;
 124         return $timer;
 125     }
 126
 127     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 128     # but it was compared against calendar queues, heaps, naive push/sort,
 129     # and a bunch of other versions, and found to be fastest with a large
 130     # variety of datasets.)
 131     for (my $i = 0; $i < @Timers; $i++) {
 132         if ($Timers[$i][0] > $fire_time) {
 133             splice(@Timers, $i, 0, $timer);
 134             return $timer;
 135         }
 136     }
 137
 138     die "Shouldn't get here.";
 139 }
 140
 141 # keeping this around in case we support other FD types for now,
 142 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 143 sub set_cloexec ($) {
 144     my ($fd) = @_;
 145
 146     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 147     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 148     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 149 }
 150
 151 sub _InitPoller
 152 {
 153     return if $DoneInit;
 154     $DoneInit = 1;
 155
 156     if ($HAVE_KQUEUE) {
 157         $KQueue = IO::KQueue->new();
 158         $HaveKQueue = defined $KQueue;
 159         if ($HaveKQueue) {
 160             *EventLoop = *KQueueEventLoop;
 161         }
 162     }
 163     elsif (PublicInbox::Syscall::epoll_defined()) {
 164         $Epoll = eval { epoll_create(1024); };
 165         $HaveEpoll = defined $Epoll && $Epoll >= 0;
 166         if ($HaveEpoll) {
 167             set_cloexec($Epoll);
 168             *EventLoop = *EpollEventLoop;
 169         }
 170     }
 171
 172     if (!$HaveEpoll && !$HaveKQueue) {
 173         require IO::Poll;
 174         *EventLoop = *PollEventLoop;
 175     }
 176 }
 177
 178 =head2 C<< CLASS->EventLoop() >>
 179
 180 Start processing IO events. In most daemon programs this never exits. See
 181 C<PostLoopCallback> below for how to exit the loop.
 182
 183 =cut
 184 sub FirstTimeEventLoop {
 185     my $class = shift;
 186
 187     _InitPoller();
 188
 189     if ($HaveEpoll) {
 190         EpollEventLoop($class);
 191     } elsif ($HaveKQueue) {
 192         KQueueEventLoop($class);
 193     } else {
 194         PollEventLoop($class);
 195     }
 196 }
 197
 198 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 199
 200 # runs timers and returns milliseconds for next one, or next event loop
 201 sub RunTimers {
 202     return $LoopTimeout unless @Timers;
 203
 204     my $now = now();
 205
 206     # Run expired timers
 207     while (@Timers && $Timers[0][0] <= $now) {
 208         my $to_run = shift(@Timers);
 209         $to_run->[1]->($now) if $to_run->[1];
 210     }
 211
 212     return $LoopTimeout unless @Timers;
 213
 214     # convert time to an even number of milliseconds, adding 1
 215     # extra, otherwise floating point fun can occur and we'll
 216     # call RunTimers like 20-30 times, each returning a timeout
 217     # of 0.0000212 seconds
 218     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 219
 220     # -1 is an infinite timeout, so prefer a real timeout
 221     return $timeout     if $LoopTimeout == -1;
 222
 223     # otherwise pick the lower of our regular timeout and time until
 224     # the next timer
 225     return $LoopTimeout if $LoopTimeout < $timeout;
 226     return $timeout;
 227 }
 228
 229 ### The epoll-based event loop. Gets installed as EventLoop if IO::Epoll loads
 230 ### okay.
 231 sub EpollEventLoop {
 232     my $class = shift;
 233
 234     while (1) {
 235         my @events;
 236         my $i;
 237         my $timeout = RunTimers();
 238
 239         # get up to 1000 events
 240         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 241         for ($i=0; $i<$evcount; $i++) {
 242             # it's possible epoll_wait returned many events, including some at the end
 243             # that ones in the front triggered unregister-interest actions.  if we
 244             # can't find the %sock entry, it's because we're no longer interested
 245             # in that event.
 246             $DescriptorMap{$events[$i]->[0]}->event_step;
 247         }
 248         return unless PostEventLoop();
 249     }
 250     exit 0;
 251 }
 252
 253 ### The fallback IO::Poll-based event loop. Gets installed as EventLoop if
 254 ### IO::Epoll fails to load.
 255 sub PollEventLoop {
 256     my $class = shift;
 257
 258     my PublicInbox::DS $pob;
 259
 260     while (1) {
 261         my $timeout = RunTimers();
 262
 263         # the following sets up @poll as a series of ($poll,$event_mask)
 264         # items, then uses IO::Poll::_poll, implemented in XS, which
 265         # modifies the array in place with the even elements being
 266         # replaced with the event masks that occured.
 267         my @poll;
 268         while ( my ($fd, $sock) = each %DescriptorMap ) {
 269             push @poll, $fd, $sock->{event_watch};
 270         }
 271
 272         # if nothing to poll, either end immediately (if no timeout)
 273         # or just keep calling the callback
 274         unless (@poll) {
 275             select undef, undef, undef, ($timeout / 1000);
 276             return unless PostEventLoop();
 277             next;
 278         }
 279
 280         my $count = IO::Poll::_poll($timeout, @poll);
 281         unless ($count >= 0) {
 282             return unless PostEventLoop();
 283             next;
 284         }
 285
 286         # Fetch handles with read events
 287         while (@poll) {
 288             my ($fd, $state) = splice(@poll, 0, 2);
 289             $DescriptorMap{$fd}->event_step if $state;
 290         }
 291
 292         return unless PostEventLoop();
 293     }
 294
 295     exit 0;
 296 }
 297
 298 ### The kqueue-based event loop. Gets installed as EventLoop if IO::KQueue works
 299 ### okay.
 300 sub KQueueEventLoop {
 301     my $class = shift;
 302
 303     while (1) {
 304         my $timeout = RunTimers();
 305         my @ret = eval { $KQueue->kevent($timeout) };
 306         if (my $err = $@) {
 307             # workaround https://rt.cpan.org/Ticket/Display.html?id=116615
 308             if ($err =~ /Interrupted system call/) {
 309                 @ret = ();
 310             } else {
 311                 die $err;
 312             }
 313         }
 314
 315         foreach my $kev (@ret) {
 316             $DescriptorMap{$kev->[0]}->event_step;
 317         }
 318         return unless PostEventLoop();
 319     }
 320
 321     exit(0);
 322 }
 323
 324 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 325
 326 Sets post loop callback function.  Pass a subref and it will be
 327 called every time the event loop finishes.
 328
 329 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 330 and it will exit.
 331
 332 The callback function will be passed two parameters: \%DescriptorMap
 333
 334 =cut
 335 sub SetPostLoopCallback {
 336     my ($class, $ref) = @_;
 337
 338     # global callback
 339     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 340 }
 341
 342 # Internal function: run the post-event callback, send read events
 343 # for pushed-back data, and close pending connections.  returns 1
 344 # if event loop should continue, or 0 to shut it all down.
 345 sub PostEventLoop {
 346     # now we can close sockets that wanted to close during our event processing.
 347     # (we didn't want to close them during the loop, as we didn't want fd numbers
 348     #  being reused and confused during the event loop)
 349     while (my $sock = shift @ToClose) {
 350         my $fd = fileno($sock);
 351
 352         # close the socket.  (not a PublicInbox::DS close)
 353         $sock->close;
 354
 355         # and now we can finally remove the fd from the map.  see
 356         # comment above in ->close.
 357         delete $DescriptorMap{$fd};
 358     }
 359
 360
 361     # by default we keep running, unless a postloop callback (either per-object
 362     # or global) cancels it
 363     my $keep_running = 1;
 364
 365     # now we're at the very end, call callback if defined
 366     if (defined $PostLoopCallback) {
 367         $keep_running &&= $PostLoopCallback->(\%DescriptorMap);
 368     }
 369
 370     return $keep_running;
 371 }
 372
 373 #####################################################################
 374 ### PublicInbox::DS-the-object code
 375 #####################################################################
 376
 377 =head2 OBJECT METHODS
 378
 379 =head2 C<< CLASS->new( $socket ) >>
 380
 381 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 382 react to events on it during the C<EventLoop>.
 383
 384 This is normally (always?) called from your subclass via:
 385
 386   $class->SUPER::new($socket);
 387
 388 =cut
 389 sub new {
 390     my ($self, $sock, $ev) = @_;
 391     $self = fields::new($self) unless ref $self;
 392
 393     $self->{sock} = $sock;
 394     my $fd = fileno($sock);
 395
 396     Carp::cluck("undef sock and/or fd in PublicInbox::DS->new.  sock=" . ($sock || "") . ", fd=" . ($fd || ""))
 397         unless $sock && $fd;
 398
 399     $self->{event_watch} = $ev;
 400
 401     _InitPoller();
 402
 403     if ($HaveEpoll) {
 404 retry:
 405         if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 406             if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 407                 $self->{event_watch} = ($ev &= ~EPOLLEXCLUSIVE);
 408                 goto retry;
 409             }
 410             die "couldn't add epoll watch for $fd: $!\n";
 411         }
 412     }
 413     elsif ($HaveKQueue) {
 414         my $f = $ev & EPOLLIN ? IO::KQueue::EV_ENABLE()
 415                               : IO::KQueue::EV_DISABLE();
 416         $KQueue->EV_SET($fd, IO::KQueue::EVFILT_READ(),
 417                         IO::KQueue::EV_ADD() | $f);
 418         $f = $ev & EPOLLOUT ? IO::KQueue::EV_ENABLE()
 419                             : IO::KQueue::EV_DISABLE();
 420         $KQueue->EV_SET($fd, IO::KQueue::EVFILT_WRITE(),
 421                         IO::KQueue::EV_ADD() | $f);
 422     }
 423
 424     Carp::cluck("PublicInbox::DS::new blowing away existing descriptor map for fd=$fd ($DescriptorMap{$fd})")
 425         if $DescriptorMap{$fd};
 426
 427     $DescriptorMap{$fd} = $self;
 428     return $self;
 429 }
 430
 431
 432 #####################################################################
 433 ### I N S T A N C E   M E T H O D S
 434 #####################################################################
 435
 436 =head2 C<< $obj->close >>
 437
 438 Close the socket.
 439
 440 =cut
 441 sub close {
 442     my ($self) = @_;
 443     my $sock = delete $self->{sock} or return;
 444
 445     # we need to flush our write buffer, as there may
 446     # be self-referential closures (sub { $client->close })
 447     # preventing the object from being destroyed
 448     delete $self->{wbuf};
 449
 450     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 451     # notifications about it
 452     if ($HaveEpoll) {
 453         my $fd = fileno($sock);
 454         epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 455             confess("EPOLL_CTL_DEL: $!");
 456     }
 457
 458     # we explicitly don't delete from DescriptorMap here until we
 459     # actually close the socket, as we might be in the middle of
 460     # processing an epoll_wait/etc that returned hundreds of fds, one
 461     # of which is not yet processed and is what we're closing.  if we
 462     # keep it in DescriptorMap, then the event harnesses can just
 463     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 464     # un-accounted for fd, then it (understandably) freak out a bit
 465     # and emit warnings, thinking their state got off.
 466
 467     # defer closing the actual socket until the event loop is done
 468     # processing this round of events.  (otherwise we might reuse fds)
 469     push @ToClose, $sock;
 470
 471     return 0;
 472 }
 473
 474 # portable, non-thread-safe sendfile emulation (no pread, yet)
 475 sub psendfile ($$$) {
 476     my ($sock, $fh, $off) = @_;
 477
 478     sysseek($fh, $$off, SEEK_SET) or return;
 479     defined(my $to_write = sysread($fh, my $buf, 16384)) or return;
 480     my $written = 0;
 481     while ($to_write > 0) {
 482         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 483             $written += $w;
 484             $to_write -= $w;
 485         } else {
 486             return if $written == 0;
 487             last;
 488         }
 489     }
 490     $$off += $written;
 491     $written;
 492 }
 493
 494 # returns 1 if done, 0 if incomplete
 495 sub flush_write ($) {
 496     my ($self) = @_;
 497     my $wbuf = $self->{wbuf} or return 1;
 498     my $sock = $self->{sock} or return 1;
 499
 500 next_buf:
 501     while (my $bref = $wbuf->[0]) {
 502         if (ref($bref) ne 'CODE') {
 503             my $off = delete($self->{wbuf_off}) // 0;
 504             while (1) {
 505                 my $w = psendfile($sock, $bref, \$off);
 506                 if (defined $w) {
 507                     if ($w == 0) {
 508                         shift @$wbuf;
 509                         goto next_buf;
 510                     }
 511                 } elsif ($! == EAGAIN) {
 512                     $self->{wbuf_off} = $off;
 513                     watch_write($self, 1);
 514                     return 0;
 515                 } else {
 516                     return $self->close;
 517                 }
 518             }
 519         } else { #($ref eq 'CODE') {
 520             shift @$wbuf;
 521             $bref->();
 522         }
 523     } # while @$wbuf
 524
 525     delete $self->{wbuf};
 526     $self->watch_write(0);
 527     1; # all done
 528 }
 529
 530 sub write_in_full ($$$$) {
 531     my ($fh, $bref, $len, $off) = @_;
 532     my $rv = 0;
 533     while ($len > 0) {
 534         my $w = syswrite($fh, $$bref, $len, $off);
 535         return ($rv ? $rv : $w) unless $w; # undef or 0
 536         $rv += $w;
 537         $len -= $w;
 538         $off += $w;
 539     }
 540     $rv
 541 }
 542
 543 sub tmpbuf ($$) {
 544     my ($bref, $off) = @_;
 545     # open(my $fh, '+>>', undef) doesn't set O_APPEND
 546     my ($fh, $path) = tempfile('wbuf-XXXXXXX', TMPDIR => 1);
 547     open $fh, '+>>', $path or die "open: $!";
 548     unlink $path;
 549     my $to_write = bytes::length($$bref) - $off;
 550     my $w = write_in_full($fh, $bref, $to_write, $off);
 551     die "write_in_full ($to_write): $!" unless defined $w;
 552     $w == $to_write ? $fh : die("short write $w < $to_write");
 553 }
 554
 555 =head2 C<< $obj->write( $data ) >>
 556
 557 Write the specified data to the underlying handle.  I<data> may be scalar,
 558 scalar ref, code ref (to run when there).
 559 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 560 it returns 1, caller should stop waiting for 'writable' events)
 561
 562 =cut
 563 sub write {
 564     my ($self, $data) = @_;
 565
 566     # nobody should be writing to closed sockets, but caller code can
 567     # do two writes within an event, have the first fail and
 568     # disconnect the other side (whose destructor then closes the
 569     # calling object, but it's still in a method), and then the
 570     # now-dead object does its second write.  that is this case.  we
 571     # just lie and say it worked.  it'll be dead soon and won't be
 572     # hurt by this lie.
 573     my $sock = $self->{sock} or return 1;
 574     my $ref = ref $data;
 575     my $bref = $ref ? $data : \$data;
 576     if (my $wbuf = $self->{wbuf}) { # already buffering, can't write more...
 577         if ($ref eq 'CODE') {
 578             push @$wbuf, $bref;
 579         } else {
 580             my $last = $wbuf->[-1];
 581             if (ref($last) eq 'GLOB') { # append to tmp file buffer
 582                 write_in_full($last, $bref, bytes::length($$bref), 0);
 583             } else {
 584                 push @$wbuf, tmpbuf($bref, 0);
 585             }
 586         }
 587         return 0;
 588     } elsif ($ref eq 'CODE') {
 589         $bref->();
 590         return 1;
 591     } else {
 592         my $to_write = bytes::length($$bref);
 593         my $written = syswrite($sock, $$bref, $to_write);
 594
 595         if (defined $written) {
 596             return 1 if $written == $to_write;
 597         } elsif ($! == EAGAIN) {
 598             $written = 0;
 599         } else {
 600             return $self->close;
 601         }
 602         $self->{wbuf} = [ tmpbuf($bref, $written) ];
 603         watch_write($self, 1);
 604         return 0;
 605     }
 606 }
 607
 608 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 609
 610 sub msg_more ($$) {
 611     my $self = $_[0];
 612     my $sock = $self->{sock} or return 1;
 613
 614     if (MSG_MORE && !$self->{wbuf}) {
 615         my $n = send($sock, $_[1], MSG_MORE);
 616         if (defined $n) {
 617             my $nlen = bytes::length($_[1]) - $n;
 618             return 1 if $nlen == 0; # all done!
 619
 620             # queue up the unwritten substring:
 621             $self->{wbuf} = [ tmpbuf(\($_[1]), $n) ];
 622             watch_write($self, 1);
 623             return 0;
 624         }
 625     }
 626     $self->write(\($_[1]));
 627 }
 628
 629 =head2 C<< $obj->watch_read( $boolean ) >>
 630
 631 Turn 'readable' event notification on or off.
 632
 633 =cut
 634 sub watch_read {
 635     my PublicInbox::DS $self = shift;
 636     my $sock = $self->{sock} or return;
 637
 638     my $val = shift;
 639     my $event = $self->{event_watch};
 640
 641     $event &= ~EPOLLIN if ! $val;
 642     $event |=  EPOLLIN if   $val;
 643
 644     my $fd = fileno($sock);
 645     # If it changed, set it
 646     if ($event != $self->{event_watch}) {
 647         if ($HaveKQueue) {
 648             $KQueue->EV_SET($fd, IO::KQueue::EVFILT_READ(),
 649                             $val ? IO::KQueue::EV_ENABLE() : IO::KQueue::EV_DISABLE());
 650         }
 651         elsif ($HaveEpoll) {
 652             epoll_ctl($Epoll, EPOLL_CTL_MOD, $fd, $event) and
 653                 confess("EPOLL_CTL_MOD: $!");
 654         }
 655         $self->{event_watch} = $event;
 656     }
 657 }
 658
 659 =head2 C<< $obj->watch_write( $boolean ) >>
 660
 661 Turn 'writable' event notification on or off.
 662
 663 =cut
 664 sub watch_write {
 665     my PublicInbox::DS $self = shift;
 666     my $sock = $self->{sock} or return;
 667
 668     my $val = shift;
 669     my $event = $self->{event_watch};
 670
 671     $event &= ~EPOLLOUT if ! $val;
 672     $event |=  EPOLLOUT if   $val;
 673     my $fd = fileno($sock);
 674
 675     # If it changed, set it
 676     if ($event != $self->{event_watch}) {
 677         if ($HaveKQueue) {
 678             $KQueue->EV_SET($fd, IO::KQueue::EVFILT_WRITE(),
 679                             $val ? IO::KQueue::EV_ENABLE() : IO::KQueue::EV_DISABLE());
 680         }
 681         elsif ($HaveEpoll) {
 682             epoll_ctl($Epoll, EPOLL_CTL_MOD, $fd, $event) and
 683                     confess "EPOLL_CTL_MOD: $!";
 684         }
 685         $self->{event_watch} = $event;
 686     }
 687 }
 688
 689 package PublicInbox::DS::Timer;
 690 # [$abs_float_firetime, $coderef];
 691 sub cancel {
 692     $_[0][1] = undef;
 693 }
 694
 695 1;
 696
 697 =head1 AUTHORS (Danga::Socket)
 698
 699 Brad Fitzpatrick <brad@danga.com> - author
 700
 701 Michael Granger <ged@danga.com> - docs, testing
 702
 703 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 704
 705 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits