lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the httpd, imapd, and nntpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle; # ->autoflush
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 STDOUT->autoflush(1);
  15 STDERR->autoflush(1);
  16 use PublicInbox::DS qw(now);
  17 use PublicInbox::Syscall qw($SFD_NONBLOCK);
  18 require PublicInbox::Listener;
  19 use PublicInbox::EOFpipe;
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::GitAsyncCat;
  22 my @CMD;
  23 my ($set_user, $oldset);
  24 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  25 my $worker_processes = 1;
  26 my @listeners;
  27 my %pids;
  28 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  29 my $reexec_pid;
  30 my ($uid, $gid);
  31 my ($default_cert, $default_key);
  32 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps', 993 => 'imaps' );
  33 my %KNOWN_STARTTLS = ( 119 => 'nntp', 143 => 'imap' );
  34
  35 sub accept_tls_opt ($) {
  36         my ($opt_str) = @_;
  37         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  38         require PublicInbox::TLS;
  39         my $o = {};
  40         # allow ',' as delimiter since '&' is shell-unfriendly
  41         foreach (split(/[,&]/, $opt_str)) {
  42                 my ($k, $v) = split(/=/, $_, 2);
  43                 push @{$o->{$k} ||= []}, $v;
  44         }
  45
  46         # key may be a part of cert.  At least
  47         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  48         $o->{cert} //= [ $default_cert ];
  49         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  50         my %ctx_opt = (SSL_server => 1);
  51         # parse out hostname:/path/to/ mappings:
  52         foreach my $k (qw(cert key)) {
  53                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  54                 foreach my $path (@{$o->{$k}}) {
  55                         my $host = '';
  56                         $path =~ s/\A([^:]+):// and $host = $1;
  57                         $x->{$host} = $path;
  58                 }
  59         }
  60         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  61                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  62
  63         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  64         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  65         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  66         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  67         if ($mode && $ctx->{context}) {
  68                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  69                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  70         }
  71
  72         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  73 }
  74
  75 sub daemon_prepare ($) {
  76         my ($default_listen) = @_;
  77         my $listener_names = {}; # sockname => IO::Handle
  78         $oldset = PublicInbox::Sigfd::block_signals();
  79         @CMD = ($0, @ARGV);
  80         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  81         my $help = <<EOF;
  82 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
  83
  84 options:
  85
  86   -l ADDRESS    address to listen on (default: $default_listen)
  87   --cert=FILE   default SSL/TLS certificate
  88   --key=FILE    default SSL/TLS certificate
  89   -W WORKERS    number of worker processes to spawn (default: 1)
  90
  91 See public-inbox-daemon(8) and $prog(1) man pages for more.
  92 EOF
  93         my %opt = (
  94                 'l|listen=s' => \@cfg_listen,
  95                 '1|stdout=s' => \$stdout,
  96                 '2|stderr=s' => \$stderr,
  97                 'W|worker-processes=i' => \$worker_processes,
  98                 'P|pid-file=s' => \$pid_file,
  99                 'u|user=s' => \$user,
 100                 'g|group=s' => \$group,
 101                 'D|daemonize' => \$daemonize,
 102                 'cert=s' => \$default_cert,
 103                 'key=s' => \$default_key,
 104                 'help|h' => \(my $show_help),
 105         );
 106         GetOptions(%opt) or die $help;
 107         if ($show_help) { print $help; exit 0 };
 108
 109         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 110                 die "--pid-file cannot end with '.oldbin'\n";
 111         }
 112         @listeners = inherit($listener_names);
 113
 114         # allow socket-activation users to set certs once and not
 115         # have to configure each socket:
 116         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 117
 118         # ignore daemonize when inheriting
 119         $daemonize = undef if scalar @listeners;
 120
 121         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 122
 123         foreach my $l (@cfg_listen) {
 124                 my $orig = $l;
 125                 my $scheme = '';
 126                 if ($l =~ s!\A([^:]+)://!!) {
 127                         $scheme = $1;
 128                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 129                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 130                         $scheme = $s if defined $s;
 131                 }
 132                 if ($l =~ s!/?\?(.+)\z!!) {
 133                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 134                 } elsif (defined($default_cert)) {
 135                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 136                 } elsif ($scheme =~ /\A(?:https|imaps|imaps)\z/) {
 137                         die "$orig specified w/o cert=\n";
 138                 }
 139                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 140
 141                 next if $listener_names->{$l}; # already inherited
 142                 my (%o, $sock_pkg);
 143                 if (index($l, '/') == 0) {
 144                         $sock_pkg = 'IO::Socket::UNIX';
 145                         eval "use $sock_pkg";
 146                         die $@ if $@;
 147                         %o = (Type => SOCK_STREAM, Peer => $l);
 148                         if (-S $l) {
 149                                 my $c = $sock_pkg->new(%o);
 150                                 if (!defined($c) && $!{ECONNREFUSED}) {
 151                                         unlink $l or die
 152 "failed to unlink stale socket=$l: $!\n";
 153                                 } # else: let the bind fail
 154                         }
 155                         $o{Local} = delete $o{Peer};
 156                 } else {
 157                         # both work for IPv4, too
 158                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 159                                 $sock_pkg = $_;
 160                                 eval "use $sock_pkg";
 161                                 $@ or last;
 162                         }
 163                         die $@ if $@;
 164                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 165                 }
 166                 $o{Listen} = 1024;
 167                 my $prev = umask 0000;
 168                 my $s = eval { $sock_pkg->new(%o) };
 169                 warn "error binding $l: $! ($@)\n" unless $s;
 170                 umask $prev;
 171                 if ($s) {
 172                         $listener_names->{sockname($s)} = $s;
 173                         $s->blocking(0);
 174                         push @listeners, $s;
 175                 }
 176         }
 177
 178         # cert/key options in @cfg_listen takes precedence when inheriting,
 179         # but map well-known inherited ports if --listen isn't specified
 180         # at all
 181         for my $sockname (@inherited_names) {
 182                 $sockname =~ /:([0-9]+)\z/ or next;
 183                 if (my $scheme = $KNOWN_TLS{$1}) {
 184                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 185                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 186                         next if $tls_opt{"$scheme://$sockname"};
 187                         $tls_opt{''} ||= accept_tls_opt('');
 188                 }
 189         }
 190
 191         die "No listeners bound\n" unless @listeners;
 192 }
 193
 194 sub check_absolute ($$) {
 195         my ($var, $val) = @_;
 196         if (defined $val && index($val, '/') != 0) {
 197                 die
 198 "--$var must be an absolute path when using --daemonize: $val\n";
 199         }
 200 }
 201
 202 sub daemonize () {
 203         if ($daemonize) {
 204                 require Cwd;
 205                 foreach my $i (0..$#ARGV) {
 206                         my $arg = $ARGV[$i];
 207                         next unless -e $arg;
 208                         $ARGV[$i] = Cwd::abs_path($arg);
 209                 }
 210                 check_absolute('stdout', $stdout);
 211                 check_absolute('stderr', $stderr);
 212                 check_absolute('pid-file', $pid_file);
 213
 214                 chdir '/' or die "chdir failed: $!";
 215         }
 216         if (defined($pid_file) || defined($group) || defined($user)) {
 217                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 218 Net::Server required for --pid-file, --group, --user
 219 $@
 220 EOF
 221         }
 222         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 223         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 224         if (defined $group) {
 225                 $gid = Net::Server::Daemonize::get_gid($group);
 226                 $gid = (split /\s+/, $gid)[0];
 227         } elsif (defined $uid) {
 228                 $gid = (getpwuid($uid))[3];
 229         }
 230
 231         # We change users in the worker to ensure upgradability,
 232         # The upgrade will create the ".oldbin" pid file in the
 233         # same directory as the given pid file.
 234         $uid and $set_user = sub {
 235                 $set_user = undef;
 236                 Net::Server::Daemonize::set_user($uid, $gid);
 237         };
 238
 239         if ($daemonize) {
 240                 my $pid = fork // die "fork: $!";
 241                 exit if $pid;
 242
 243                 open(STDIN, '+<', '/dev/null') or
 244                                         die "redirect stdin failed: $!\n";
 245                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 246                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 247                 POSIX::setsid();
 248                 $pid = fork // die "fork: $!";
 249                 exit if $pid;
 250         }
 251         return unless defined $pid_file;
 252
 253         write_pid($pid_file);
 254         # for ->DESTROY:
 255         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 256 }
 257
 258 sub worker_quit { # $_[0] = signal name or number (unused)
 259         # killing again terminates immediately:
 260         exit unless @listeners;
 261
 262         $_->close foreach @listeners; # call PublicInbox::DS::close
 263         @listeners = ();
 264         my $proc_name;
 265         my $warn = 0;
 266         # drop idle connections and try to quit gracefully
 267         PublicInbox::DS->SetPostLoopCallback(sub {
 268                 my ($dmap, undef) = @_;
 269                 my $n = 0;
 270                 my $now = now();
 271
 272                 foreach my $s (values %$dmap) {
 273                         $s->can('busy') or next;
 274                         if ($s->busy($now)) {
 275                                 ++$n;
 276                         } else {
 277                                 # close as much as possible, early as possible
 278                                 $s->close;
 279                         }
 280                 }
 281                 if ($n) {
 282                         if (($warn + 5) < now()) {
 283                                 warn "$$ quitting, $n client(s) left\n";
 284                                 $warn = now();
 285                         }
 286                         unless (defined $proc_name) {
 287                                 $proc_name = (split(/\s+/, $0))[0];
 288                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 289                         }
 290                         $0 = "$proc_name quitting, $n client(s) left";
 291                 }
 292                 $n; # true: loop continues, false: loop breaks
 293         });
 294 }
 295
 296 sub reopen_logs {
 297         if ($stdout) {
 298                 open STDOUT, '>>', $stdout or
 299                         warn "failed to redirect stdout to $stdout: $!\n";
 300                 STDOUT->autoflush(1);
 301                 do_chown($stdout);
 302         }
 303         if ($stderr) {
 304                 open STDERR, '>>', $stderr or
 305                         warn "failed to redirect stderr to $stderr: $!\n";
 306                 STDERR->autoflush(1);
 307                 do_chown($stderr);
 308         }
 309 }
 310
 311 sub sockname ($) {
 312         my ($s) = @_;
 313         my $addr = getsockname($s) or return;
 314         my ($host, $port) = host_with_port($addr);
 315         if ($port == 0 && $host eq '127.0.0.1') {
 316                 my ($path) = Socket::sockaddr_un($addr);
 317                 return $path;
 318         }
 319         "$host:$port";
 320 }
 321
 322 sub unpack_ipv6 ($) {
 323         my ($addr) = @_;
 324         my ($port, $host);
 325
 326         # Socket.pm in Perl 5.14+ supports IPv6:
 327         eval {
 328                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 329                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 330         };
 331
 332         if ($@) {
 333                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 334                 # Socket6, so it may be installed on our system, already
 335                 # (otherwise die here):
 336                 require Socket6;
 337
 338                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 339                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 340         }
 341         ($host, $port);
 342 }
 343
 344 sub host_with_port ($) {
 345         my ($addr) = @_;
 346         my ($port, $host);
 347
 348         # this eval will die on Unix sockets:
 349         eval {
 350                 if (length($addr) >= 28) {
 351                         ($host, $port) = unpack_ipv6($addr);
 352                         $host = "[$host]";
 353                 } else {
 354                         ($port, $host) = Socket::sockaddr_in($addr);
 355                         $host = Socket::inet_ntoa($host);
 356                 }
 357         };
 358         $@ ? ('127.0.0.1', 0) : ($host, $port);
 359 }
 360
 361 sub inherit ($) {
 362         my ($listener_names) = @_;
 363         return () if ($ENV{LISTEN_PID} || 0) != $$;
 364         my $fds = $ENV{LISTEN_FDS} or return ();
 365         my $end = $fds + 2; # LISTEN_FDS_START - 1
 366         my @rv = ();
 367         foreach my $fd (3..$end) {
 368                 my $s = IO::Handle->new_from_fd($fd, 'r');
 369                 if (my $k = sockname($s)) {
 370                         my $prev_was_blocking = $s->blocking(0);
 371                         warn <<"" if $prev_was_blocking;
 372 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 373 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 374 processes when multiple service instances start.
 375
 376                         $listener_names->{$k} = $s;
 377                         push @rv, $s;
 378                 } else {
 379                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 380                 }
 381         }
 382         @rv
 383 }
 384
 385 sub upgrade { # $_[0] = signal name or number (unused)
 386         if ($reexec_pid) {
 387                 warn "upgrade in-progress: $reexec_pid\n";
 388                 return;
 389         }
 390         if (defined $pid_file) {
 391                 if ($pid_file =~ /\.oldbin\z/) {
 392                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 393                         return;
 394                 }
 395                 unlink_pid_file_safe_ish($$, $pid_file);
 396                 $pid_file .= '.oldbin';
 397                 write_pid($pid_file);
 398         }
 399         my $pid = fork;
 400         unless (defined $pid) {
 401                 warn "fork failed: $!\n";
 402                 return;
 403         }
 404         if ($pid == 0) {
 405                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 406                 $ENV{LISTEN_FDS} = scalar @listeners;
 407                 $ENV{LISTEN_PID} = $$;
 408                 foreach my $s (@listeners) {
 409                         # @listeners are globs with workers, PI::L w/o workers
 410                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 411
 412                         my $fl = fcntl($s, F_GETFD, 0);
 413                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 414                 }
 415                 exec @CMD;
 416                 die "Failed to exec: $!\n";
 417         }
 418         $reexec_pid = $pid;
 419 }
 420
 421 sub kill_workers ($) {
 422         my ($sig) = @_;
 423         kill $sig, keys(%pids);
 424 }
 425
 426 sub upgrade_aborted ($) {
 427         my ($p) = @_;
 428         warn "reexec PID($p) died with: $?\n";
 429         $reexec_pid = undef;
 430         return unless $pid_file;
 431
 432         my $file = $pid_file;
 433         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 434         unlink_pid_file_safe_ish($$, $pid_file);
 435         $pid_file = $file;
 436         eval { write_pid($pid_file) };
 437         warn $@, "\n" if $@;
 438 }
 439
 440 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 441         while (1) {
 442                 my $p = waitpid(-1, WNOHANG) or return;
 443                 if (defined $reexec_pid && $p == $reexec_pid) {
 444                         upgrade_aborted($p);
 445                 } elsif (defined(my $id = delete $pids{$p})) {
 446                         warn "worker[$id] PID($p) died with: $?\n";
 447                 } elsif ($p > 0) {
 448                         warn "unknown PID($p) reaped: $?\n";
 449                 } else {
 450                         return;
 451                 }
 452         }
 453 }
 454
 455 sub unlink_pid_file_safe_ish ($$) {
 456         my ($unlink_pid, $file) = @_;
 457         return unless defined $unlink_pid && $unlink_pid == $$;
 458
 459         open my $fh, '<', $file or return;
 460         local $/ = "\n";
 461         defined(my $read_pid = <$fh>) or return;
 462         chomp $read_pid;
 463         if ($read_pid == $unlink_pid) {
 464                 Net::Server::Daemonize::unlink_pid_file($file);
 465         }
 466 }
 467
 468 sub master_quit ($) {
 469         exit unless @listeners;
 470         @listeners = ();
 471         kill_workers($_[0]);
 472 }
 473
 474 sub master_loop {
 475         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 476         my $set_workers = $worker_processes;
 477         reopen_logs();
 478         my $ignore_winch;
 479         my $sig = {
 480                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 481                 USR2 => \&upgrade,
 482                 QUIT => \&master_quit,
 483                 INT => \&master_quit,
 484                 TERM => \&master_quit,
 485                 WINCH => sub {
 486                         return if $ignore_winch || !@listeners;
 487                         if (-t STDIN || -t STDOUT || -t STDERR) {
 488                                 $ignore_winch = 1;
 489                                 warn <<EOF;
 490 ignoring SIGWINCH since we are not daemonized
 491 EOF
 492                         } else {
 493                                 $worker_processes = 0;
 494                         }
 495                 },
 496                 HUP => sub {
 497                         return unless @listeners;
 498                         $worker_processes = $set_workers;
 499                         kill_workers($_[0]);
 500                 },
 501                 TTIN => sub {
 502                         return unless @listeners;
 503                         if ($set_workers > $worker_processes) {
 504                                 ++$worker_processes;
 505                         } else {
 506                                 $worker_processes = ++$set_workers;
 507                         }
 508                 },
 509                 TTOU => sub {
 510                         $worker_processes = --$set_workers if $set_workers > 0;
 511                 },
 512                 CHLD => \&reap_children,
 513         };
 514         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 515         local %SIG = (%SIG, %$sig) if !$sigfd;
 516         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 517         while (1) { # main loop
 518                 my $n = scalar keys %pids;
 519                 unless (@listeners) {
 520                         exit if $n == 0;
 521                         $set_workers = $worker_processes = $n = 0;
 522                 }
 523
 524                 if ($n > $worker_processes) {
 525                         while (my ($k, $v) = each %pids) {
 526                                 kill('TERM', $k) if $v >= $worker_processes;
 527                         }
 528                         $n = $worker_processes;
 529                 }
 530                 my $want = $worker_processes - 1;
 531                 if ($n <= $want) {
 532                         PublicInbox::Sigfd::block_signals() if !$sigfd;
 533                         for my $i ($n..$want) {
 534                                 my $pid = fork;
 535                                 if (!defined $pid) {
 536                                         warn "failed to fork worker[$i]: $!\n";
 537                                 } elsif ($pid == 0) {
 538                                         $set_user->() if $set_user;
 539                                         return $p0; # run normal work code
 540                                 } else {
 541                                         warn "PID=$pid is worker[$i]\n";
 542                                         $pids{$pid} = $i;
 543                                 }
 544                         }
 545                         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 546                 }
 547
 548                 if ($sigfd) { # Linux and IO::KQueue users:
 549                         $sigfd->wait_once;
 550                 } else { # wake up every second
 551                         sleep(1);
 552                 }
 553         }
 554         exit # never gets here, just for documentation
 555 }
 556
 557 sub tls_start_cb ($$) {
 558         my ($opt, $orig_post_accept) = @_;
 559         sub {
 560                 my ($io, $addr, $srv) = @_;
 561                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 562                 $orig_post_accept->($ssl, $addr, $srv);
 563         }
 564 }
 565
 566 sub defer_accept ($$) {
 567         my ($s, $af_name) = @_;
 568         return unless defined $af_name;
 569         if ($^O eq 'linux') {
 570                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 571                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 572                 return unless defined $x; # may be Unix socket
 573                 my $sec = unpack('i', $x);
 574                 return if $sec > 0; # systemd users may set a higher value
 575                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 576         } elsif ($^O eq 'freebsd') {
 577                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 578                 return if defined $x; # don't change if set
 579                 my $accf_arg = pack('a16a240', $af_name, '');
 580                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 581         }
 582 }
 583
 584 sub daemon_loop ($$$$) {
 585         my ($refresh, $post_accept, $tlsd, $af_default) = @_;
 586         my %post_accept;
 587         while (my ($k, $v) = each %tls_opt) {
 588                 if ($k =~ s!\A(?:https|imaps|nntps)://!!) {
 589                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 590                 } elsif ($tlsd) { # STARTTLS, $k eq '' is OK
 591                         $tlsd->{accept_tls} = $v;
 592                 }
 593         }
 594         my $sig = {
 595                 HUP => $refresh,
 596                 INT => \&worker_quit,
 597                 QUIT => \&worker_quit,
 598                 TERM => \&worker_quit,
 599                 TTIN => 'IGNORE',
 600                 TTOU => 'IGNORE',
 601                 USR1 => \&reopen_logs,
 602                 USR2 => 'IGNORE',
 603                 WINCH => 'IGNORE',
 604                 CHLD => \&PublicInbox::DS::enqueue_reap,
 605         };
 606         if ($worker_processes > 0) {
 607                 $refresh->(); # preload by default
 608                 my $fh = master_loop(); # returns if in child process
 609                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 610         } else {
 611                 reopen_logs();
 612                 $set_user->() if $set_user;
 613                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 614                 $refresh->();
 615         }
 616         $uid = $gid = undef;
 617         reopen_logs();
 618         @listeners = map {;
 619                 my $tls_cb = $post_accept{sockname($_)};
 620
 621                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 622                 # IMAP, NNTP and POP3 are server-first
 623                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 624
 625                 # this calls epoll_create:
 626                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 627         } @listeners;
 628         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 629         local %SIG = (%SIG, %$sig) if !$sigfd;
 630         if (!$sigfd) {
 631                 # wake up every second to accept signals if we don't
 632                 # have signalfd or IO::KQueue:
 633                 PublicInbox::Sigfd::sig_setmask($oldset);
 634                 PublicInbox::DS->SetLoopTimeout(1000);
 635         }
 636         PublicInbox::DS->EventLoop;
 637 }
 638
 639 sub run ($$$;$) {
 640         my ($default, $refresh, $post_accept, $tlsd) = @_;
 641         local $SIG{PIPE} = 'IGNORE';
 642         daemon_prepare($default);
 643         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 644         my $for_destroy = daemonize();
 645
 646         # localize GCF2C for tests:
 647         local $PublicInbox::GitAsyncCat::GCF2C;
 648
 649         daemon_loop($refresh, $post_accept, $tlsd, $af_default);
 650         PublicInbox::DS->Reset;
 651         # ->DESTROY runs when $for_destroy goes out-of-scope
 652 }
 653
 654 sub do_chown ($) {
 655         my ($path) = @_;
 656         if (defined $uid and !chown($uid, $gid, $path)) {
 657                 warn "could not chown $path: $!\n";
 658         }
 659 }
 660
 661 sub write_pid ($) {
 662         my ($path) = @_;
 663         Net::Server::Daemonize::create_pid_file($path);
 664         do_chown($path);
 665 }
 666
 667 sub DESTROY {
 668         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 669 }
 670
 671 1;