lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use POSIX qw(WNOHANG :signal_h);
  14 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Listener;
  19 use PublicInbox::EOFpipe;
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::Git;
  22 use PublicInbox::GitAsyncCat;
  23 use PublicInbox::Eml;
  24 our $SO_ACCEPTFILTER = 0x1000;
  25 my @CMD;
  26 my ($set_user, $oldset);
  27 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  28 my $worker_processes = 1;
  29 my @listeners;
  30 my %pids;
  31 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  32 my $reexec_pid;
  33 my ($uid, $gid);
  34 my ($default_cert, $default_key);
  35 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps', 993 => 'imaps' );
  36 my %KNOWN_STARTTLS = ( 119 => 'nntp', 143 => 'imap' );
  37
  38 sub accept_tls_opt ($) {
  39         my ($opt_str) = @_;
  40         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  41         require PublicInbox::TLS;
  42         my $o = {};
  43         # allow ',' as delimiter since '&' is shell-unfriendly
  44         foreach (split(/[,&]/, $opt_str)) {
  45                 my ($k, $v) = split(/=/, $_, 2);
  46                 push @{$o->{$k} ||= []}, $v;
  47         }
  48
  49         # key may be a part of cert.  At least
  50         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  51         $o->{cert} //= [ $default_cert ];
  52         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  53         my %ctx_opt = (SSL_server => 1);
  54         # parse out hostname:/path/to/ mappings:
  55         foreach my $k (qw(cert key)) {
  56                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  57                 foreach my $path (@{$o->{$k}}) {
  58                         my $host = '';
  59                         $path =~ s/\A([^:]+):// and $host = $1;
  60                         $x->{$host} = $path;
  61                 }
  62         }
  63         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  64                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  65
  66         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  67         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  68         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  69         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  70         if ($mode && $ctx->{context}) {
  71                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  72                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  73         }
  74
  75         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  76 }
  77
  78 sub daemon_prepare ($) {
  79         my ($default_listen) = @_;
  80         my $listener_names = {}; # sockname => IO::Handle
  81         $oldset = PublicInbox::DS::block_signals();
  82         @CMD = ($0, @ARGV);
  83         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  84         my $help = <<EOF;
  85 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
  86
  87 options:
  88
  89   -l ADDRESS    address to listen on (default: $default_listen)
  90   --cert=FILE   default SSL/TLS certificate
  91   --key=FILE    default SSL/TLS certificate
  92   -W WORKERS    number of worker processes to spawn (default: 1)
  93
  94 See public-inbox-daemon(8) and $prog(1) man pages for more.
  95 EOF
  96         my %opt = (
  97                 'l|listen=s' => \@cfg_listen,
  98                 '1|stdout=s' => \$stdout,
  99                 '2|stderr=s' => \$stderr,
 100                 'W|worker-processes=i' => \$worker_processes,
 101                 'P|pid-file=s' => \$pid_file,
 102                 'u|user=s' => \$user,
 103                 'g|group=s' => \$group,
 104                 'D|daemonize' => \$daemonize,
 105                 'cert=s' => \$default_cert,
 106                 'key=s' => \$default_key,
 107                 'help|h' => \(my $show_help),
 108         );
 109         GetOptions(%opt) or die $help;
 110         if ($show_help) { print $help; exit 0 };
 111
 112         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 113                 die "--pid-file cannot end with '.oldbin'\n";
 114         }
 115         @listeners = inherit($listener_names);
 116
 117         # allow socket-activation users to set certs once and not
 118         # have to configure each socket:
 119         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 120
 121         # ignore daemonize when inheriting
 122         $daemonize = undef if scalar @listeners;
 123
 124         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 125
 126         foreach my $l (@cfg_listen) {
 127                 my $orig = $l;
 128                 my $scheme = '';
 129                 if ($l =~ s!\A([^:]+)://!!) {
 130                         $scheme = $1;
 131                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 132                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 133                         $scheme = $s if defined $s;
 134                 }
 135                 if ($l =~ s!/?\?(.+)\z!!) {
 136                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 137                 } elsif (defined($default_cert)) {
 138                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 139                 } elsif ($scheme =~ /\A(?:https|imaps|imaps)\z/) {
 140                         die "$orig specified w/o cert=\n";
 141                 }
 142                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 143
 144                 next if $listener_names->{$l}; # already inherited
 145                 my (%o, $sock_pkg);
 146                 if (index($l, '/') == 0) {
 147                         $sock_pkg = 'IO::Socket::UNIX';
 148                         eval "use $sock_pkg";
 149                         die $@ if $@;
 150                         %o = (Type => SOCK_STREAM, Peer => $l);
 151                         if (-S $l) {
 152                                 my $c = $sock_pkg->new(%o);
 153                                 if (!defined($c) && $!{ECONNREFUSED}) {
 154                                         unlink $l or die
 155 "failed to unlink stale socket=$l: $!\n";
 156                                 } # else: let the bind fail
 157                         }
 158                         $o{Local} = delete $o{Peer};
 159                 } else {
 160                         # both work for IPv4, too
 161                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 162                                 $sock_pkg = $_;
 163                                 eval "use $sock_pkg";
 164                                 $@ or last;
 165                         }
 166                         die $@ if $@;
 167                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 168                 }
 169                 $o{Listen} = 1024;
 170                 my $prev = umask 0000;
 171                 my $s = eval { $sock_pkg->new(%o) };
 172                 warn "error binding $l: $! ($@)\n" unless $s;
 173                 umask $prev;
 174                 if ($s) {
 175                         $listener_names->{sockname($s)} = $s;
 176                         $s->blocking(0);
 177                         push @listeners, $s;
 178                 }
 179         }
 180
 181         # cert/key options in @cfg_listen takes precedence when inheriting,
 182         # but map well-known inherited ports if --listen isn't specified
 183         # at all
 184         for my $sockname (@inherited_names) {
 185                 $sockname =~ /:([0-9]+)\z/ or next;
 186                 if (my $scheme = $KNOWN_TLS{$1}) {
 187                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 188                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 189                         next if $tls_opt{"$scheme://$sockname"};
 190                         $tls_opt{''} ||= accept_tls_opt('');
 191                 }
 192         }
 193
 194         die "No listeners bound\n" unless @listeners;
 195 }
 196
 197 sub check_absolute ($$) {
 198         my ($var, $val) = @_;
 199         if (defined $val && index($val, '/') != 0) {
 200                 die
 201 "--$var must be an absolute path when using --daemonize: $val\n";
 202         }
 203 }
 204
 205 sub daemonize () {
 206         if ($daemonize) {
 207                 require Cwd;
 208                 foreach my $i (0..$#ARGV) {
 209                         my $arg = $ARGV[$i];
 210                         next unless -e $arg;
 211                         $ARGV[$i] = Cwd::abs_path($arg);
 212                 }
 213                 check_absolute('stdout', $stdout);
 214                 check_absolute('stderr', $stderr);
 215                 check_absolute('pid-file', $pid_file);
 216
 217                 chdir '/' or die "chdir failed: $!";
 218         }
 219         if (defined($pid_file) || defined($group) || defined($user)) {
 220                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 221 Net::Server required for --pid-file, --group, --user
 222 $@
 223 EOF
 224         }
 225         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 226         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 227         if (defined $group) {
 228                 $gid = Net::Server::Daemonize::get_gid($group);
 229                 $gid = (split /\s+/, $gid)[0];
 230         } elsif (defined $uid) {
 231                 $gid = (getpwuid($uid))[3];
 232         }
 233
 234         # We change users in the worker to ensure upgradability,
 235         # The upgrade will create the ".oldbin" pid file in the
 236         # same directory as the given pid file.
 237         $uid and $set_user = sub {
 238                 $set_user = undef;
 239                 Net::Server::Daemonize::set_user($uid, $gid);
 240         };
 241
 242         if ($daemonize) {
 243                 my $pid = fork // die "fork: $!";
 244                 exit if $pid;
 245
 246                 open(STDIN, '+<', '/dev/null') or
 247                                         die "redirect stdin failed: $!\n";
 248                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 249                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 250                 POSIX::setsid();
 251                 $pid = fork // die "fork: $!";
 252                 exit if $pid;
 253         }
 254         return unless defined $pid_file;
 255
 256         write_pid($pid_file);
 257         # for ->DESTROY:
 258         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 259 }
 260
 261 sub worker_quit { # $_[0] = signal name or number (unused)
 262         # killing again terminates immediately:
 263         exit unless @listeners;
 264
 265         $_->close foreach @listeners; # call PublicInbox::DS::close
 266         @listeners = ();
 267         my $proc_name;
 268         my $warn = 0;
 269         # drop idle connections and try to quit gracefully
 270         PublicInbox::DS->SetPostLoopCallback(sub {
 271                 my ($dmap, undef) = @_;
 272                 my $n = 0;
 273                 my $now = now();
 274
 275                 foreach my $s (values %$dmap) {
 276                         $s->can('busy') or next;
 277                         if ($s->busy($now)) {
 278                                 ++$n;
 279                         } else {
 280                                 # close as much as possible, early as possible
 281                                 $s->close;
 282                         }
 283                 }
 284                 if ($n) {
 285                         if (($warn + 5) < now()) {
 286                                 warn "$$ quitting, $n client(s) left\n";
 287                                 $warn = now();
 288                         }
 289                         unless (defined $proc_name) {
 290                                 $proc_name = (split(/\s+/, $0))[0];
 291                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 292                         }
 293                         $0 = "$proc_name quitting, $n client(s) left";
 294                 }
 295                 $n; # true: loop continues, false: loop breaks
 296         });
 297 }
 298
 299 sub reopen_logs {
 300         if ($stdout) {
 301                 open STDOUT, '>>', $stdout or
 302                         warn "failed to redirect stdout to $stdout: $!\n";
 303                 STDOUT->autoflush(1);
 304                 do_chown($stdout);
 305         }
 306         if ($stderr) {
 307                 open STDERR, '>>', $stderr or
 308                         warn "failed to redirect stderr to $stderr: $!\n";
 309                 STDERR->autoflush(1);
 310                 do_chown($stderr);
 311         }
 312 }
 313
 314 sub sockname ($) {
 315         my ($s) = @_;
 316         my $addr = getsockname($s) or return;
 317         my ($host, $port) = host_with_port($addr);
 318         if ($port == 0 && $host eq '127.0.0.1') {
 319                 my ($path) = Socket::sockaddr_un($addr);
 320                 return $path;
 321         }
 322         "$host:$port";
 323 }
 324
 325 sub unpack_ipv6 ($) {
 326         my ($addr) = @_;
 327         my ($port, $host);
 328
 329         # Socket.pm in Perl 5.14+ supports IPv6:
 330         eval {
 331                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 332                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 333         };
 334
 335         if ($@) {
 336                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 337                 # Socket6, so it may be installed on our system, already
 338                 # (otherwise die here):
 339                 require Socket6;
 340
 341                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 342                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 343         }
 344         ($host, $port);
 345 }
 346
 347 sub host_with_port ($) {
 348         my ($addr) = @_;
 349         my ($port, $host);
 350
 351         # this eval will die on Unix sockets:
 352         eval {
 353                 if (length($addr) >= 28) {
 354                         ($host, $port) = unpack_ipv6($addr);
 355                         $host = "[$host]";
 356                 } else {
 357                         ($port, $host) = Socket::sockaddr_in($addr);
 358                         $host = Socket::inet_ntoa($host);
 359                 }
 360         };
 361         $@ ? ('127.0.0.1', 0) : ($host, $port);
 362 }
 363
 364 sub inherit ($) {
 365         my ($listener_names) = @_;
 366         return () if ($ENV{LISTEN_PID} || 0) != $$;
 367         my $fds = $ENV{LISTEN_FDS} or return ();
 368         my $end = $fds + 2; # LISTEN_FDS_START - 1
 369         my @rv = ();
 370         foreach my $fd (3..$end) {
 371                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 372                 if (my $k = sockname($s)) {
 373                         my $prev_was_blocking = $s->blocking(0);
 374                         warn <<"" if $prev_was_blocking;
 375 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 376 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 377 processes when multiple service instances start.
 378
 379                         $listener_names->{$k} = $s;
 380                         push @rv, $s;
 381                 } else {
 382                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 383                 }
 384         }
 385         @rv
 386 }
 387
 388 sub upgrade { # $_[0] = signal name or number (unused)
 389         if ($reexec_pid) {
 390                 warn "upgrade in-progress: $reexec_pid\n";
 391                 return;
 392         }
 393         if (defined $pid_file) {
 394                 if ($pid_file =~ /\.oldbin\z/) {
 395                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 396                         return;
 397                 }
 398                 unlink_pid_file_safe_ish($$, $pid_file);
 399                 $pid_file .= '.oldbin';
 400                 write_pid($pid_file);
 401         }
 402         my $pid = fork;
 403         unless (defined $pid) {
 404                 warn "fork failed: $!\n";
 405                 return;
 406         }
 407         if ($pid == 0) {
 408                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 409                 $ENV{LISTEN_FDS} = scalar @listeners;
 410                 $ENV{LISTEN_PID} = $$;
 411                 foreach my $s (@listeners) {
 412                         # @listeners are globs with workers, PI::L w/o workers
 413                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 414
 415                         my $fl = fcntl($s, F_GETFD, 0);
 416                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 417                 }
 418                 exec @CMD;
 419                 die "Failed to exec: $!\n";
 420         }
 421         $reexec_pid = $pid;
 422 }
 423
 424 sub kill_workers ($) {
 425         my ($sig) = @_;
 426         kill $sig, keys(%pids);
 427 }
 428
 429 sub upgrade_aborted ($) {
 430         my ($p) = @_;
 431         warn "reexec PID($p) died with: $?\n";
 432         $reexec_pid = undef;
 433         return unless $pid_file;
 434
 435         my $file = $pid_file;
 436         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 437         unlink_pid_file_safe_ish($$, $pid_file);
 438         $pid_file = $file;
 439         eval { write_pid($pid_file) };
 440         warn $@, "\n" if $@;
 441 }
 442
 443 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 444         while (1) {
 445                 my $p = waitpid(-1, WNOHANG) or return;
 446                 if (defined $reexec_pid && $p == $reexec_pid) {
 447                         upgrade_aborted($p);
 448                 } elsif (defined(my $id = delete $pids{$p})) {
 449                         warn "worker[$id] PID($p) died with: $?\n";
 450                 } elsif ($p > 0) {
 451                         warn "unknown PID($p) reaped: $?\n";
 452                 } else {
 453                         return;
 454                 }
 455         }
 456 }
 457
 458 sub unlink_pid_file_safe_ish ($$) {
 459         my ($unlink_pid, $file) = @_;
 460         return unless defined $unlink_pid && $unlink_pid == $$;
 461
 462         open my $fh, '<', $file or return;
 463         local $/ = "\n";
 464         defined(my $read_pid = <$fh>) or return;
 465         chomp $read_pid;
 466         if ($read_pid == $unlink_pid) {
 467                 Net::Server::Daemonize::unlink_pid_file($file);
 468         }
 469 }
 470
 471 sub master_quit ($) {
 472         exit unless @listeners;
 473         @listeners = ();
 474         kill_workers($_[0]);
 475 }
 476
 477 sub master_loop {
 478         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 479         my $set_workers = $worker_processes;
 480         reopen_logs();
 481         my $ignore_winch;
 482         my $sig = {
 483                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 484                 USR2 => \&upgrade,
 485                 QUIT => \&master_quit,
 486                 INT => \&master_quit,
 487                 TERM => \&master_quit,
 488                 WINCH => sub {
 489                         return if $ignore_winch || !@listeners;
 490                         if (-t STDIN || -t STDOUT || -t STDERR) {
 491                                 $ignore_winch = 1;
 492                                 warn <<EOF;
 493 ignoring SIGWINCH since we are not daemonized
 494 EOF
 495                         } else {
 496                                 $worker_processes = 0;
 497                         }
 498                 },
 499                 HUP => sub {
 500                         return unless @listeners;
 501                         $worker_processes = $set_workers;
 502                         kill_workers($_[0]);
 503                 },
 504                 TTIN => sub {
 505                         return unless @listeners;
 506                         if ($set_workers > $worker_processes) {
 507                                 ++$worker_processes;
 508                         } else {
 509                                 $worker_processes = ++$set_workers;
 510                         }
 511                 },
 512                 TTOU => sub {
 513                         $worker_processes = --$set_workers if $set_workers > 0;
 514                 },
 515                 CHLD => \&reap_children,
 516         };
 517         my $sigfd = PublicInbox::Sigfd->new($sig);
 518         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 519         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 520         while (1) { # main loop
 521                 my $n = scalar keys %pids;
 522                 unless (@listeners) {
 523                         exit if $n == 0;
 524                         $set_workers = $worker_processes = $n = 0;
 525                 }
 526
 527                 if ($n > $worker_processes) {
 528                         while (my ($k, $v) = each %pids) {
 529                                 kill('TERM', $k) if $v >= $worker_processes;
 530                         }
 531                         $n = $worker_processes;
 532                 }
 533                 my $want = $worker_processes - 1;
 534                 if ($n <= $want) {
 535                         PublicInbox::DS::block_signals() if !$sigfd;
 536                         for my $i ($n..$want) {
 537                                 my $seed = rand(0xffffffff);
 538                                 my $pid = fork;
 539                                 if (!defined $pid) {
 540                                         warn "failed to fork worker[$i]: $!\n";
 541                                 } elsif ($pid == 0) {
 542                                         srand($seed);
 543                                         eval { Net::SSLeay::randomize() };
 544                                         $set_user->() if $set_user;
 545                                         return $p0; # run normal work code
 546                                 } else {
 547                                         warn "PID=$pid is worker[$i]\n";
 548                                         $pids{$pid} = $i;
 549                                 }
 550                         }
 551                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 552                 }
 553
 554                 if ($sigfd) { # Linux and IO::KQueue users:
 555                         $sigfd->wait_once;
 556                 } else { # wake up every second
 557                         sleep(1);
 558                 }
 559         }
 560         exit # never gets here, just for documentation
 561 }
 562
 563 sub tls_start_cb ($$) {
 564         my ($opt, $orig_post_accept) = @_;
 565         sub {
 566                 my ($io, $addr, $srv) = @_;
 567                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 568                 $orig_post_accept->($ssl, $addr, $srv);
 569         }
 570 }
 571
 572 sub defer_accept ($$) {
 573         my ($s, $af_name) = @_;
 574         return unless defined $af_name;
 575         if ($^O eq 'linux') {
 576                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 577                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 578                 return unless defined $x; # may be Unix socket
 579                 my $sec = unpack('i', $x);
 580                 return if $sec > 0; # systemd users may set a higher value
 581                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 582         } elsif ($^O eq 'freebsd') {
 583                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 584                 return if defined $x; # don't change if set
 585                 my $accf_arg = pack('a16a240', $af_name, '');
 586                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 587         }
 588 }
 589
 590 sub daemon_loop ($$$$) {
 591         my ($refresh, $post_accept, $tlsd, $af_default) = @_;
 592         my %post_accept;
 593         while (my ($k, $v) = each %tls_opt) {
 594                 if ($k =~ s!\A(?:https|imaps|nntps)://!!) {
 595                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 596                 } elsif ($tlsd) { # STARTTLS, $k eq '' is OK
 597                         $tlsd->{accept_tls} = $v;
 598                 }
 599         }
 600         my $sig = {
 601                 HUP => $refresh,
 602                 INT => \&worker_quit,
 603                 QUIT => \&worker_quit,
 604                 TERM => \&worker_quit,
 605                 TTIN => 'IGNORE',
 606                 TTOU => 'IGNORE',
 607                 USR1 => \&reopen_logs,
 608                 USR2 => 'IGNORE',
 609                 WINCH => 'IGNORE',
 610                 CHLD => \&PublicInbox::DS::enqueue_reap,
 611         };
 612         if ($worker_processes > 0) {
 613                 $refresh->(); # preload by default
 614                 my $fh = master_loop(); # returns if in child process
 615                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 616         } else {
 617                 reopen_logs();
 618                 $set_user->() if $set_user;
 619                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 620                 $refresh->();
 621         }
 622         $uid = $gid = undef;
 623         reopen_logs();
 624         @listeners = map {;
 625                 my $tls_cb = $post_accept{sockname($_)};
 626
 627                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 628                 # IMAP, NNTP and POP3 are server-first
 629                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 630
 631                 # this calls epoll_create:
 632                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 633         } @listeners;
 634         PublicInbox::DS::event_loop($sig, $oldset);
 635 }
 636
 637 sub run ($$$;$) {
 638         my ($default, $refresh, $post_accept, $tlsd) = @_;
 639         daemon_prepare($default);
 640         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 641         my $for_destroy = daemonize();
 642
 643         # localize GCF2C for tests:
 644         local $PublicInbox::GitAsyncCat::GCF2C;
 645         local $PublicInbox::Git::async_warn = 1;
 646         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 647
 648         daemon_loop($refresh, $post_accept, $tlsd, $af_default);
 649         PublicInbox::DS->Reset;
 650         # ->DESTROY runs when $for_destroy goes out-of-scope
 651 }
 652
 653 sub do_chown ($) {
 654         my ($path) = @_;
 655         if (defined $uid and !chown($uid, $gid, $path)) {
 656                 warn "could not chown $path: $!\n";
 657         }
 658 }
 659
 660 sub write_pid ($) {
 661         my ($path) = @_;
 662         Net::Server::Daemonize::create_pid_file($path);
 663         do_chown($path);
 664 }
 665
 666 sub DESTROY {
 667         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 668 }
 669
 670 1;