lib/PublicInbox/DSKQXS.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # Licensed the same as Danga::Socket (and Perl5)
   3 # License: GPL-1.0+ or Artistic-1.0-Perl
   4 #  <https://www.gnu.org/licenses/gpl-1.0.txt>
   5 #  <https://dev.perl.org/licenses/artistic.html>
   6 #
   7 # kqueue support via IO::KQueue XS module.  This makes kqueue look
   8 # like epoll to simplify the code in DS.pm.  This is NOT meant to be
   9 # an all encompassing emulation of epoll via IO::KQueue, but just to
  10 # support cases public-inbox-nntpd/httpd care about.
  11 # A pure-Perl version using syscall() is planned, and it should be
  12 # faster due to the lack of syscall overhead.
  13 package PublicInbox::DSKQXS;
  14 use strict;
  15 use warnings;
  16 use parent qw(IO::KQueue);
  17 use parent qw(Exporter);
  18 use IO::KQueue;
  19 use PublicInbox::Syscall qw(EPOLLONESHOT EPOLLIN EPOLLOUT EPOLLET
  20         EPOLL_CTL_ADD EPOLL_CTL_MOD EPOLL_CTL_DEL);
  21 our @EXPORT_OK = qw(epoll_ctl epoll_wait);
  22 my $owner_pid = -1; # kqueue is close-on-fork (yes, fork, not exec)
  23
  24 sub EV_DISPATCH () { 0x0080 }
  25
  26 # map EPOLL* bits to kqueue EV_* flags for EV_SET
  27 sub kq_flag ($$) {
  28         my ($bit, $ev) = @_;
  29         if ($ev & $bit) {
  30                 my $fl = EV_ENABLE;
  31                 $fl |= EV_CLEAR if $fl & EPOLLET;
  32
  33                 # EV_DISPATCH matches EPOLLONESHOT semantics more closely
  34                 # than EV_ONESHOT, in that EV_ADD is not required to
  35                 # re-enable a disabled watch.
  36                 ($ev & EPOLLONESHOT) ? ($fl | EV_DISPATCH) : $fl;
  37         } else {
  38                 EV_DISABLE;
  39         }
  40 }
  41
  42 sub new {
  43         my ($class) = @_;
  44         die 'non-singleton use not supported' if $owner_pid == $$;
  45         $owner_pid = $$;
  46         $class->SUPER::new;
  47 }
  48
  49 sub epoll_ctl {
  50         my ($self, $op, $fd, $ev) = @_;
  51         if ($op == EPOLL_CTL_MOD) {
  52                 $self->EV_SET($fd, EVFILT_READ, kq_flag(EPOLLIN, $ev));
  53                 $self->EV_SET($fd, EVFILT_WRITE, kq_flag(EPOLLOUT, $ev));
  54         } elsif ($op == EPOLL_CTL_DEL) {
  55                 $self->EV_SET($fd, EVFILT_READ, EV_DISABLE);
  56                 $self->EV_SET($fd, EVFILT_WRITE, EV_DISABLE);
  57         } else {
  58                 $self->EV_SET($fd, EVFILT_READ, EV_ADD|kq_flag(EPOLLIN, $ev));
  59                 $self->EV_SET($fd, EVFILT_WRITE, EV_ADD|kq_flag(EPOLLOUT, $ev));
  60         }
  61         0;
  62 }
  63
  64 sub epoll_wait {
  65         my ($self, $maxevents, $timeout_msec, $events) = @_;
  66         @$events = eval { $self->kevent($timeout_msec) };
  67         if (my $err = $@) {
  68                 # workaround https://rt.cpan.org/Ticket/Display.html?id=116615
  69                 if ($err =~ /Interrupted system call/) {
  70                         @$events = ();
  71                 } else {
  72                         die $err;
  73                 }
  74         }
  75         # caller only cares for $events[$i]->[0]
  76         scalar(@$events);
  77 }
  78
  79 sub DESTROY {
  80         my ($self) = @_;
  81         if ($owner_pid == $$) {
  82                 POSIX::close($$self);
  83                 $owner_pid = -1;
  84         }
  85 }
  86
  87 1;