lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 use Cwd qw/abs_path/;
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Syscall qw(SFD_NONBLOCK);
  19 require PublicInbox::Listener;
  20 require PublicInbox::ParentPipe;
  21 require PublicInbox::Sigfd;
  22 my @CMD;
  23 my ($set_user, $oldset, $newset);
  24 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  25 my $worker_processes = 1;
  26 my @listeners;
  27 my %pids;
  28 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  29 my $reexec_pid;
  30 my ($uid, $gid);
  31 my ($default_cert, $default_key);
  32 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps' );
  33 my %KNOWN_STARTTLS = ( 119 => 'nntp' );
  34
  35 sub accept_tls_opt ($) {
  36         my ($opt_str) = @_;
  37         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  38         require PublicInbox::TLS;
  39         my $o = {};
  40         # allow ',' as delimiter since '&' is shell-unfriendly
  41         foreach (split(/[,&]/, $opt_str)) {
  42                 my ($k, $v) = split(/=/, $_, 2);
  43                 push @{$o->{$k} ||= []}, $v;
  44         }
  45
  46         # key may be a part of cert.  At least
  47         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  48         $o->{cert} //= [ $default_cert ];
  49         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  50         my %ctx_opt = (SSL_server => 1);
  51         # parse out hostname:/path/to/ mappings:
  52         foreach my $k (qw(cert key)) {
  53                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  54                 foreach my $path (@{$o->{$k}}) {
  55                         my $host = '';
  56                         $path =~ s/\A([^:]+):// and $host = $1;
  57                         $x->{$host} = $path;
  58                 }
  59         }
  60         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  61                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  62
  63         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  64         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  65         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  66         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  67         if ($mode && $ctx->{context}) {
  68                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  69                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  70         }
  71
  72         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  73 }
  74
  75 sub sig_setmask { sigprocmask(SIG_SETMASK, @_) or die "sigprocmask: $!" }
  76
  77 sub daemon_prepare ($) {
  78         my ($default_listen) = @_;
  79         my $listener_names = {}; # sockname => IO::Handle
  80         $oldset = POSIX::SigSet->new();
  81         $newset = POSIX::SigSet->new();
  82         $newset->fillset or die "fillset: $!";
  83         sig_setmask($newset, $oldset);
  84         @CMD = ($0, @ARGV);
  85         my %opts = (
  86                 'l|listen=s' => \@cfg_listen,
  87                 '1|stdout=s' => \$stdout,
  88                 '2|stderr=s' => \$stderr,
  89                 'W|worker-processes=i' => \$worker_processes,
  90                 'P|pid-file=s' => \$pid_file,
  91                 'u|user=s' => \$user,
  92                 'g|group=s' => \$group,
  93                 'D|daemonize' => \$daemonize,
  94                 'cert=s' => \$default_cert,
  95                 'key=s' => \$default_key,
  96         );
  97         GetOptions(%opts) or die "bad command-line args\n";
  98
  99         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 100                 die "--pid-file cannot end with '.oldbin'\n";
 101         }
 102         @listeners = inherit($listener_names);
 103
 104         # allow socket-activation users to set certs once and not
 105         # have to configure each socket:
 106         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 107
 108         # ignore daemonize when inheriting
 109         $daemonize = undef if scalar @listeners;
 110
 111         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 112
 113         foreach my $l (@cfg_listen) {
 114                 my $orig = $l;
 115                 my $scheme = '';
 116                 if ($l =~ s!\A([^:]+)://!!) {
 117                         $scheme = $1;
 118                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 119                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 120                         $scheme = $s if defined $s;
 121                 }
 122                 if ($l =~ s!/?\?(.+)\z!!) {
 123                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 124                 } elsif (defined($default_cert)) {
 125                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 126                 } elsif ($scheme =~ /\A(?:nntps|https)\z/) {
 127                         die "$orig specified w/o cert=\n";
 128                 }
 129                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 130
 131                 next if $listener_names->{$l}; # already inherited
 132                 my (%o, $sock_pkg);
 133                 if (index($l, '/') == 0) {
 134                         $sock_pkg = 'IO::Socket::UNIX';
 135                         eval "use $sock_pkg";
 136                         die $@ if $@;
 137                         %o = (Type => SOCK_STREAM, Peer => $l);
 138                         if (-S $l) {
 139                                 my $c = $sock_pkg->new(%o);
 140                                 if (!defined($c) && $!{ECONNREFUSED}) {
 141                                         unlink $l or die
 142 "failed to unlink stale socket=$l: $!\n";
 143                                 } # else: let the bind fail
 144                         }
 145                         $o{Local} = delete $o{Peer};
 146                 } else {
 147                         # both work for IPv4, too
 148                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 149                                 $sock_pkg = $_;
 150                                 eval "use $sock_pkg";
 151                                 $@ or last;
 152                         }
 153                         die $@ if $@;
 154                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 155                 }
 156                 $o{Listen} = 1024;
 157                 my $prev = umask 0000;
 158                 my $s = eval { $sock_pkg->new(%o) };
 159                 warn "error binding $l: $! ($@)\n" unless $s;
 160                 umask $prev;
 161                 if ($s) {
 162                         $listener_names->{sockname($s)} = $s;
 163                         $s->blocking(0);
 164                         push @listeners, $s;
 165                 }
 166         }
 167
 168         # cert/key options in @cfg_listen takes precedence when inheriting,
 169         # but map well-known inherited ports if --listen isn't specified
 170         # at all
 171         for my $sockname (@inherited_names) {
 172                 $sockname =~ /:([0-9]+)\z/ or next;
 173                 if (my $scheme = $KNOWN_TLS{$1}) {
 174                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 175                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 176                         next if $tls_opt{"$scheme://$sockname"};
 177                         $tls_opt{''} ||= accept_tls_opt('');
 178                 }
 179         }
 180
 181         die "No listeners bound\n" unless @listeners;
 182 }
 183
 184 sub check_absolute ($$) {
 185         my ($var, $val) = @_;
 186         if (defined $val && index($val, '/') != 0) {
 187                 die
 188 "--$var must be an absolute path when using --daemonize: $val\n";
 189         }
 190 }
 191
 192 sub daemonize () {
 193         if ($daemonize) {
 194                 foreach my $i (0..$#ARGV) {
 195                         my $arg = $ARGV[$i];
 196                         next unless -e $arg;
 197                         $ARGV[$i] = abs_path($arg);
 198                 }
 199                 check_absolute('stdout', $stdout);
 200                 check_absolute('stderr', $stderr);
 201                 check_absolute('pid-file', $pid_file);
 202
 203                 chdir '/' or die "chdir failed: $!";
 204         }
 205
 206         return unless (defined $pid_file || defined $group || defined $user
 207                         || $daemonize);
 208
 209         eval { require Net::Server::Daemonize };
 210         if ($@) {
 211                 die
 212 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 213         }
 214
 215         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 216         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 217         if (defined $group) {
 218                 $gid = Net::Server::Daemonize::get_gid($group);
 219                 $gid = (split /\s+/, $gid)[0];
 220         } elsif (defined $uid) {
 221                 $gid = (getpwuid($uid))[3];
 222         }
 223
 224         # We change users in the worker to ensure upgradability,
 225         # The upgrade will create the ".oldbin" pid file in the
 226         # same directory as the given pid file.
 227         $uid and $set_user = sub {
 228                 $set_user = undef;
 229                 Net::Server::Daemonize::set_user($uid, $gid);
 230         };
 231
 232         if ($daemonize) {
 233                 my $pid = fork;
 234                 die "could not fork: $!\n" unless defined $pid;
 235                 exit if $pid;
 236
 237                 open(STDIN, '+<', '/dev/null') or
 238                                         die "redirect stdin failed: $!\n";
 239                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 240                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 241                 POSIX::setsid();
 242                 $pid = fork;
 243                 die "could not fork: $!\n" unless defined $pid;
 244                 exit if $pid;
 245         }
 246         return unless defined $pid_file;
 247
 248         write_pid($pid_file);
 249         # for ->DESTROY:
 250         bless { pid => $$, pid_file => $pid_file }, __PACKAGE__;
 251 }
 252
 253 sub worker_quit { # $_[0] = signal name or number (unused)
 254         # killing again terminates immediately:
 255         exit unless @listeners;
 256
 257         $_->close foreach @listeners; # call PublicInbox::DS::close
 258         @listeners = ();
 259         my $proc_name;
 260         my $warn = 0;
 261         # drop idle connections and try to quit gracefully
 262         PublicInbox::DS->SetPostLoopCallback(sub {
 263                 my ($dmap, undef) = @_;
 264                 my $n = 0;
 265                 my $now = now();
 266
 267                 foreach my $s (values %$dmap) {
 268                         $s->can('busy') or next;
 269                         if ($s->busy($now)) {
 270                                 ++$n;
 271                         } else {
 272                                 # close as much as possible, early as possible
 273                                 $s->close;
 274                         }
 275                 }
 276                 if ($n) {
 277                         if (($warn + 5) < now()) {
 278                                 warn "$$ quitting, $n client(s) left\n";
 279                                 $warn = now();
 280                         }
 281                         unless (defined $proc_name) {
 282                                 $proc_name = (split(/\s+/, $0))[0];
 283                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 284                         }
 285                         $0 = "$proc_name quitting, $n client(s) left";
 286                 }
 287                 $n; # true: loop continues, false: loop breaks
 288         });
 289 }
 290
 291 sub reopen_logs {
 292         if ($stdout) {
 293                 open STDOUT, '>>', $stdout or
 294                         warn "failed to redirect stdout to $stdout: $!\n";
 295                 STDOUT->autoflush(1);
 296                 do_chown($stdout);
 297         }
 298         if ($stderr) {
 299                 open STDERR, '>>', $stderr or
 300                         warn "failed to redirect stderr to $stderr: $!\n";
 301                 STDERR->autoflush(1);
 302                 do_chown($stderr);
 303         }
 304 }
 305
 306 sub sockname ($) {
 307         my ($s) = @_;
 308         my $addr = getsockname($s) or return;
 309         my ($host, $port) = host_with_port($addr);
 310         if ($port == 0 && $host eq '127.0.0.1') {
 311                 my ($path) = Socket::sockaddr_un($addr);
 312                 return $path;
 313         }
 314         "$host:$port";
 315 }
 316
 317 sub unpack_ipv6 ($) {
 318         my ($addr) = @_;
 319         my ($port, $host);
 320
 321         # Socket.pm in Perl 5.14+ supports IPv6:
 322         eval {
 323                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 324                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 325         };
 326
 327         if ($@) {
 328                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 329                 # Socket6, so it may be installed on our system, already
 330                 # (otherwise die here):
 331                 require Socket6;
 332
 333                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 334                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 335         }
 336         ($host, $port);
 337 }
 338
 339 sub host_with_port ($) {
 340         my ($addr) = @_;
 341         my ($port, $host);
 342
 343         # this eval will die on Unix sockets:
 344         eval {
 345                 if (length($addr) >= 28) {
 346                         ($host, $port) = unpack_ipv6($addr);
 347                         $host = "[$host]";
 348                 } else {
 349                         ($port, $host) = Socket::sockaddr_in($addr);
 350                         $host = Socket::inet_ntoa($host);
 351                 }
 352         };
 353         $@ ? ('127.0.0.1', 0) : ($host, $port);
 354 }
 355
 356 sub inherit ($) {
 357         my ($listener_names) = @_;
 358         return () if ($ENV{LISTEN_PID} || 0) != $$;
 359         my $fds = $ENV{LISTEN_FDS} or return ();
 360         my $end = $fds + 2; # LISTEN_FDS_START - 1
 361         my @rv = ();
 362         foreach my $fd (3..$end) {
 363                 my $s = IO::Handle->new_from_fd($fd, 'r');
 364                 if (my $k = sockname($s)) {
 365                         if ($s->blocking) {
 366                                 $s->blocking(0);
 367                                 warn <<"";
 368 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 369 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 370 processes when multiple service instances start.
 371
 372                         }
 373                         $listener_names->{$k} = $s;
 374                         push @rv, $s;
 375                 } else {
 376                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 377                 }
 378         }
 379         @rv
 380 }
 381
 382 sub upgrade { # $_[0] = signal name or number (unused)
 383         if ($reexec_pid) {
 384                 warn "upgrade in-progress: $reexec_pid\n";
 385                 return;
 386         }
 387         if (defined $pid_file) {
 388                 if ($pid_file =~ /\.oldbin\z/) {
 389                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 390                         return;
 391                 }
 392                 unlink_pid_file_safe_ish($$, $pid_file);
 393                 $pid_file .= '.oldbin';
 394                 write_pid($pid_file);
 395         }
 396         my $pid = fork;
 397         unless (defined $pid) {
 398                 warn "fork failed: $!\n";
 399                 return;
 400         }
 401         if ($pid == 0) {
 402                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 403                 $ENV{LISTEN_FDS} = scalar @listeners;
 404                 $ENV{LISTEN_PID} = $$;
 405                 foreach my $s (@listeners) {
 406                         my $fl = fcntl($s, F_GETFD, 0);
 407                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 408                 }
 409                 exec @CMD;
 410                 die "Failed to exec: $!\n";
 411         }
 412         $reexec_pid = $pid;
 413 }
 414
 415 sub kill_workers ($) {
 416         my ($s) = @_;
 417
 418         while (my ($pid, $id) = each %pids) {
 419                 kill $s, $pid;
 420         }
 421 }
 422
 423 sub upgrade_aborted ($) {
 424         my ($p) = @_;
 425         warn "reexec PID($p) died with: $?\n";
 426         $reexec_pid = undef;
 427         return unless $pid_file;
 428
 429         my $file = $pid_file;
 430         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 431         unlink_pid_file_safe_ish($$, $pid_file);
 432         $pid_file = $file;
 433         eval { write_pid($pid_file) };
 434         warn $@, "\n" if $@;
 435 }
 436
 437 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 438         while (1) {
 439                 my $p = waitpid(-1, WNOHANG) or return;
 440                 if (defined $reexec_pid && $p == $reexec_pid) {
 441                         upgrade_aborted($p);
 442                 } elsif (defined(my $id = delete $pids{$p})) {
 443                         warn "worker[$id] PID($p) died with: $?\n";
 444                 } elsif ($p > 0) {
 445                         warn "unknown PID($p) reaped: $?\n";
 446                 } else {
 447                         return;
 448                 }
 449         }
 450 }
 451
 452 sub unlink_pid_file_safe_ish ($$) {
 453         my ($unlink_pid, $file) = @_;
 454         return unless defined $unlink_pid && $unlink_pid == $$;
 455
 456         open my $fh, '<', $file or return;
 457         local $/ = "\n";
 458         defined(my $read_pid = <$fh>) or return;
 459         chomp $read_pid;
 460         if ($read_pid == $unlink_pid) {
 461                 Net::Server::Daemonize::unlink_pid_file($file);
 462         }
 463 }
 464
 465 sub master_quit ($) {
 466         exit unless @listeners;
 467         @listeners = ();
 468         kill_workers($_[0]);
 469 }
 470
 471 sub master_loop {
 472         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 473         # 1031: F_SETPIPE_SZ, 4096: page size
 474         fcntl($p1, 1031, 4096) if $^O eq 'linux';
 475         my $set_workers = $worker_processes;
 476         reopen_logs();
 477         my $ignore_winch;
 478         my $sig = {
 479                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 480                 USR2 => \&upgrade,
 481                 QUIT => \&master_quit,
 482                 INT => \&master_quit,
 483                 TERM => \&master_quit,
 484                 WINCH => sub {
 485                         return if $ignore_winch || !@listeners;
 486                         if (-t STDIN || -t STDOUT || -t STDERR) {
 487                                 $ignore_winch = 1;
 488                                 warn <<EOF;
 489 ignoring SIGWINCH since we are not daemonized
 490 EOF
 491                         } else {
 492                                 $worker_processes = 0;
 493                         }
 494                 },
 495                 HUP => sub {
 496                         return unless @listeners;
 497                         $worker_processes = $set_workers;
 498                         kill_workers($_[0]);
 499                 },
 500                 TTIN => sub {
 501                         return unless @listeners;
 502                         if ($set_workers > $worker_processes) {
 503                                 ++$worker_processes;
 504                         } else {
 505                                 $worker_processes = ++$set_workers;
 506                         }
 507                 },
 508                 TTOU => sub {
 509                         $worker_processes = --$set_workers if $set_workers > 0;
 510                 },
 511                 CHLD => \&reap_children,
 512         };
 513         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 514         local %SIG = (%SIG, %$sig) if !$sigfd;
 515         sig_setmask($oldset) if !$sigfd;
 516         while (1) { # main loop
 517                 my $n = scalar keys %pids;
 518                 unless (@listeners) {
 519                         exit if $n == 0;
 520                         $set_workers = $worker_processes = $n = 0;
 521                 }
 522
 523                 if ($n > $worker_processes) {
 524                         while (my ($k, $v) = each %pids) {
 525                                 kill('TERM', $k) if $v >= $worker_processes;
 526                         }
 527                         $n = $worker_processes;
 528                 }
 529                 my $want = $worker_processes - 1;
 530                 if ($n <= $want) {
 531                         sig_setmask($newset) if !$sigfd;
 532                         for my $i ($n..$want) {
 533                                 my $pid = fork;
 534                                 if (!defined $pid) {
 535                                         warn "failed to fork worker[$i]: $!\n";
 536                                 } elsif ($pid == 0) {
 537                                         $set_user->() if $set_user;
 538                                         return $p0; # run normal work code
 539                                 } else {
 540                                         warn "PID=$pid is worker[$i]\n";
 541                                         $pids{$pid} = $i;
 542                                 }
 543                         }
 544                         sig_setmask($oldset) if !$sigfd;
 545                 }
 546
 547                 if ($sigfd) { # Linux and IO::KQueue users:
 548                         $sigfd->wait_once;
 549                 } else { # wake up every second
 550                         sleep(1);
 551                 }
 552         }
 553         exit # never gets here, just for documentation
 554 }
 555
 556 sub tls_start_cb ($$) {
 557         my ($opt, $orig_post_accept) = @_;
 558         sub {
 559                 my ($io, $addr, $srv) = @_;
 560                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 561                 $orig_post_accept->($ssl, $addr, $srv);
 562         }
 563 }
 564
 565 sub defer_accept ($$) {
 566         my ($s, $af_name) = @_;
 567         return unless defined $af_name;
 568         if ($^O eq 'linux') {
 569                 my $x = getsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT());
 570                 return unless defined $x; # may be Unix socket
 571                 my $sec = unpack('i', $x);
 572                 return if $sec > 0; # systemd users may set a higher value
 573                 setsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT(), 1);
 574         } elsif ($^O eq 'freebsd') {
 575                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 576                 return if defined $x; # don't change if set
 577                 my $accf_arg = pack('a16a240', $af_name, '');
 578                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 579         }
 580 }
 581
 582 sub daemon_loop ($$$$) {
 583         my ($refresh, $post_accept, $nntpd, $af_default) = @_;
 584         my %post_accept;
 585         while (my ($k, $v) = each %tls_opt) {
 586                 if ($k =~ s!\A(?:nntps|https)://!!) {
 587                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 588                 } elsif ($nntpd) { # STARTTLS, $k eq '' is OK
 589                         $nntpd->{accept_tls} = $v;
 590                 }
 591         }
 592         my $sig = {
 593                 HUP => $refresh,
 594                 INT => \&worker_quit,
 595                 QUIT => \&worker_quit,
 596                 TERM => \&worker_quit,
 597                 TTIN => 'IGNORE',
 598                 TTOU => 'IGNORE',
 599                 USR1 => \&reopen_logs,
 600                 USR2 => 'IGNORE',
 601                 WINCH => 'IGNORE',
 602                 CHLD => \&PublicInbox::DS::enqueue_reap,
 603         };
 604         my $parent_pipe;
 605         if ($worker_processes > 0) {
 606                 $refresh->(); # preload by default
 607                 my $fh = master_loop(); # returns if in child process
 608                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 609         } else {
 610                 reopen_logs();
 611                 $set_user->() if $set_user;
 612                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 613                 $refresh->();
 614         }
 615         $uid = $gid = undef;
 616         reopen_logs();
 617         @listeners = map {;
 618                 my $tls_cb = $post_accept{sockname($_)};
 619
 620                 # NNTPS, HTTPS, HTTP, and POP3S are client-first traffic
 621                 # NNTP and POP3 are server-first
 622                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 623
 624                 # this calls epoll_create:
 625                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 626         } @listeners;
 627         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 628         local %SIG = (%SIG, %$sig) if !$sigfd;
 629         if (!$sigfd) {
 630                 # wake up every second to accept signals if we don't
 631                 # have signalfd or IO::KQueue:
 632                 sig_setmask($oldset);
 633                 PublicInbox::DS->SetLoopTimeout(1000);
 634         }
 635         PublicInbox::DS->EventLoop;
 636 }
 637
 638 sub run ($$$;$) {
 639         my ($default, $refresh, $post_accept, $nntpd) = @_;
 640         daemon_prepare($default);
 641         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 642         my $for_destroy = daemonize();
 643         daemon_loop($refresh, $post_accept, $nntpd, $af_default);
 644         PublicInbox::DS->Reset;
 645         # ->DESTROY runs when $for_destroy goes out-of-scope
 646 }
 647
 648 sub do_chown ($) {
 649         my ($path) = @_;
 650         if (defined $uid and !chown($uid, $gid, $path)) {
 651                 warn "could not chown $path: $!\n";
 652         }
 653 }
 654
 655 sub write_pid ($) {
 656         my ($path) = @_;
 657         Net::Server::Daemonize::create_pid_file($path);
 658         do_chown($path);
 659 }
 660
 661 sub DESTROY {
 662         unlink_pid_file_safe_ish($_[0]->{pid}, $_[0]->{pid_file});
 663 }
 664
 665 1;