lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use POSIX qw(WNOHANG :signal_h);
  14 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Listener;
  19 use PublicInbox::EOFpipe;
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::Git;
  22 use PublicInbox::GitAsyncCat;
  23 use PublicInbox::Eml;
  24 our $SO_ACCEPTFILTER = 0x1000;
  25 my @CMD;
  26 my ($set_user, $oldset);
  27 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  28 my $worker_processes = 1;
  29 my @listeners;
  30 my %pids;
  31 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  32 my $reexec_pid;
  33 my ($uid, $gid);
  34 my ($default_cert, $default_key);
  35 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps', 993 => 'imaps' );
  36 my %KNOWN_STARTTLS = ( 119 => 'nntp', 143 => 'imap' );
  37
  38 sub accept_tls_opt ($) {
  39         my ($opt_str) = @_;
  40         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  41         require PublicInbox::TLS;
  42         my $o = {};
  43         # allow ',' as delimiter since '&' is shell-unfriendly
  44         foreach (split(/[,&]/, $opt_str)) {
  45                 my ($k, $v) = split(/=/, $_, 2);
  46                 push @{$o->{$k} ||= []}, $v;
  47         }
  48
  49         # key may be a part of cert.  At least
  50         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  51         $o->{cert} //= [ $default_cert ];
  52         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  53         my %ctx_opt = (SSL_server => 1);
  54         # parse out hostname:/path/to/ mappings:
  55         foreach my $k (qw(cert key)) {
  56                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  57                 foreach my $path (@{$o->{$k}}) {
  58                         my $host = '';
  59                         $path =~ s/\A([^:]+):// and $host = $1;
  60                         $x->{$host} = $path;
  61                 }
  62         }
  63         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  64                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  65
  66         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  67         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  68         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  69         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  70         if ($mode && $ctx->{context}) {
  71                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  72                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  73         }
  74
  75         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  76 }
  77
  78 sub load_mod ($) {
  79         my ($scheme) = @_;
  80         my $modc = "PublicInbox::\U$1";
  81         my $mod = $modc.'D';
  82         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
  83         die $@ if $@;
  84         my %xn = map { $_ => $mod->can($_) } qw(refresh post_accept);
  85         $xn{tlsd} = $mod->new if $mod->can('refresh_groups'); #!HTTPD
  86         my $tlsd = $xn{tlsd};
  87         $xn{refresh} //= sub { $tlsd->refresh_groups(@_) };
  88         $xn{post_accept} //= sub { $modc->new($_[0], $tlsd) };
  89         $xn{af_default} = 'httpready' if $modc eq 'PublicInbox::HTTP';
  90         \%xn;
  91 }
  92
  93 sub daemon_prepare ($$) {
  94         my ($default_listen, $xnetd) = @_;
  95         my $listener_names = {}; # sockname => IO::Handle
  96         $oldset = PublicInbox::DS::block_signals();
  97         @CMD = ($0, @ARGV);
  98         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  99         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 100         my $help = <<EOF;
 101 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 102
 103 options:
 104
 105   -l ADDRESS    address to listen on$dh
 106   --cert=FILE   default SSL/TLS certificate
 107   --key=FILE    default SSL/TLS certificate
 108   -W WORKERS    number of worker processes to spawn (default: 1)
 109
 110 See public-inbox-daemon(8) and $prog(1) man pages for more.
 111 EOF
 112         my %opt = (
 113                 'l|listen=s' => \@cfg_listen,
 114                 '1|stdout=s' => \$stdout,
 115                 '2|stderr=s' => \$stderr,
 116                 'W|worker-processes=i' => \$worker_processes,
 117                 'P|pid-file=s' => \$pid_file,
 118                 'u|user=s' => \$user,
 119                 'g|group=s' => \$group,
 120                 'D|daemonize' => \$daemonize,
 121                 'cert=s' => \$default_cert,
 122                 'key=s' => \$default_key,
 123                 'help|h' => \(my $show_help),
 124         );
 125         GetOptions(%opt) or die $help;
 126         if ($show_help) { print $help; exit 0 };
 127
 128         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 129                 die "--pid-file cannot end with '.oldbin'\n";
 130         }
 131         @listeners = inherit($listener_names);
 132
 133         # allow socket-activation users to set certs once and not
 134         # have to configure each socket:
 135         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 136
 137         # ignore daemonize when inheriting
 138         $daemonize = undef if scalar @listeners;
 139
 140         unless (@listeners || @cfg_listen) {
 141                 $default_listen // die "no listeners specified\n";
 142                 push @cfg_listen, $default_listen
 143         }
 144
 145         foreach my $l (@cfg_listen) {
 146                 my $orig = $l;
 147                 my $scheme = '';
 148                 if ($l =~ s!\A([^:]+)://!!) {
 149                         $scheme = $1;
 150                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 151                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 152                         $scheme = $s if defined $s;
 153                 }
 154                 if ($l =~ s!/?\?(.+)\z!!) {
 155                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 156                 } elsif (defined($default_cert)) {
 157                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 158                 } elsif ($scheme =~ /\A(?:https|imaps|imaps)\z/) {
 159                         die "$orig specified w/o cert=\n";
 160                 }
 161                 $scheme =~ /\A(http|imap|nntp|pop3)/ and
 162                         $xnetd->{$l} = load_mod($1);
 163
 164                 next if $listener_names->{$l}; # already inherited
 165                 my (%o, $sock_pkg);
 166                 if (index($l, '/') == 0) {
 167                         $sock_pkg = 'IO::Socket::UNIX';
 168                         eval "use $sock_pkg";
 169                         die $@ if $@;
 170                         %o = (Type => SOCK_STREAM, Peer => $l);
 171                         if (-S $l) {
 172                                 my $c = $sock_pkg->new(%o);
 173                                 if (!defined($c) && $!{ECONNREFUSED}) {
 174                                         unlink $l or die
 175 "failed to unlink stale socket=$l: $!\n";
 176                                 } # else: let the bind fail
 177                         }
 178                         $o{Local} = delete $o{Peer};
 179                 } else {
 180                         # both work for IPv4, too
 181                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 182                                 $sock_pkg = $_;
 183                                 eval "use $sock_pkg";
 184                                 $@ or last;
 185                         }
 186                         die $@ if $@;
 187                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 188                 }
 189                 $o{Listen} = 1024;
 190                 my $prev = umask 0000;
 191                 my $s = eval { $sock_pkg->new(%o) };
 192                 warn "error binding $l: $! ($@)\n" unless $s;
 193                 umask $prev;
 194                 if ($s) {
 195                         $listener_names->{sockname($s)} = $s;
 196                         $s->blocking(0);
 197                         push @listeners, $s;
 198                 }
 199         }
 200
 201         # cert/key options in @cfg_listen takes precedence when inheriting,
 202         # but map well-known inherited ports if --listen isn't specified
 203         # at all
 204         for my $sockname (@inherited_names) {
 205                 $sockname =~ /:([0-9]+)\z/ or next;
 206                 if (my $scheme = $KNOWN_TLS{$1}) {
 207                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 208                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 209                         next if $tls_opt{"$scheme://$sockname"};
 210                         $tls_opt{''} ||= accept_tls_opt('');
 211                 }
 212         }
 213
 214         die "No listeners bound\n" unless @listeners;
 215 }
 216
 217 sub check_absolute ($$) {
 218         my ($var, $val) = @_;
 219         if (defined $val && index($val, '/') != 0) {
 220                 die
 221 "--$var must be an absolute path when using --daemonize: $val\n";
 222         }
 223 }
 224
 225 sub daemonize () {
 226         if ($daemonize) {
 227                 require Cwd;
 228                 foreach my $i (0..$#ARGV) {
 229                         my $arg = $ARGV[$i];
 230                         next unless -e $arg;
 231                         $ARGV[$i] = Cwd::abs_path($arg);
 232                 }
 233                 check_absolute('stdout', $stdout);
 234                 check_absolute('stderr', $stderr);
 235                 check_absolute('pid-file', $pid_file);
 236
 237                 chdir '/' or die "chdir failed: $!";
 238         }
 239         if (defined($pid_file) || defined($group) || defined($user)) {
 240                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 241 Net::Server required for --pid-file, --group, --user
 242 $@
 243 EOF
 244         }
 245         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 246         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 247         if (defined $group) {
 248                 $gid = Net::Server::Daemonize::get_gid($group);
 249                 $gid = (split /\s+/, $gid)[0];
 250         } elsif (defined $uid) {
 251                 $gid = (getpwuid($uid))[3];
 252         }
 253
 254         # We change users in the worker to ensure upgradability,
 255         # The upgrade will create the ".oldbin" pid file in the
 256         # same directory as the given pid file.
 257         $uid and $set_user = sub {
 258                 $set_user = undef;
 259                 Net::Server::Daemonize::set_user($uid, $gid);
 260         };
 261
 262         if ($daemonize) {
 263                 my $pid = fork // die "fork: $!";
 264                 exit if $pid;
 265
 266                 open(STDIN, '+<', '/dev/null') or
 267                                         die "redirect stdin failed: $!\n";
 268                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 269                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 270                 POSIX::setsid();
 271                 $pid = fork // die "fork: $!";
 272                 exit if $pid;
 273         }
 274         return unless defined $pid_file;
 275
 276         write_pid($pid_file);
 277         # for ->DESTROY:
 278         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 279 }
 280
 281 sub worker_quit { # $_[0] = signal name or number (unused)
 282         # killing again terminates immediately:
 283         exit unless @listeners;
 284
 285         $_->close foreach @listeners; # call PublicInbox::DS::close
 286         @listeners = ();
 287         my $proc_name;
 288         my $warn = 0;
 289         # drop idle connections and try to quit gracefully
 290         PublicInbox::DS->SetPostLoopCallback(sub {
 291                 my ($dmap, undef) = @_;
 292                 my $n = 0;
 293                 my $now = now();
 294                 for my $s (values %$dmap) {
 295                         $s->can('busy') or next;
 296                         if ($s->busy) {
 297                                 ++$n;
 298                         } else { # close as much as possible, early as possible
 299                                 $s->close;
 300                         }
 301                 }
 302                 if ($n) {
 303                         if (($warn + 5) < now()) {
 304                                 warn "$$ quitting, $n client(s) left\n";
 305                                 $warn = now();
 306                         }
 307                         unless (defined $proc_name) {
 308                                 $proc_name = (split(/\s+/, $0))[0];
 309                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 310                         }
 311                         $0 = "$proc_name quitting, $n client(s) left";
 312                 }
 313                 $n; # true: loop continues, false: loop breaks
 314         });
 315 }
 316
 317 sub reopen_logs {
 318         if ($stdout) {
 319                 open STDOUT, '>>', $stdout or
 320                         warn "failed to redirect stdout to $stdout: $!\n";
 321                 STDOUT->autoflush(1);
 322                 do_chown($stdout);
 323         }
 324         if ($stderr) {
 325                 open STDERR, '>>', $stderr or
 326                         warn "failed to redirect stderr to $stderr: $!\n";
 327                 STDERR->autoflush(1);
 328                 do_chown($stderr);
 329         }
 330 }
 331
 332 sub sockname ($) {
 333         my ($s) = @_;
 334         my $addr = getsockname($s) or return;
 335         my ($host, $port) = host_with_port($addr);
 336         if ($port == 0 && $host eq '127.0.0.1') {
 337                 my ($path) = Socket::sockaddr_un($addr);
 338                 return $path;
 339         }
 340         "$host:$port";
 341 }
 342
 343 sub unpack_ipv6 ($) {
 344         my ($addr) = @_;
 345         my ($port, $host);
 346
 347         # Socket.pm in Perl 5.14+ supports IPv6:
 348         eval {
 349                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 350                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 351         };
 352
 353         if ($@) {
 354                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 355                 # Socket6, so it may be installed on our system, already
 356                 # (otherwise die here):
 357                 require Socket6;
 358
 359                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 360                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 361         }
 362         ($host, $port);
 363 }
 364
 365 sub host_with_port ($) {
 366         my ($addr) = @_;
 367         my ($port, $host);
 368
 369         # this eval will die on Unix sockets:
 370         eval {
 371                 if (length($addr) >= 28) {
 372                         ($host, $port) = unpack_ipv6($addr);
 373                         $host = "[$host]";
 374                 } else {
 375                         ($port, $host) = Socket::sockaddr_in($addr);
 376                         $host = Socket::inet_ntoa($host);
 377                 }
 378         };
 379         $@ ? ('127.0.0.1', 0) : ($host, $port);
 380 }
 381
 382 sub inherit ($) {
 383         my ($listener_names) = @_;
 384         return () if ($ENV{LISTEN_PID} || 0) != $$;
 385         my $fds = $ENV{LISTEN_FDS} or return ();
 386         my $end = $fds + 2; # LISTEN_FDS_START - 1
 387         my @rv = ();
 388         foreach my $fd (3..$end) {
 389                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 390                 if (my $k = sockname($s)) {
 391                         my $prev_was_blocking = $s->blocking(0);
 392                         warn <<"" if $prev_was_blocking;
 393 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 394 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 395 processes when multiple service instances start.
 396
 397                         $listener_names->{$k} = $s;
 398                         push @rv, $s;
 399                 } else {
 400                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 401                 }
 402         }
 403         @rv
 404 }
 405
 406 sub upgrade { # $_[0] = signal name or number (unused)
 407         if ($reexec_pid) {
 408                 warn "upgrade in-progress: $reexec_pid\n";
 409                 return;
 410         }
 411         if (defined $pid_file) {
 412                 if ($pid_file =~ /\.oldbin\z/) {
 413                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 414                         return;
 415                 }
 416                 unlink_pid_file_safe_ish($$, $pid_file);
 417                 $pid_file .= '.oldbin';
 418                 write_pid($pid_file);
 419         }
 420         my $pid = fork;
 421         unless (defined $pid) {
 422                 warn "fork failed: $!\n";
 423                 return;
 424         }
 425         if ($pid == 0) {
 426                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 427                 $ENV{LISTEN_FDS} = scalar @listeners;
 428                 $ENV{LISTEN_PID} = $$;
 429                 foreach my $s (@listeners) {
 430                         # @listeners are globs with workers, PI::L w/o workers
 431                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 432
 433                         my $fl = fcntl($s, F_GETFD, 0);
 434                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 435                 }
 436                 exec @CMD;
 437                 die "Failed to exec: $!\n";
 438         }
 439         $reexec_pid = $pid;
 440 }
 441
 442 sub kill_workers ($) {
 443         my ($sig) = @_;
 444         kill $sig, keys(%pids);
 445 }
 446
 447 sub upgrade_aborted ($) {
 448         my ($p) = @_;
 449         warn "reexec PID($p) died with: $?\n";
 450         $reexec_pid = undef;
 451         return unless $pid_file;
 452
 453         my $file = $pid_file;
 454         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 455         unlink_pid_file_safe_ish($$, $pid_file);
 456         $pid_file = $file;
 457         eval { write_pid($pid_file) };
 458         warn $@, "\n" if $@;
 459 }
 460
 461 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 462         while (1) {
 463                 my $p = waitpid(-1, WNOHANG) or return;
 464                 if (defined $reexec_pid && $p == $reexec_pid) {
 465                         upgrade_aborted($p);
 466                 } elsif (defined(my $id = delete $pids{$p})) {
 467                         warn "worker[$id] PID($p) died with: $?\n";
 468                 } elsif ($p > 0) {
 469                         warn "unknown PID($p) reaped: $?\n";
 470                 } else {
 471                         return;
 472                 }
 473         }
 474 }
 475
 476 sub unlink_pid_file_safe_ish ($$) {
 477         my ($unlink_pid, $file) = @_;
 478         return unless defined $unlink_pid && $unlink_pid == $$;
 479
 480         open my $fh, '<', $file or return;
 481         local $/ = "\n";
 482         defined(my $read_pid = <$fh>) or return;
 483         chomp $read_pid;
 484         if ($read_pid == $unlink_pid) {
 485                 Net::Server::Daemonize::unlink_pid_file($file);
 486         }
 487 }
 488
 489 sub master_quit ($) {
 490         exit unless @listeners;
 491         @listeners = ();
 492         kill_workers($_[0]);
 493 }
 494
 495 sub master_loop {
 496         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 497         my $set_workers = $worker_processes;
 498         reopen_logs();
 499         my $ignore_winch;
 500         my $sig = {
 501                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 502                 USR2 => \&upgrade,
 503                 QUIT => \&master_quit,
 504                 INT => \&master_quit,
 505                 TERM => \&master_quit,
 506                 WINCH => sub {
 507                         return if $ignore_winch || !@listeners;
 508                         if (-t STDIN || -t STDOUT || -t STDERR) {
 509                                 $ignore_winch = 1;
 510                                 warn <<EOF;
 511 ignoring SIGWINCH since we are not daemonized
 512 EOF
 513                         } else {
 514                                 $worker_processes = 0;
 515                         }
 516                 },
 517                 HUP => sub {
 518                         return unless @listeners;
 519                         $worker_processes = $set_workers;
 520                         kill_workers($_[0]);
 521                 },
 522                 TTIN => sub {
 523                         return unless @listeners;
 524                         if ($set_workers > $worker_processes) {
 525                                 ++$worker_processes;
 526                         } else {
 527                                 $worker_processes = ++$set_workers;
 528                         }
 529                 },
 530                 TTOU => sub {
 531                         $worker_processes = --$set_workers if $set_workers > 0;
 532                 },
 533                 CHLD => \&reap_children,
 534         };
 535         my $sigfd = PublicInbox::Sigfd->new($sig);
 536         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 537         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 538         while (1) { # main loop
 539                 my $n = scalar keys %pids;
 540                 unless (@listeners) {
 541                         exit if $n == 0;
 542                         $set_workers = $worker_processes = $n = 0;
 543                 }
 544
 545                 if ($n > $worker_processes) {
 546                         while (my ($k, $v) = each %pids) {
 547                                 kill('TERM', $k) if $v >= $worker_processes;
 548                         }
 549                         $n = $worker_processes;
 550                 }
 551                 my $want = $worker_processes - 1;
 552                 if ($n <= $want) {
 553                         PublicInbox::DS::block_signals() if !$sigfd;
 554                         for my $i ($n..$want) {
 555                                 my $seed = rand(0xffffffff);
 556                                 my $pid = fork;
 557                                 if (!defined $pid) {
 558                                         warn "failed to fork worker[$i]: $!\n";
 559                                 } elsif ($pid == 0) {
 560                                         srand($seed);
 561                                         eval { Net::SSLeay::randomize() };
 562                                         $set_user->() if $set_user;
 563                                         return $p0; # run normal work code
 564                                 } else {
 565                                         warn "PID=$pid is worker[$i]\n";
 566                                         $pids{$pid} = $i;
 567                                 }
 568                         }
 569                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 570                 }
 571
 572                 if ($sigfd) { # Linux and IO::KQueue users:
 573                         $sigfd->wait_once;
 574                 } else { # wake up every second
 575                         sleep(1);
 576                 }
 577         }
 578         exit # never gets here, just for documentation
 579 }
 580
 581 sub tls_start_cb ($$) {
 582         my ($opt, $orig_post_accept) = @_;
 583         sub {
 584                 my ($io, $addr, $srv) = @_;
 585                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 586                 $orig_post_accept->($ssl, $addr, $srv);
 587         }
 588 }
 589
 590 sub defer_accept ($$) {
 591         my ($s, $af_name) = @_;
 592         return unless defined $af_name;
 593         if ($^O eq 'linux') {
 594                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 595                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 596                 return unless defined $x; # may be Unix socket
 597                 my $sec = unpack('i', $x);
 598                 return if $sec > 0; # systemd users may set a higher value
 599                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 600         } elsif ($^O eq 'freebsd') {
 601                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 602                 return if defined $x; # don't change if set
 603                 my $accf_arg = pack('a16a240', $af_name, '');
 604                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 605         }
 606 }
 607
 608 sub daemon_loop ($) {
 609         my ($xnetd) = @_;
 610         my $refresh = sub {
 611                 my ($sig) = @_;
 612                 for my $xn (values %$xnetd) {
 613                         eval { $xn->{refresh}->($sig) };
 614                         warn "refresh $@\n" if $@;
 615                 }
 616         };
 617         my %post_accept;
 618         while (my ($k, $v) = each %tls_opt) {
 619                 my $l = $k;
 620                 $l =~ s!\A([^:]+)://!!;
 621                 my $scheme = $1;
 622                 my $xn = $xnetd->{$l} // $xnetd->{''};
 623                 if ($scheme =~ s!\A(?:https|imaps|nntps)!!) {
 624                         $post_accept{$l} = tls_start_cb($v, $xn->{post_accept});
 625                 } elsif ($xn->{tlsd}) { # STARTTLS, $k eq '' is OK
 626                         $xn->{tlsd}->{accept_tls} = $v;
 627                 }
 628         }
 629         my $sig = {
 630                 HUP => $refresh,
 631                 INT => \&worker_quit,
 632                 QUIT => \&worker_quit,
 633                 TERM => \&worker_quit,
 634                 TTIN => 'IGNORE',
 635                 TTOU => 'IGNORE',
 636                 USR1 => \&reopen_logs,
 637                 USR2 => 'IGNORE',
 638                 WINCH => 'IGNORE',
 639                 CHLD => \&PublicInbox::DS::enqueue_reap,
 640         };
 641         if ($worker_processes > 0) {
 642                 $refresh->(); # preload by default
 643                 my $fh = master_loop(); # returns if in child process
 644                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 645         } else {
 646                 reopen_logs();
 647                 $set_user->() if $set_user;
 648                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 649                 $refresh->();
 650         }
 651         $uid = $gid = undef;
 652         reopen_logs();
 653         @listeners = map {;
 654                 my $l = sockname($_);
 655                 my $tls_cb = $post_accept{$l};
 656                 my $xn = $xnetd->{$l} // $xnetd->{''};
 657
 658                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 659                 # IMAP, NNTP and POP3 are server-first
 660                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 661
 662                 # this calls epoll_create:
 663                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 664         } @listeners;
 665         PublicInbox::DS::event_loop($sig, $oldset);
 666 }
 667
 668 sub run {
 669         my ($default_listen) = @_;
 670         my $xnetd = {};
 671         if ($default_listen) {
 672                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 673                         die "BUG: $default_listen";
 674                 $xnetd->{''} = load_mod($1);
 675         }
 676         daemon_prepare($default_listen, $xnetd);
 677         my $for_destroy = daemonize();
 678
 679         # localize GCF2C for tests:
 680         local $PublicInbox::GitAsyncCat::GCF2C;
 681         local $PublicInbox::Git::async_warn = 1;
 682         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 683
 684         daemon_loop($xnetd);
 685         PublicInbox::DS->Reset;
 686         # ->DESTROY runs when $for_destroy goes out-of-scope
 687 }
 688
 689 sub do_chown ($) {
 690         my ($path) = @_;
 691         if (defined $uid and !chown($uid, $gid, $path)) {
 692                 warn "could not chown $path: $!\n";
 693         }
 694 }
 695
 696 sub write_pid ($) {
 697         my ($path) = @_;
 698         Net::Server::Daemonize::create_pid_file($path);
 699         do_chown($path);
 700 }
 701
 702 sub DESTROY {
 703         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 704 }
 705
 706 1;