lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the httpd, imapd, and nntpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle; # ->autoflush
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 use Cwd qw/abs_path/;
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Syscall qw($SFD_NONBLOCK);
  19 require PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 my @CMD;
  23 my ($set_user, $oldset);
  24 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  25 my $worker_processes = 1;
  26 my @listeners;
  27 my %pids;
  28 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  29 my $reexec_pid;
  30 my ($uid, $gid);
  31 my ($default_cert, $default_key);
  32 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps', 993 => 'imaps' );
  33 my %KNOWN_STARTTLS = ( 119 => 'nntp', 143 => 'imap' );
  34
  35 sub accept_tls_opt ($) {
  36         my ($opt_str) = @_;
  37         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  38         require PublicInbox::TLS;
  39         my $o = {};
  40         # allow ',' as delimiter since '&' is shell-unfriendly
  41         foreach (split(/[,&]/, $opt_str)) {
  42                 my ($k, $v) = split(/=/, $_, 2);
  43                 push @{$o->{$k} ||= []}, $v;
  44         }
  45
  46         # key may be a part of cert.  At least
  47         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  48         $o->{cert} //= [ $default_cert ];
  49         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  50         my %ctx_opt = (SSL_server => 1);
  51         # parse out hostname:/path/to/ mappings:
  52         foreach my $k (qw(cert key)) {
  53                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  54                 foreach my $path (@{$o->{$k}}) {
  55                         my $host = '';
  56                         $path =~ s/\A([^:]+):// and $host = $1;
  57                         $x->{$host} = $path;
  58                 }
  59         }
  60         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  61                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  62
  63         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  64         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  65         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  66         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  67         if ($mode && $ctx->{context}) {
  68                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  69                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  70         }
  71
  72         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  73 }
  74
  75 sub daemon_prepare ($) {
  76         my ($default_listen) = @_;
  77         my $listener_names = {}; # sockname => IO::Handle
  78         $oldset = PublicInbox::Sigfd::block_signals();
  79         @CMD = ($0, @ARGV);
  80         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  81         my $help = <<EOF;
  82 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
  83
  84 options:
  85
  86   -l ADDRESS    address to listen on (default: $default_listen)
  87   --cert=FILE   default SSL/TLS certificate
  88   --key=FILE    default SSL/TLS certificate
  89   -W WORKERS    number of worker processes to spawn (default: 1)
  90
  91 See public-inbox-daemon(8) and $prog(1) man pages for more.
  92 EOF
  93         my %opt = (
  94                 'l|listen=s' => \@cfg_listen,
  95                 '1|stdout=s' => \$stdout,
  96                 '2|stderr=s' => \$stderr,
  97                 'W|worker-processes=i' => \$worker_processes,
  98                 'P|pid-file=s' => \$pid_file,
  99                 'u|user=s' => \$user,
 100                 'g|group=s' => \$group,
 101                 'D|daemonize' => \$daemonize,
 102                 'cert=s' => \$default_cert,
 103                 'key=s' => \$default_key,
 104                 'help|h' => \(my $show_help),
 105         );
 106         GetOptions(%opt) or die $help;
 107         if ($show_help) { print $help; exit 0 };
 108
 109         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 110                 die "--pid-file cannot end with '.oldbin'\n";
 111         }
 112         @listeners = inherit($listener_names);
 113
 114         # allow socket-activation users to set certs once and not
 115         # have to configure each socket:
 116         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 117
 118         # ignore daemonize when inheriting
 119         $daemonize = undef if scalar @listeners;
 120
 121         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 122
 123         foreach my $l (@cfg_listen) {
 124                 my $orig = $l;
 125                 my $scheme = '';
 126                 if ($l =~ s!\A([^:]+)://!!) {
 127                         $scheme = $1;
 128                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 129                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 130                         $scheme = $s if defined $s;
 131                 }
 132                 if ($l =~ s!/?\?(.+)\z!!) {
 133                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 134                 } elsif (defined($default_cert)) {
 135                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 136                 } elsif ($scheme =~ /\A(?:https|imaps|imaps)\z/) {
 137                         die "$orig specified w/o cert=\n";
 138                 }
 139                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 140
 141                 next if $listener_names->{$l}; # already inherited
 142                 my (%o, $sock_pkg);
 143                 if (index($l, '/') == 0) {
 144                         $sock_pkg = 'IO::Socket::UNIX';
 145                         eval "use $sock_pkg";
 146                         die $@ if $@;
 147                         %o = (Type => SOCK_STREAM, Peer => $l);
 148                         if (-S $l) {
 149                                 my $c = $sock_pkg->new(%o);
 150                                 if (!defined($c) && $!{ECONNREFUSED}) {
 151                                         unlink $l or die
 152 "failed to unlink stale socket=$l: $!\n";
 153                                 } # else: let the bind fail
 154                         }
 155                         $o{Local} = delete $o{Peer};
 156                 } else {
 157                         # both work for IPv4, too
 158                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 159                                 $sock_pkg = $_;
 160                                 eval "use $sock_pkg";
 161                                 $@ or last;
 162                         }
 163                         die $@ if $@;
 164                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 165                 }
 166                 $o{Listen} = 1024;
 167                 my $prev = umask 0000;
 168                 my $s = eval { $sock_pkg->new(%o) };
 169                 warn "error binding $l: $! ($@)\n" unless $s;
 170                 umask $prev;
 171                 if ($s) {
 172                         $listener_names->{sockname($s)} = $s;
 173                         $s->blocking(0);
 174                         push @listeners, $s;
 175                 }
 176         }
 177
 178         # cert/key options in @cfg_listen takes precedence when inheriting,
 179         # but map well-known inherited ports if --listen isn't specified
 180         # at all
 181         for my $sockname (@inherited_names) {
 182                 $sockname =~ /:([0-9]+)\z/ or next;
 183                 if (my $scheme = $KNOWN_TLS{$1}) {
 184                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 185                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 186                         next if $tls_opt{"$scheme://$sockname"};
 187                         $tls_opt{''} ||= accept_tls_opt('');
 188                 }
 189         }
 190
 191         die "No listeners bound\n" unless @listeners;
 192 }
 193
 194 sub check_absolute ($$) {
 195         my ($var, $val) = @_;
 196         if (defined $val && index($val, '/') != 0) {
 197                 die
 198 "--$var must be an absolute path when using --daemonize: $val\n";
 199         }
 200 }
 201
 202 sub daemonize () {
 203         if ($daemonize) {
 204                 foreach my $i (0..$#ARGV) {
 205                         my $arg = $ARGV[$i];
 206                         next unless -e $arg;
 207                         $ARGV[$i] = abs_path($arg);
 208                 }
 209                 check_absolute('stdout', $stdout);
 210                 check_absolute('stderr', $stderr);
 211                 check_absolute('pid-file', $pid_file);
 212
 213                 chdir '/' or die "chdir failed: $!";
 214         }
 215         if (defined($pid_file) || defined($group) || defined($user)) {
 216                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 217 Net::Server required for --pid-file, --group, --user
 218 $@
 219 EOF
 220         }
 221         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 222         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 223         if (defined $group) {
 224                 $gid = Net::Server::Daemonize::get_gid($group);
 225                 $gid = (split /\s+/, $gid)[0];
 226         } elsif (defined $uid) {
 227                 $gid = (getpwuid($uid))[3];
 228         }
 229
 230         # We change users in the worker to ensure upgradability,
 231         # The upgrade will create the ".oldbin" pid file in the
 232         # same directory as the given pid file.
 233         $uid and $set_user = sub {
 234                 $set_user = undef;
 235                 Net::Server::Daemonize::set_user($uid, $gid);
 236         };
 237
 238         if ($daemonize) {
 239                 my $pid = fork;
 240                 die "could not fork: $!\n" unless defined $pid;
 241                 exit if $pid;
 242
 243                 open(STDIN, '+<', '/dev/null') or
 244                                         die "redirect stdin failed: $!\n";
 245                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 246                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 247                 POSIX::setsid();
 248                 $pid = fork;
 249                 die "could not fork: $!\n" unless defined $pid;
 250                 exit if $pid;
 251         }
 252         return unless defined $pid_file;
 253
 254         write_pid($pid_file);
 255         # for ->DESTROY:
 256         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 257 }
 258
 259 sub worker_quit { # $_[0] = signal name or number (unused)
 260         # killing again terminates immediately:
 261         exit unless @listeners;
 262
 263         $_->close foreach @listeners; # call PublicInbox::DS::close
 264         @listeners = ();
 265         my $proc_name;
 266         my $warn = 0;
 267         # drop idle connections and try to quit gracefully
 268         PublicInbox::DS->SetPostLoopCallback(sub {
 269                 my ($dmap, undef) = @_;
 270                 my $n = 0;
 271                 my $now = now();
 272
 273                 foreach my $s (values %$dmap) {
 274                         $s->can('busy') or next;
 275                         if ($s->busy($now)) {
 276                                 ++$n;
 277                         } else {
 278                                 # close as much as possible, early as possible
 279                                 $s->close;
 280                         }
 281                 }
 282                 if ($n) {
 283                         if (($warn + 5) < now()) {
 284                                 warn "$$ quitting, $n client(s) left\n";
 285                                 $warn = now();
 286                         }
 287                         unless (defined $proc_name) {
 288                                 $proc_name = (split(/\s+/, $0))[0];
 289                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 290                         }
 291                         $0 = "$proc_name quitting, $n client(s) left";
 292                 }
 293                 $n; # true: loop continues, false: loop breaks
 294         });
 295 }
 296
 297 sub reopen_logs {
 298         if ($stdout) {
 299                 open STDOUT, '>>', $stdout or
 300                         warn "failed to redirect stdout to $stdout: $!\n";
 301                 STDOUT->autoflush(1);
 302                 do_chown($stdout);
 303         }
 304         if ($stderr) {
 305                 open STDERR, '>>', $stderr or
 306                         warn "failed to redirect stderr to $stderr: $!\n";
 307                 STDERR->autoflush(1);
 308                 do_chown($stderr);
 309         }
 310 }
 311
 312 sub sockname ($) {
 313         my ($s) = @_;
 314         my $addr = getsockname($s) or return;
 315         my ($host, $port) = host_with_port($addr);
 316         if ($port == 0 && $host eq '127.0.0.1') {
 317                 my ($path) = Socket::sockaddr_un($addr);
 318                 return $path;
 319         }
 320         "$host:$port";
 321 }
 322
 323 sub unpack_ipv6 ($) {
 324         my ($addr) = @_;
 325         my ($port, $host);
 326
 327         # Socket.pm in Perl 5.14+ supports IPv6:
 328         eval {
 329                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 330                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 331         };
 332
 333         if ($@) {
 334                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 335                 # Socket6, so it may be installed on our system, already
 336                 # (otherwise die here):
 337                 require Socket6;
 338
 339                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 340                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 341         }
 342         ($host, $port);
 343 }
 344
 345 sub host_with_port ($) {
 346         my ($addr) = @_;
 347         my ($port, $host);
 348
 349         # this eval will die on Unix sockets:
 350         eval {
 351                 if (length($addr) >= 28) {
 352                         ($host, $port) = unpack_ipv6($addr);
 353                         $host = "[$host]";
 354                 } else {
 355                         ($port, $host) = Socket::sockaddr_in($addr);
 356                         $host = Socket::inet_ntoa($host);
 357                 }
 358         };
 359         $@ ? ('127.0.0.1', 0) : ($host, $port);
 360 }
 361
 362 sub inherit ($) {
 363         my ($listener_names) = @_;
 364         return () if ($ENV{LISTEN_PID} || 0) != $$;
 365         my $fds = $ENV{LISTEN_FDS} or return ();
 366         my $end = $fds + 2; # LISTEN_FDS_START - 1
 367         my @rv = ();
 368         foreach my $fd (3..$end) {
 369                 my $s = IO::Handle->new_from_fd($fd, 'r');
 370                 if (my $k = sockname($s)) {
 371                         if ($s->blocking) {
 372                                 $s->blocking(0);
 373                                 warn <<"";
 374 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 375 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 376 processes when multiple service instances start.
 377
 378                         }
 379                         $listener_names->{$k} = $s;
 380                         push @rv, $s;
 381                 } else {
 382                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 383                 }
 384         }
 385         @rv
 386 }
 387
 388 sub upgrade { # $_[0] = signal name or number (unused)
 389         if ($reexec_pid) {
 390                 warn "upgrade in-progress: $reexec_pid\n";
 391                 return;
 392         }
 393         if (defined $pid_file) {
 394                 if ($pid_file =~ /\.oldbin\z/) {
 395                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 396                         return;
 397                 }
 398                 unlink_pid_file_safe_ish($$, $pid_file);
 399                 $pid_file .= '.oldbin';
 400                 write_pid($pid_file);
 401         }
 402         my $pid = fork;
 403         unless (defined $pid) {
 404                 warn "fork failed: $!\n";
 405                 return;
 406         }
 407         if ($pid == 0) {
 408                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 409                 $ENV{LISTEN_FDS} = scalar @listeners;
 410                 $ENV{LISTEN_PID} = $$;
 411                 foreach my $s (@listeners) {
 412                         # @listeners are globs with workers, PI::L w/o workers
 413                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 414
 415                         my $fl = fcntl($s, F_GETFD, 0);
 416                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 417                 }
 418                 exec @CMD;
 419                 die "Failed to exec: $!\n";
 420         }
 421         $reexec_pid = $pid;
 422 }
 423
 424 sub kill_workers ($) {
 425         my ($s) = @_;
 426
 427         while (my ($pid, $id) = each %pids) {
 428                 kill $s, $pid;
 429         }
 430 }
 431
 432 sub upgrade_aborted ($) {
 433         my ($p) = @_;
 434         warn "reexec PID($p) died with: $?\n";
 435         $reexec_pid = undef;
 436         return unless $pid_file;
 437
 438         my $file = $pid_file;
 439         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 440         unlink_pid_file_safe_ish($$, $pid_file);
 441         $pid_file = $file;
 442         eval { write_pid($pid_file) };
 443         warn $@, "\n" if $@;
 444 }
 445
 446 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 447         while (1) {
 448                 my $p = waitpid(-1, WNOHANG) or return;
 449                 if (defined $reexec_pid && $p == $reexec_pid) {
 450                         upgrade_aborted($p);
 451                 } elsif (defined(my $id = delete $pids{$p})) {
 452                         warn "worker[$id] PID($p) died with: $?\n";
 453                 } elsif ($p > 0) {
 454                         warn "unknown PID($p) reaped: $?\n";
 455                 } else {
 456                         return;
 457                 }
 458         }
 459 }
 460
 461 sub unlink_pid_file_safe_ish ($$) {
 462         my ($unlink_pid, $file) = @_;
 463         return unless defined $unlink_pid && $unlink_pid == $$;
 464
 465         open my $fh, '<', $file or return;
 466         local $/ = "\n";
 467         defined(my $read_pid = <$fh>) or return;
 468         chomp $read_pid;
 469         if ($read_pid == $unlink_pid) {
 470                 Net::Server::Daemonize::unlink_pid_file($file);
 471         }
 472 }
 473
 474 sub master_quit ($) {
 475         exit unless @listeners;
 476         @listeners = ();
 477         kill_workers($_[0]);
 478 }
 479
 480 sub master_loop {
 481         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 482         my $set_workers = $worker_processes;
 483         reopen_logs();
 484         my $ignore_winch;
 485         my $sig = {
 486                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 487                 USR2 => \&upgrade,
 488                 QUIT => \&master_quit,
 489                 INT => \&master_quit,
 490                 TERM => \&master_quit,
 491                 WINCH => sub {
 492                         return if $ignore_winch || !@listeners;
 493                         if (-t STDIN || -t STDOUT || -t STDERR) {
 494                                 $ignore_winch = 1;
 495                                 warn <<EOF;
 496 ignoring SIGWINCH since we are not daemonized
 497 EOF
 498                         } else {
 499                                 $worker_processes = 0;
 500                         }
 501                 },
 502                 HUP => sub {
 503                         return unless @listeners;
 504                         $worker_processes = $set_workers;
 505                         kill_workers($_[0]);
 506                 },
 507                 TTIN => sub {
 508                         return unless @listeners;
 509                         if ($set_workers > $worker_processes) {
 510                                 ++$worker_processes;
 511                         } else {
 512                                 $worker_processes = ++$set_workers;
 513                         }
 514                 },
 515                 TTOU => sub {
 516                         $worker_processes = --$set_workers if $set_workers > 0;
 517                 },
 518                 CHLD => \&reap_children,
 519         };
 520         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 521         local %SIG = (%SIG, %$sig) if !$sigfd;
 522         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 523         while (1) { # main loop
 524                 my $n = scalar keys %pids;
 525                 unless (@listeners) {
 526                         exit if $n == 0;
 527                         $set_workers = $worker_processes = $n = 0;
 528                 }
 529
 530                 if ($n > $worker_processes) {
 531                         while (my ($k, $v) = each %pids) {
 532                                 kill('TERM', $k) if $v >= $worker_processes;
 533                         }
 534                         $n = $worker_processes;
 535                 }
 536                 my $want = $worker_processes - 1;
 537                 if ($n <= $want) {
 538                         PublicInbox::Sigfd::block_signals() if !$sigfd;
 539                         for my $i ($n..$want) {
 540                                 my $pid = fork;
 541                                 if (!defined $pid) {
 542                                         warn "failed to fork worker[$i]: $!\n";
 543                                 } elsif ($pid == 0) {
 544                                         $set_user->() if $set_user;
 545                                         return $p0; # run normal work code
 546                                 } else {
 547                                         warn "PID=$pid is worker[$i]\n";
 548                                         $pids{$pid} = $i;
 549                                 }
 550                         }
 551                         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 552                 }
 553
 554                 if ($sigfd) { # Linux and IO::KQueue users:
 555                         $sigfd->wait_once;
 556                 } else { # wake up every second
 557                         sleep(1);
 558                 }
 559         }
 560         exit # never gets here, just for documentation
 561 }
 562
 563 sub tls_start_cb ($$) {
 564         my ($opt, $orig_post_accept) = @_;
 565         sub {
 566                 my ($io, $addr, $srv) = @_;
 567                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 568                 $orig_post_accept->($ssl, $addr, $srv);
 569         }
 570 }
 571
 572 sub defer_accept ($$) {
 573         my ($s, $af_name) = @_;
 574         return unless defined $af_name;
 575         if ($^O eq 'linux') {
 576                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 577                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 578                 return unless defined $x; # may be Unix socket
 579                 my $sec = unpack('i', $x);
 580                 return if $sec > 0; # systemd users may set a higher value
 581                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 582         } elsif ($^O eq 'freebsd') {
 583                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 584                 return if defined $x; # don't change if set
 585                 my $accf_arg = pack('a16a240', $af_name, '');
 586                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 587         }
 588 }
 589
 590 sub daemon_loop ($$$$) {
 591         my ($refresh, $post_accept, $tlsd, $af_default) = @_;
 592         my %post_accept;
 593         while (my ($k, $v) = each %tls_opt) {
 594                 if ($k =~ s!\A(?:https|imaps|nntps)://!!) {
 595                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 596                 } elsif ($tlsd) { # STARTTLS, $k eq '' is OK
 597                         $tlsd->{accept_tls} = $v;
 598                 }
 599         }
 600         my $sig = {
 601                 HUP => $refresh,
 602                 INT => \&worker_quit,
 603                 QUIT => \&worker_quit,
 604                 TERM => \&worker_quit,
 605                 TTIN => 'IGNORE',
 606                 TTOU => 'IGNORE',
 607                 USR1 => \&reopen_logs,
 608                 USR2 => 'IGNORE',
 609                 WINCH => 'IGNORE',
 610                 CHLD => \&PublicInbox::DS::enqueue_reap,
 611         };
 612         if ($worker_processes > 0) {
 613                 $refresh->(); # preload by default
 614                 my $fh = master_loop(); # returns if in child process
 615                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 616         } else {
 617                 reopen_logs();
 618                 $set_user->() if $set_user;
 619                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 620                 $refresh->();
 621         }
 622         $uid = $gid = undef;
 623         reopen_logs();
 624         @listeners = map {;
 625                 my $tls_cb = $post_accept{sockname($_)};
 626
 627                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 628                 # IMAP, NNTP and POP3 are server-first
 629                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 630
 631                 # this calls epoll_create:
 632                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 633         } @listeners;
 634         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 635         local %SIG = (%SIG, %$sig) if !$sigfd;
 636         if (!$sigfd) {
 637                 # wake up every second to accept signals if we don't
 638                 # have signalfd or IO::KQueue:
 639                 PublicInbox::Sigfd::sig_setmask($oldset);
 640                 PublicInbox::DS->SetLoopTimeout(1000);
 641         }
 642         PublicInbox::DS->EventLoop;
 643 }
 644
 645 sub run ($$$;$) {
 646         my ($default, $refresh, $post_accept, $tlsd) = @_;
 647         local $SIG{PIPE} = 'IGNORE';
 648         daemon_prepare($default);
 649         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 650         my $for_destroy = daemonize();
 651         daemon_loop($refresh, $post_accept, $tlsd, $af_default);
 652         PublicInbox::DS->Reset;
 653         # ->DESTROY runs when $for_destroy goes out-of-scope
 654 }
 655
 656 sub do_chown ($) {
 657         my ($path) = @_;
 658         if (defined $uid and !chown($uid, $gid, $path)) {
 659                 warn "could not chown $path: $!\n";
 660         }
 661 }
 662
 663 sub write_pid ($) {
 664         my ($path) = @_;
 665         Net::Server::Daemonize::create_pid_file($path);
 666         do_chown($path);
 667 }
 668
 669 sub DESTROY {
 670         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 671 }
 672
 673 1;