lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use File::Spec;
  14 use POSIX qw(WNOHANG :signal_h);
  15 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::Git;
  23 use PublicInbox::GitAsyncCat;
  24 use PublicInbox::Eml;
  25 our $SO_ACCEPTFILTER = 0x1000;
  26 my @CMD;
  27 my ($set_user, $oldset);
  28 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  29 my $worker_processes = 1;
  30 my @listeners;
  31 my (%pids, %logs);
  32 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  33 my $reexec_pid;
  34 my ($uid, $gid);
  35 my ($default_cert, $default_key);
  36 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  37 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  38 my %SCHEME2PORT = map { $KNOWN_TLS{$_} => $_ + 0 } keys %KNOWN_TLS;
  39 for (keys %KNOWN_STARTTLS) { $SCHEME2PORT{$KNOWN_STARTTLS{$_}} = $_ + 0 }
  40 $SCHEME2PORT{http} = 80;
  41
  42 sub listener_opt ($) {
  43         my ($str) = @_; # opt1=val1,opt2=val2 (opt may repeat for multi-value)
  44         my $o = {};
  45         # allow ',' as delimiter since '&' is shell-unfriendly
  46         for (split(/[,&]/, $str)) {
  47                 my ($k, $v) = split(/=/, $_, 2);
  48                 push @{$o->{$k}}, $v;
  49         }
  50
  51         # key may be a part of cert.  At least
  52         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  53         $o->{cert} //= [ $default_cert ] if defined($default_cert);
  54         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  55         $o;
  56 }
  57
  58 sub accept_tls_opt ($) {
  59         my ($opt) = @_;
  60         my $o = ref($opt) eq 'HASH' ? $opt : listener_opt($opt);
  61         return if !defined($o->{cert});
  62         require PublicInbox::TLS;
  63         my %ctx_opt = (SSL_server => 1);
  64         # parse out hostname:/path/to/ mappings:
  65         for my $k (qw(cert key)) {
  66                 $o->{$k} // next;
  67                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  68                 foreach my $path (@{$o->{$k}}) {
  69                         my $host = '';
  70                         $path =~ s/\A([^:]+):// and $host = $1;
  71                         $x->{$host} = $path;
  72                         check_absolute($k, $path) if $daemonize;
  73                 }
  74         }
  75         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  76                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  77
  78         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  79         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  80         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  81         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  82         if ($mode && $ctx->{context}) {
  83                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  84                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  85         }
  86
  87         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  88 }
  89
  90 sub check_absolute ($$) {
  91         my ($var, $val) = @_;
  92         die <<EOM if index($val // '/', '/') != 0;
  93 $var must be an absolute path when using --daemonize: $val
  94 EOM
  95 }
  96
  97 sub do_chown ($) {
  98         $uid // return;
  99         my ($path) = @_;
 100         chown($uid, $gid, $path) or warn "chown $path: $!\n";
 101 }
 102
 103 sub open_log_path ($$) { # my ($fh, $path) = @_; # $_[0] is modified
 104         open $_[0], '>>', $_[1] or die "open(>> $_[1]): $!";
 105         $_[0]->autoflush(1);
 106         do_chown($_[1]);
 107         $_[0];
 108 }
 109
 110 sub load_mod ($;$$) {
 111         my ($scheme, $opt, $addr) = @_;
 112         my $modc = "PublicInbox::\U$scheme";
 113         $modc =~ s/S\z//;
 114         my $mod = $modc.'D';
 115         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
 116         die $@ if $@;
 117         my %xn;
 118         my $tlsd = $xn{tlsd} = $mod->new;
 119         my %env = map {
 120                 substr($_, length('env.')) => $opt->{$_}->[-1];
 121         } grep(/\Aenv\./, keys %$opt);
 122         $xn{refresh} = sub {
 123                 my ($sig) = @_;
 124                 local @ENV{keys %env} = values %env;
 125                 $tlsd->refresh_groups($sig);
 126         };
 127         $xn{post_accept} = $tlsd->can('post_accept_cb') ?
 128                         $tlsd->post_accept_cb : sub { $modc->new($_[0], $tlsd) };
 129         my @paths = qw(out err);
 130         if ($modc eq 'PublicInbox::HTTP') {
 131                 @paths = qw(err);
 132                 $xn{af_default} = 'httpready';
 133                 if (my $p = $opt->{psgi}) {
 134                         die "multiple psgi= options specified\n" if @$p > 1;
 135                         check_absolute('psgi=', $p->[0]) if $daemonize;
 136                         $tlsd->{psgi} = $p->[0];
 137                         warn "# $scheme://$addr psgi=$p->[0]\n";
 138                 }
 139         }
 140         for my $f (@paths) {
 141                 my $p = $opt->{$f} or next;
 142                 die "multiple $f= options specified\n" if @$p > 1;
 143                 check_absolute("$f=", $p->[0]) if $daemonize;
 144                 $p = File::Spec->canonpath($p->[0]);
 145                 $tlsd->{$f} = $logs{$p} //= open_log_path(my $fh, $p);
 146                 warn "# $scheme://$addr $f=$p\n";
 147         }
 148         \%xn;
 149 }
 150
 151 sub daemon_prepare ($$) {
 152         my ($default_listen, $xnetd) = @_;
 153         my $listener_names = {}; # sockname => IO::Handle
 154         $oldset = PublicInbox::DS::block_signals();
 155         @CMD = ($0, @ARGV);
 156         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
 157         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 158         my $help = <<EOF;
 159 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 160
 161 options:
 162
 163   -l ADDRESS    address to listen on$dh
 164   --cert=FILE   default SSL/TLS certificate
 165   --key=FILE    default SSL/TLS certificate
 166   -W WORKERS    number of worker processes to spawn (default: 1)
 167
 168 See public-inbox-daemon(8) and $prog(1) man pages for more.
 169 EOF
 170         my %opt = (
 171                 'l|listen=s' => \@cfg_listen,
 172                 '1|stdout=s' => \$stdout,
 173                 '2|stderr=s' => \$stderr,
 174                 'W|worker-processes=i' => \$worker_processes,
 175                 'P|pid-file=s' => \$pid_file,
 176                 'u|user=s' => \$user,
 177                 'g|group=s' => \$group,
 178                 'D|daemonize' => \$daemonize,
 179                 'cert=s' => \$default_cert,
 180                 'key=s' => \$default_key,
 181                 'help|h' => \(my $show_help),
 182         );
 183         GetOptions(%opt) or die $help;
 184         if ($show_help) { print $help; exit 0 };
 185
 186         $_ = File::Spec->canonpath($_ // next) for ($stdout, $stderr);
 187         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 188                 die "--pid-file cannot end with '.oldbin'\n";
 189         }
 190         @listeners = inherit($listener_names);
 191
 192         # allow socket-activation users to set certs once and not
 193         # have to configure each socket:
 194         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 195
 196         # ignore daemonize when inheriting
 197         $daemonize = undef if scalar @listeners;
 198
 199         unless (@listeners || @cfg_listen) {
 200                 $default_listen // die "no listeners specified\n";
 201                 push @cfg_listen, $default_listen
 202         }
 203
 204         foreach my $l (@cfg_listen) {
 205                 my $orig = $l;
 206                 my $scheme = '';
 207                 my $port;
 208                 if ($l =~ s!\A([^:]+)://!!) { $scheme = $1 }
 209                 if ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9]+)/) {
 210                         $port = $1 + 0;
 211                         my $s = $KNOWN_TLS{$port} // $KNOWN_STARTTLS{$port};
 212                         $scheme //= $s if defined $s;
 213                 } elsif (index($l, '/') != 0) { # unix socket
 214                         $port //= $SCHEME2PORT{$scheme} if $scheme;
 215                         $port // die "no port in listen=$l\n";
 216                         $l =~ s!\A([^/]+)!$1:$port! or
 217                                 die "unable to add port=$port to $l\n";
 218                 }
 219                 my $opt; # non-TLS options
 220                 if ($l =~ s!/?\?(.+)\z!!) {
 221                         $opt = listener_opt($1);
 222                         $tls_opt{"$scheme://$l"} = accept_tls_opt($opt);
 223                 } elsif (defined($default_cert)) {
 224                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 225                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 226                         die "$orig specified w/o cert=\n";
 227                 }
 228                 $scheme =~ /\A(?:http|imap|nntp|pop3)/ and
 229                         $xnetd->{$l} = load_mod($scheme, $opt, $l);
 230
 231                 next if $listener_names->{$l}; # already inherited
 232                 my (%o, $sock_pkg);
 233                 if (index($l, '/') == 0) {
 234                         $sock_pkg = 'IO::Socket::UNIX';
 235                         eval "use $sock_pkg";
 236                         die $@ if $@;
 237                         %o = (Type => SOCK_STREAM, Peer => $l);
 238                         if (-S $l) {
 239                                 my $c = $sock_pkg->new(%o);
 240                                 if (!defined($c) && $!{ECONNREFUSED}) {
 241                                         unlink $l or die
 242 "failed to unlink stale socket=$l: $!\n";
 243                                 } # else: let the bind fail
 244                         }
 245                         $o{Local} = delete $o{Peer};
 246                 } else {
 247                         # both work for IPv4, too
 248                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 249                                 $sock_pkg = $_;
 250                                 eval "use $sock_pkg";
 251                                 $@ or last;
 252                         }
 253                         die $@ if $@;
 254                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 255                 }
 256                 $o{Listen} = 1024;
 257                 my $prev = umask 0000;
 258                 my $s = eval { $sock_pkg->new(%o) };
 259                 warn "error binding $l: $! ($@)\n" unless $s;
 260                 umask $prev;
 261                 if ($s) {
 262                         $s->blocking(0);
 263                         my $k = sockname($s);
 264                         warn "# bound $scheme://$k\n";
 265                         $listener_names->{$k} = $s;
 266                         push @listeners, $s;
 267                 }
 268         }
 269
 270         # cert/key options in @cfg_listen takes precedence when inheriting,
 271         # but map well-known inherited ports if --listen isn't specified
 272         # at all
 273         for my $sockname (@inherited_names) {
 274                 $sockname =~ /:([0-9]+)\z/ or next;
 275                 if (my $scheme = $KNOWN_TLS{$1}) {
 276                         $xnetd->{$sockname} = load_mod($scheme);
 277                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 278                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 279                         $xnetd->{$sockname} = load_mod($scheme);
 280                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 281                         $tls_opt{''} ||= accept_tls_opt('');
 282                 }
 283         }
 284         my @d;
 285         while (my ($k, $v) = each %tls_opt) { push(@d, $k) if !defined($v) }
 286         delete @tls_opt{@d};
 287         die "No listeners bound\n" unless @listeners;
 288 }
 289
 290 sub daemonize () {
 291         if ($daemonize) {
 292                 require Cwd;
 293                 foreach my $i (0..$#ARGV) {
 294                         my $arg = $ARGV[$i];
 295                         next unless -e $arg;
 296                         $ARGV[$i] = Cwd::abs_path($arg);
 297                 }
 298                 check_absolute('--stdout', $stdout);
 299                 check_absolute('--stderr', $stderr);
 300                 check_absolute('--pid-file', $pid_file);
 301                 check_absolute('--cert', $default_cert);
 302                 check_absolute('--key', $default_key);
 303
 304                 chdir '/' or die "chdir failed: $!";
 305         }
 306         if (defined($pid_file) || defined($group) || defined($user)) {
 307                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 308 Net::Server required for --pid-file, --group, --user
 309 $@
 310 EOF
 311         }
 312         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 313         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 314         if (defined $group) {
 315                 $gid = Net::Server::Daemonize::get_gid($group);
 316                 $gid = (split /\s+/, $gid)[0];
 317         } elsif (defined $uid) {
 318                 $gid = (getpwuid($uid))[3];
 319         }
 320
 321         # We change users in the worker to ensure upgradability,
 322         # The upgrade will create the ".oldbin" pid file in the
 323         # same directory as the given pid file.
 324         $uid and $set_user = sub {
 325                 $set_user = undef;
 326                 Net::Server::Daemonize::set_user($uid, $gid);
 327         };
 328
 329         if ($daemonize) {
 330                 my $pid = fork // die "fork: $!";
 331                 exit if $pid;
 332
 333                 open(STDIN, '+<', '/dev/null') or
 334                                         die "redirect stdin failed: $!\n";
 335                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 336                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 337                 POSIX::setsid();
 338                 $pid = fork // die "fork: $!";
 339                 exit if $pid;
 340         }
 341         return unless defined $pid_file;
 342
 343         write_pid($pid_file);
 344         # for ->DESTROY:
 345         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 346 }
 347
 348 sub worker_quit { # $_[0] = signal name or number (unused)
 349         # killing again terminates immediately:
 350         exit unless @listeners;
 351
 352         $_->close foreach @listeners; # call PublicInbox::DS::close
 353         @listeners = ();
 354         my $proc_name;
 355         my $warn = 0;
 356         # drop idle connections and try to quit gracefully
 357         PublicInbox::DS->SetPostLoopCallback(sub {
 358                 my ($dmap, undef) = @_;
 359                 my $n = 0;
 360                 my $now = now();
 361                 for my $s (values %$dmap) {
 362                         $s->can('busy') or next;
 363                         if ($s->busy) {
 364                                 ++$n;
 365                         } else { # close as much as possible, early as possible
 366                                 $s->close;
 367                         }
 368                 }
 369                 if ($n) {
 370                         if (($warn + 5) < now()) {
 371                                 warn "$$ quitting, $n client(s) left\n";
 372                                 $warn = now();
 373                         }
 374                         unless (defined $proc_name) {
 375                                 $proc_name = (split(/\s+/, $0))[0];
 376                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 377                         }
 378                         $0 = "$proc_name quitting, $n client(s) left";
 379                 }
 380                 $n; # true: loop continues, false: loop breaks
 381         });
 382 }
 383
 384 sub reopen_logs {
 385         $logs{$stdout} //= \*STDOUT if defined $stdout;
 386         $logs{$stderr} //= \*STDERR if defined $stderr;
 387         while (my ($p, $fh) = each %logs) { open_log_path($fh, $p) }
 388 }
 389
 390 sub sockname ($) {
 391         my ($s) = @_;
 392         my $addr = getsockname($s) or return;
 393         my ($host, $port) = host_with_port($addr);
 394         if ($port == 0 && $host eq '127.0.0.1') {
 395                 my ($path) = Socket::sockaddr_un($addr);
 396                 return $path;
 397         }
 398         "$host:$port";
 399 }
 400
 401 sub unpack_ipv6 ($) {
 402         my ($addr) = @_;
 403         my ($port, $host);
 404
 405         # Socket.pm in Perl 5.14+ supports IPv6:
 406         eval {
 407                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 408                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 409         };
 410
 411         if ($@) {
 412                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 413                 # Socket6, so it may be installed on our system, already
 414                 # (otherwise die here):
 415                 require Socket6;
 416
 417                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 418                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 419         }
 420         ($host, $port);
 421 }
 422
 423 sub host_with_port ($) {
 424         my ($addr) = @_;
 425         my ($port, $host);
 426
 427         # this eval will die on Unix sockets:
 428         eval {
 429                 if (length($addr) >= 28) {
 430                         ($host, $port) = unpack_ipv6($addr);
 431                         $host = "[$host]";
 432                 } else {
 433                         ($port, $host) = Socket::sockaddr_in($addr);
 434                         $host = Socket::inet_ntoa($host);
 435                 }
 436         };
 437         $@ ? ('127.0.0.1', 0) : ($host, $port);
 438 }
 439
 440 sub inherit ($) {
 441         my ($listener_names) = @_;
 442         return () if ($ENV{LISTEN_PID} || 0) != $$;
 443         my $fds = $ENV{LISTEN_FDS} or return ();
 444         my $end = $fds + 2; # LISTEN_FDS_START - 1
 445         my @rv = ();
 446         foreach my $fd (3..$end) {
 447                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 448                 if (my $k = sockname($s)) {
 449                         my $prev_was_blocking = $s->blocking(0);
 450                         warn <<"" if $prev_was_blocking;
 451 Inherited socket ($k fd=$fd) is blocking, making it non-blocking.
 452 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 453 processes when multiple service instances start.
 454
 455                         $listener_names->{$k} = $s;
 456                         warn "# inherited $k fd=$fd\n";
 457                         push @rv, $s;
 458                 } else {
 459                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 460                 }
 461         }
 462         @rv
 463 }
 464
 465 sub upgrade { # $_[0] = signal name or number (unused)
 466         if ($reexec_pid) {
 467                 warn "upgrade in-progress: $reexec_pid\n";
 468                 return;
 469         }
 470         if (defined $pid_file) {
 471                 if ($pid_file =~ /\.oldbin\z/) {
 472                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 473                         return;
 474                 }
 475                 unlink_pid_file_safe_ish($$, $pid_file);
 476                 $pid_file .= '.oldbin';
 477                 write_pid($pid_file);
 478         }
 479         my $pid = fork;
 480         unless (defined $pid) {
 481                 warn "fork failed: $!\n";
 482                 return;
 483         }
 484         if ($pid == 0) {
 485                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 486                 $ENV{LISTEN_FDS} = scalar @listeners;
 487                 $ENV{LISTEN_PID} = $$;
 488                 foreach my $s (@listeners) {
 489                         # @listeners are globs with workers, PI::L w/o workers
 490                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 491
 492                         my $fl = fcntl($s, F_GETFD, 0);
 493                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 494                 }
 495                 exec @CMD;
 496                 die "Failed to exec: $!\n";
 497         }
 498         $reexec_pid = $pid;
 499 }
 500
 501 sub kill_workers ($) {
 502         my ($sig) = @_;
 503         kill $sig, keys(%pids);
 504 }
 505
 506 sub upgrade_aborted ($) {
 507         my ($p) = @_;
 508         warn "reexec PID($p) died with: $?\n";
 509         $reexec_pid = undef;
 510         return unless $pid_file;
 511
 512         my $file = $pid_file;
 513         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 514         unlink_pid_file_safe_ish($$, $pid_file);
 515         $pid_file = $file;
 516         eval { write_pid($pid_file) };
 517         warn $@, "\n" if $@;
 518 }
 519
 520 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 521         while (1) {
 522                 my $p = waitpid(-1, WNOHANG) or return;
 523                 if (defined $reexec_pid && $p == $reexec_pid) {
 524                         upgrade_aborted($p);
 525                 } elsif (defined(my $id = delete $pids{$p})) {
 526                         warn "worker[$id] PID($p) died with: $?\n";
 527                 } elsif ($p > 0) {
 528                         warn "unknown PID($p) reaped: $?\n";
 529                 } else {
 530                         return;
 531                 }
 532         }
 533 }
 534
 535 sub unlink_pid_file_safe_ish ($$) {
 536         my ($unlink_pid, $file) = @_;
 537         return unless defined $unlink_pid && $unlink_pid == $$;
 538
 539         open my $fh, '<', $file or return;
 540         local $/ = "\n";
 541         defined(my $read_pid = <$fh>) or return;
 542         chomp $read_pid;
 543         if ($read_pid == $unlink_pid) {
 544                 Net::Server::Daemonize::unlink_pid_file($file);
 545         }
 546 }
 547
 548 sub master_quit ($) {
 549         exit unless @listeners;
 550         @listeners = ();
 551         kill_workers($_[0]);
 552 }
 553
 554 sub master_loop {
 555         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 556         my $set_workers = $worker_processes;
 557         reopen_logs();
 558         my $ignore_winch;
 559         my $sig = {
 560                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 561                 USR2 => \&upgrade,
 562                 QUIT => \&master_quit,
 563                 INT => \&master_quit,
 564                 TERM => \&master_quit,
 565                 WINCH => sub {
 566                         return if $ignore_winch || !@listeners;
 567                         if (-t STDIN || -t STDOUT || -t STDERR) {
 568                                 $ignore_winch = 1;
 569                                 warn <<EOF;
 570 ignoring SIGWINCH since we are not daemonized
 571 EOF
 572                         } else {
 573                                 $worker_processes = 0;
 574                         }
 575                 },
 576                 HUP => sub {
 577                         return unless @listeners;
 578                         $worker_processes = $set_workers;
 579                         kill_workers($_[0]);
 580                 },
 581                 TTIN => sub {
 582                         return unless @listeners;
 583                         if ($set_workers > $worker_processes) {
 584                                 ++$worker_processes;
 585                         } else {
 586                                 $worker_processes = ++$set_workers;
 587                         }
 588                 },
 589                 TTOU => sub {
 590                         $worker_processes = --$set_workers if $set_workers > 0;
 591                 },
 592                 CHLD => \&reap_children,
 593         };
 594         my $sigfd = PublicInbox::Sigfd->new($sig);
 595         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 596         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 597         while (1) { # main loop
 598                 my $n = scalar keys %pids;
 599                 unless (@listeners) {
 600                         exit if $n == 0;
 601                         $set_workers = $worker_processes = $n = 0;
 602                 }
 603
 604                 if ($n > $worker_processes) {
 605                         while (my ($k, $v) = each %pids) {
 606                                 kill('TERM', $k) if $v >= $worker_processes;
 607                         }
 608                         $n = $worker_processes;
 609                 }
 610                 my $want = $worker_processes - 1;
 611                 if ($n <= $want) {
 612                         PublicInbox::DS::block_signals() if !$sigfd;
 613                         for my $i ($n..$want) {
 614                                 my $seed = rand(0xffffffff);
 615                                 my $pid = fork;
 616                                 if (!defined $pid) {
 617                                         warn "failed to fork worker[$i]: $!\n";
 618                                 } elsif ($pid == 0) {
 619                                         srand($seed);
 620                                         eval { Net::SSLeay::randomize() };
 621                                         $set_user->() if $set_user;
 622                                         return $p0; # run normal work code
 623                                 } else {
 624                                         warn "PID=$pid is worker[$i]\n";
 625                                         $pids{$pid} = $i;
 626                                 }
 627                         }
 628                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 629                 }
 630
 631                 if ($sigfd) { # Linux and IO::KQueue users:
 632                         $sigfd->wait_once;
 633                 } else { # wake up every second
 634                         sleep(1);
 635                 }
 636         }
 637         exit # never gets here, just for documentation
 638 }
 639
 640 sub tls_start_cb ($$) {
 641         my ($opt, $orig_post_accept) = @_;
 642         sub {
 643                 my ($io, $addr, $srv) = @_;
 644                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 645                 $orig_post_accept->($ssl, $addr, $srv);
 646         }
 647 }
 648
 649 sub defer_accept ($$) {
 650         my ($s, $af_name) = @_;
 651         return unless defined $af_name;
 652         if ($^O eq 'linux') {
 653                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 654                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 655                 return unless defined $x; # may be Unix socket
 656                 my $sec = unpack('i', $x);
 657                 return if $sec > 0; # systemd users may set a higher value
 658                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 659         } elsif ($^O eq 'freebsd') {
 660                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 661                 return if defined $x; # don't change if set
 662                 my $accf_arg = pack('a16a240', $af_name, '');
 663                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 664         }
 665 }
 666
 667 sub daemon_loop ($) {
 668         my ($xnetd) = @_;
 669         my $refresh = sub {
 670                 my ($sig) = @_;
 671                 for my $xn (values %$xnetd) {
 672                         eval { $xn->{refresh}->($sig) };
 673                         warn "refresh $@\n" if $@;
 674                 }
 675         };
 676         my %post_accept;
 677         while (my ($k, $v) = each %tls_opt) {
 678                 my $l = $k;
 679                 $l =~ s!\A([^:]+)://!!;
 680                 my $scheme = $1 // '';
 681                 my $xn = $xnetd->{$l} // $xnetd->{''};
 682                 if ($scheme =~ m!\A(?:https|imaps|nntps|pop3s)!) {
 683                         $post_accept{$l} = tls_start_cb($v, $xn->{post_accept});
 684                 } elsif ($xn->{tlsd}) { # STARTTLS, $k eq '' is OK
 685                         $xn->{tlsd}->{accept_tls} = $v;
 686                 }
 687         }
 688         my $sig = {
 689                 HUP => $refresh,
 690                 INT => \&worker_quit,
 691                 QUIT => \&worker_quit,
 692                 TERM => \&worker_quit,
 693                 TTIN => 'IGNORE',
 694                 TTOU => 'IGNORE',
 695                 USR1 => \&reopen_logs,
 696                 USR2 => 'IGNORE',
 697                 WINCH => 'IGNORE',
 698                 CHLD => \&PublicInbox::DS::enqueue_reap,
 699         };
 700         if ($worker_processes > 0) {
 701                 $refresh->(); # preload by default
 702                 my $fh = master_loop(); # returns if in child process
 703                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 704         } else {
 705                 reopen_logs();
 706                 $set_user->() if $set_user;
 707                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 708                 $refresh->();
 709         }
 710         $uid = $gid = undef;
 711         reopen_logs();
 712         @listeners = map {;
 713                 my $l = sockname($_);
 714                 my $tls_cb = $post_accept{$l};
 715                 my $xn = $xnetd->{$l} // $xnetd->{''};
 716
 717                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 718                 # IMAP, NNTP and POP3 are server-first
 719                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 720
 721                 # this calls epoll_create:
 722                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 723         } @listeners;
 724         PublicInbox::DS::event_loop($sig, $oldset);
 725 }
 726
 727 sub run {
 728         my ($default_listen) = @_;
 729         my $xnetd = {};
 730         if ($default_listen) {
 731                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 732                         die "BUG: $default_listen";
 733                 $xnetd->{''} = load_mod($1);
 734         }
 735         daemon_prepare($default_listen, $xnetd);
 736         my $for_destroy = daemonize();
 737
 738         # localize GCF2C for tests:
 739         local $PublicInbox::GitAsyncCat::GCF2C;
 740         local $PublicInbox::Git::async_warn = 1;
 741         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 742
 743         daemon_loop($xnetd);
 744         PublicInbox::DS->Reset;
 745         # ->DESTROY runs when $for_destroy goes out-of-scope
 746 }
 747
 748 sub write_pid ($) {
 749         my ($path) = @_;
 750         Net::Server::Daemonize::create_pid_file($path);
 751         do_chown($path);
 752 }
 753
 754 sub DESTROY {
 755         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 756 }
 757
 758 1;