lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the httpd, imapd, and nntpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle; # ->autoflush
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 use Cwd qw/abs_path/;
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Syscall qw($SFD_NONBLOCK);
  19 require PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::GitAsyncCat;
  23 my @CMD;
  24 my ($set_user, $oldset);
  25 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  26 my $worker_processes = 1;
  27 my @listeners;
  28 my %pids;
  29 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  30 my $reexec_pid;
  31 my ($uid, $gid);
  32 my ($default_cert, $default_key);
  33 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps', 993 => 'imaps' );
  34 my %KNOWN_STARTTLS = ( 119 => 'nntp', 143 => 'imap' );
  35
  36 sub accept_tls_opt ($) {
  37         my ($opt_str) = @_;
  38         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  39         require PublicInbox::TLS;
  40         my $o = {};
  41         # allow ',' as delimiter since '&' is shell-unfriendly
  42         foreach (split(/[,&]/, $opt_str)) {
  43                 my ($k, $v) = split(/=/, $_, 2);
  44                 push @{$o->{$k} ||= []}, $v;
  45         }
  46
  47         # key may be a part of cert.  At least
  48         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  49         $o->{cert} //= [ $default_cert ];
  50         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  51         my %ctx_opt = (SSL_server => 1);
  52         # parse out hostname:/path/to/ mappings:
  53         foreach my $k (qw(cert key)) {
  54                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  55                 foreach my $path (@{$o->{$k}}) {
  56                         my $host = '';
  57                         $path =~ s/\A([^:]+):// and $host = $1;
  58                         $x->{$host} = $path;
  59                 }
  60         }
  61         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  62                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  63
  64         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  65         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  66         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  67         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  68         if ($mode && $ctx->{context}) {
  69                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  70                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  71         }
  72
  73         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  74 }
  75
  76 sub daemon_prepare ($) {
  77         my ($default_listen) = @_;
  78         my $listener_names = {}; # sockname => IO::Handle
  79         $oldset = PublicInbox::Sigfd::block_signals();
  80         @CMD = ($0, @ARGV);
  81         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  82         my $help = <<EOF;
  83 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
  84
  85 options:
  86
  87   -l ADDRESS    address to listen on (default: $default_listen)
  88   --cert=FILE   default SSL/TLS certificate
  89   --key=FILE    default SSL/TLS certificate
  90   -W WORKERS    number of worker processes to spawn (default: 1)
  91
  92 See public-inbox-daemon(8) and $prog(1) man pages for more.
  93 EOF
  94         my %opt = (
  95                 'l|listen=s' => \@cfg_listen,
  96                 '1|stdout=s' => \$stdout,
  97                 '2|stderr=s' => \$stderr,
  98                 'W|worker-processes=i' => \$worker_processes,
  99                 'P|pid-file=s' => \$pid_file,
 100                 'u|user=s' => \$user,
 101                 'g|group=s' => \$group,
 102                 'D|daemonize' => \$daemonize,
 103                 'cert=s' => \$default_cert,
 104                 'key=s' => \$default_key,
 105                 'help|h' => \(my $show_help),
 106         );
 107         GetOptions(%opt) or die $help;
 108         if ($show_help) { print $help; exit 0 };
 109
 110         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 111                 die "--pid-file cannot end with '.oldbin'\n";
 112         }
 113         @listeners = inherit($listener_names);
 114
 115         # allow socket-activation users to set certs once and not
 116         # have to configure each socket:
 117         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 118
 119         # ignore daemonize when inheriting
 120         $daemonize = undef if scalar @listeners;
 121
 122         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 123
 124         foreach my $l (@cfg_listen) {
 125                 my $orig = $l;
 126                 my $scheme = '';
 127                 if ($l =~ s!\A([^:]+)://!!) {
 128                         $scheme = $1;
 129                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 130                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 131                         $scheme = $s if defined $s;
 132                 }
 133                 if ($l =~ s!/?\?(.+)\z!!) {
 134                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 135                 } elsif (defined($default_cert)) {
 136                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 137                 } elsif ($scheme =~ /\A(?:https|imaps|imaps)\z/) {
 138                         die "$orig specified w/o cert=\n";
 139                 }
 140                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 141
 142                 next if $listener_names->{$l}; # already inherited
 143                 my (%o, $sock_pkg);
 144                 if (index($l, '/') == 0) {
 145                         $sock_pkg = 'IO::Socket::UNIX';
 146                         eval "use $sock_pkg";
 147                         die $@ if $@;
 148                         %o = (Type => SOCK_STREAM, Peer => $l);
 149                         if (-S $l) {
 150                                 my $c = $sock_pkg->new(%o);
 151                                 if (!defined($c) && $!{ECONNREFUSED}) {
 152                                         unlink $l or die
 153 "failed to unlink stale socket=$l: $!\n";
 154                                 } # else: let the bind fail
 155                         }
 156                         $o{Local} = delete $o{Peer};
 157                 } else {
 158                         # both work for IPv4, too
 159                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 160                                 $sock_pkg = $_;
 161                                 eval "use $sock_pkg";
 162                                 $@ or last;
 163                         }
 164                         die $@ if $@;
 165                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 166                 }
 167                 $o{Listen} = 1024;
 168                 my $prev = umask 0000;
 169                 my $s = eval { $sock_pkg->new(%o) };
 170                 warn "error binding $l: $! ($@)\n" unless $s;
 171                 umask $prev;
 172                 if ($s) {
 173                         $listener_names->{sockname($s)} = $s;
 174                         $s->blocking(0);
 175                         push @listeners, $s;
 176                 }
 177         }
 178
 179         # cert/key options in @cfg_listen takes precedence when inheriting,
 180         # but map well-known inherited ports if --listen isn't specified
 181         # at all
 182         for my $sockname (@inherited_names) {
 183                 $sockname =~ /:([0-9]+)\z/ or next;
 184                 if (my $scheme = $KNOWN_TLS{$1}) {
 185                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 186                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 187                         next if $tls_opt{"$scheme://$sockname"};
 188                         $tls_opt{''} ||= accept_tls_opt('');
 189                 }
 190         }
 191
 192         die "No listeners bound\n" unless @listeners;
 193 }
 194
 195 sub check_absolute ($$) {
 196         my ($var, $val) = @_;
 197         if (defined $val && index($val, '/') != 0) {
 198                 die
 199 "--$var must be an absolute path when using --daemonize: $val\n";
 200         }
 201 }
 202
 203 sub daemonize () {
 204         if ($daemonize) {
 205                 foreach my $i (0..$#ARGV) {
 206                         my $arg = $ARGV[$i];
 207                         next unless -e $arg;
 208                         $ARGV[$i] = abs_path($arg);
 209                 }
 210                 check_absolute('stdout', $stdout);
 211                 check_absolute('stderr', $stderr);
 212                 check_absolute('pid-file', $pid_file);
 213
 214                 chdir '/' or die "chdir failed: $!";
 215         }
 216
 217         return unless (defined $pid_file || defined $group || defined $user
 218                         || $daemonize);
 219
 220         eval { require Net::Server::Daemonize };
 221         if ($@) {
 222                 die
 223 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 224         }
 225
 226         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 227         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 228         if (defined $group) {
 229                 $gid = Net::Server::Daemonize::get_gid($group);
 230                 $gid = (split /\s+/, $gid)[0];
 231         } elsif (defined $uid) {
 232                 $gid = (getpwuid($uid))[3];
 233         }
 234
 235         # We change users in the worker to ensure upgradability,
 236         # The upgrade will create the ".oldbin" pid file in the
 237         # same directory as the given pid file.
 238         $uid and $set_user = sub {
 239                 $set_user = undef;
 240                 Net::Server::Daemonize::set_user($uid, $gid);
 241         };
 242
 243         if ($daemonize) {
 244                 my $pid = fork;
 245                 die "could not fork: $!\n" unless defined $pid;
 246                 exit if $pid;
 247
 248                 open(STDIN, '+<', '/dev/null') or
 249                                         die "redirect stdin failed: $!\n";
 250                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 251                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 252                 POSIX::setsid();
 253                 $pid = fork;
 254                 die "could not fork: $!\n" unless defined $pid;
 255                 exit if $pid;
 256         }
 257         return unless defined $pid_file;
 258
 259         write_pid($pid_file);
 260         # for ->DESTROY:
 261         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 262 }
 263
 264 sub worker_quit { # $_[0] = signal name or number (unused)
 265         # killing again terminates immediately:
 266         exit unless @listeners;
 267
 268         $_->close foreach @listeners; # call PublicInbox::DS::close
 269         @listeners = ();
 270         my $proc_name;
 271         my $warn = 0;
 272         # drop idle connections and try to quit gracefully
 273         PublicInbox::DS->SetPostLoopCallback(sub {
 274                 my ($dmap, undef) = @_;
 275                 my $n = 0;
 276                 my $now = now();
 277
 278                 foreach my $s (values %$dmap) {
 279                         $s->can('busy') or next;
 280                         if ($s->busy($now)) {
 281                                 ++$n;
 282                         } else {
 283                                 # close as much as possible, early as possible
 284                                 $s->close;
 285                         }
 286                 }
 287                 if ($n) {
 288                         if (($warn + 5) < now()) {
 289                                 warn "$$ quitting, $n client(s) left\n";
 290                                 $warn = now();
 291                         }
 292                         unless (defined $proc_name) {
 293                                 $proc_name = (split(/\s+/, $0))[0];
 294                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 295                         }
 296                         $0 = "$proc_name quitting, $n client(s) left";
 297                 }
 298                 $n; # true: loop continues, false: loop breaks
 299         });
 300 }
 301
 302 sub reopen_logs {
 303         if ($stdout) {
 304                 open STDOUT, '>>', $stdout or
 305                         warn "failed to redirect stdout to $stdout: $!\n";
 306                 STDOUT->autoflush(1);
 307                 do_chown($stdout);
 308         }
 309         if ($stderr) {
 310                 open STDERR, '>>', $stderr or
 311                         warn "failed to redirect stderr to $stderr: $!\n";
 312                 STDERR->autoflush(1);
 313                 do_chown($stderr);
 314         }
 315 }
 316
 317 sub sockname ($) {
 318         my ($s) = @_;
 319         my $addr = getsockname($s) or return;
 320         my ($host, $port) = host_with_port($addr);
 321         if ($port == 0 && $host eq '127.0.0.1') {
 322                 my ($path) = Socket::sockaddr_un($addr);
 323                 return $path;
 324         }
 325         "$host:$port";
 326 }
 327
 328 sub unpack_ipv6 ($) {
 329         my ($addr) = @_;
 330         my ($port, $host);
 331
 332         # Socket.pm in Perl 5.14+ supports IPv6:
 333         eval {
 334                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 335                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 336         };
 337
 338         if ($@) {
 339                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 340                 # Socket6, so it may be installed on our system, already
 341                 # (otherwise die here):
 342                 require Socket6;
 343
 344                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 345                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 346         }
 347         ($host, $port);
 348 }
 349
 350 sub host_with_port ($) {
 351         my ($addr) = @_;
 352         my ($port, $host);
 353
 354         # this eval will die on Unix sockets:
 355         eval {
 356                 if (length($addr) >= 28) {
 357                         ($host, $port) = unpack_ipv6($addr);
 358                         $host = "[$host]";
 359                 } else {
 360                         ($port, $host) = Socket::sockaddr_in($addr);
 361                         $host = Socket::inet_ntoa($host);
 362                 }
 363         };
 364         $@ ? ('127.0.0.1', 0) : ($host, $port);
 365 }
 366
 367 sub inherit ($) {
 368         my ($listener_names) = @_;
 369         return () if ($ENV{LISTEN_PID} || 0) != $$;
 370         my $fds = $ENV{LISTEN_FDS} or return ();
 371         my $end = $fds + 2; # LISTEN_FDS_START - 1
 372         my @rv = ();
 373         foreach my $fd (3..$end) {
 374                 my $s = IO::Handle->new_from_fd($fd, 'r');
 375                 if (my $k = sockname($s)) {
 376                         if ($s->blocking) {
 377                                 $s->blocking(0);
 378                                 warn <<"";
 379 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 380 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 381 processes when multiple service instances start.
 382
 383                         }
 384                         $listener_names->{$k} = $s;
 385                         push @rv, $s;
 386                 } else {
 387                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 388                 }
 389         }
 390         @rv
 391 }
 392
 393 sub upgrade { # $_[0] = signal name or number (unused)
 394         if ($reexec_pid) {
 395                 warn "upgrade in-progress: $reexec_pid\n";
 396                 return;
 397         }
 398         if (defined $pid_file) {
 399                 if ($pid_file =~ /\.oldbin\z/) {
 400                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 401                         return;
 402                 }
 403                 unlink_pid_file_safe_ish($$, $pid_file);
 404                 $pid_file .= '.oldbin';
 405                 write_pid($pid_file);
 406         }
 407         my $pid = fork;
 408         unless (defined $pid) {
 409                 warn "fork failed: $!\n";
 410                 return;
 411         }
 412         if ($pid == 0) {
 413                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 414                 $ENV{LISTEN_FDS} = scalar @listeners;
 415                 $ENV{LISTEN_PID} = $$;
 416                 foreach my $s (@listeners) {
 417                         # @listeners are globs with workers, PI::L w/o workers
 418                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 419
 420                         my $fl = fcntl($s, F_GETFD, 0);
 421                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 422                 }
 423                 exec @CMD;
 424                 die "Failed to exec: $!\n";
 425         }
 426         $reexec_pid = $pid;
 427 }
 428
 429 sub kill_workers ($) {
 430         my ($s) = @_;
 431
 432         while (my ($pid, $id) = each %pids) {
 433                 kill $s, $pid;
 434         }
 435 }
 436
 437 sub upgrade_aborted ($) {
 438         my ($p) = @_;
 439         warn "reexec PID($p) died with: $?\n";
 440         $reexec_pid = undef;
 441         return unless $pid_file;
 442
 443         my $file = $pid_file;
 444         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 445         unlink_pid_file_safe_ish($$, $pid_file);
 446         $pid_file = $file;
 447         eval { write_pid($pid_file) };
 448         warn $@, "\n" if $@;
 449 }
 450
 451 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 452         while (1) {
 453                 my $p = waitpid(-1, WNOHANG) or return;
 454                 if (defined $reexec_pid && $p == $reexec_pid) {
 455                         upgrade_aborted($p);
 456                 } elsif (defined(my $id = delete $pids{$p})) {
 457                         warn "worker[$id] PID($p) died with: $?\n";
 458                 } elsif ($p > 0) {
 459                         warn "unknown PID($p) reaped: $?\n";
 460                 } else {
 461                         return;
 462                 }
 463         }
 464 }
 465
 466 sub unlink_pid_file_safe_ish ($$) {
 467         my ($unlink_pid, $file) = @_;
 468         return unless defined $unlink_pid && $unlink_pid == $$;
 469
 470         open my $fh, '<', $file or return;
 471         local $/ = "\n";
 472         defined(my $read_pid = <$fh>) or return;
 473         chomp $read_pid;
 474         if ($read_pid == $unlink_pid) {
 475                 Net::Server::Daemonize::unlink_pid_file($file);
 476         }
 477 }
 478
 479 sub master_quit ($) {
 480         exit unless @listeners;
 481         @listeners = ();
 482         kill_workers($_[0]);
 483 }
 484
 485 sub master_loop {
 486         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 487         my $set_workers = $worker_processes;
 488         reopen_logs();
 489         my $ignore_winch;
 490         my $sig = {
 491                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 492                 USR2 => \&upgrade,
 493                 QUIT => \&master_quit,
 494                 INT => \&master_quit,
 495                 TERM => \&master_quit,
 496                 WINCH => sub {
 497                         return if $ignore_winch || !@listeners;
 498                         if (-t STDIN || -t STDOUT || -t STDERR) {
 499                                 $ignore_winch = 1;
 500                                 warn <<EOF;
 501 ignoring SIGWINCH since we are not daemonized
 502 EOF
 503                         } else {
 504                                 $worker_processes = 0;
 505                         }
 506                 },
 507                 HUP => sub {
 508                         return unless @listeners;
 509                         $worker_processes = $set_workers;
 510                         kill_workers($_[0]);
 511                 },
 512                 TTIN => sub {
 513                         return unless @listeners;
 514                         if ($set_workers > $worker_processes) {
 515                                 ++$worker_processes;
 516                         } else {
 517                                 $worker_processes = ++$set_workers;
 518                         }
 519                 },
 520                 TTOU => sub {
 521                         $worker_processes = --$set_workers if $set_workers > 0;
 522                 },
 523                 CHLD => \&reap_children,
 524         };
 525         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 526         local %SIG = (%SIG, %$sig) if !$sigfd;
 527         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 528         while (1) { # main loop
 529                 my $n = scalar keys %pids;
 530                 unless (@listeners) {
 531                         exit if $n == 0;
 532                         $set_workers = $worker_processes = $n = 0;
 533                 }
 534
 535                 if ($n > $worker_processes) {
 536                         while (my ($k, $v) = each %pids) {
 537                                 kill('TERM', $k) if $v >= $worker_processes;
 538                         }
 539                         $n = $worker_processes;
 540                 }
 541                 my $want = $worker_processes - 1;
 542                 if ($n <= $want) {
 543                         PublicInbox::Sigfd::block_signals() if !$sigfd;
 544                         for my $i ($n..$want) {
 545                                 my $pid = fork;
 546                                 if (!defined $pid) {
 547                                         warn "failed to fork worker[$i]: $!\n";
 548                                 } elsif ($pid == 0) {
 549                                         $set_user->() if $set_user;
 550                                         return $p0; # run normal work code
 551                                 } else {
 552                                         warn "PID=$pid is worker[$i]\n";
 553                                         $pids{$pid} = $i;
 554                                 }
 555                         }
 556                         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 557                 }
 558
 559                 if ($sigfd) { # Linux and IO::KQueue users:
 560                         $sigfd->wait_once;
 561                 } else { # wake up every second
 562                         sleep(1);
 563                 }
 564         }
 565         exit # never gets here, just for documentation
 566 }
 567
 568 sub tls_start_cb ($$) {
 569         my ($opt, $orig_post_accept) = @_;
 570         sub {
 571                 my ($io, $addr, $srv) = @_;
 572                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 573                 $orig_post_accept->($ssl, $addr, $srv);
 574         }
 575 }
 576
 577 sub defer_accept ($$) {
 578         my ($s, $af_name) = @_;
 579         return unless defined $af_name;
 580         if ($^O eq 'linux') {
 581                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 582                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 583                 return unless defined $x; # may be Unix socket
 584                 my $sec = unpack('i', $x);
 585                 return if $sec > 0; # systemd users may set a higher value
 586                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 587         } elsif ($^O eq 'freebsd') {
 588                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 589                 return if defined $x; # don't change if set
 590                 my $accf_arg = pack('a16a240', $af_name, '');
 591                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 592         }
 593 }
 594
 595 sub daemon_loop ($$$$) {
 596         my ($refresh, $post_accept, $tlsd, $af_default) = @_;
 597         my %post_accept;
 598         while (my ($k, $v) = each %tls_opt) {
 599                 if ($k =~ s!\A(?:https|imaps|nntps)://!!) {
 600                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 601                 } elsif ($tlsd) { # STARTTLS, $k eq '' is OK
 602                         $tlsd->{accept_tls} = $v;
 603                 }
 604         }
 605         my $sig = {
 606                 HUP => $refresh,
 607                 INT => \&worker_quit,
 608                 QUIT => \&worker_quit,
 609                 TERM => \&worker_quit,
 610                 TTIN => 'IGNORE',
 611                 TTOU => 'IGNORE',
 612                 USR1 => \&reopen_logs,
 613                 USR2 => 'IGNORE',
 614                 WINCH => 'IGNORE',
 615                 CHLD => \&PublicInbox::DS::enqueue_reap,
 616         };
 617         if ($worker_processes > 0) {
 618                 $refresh->(); # preload by default
 619                 my $fh = master_loop(); # returns if in child process
 620                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 621         } else {
 622                 reopen_logs();
 623                 $set_user->() if $set_user;
 624                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 625                 $refresh->();
 626         }
 627         $uid = $gid = undef;
 628         reopen_logs();
 629         @listeners = map {;
 630                 my $tls_cb = $post_accept{sockname($_)};
 631
 632                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 633                 # IMAP, NNTP and POP3 are server-first
 634                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 635
 636                 # this calls epoll_create:
 637                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 638         } @listeners;
 639         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 640         local %SIG = (%SIG, %$sig) if !$sigfd;
 641         if (!$sigfd) {
 642                 # wake up every second to accept signals if we don't
 643                 # have signalfd or IO::KQueue:
 644                 PublicInbox::Sigfd::sig_setmask($oldset);
 645                 PublicInbox::DS->SetLoopTimeout(1000);
 646         }
 647         PublicInbox::DS->EventLoop;
 648 }
 649
 650 sub run ($$$;$) {
 651         my ($default, $refresh, $post_accept, $tlsd) = @_;
 652         local $SIG{PIPE} = 'IGNORE';
 653         daemon_prepare($default);
 654         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 655         my $for_destroy = daemonize();
 656
 657         # localize GCF2C for tests:
 658         local $PublicInbox::GitAsyncCat::GCF2C;
 659
 660         daemon_loop($refresh, $post_accept, $tlsd, $af_default);
 661         PublicInbox::DS->Reset;
 662         # ->DESTROY runs when $for_destroy goes out-of-scope
 663 }
 664
 665 sub do_chown ($) {
 666         my ($path) = @_;
 667         if (defined $uid and !chown($uid, $gid, $path)) {
 668                 warn "could not chown $path: $!\n";
 669         }
 670 }
 671
 672 sub write_pid ($) {
 673         my ($path) = @_;
 674         Net::Server::Daemonize::create_pid_file($path);
 675         do_chown($path);
 676 }
 677
 678 sub DESTROY {
 679         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 680 }
 681
 682 1;