lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the httpd, imapd, and nntpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle; # ->autoflush
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 use Cwd qw/abs_path/;
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Syscall qw($SFD_NONBLOCK);
  19 require PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 my @CMD;
  23 my ($set_user, $oldset);
  24 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  25 my $worker_processes = 1;
  26 my @listeners;
  27 my %pids;
  28 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  29 my $reexec_pid;
  30 my ($uid, $gid);
  31 my ($default_cert, $default_key);
  32 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps', 993 => 'imaps' );
  33 my %KNOWN_STARTTLS = ( 119 => 'nntp', 143 => 'imap' );
  34
  35 sub accept_tls_opt ($) {
  36         my ($opt_str) = @_;
  37         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  38         require PublicInbox::TLS;
  39         my $o = {};
  40         # allow ',' as delimiter since '&' is shell-unfriendly
  41         foreach (split(/[,&]/, $opt_str)) {
  42                 my ($k, $v) = split(/=/, $_, 2);
  43                 push @{$o->{$k} ||= []}, $v;
  44         }
  45
  46         # key may be a part of cert.  At least
  47         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  48         $o->{cert} //= [ $default_cert ];
  49         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  50         my %ctx_opt = (SSL_server => 1);
  51         # parse out hostname:/path/to/ mappings:
  52         foreach my $k (qw(cert key)) {
  53                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  54                 foreach my $path (@{$o->{$k}}) {
  55                         my $host = '';
  56                         $path =~ s/\A([^:]+):// and $host = $1;
  57                         $x->{$host} = $path;
  58                 }
  59         }
  60         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  61                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  62
  63         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  64         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  65         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  66         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  67         if ($mode && $ctx->{context}) {
  68                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  69                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  70         }
  71
  72         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  73 }
  74
  75 sub daemon_prepare ($) {
  76         my ($default_listen) = @_;
  77         my $listener_names = {}; # sockname => IO::Handle
  78         $oldset = PublicInbox::Sigfd::block_signals();
  79         @CMD = ($0, @ARGV);
  80         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  81         my $help = <<EOF;
  82 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
  83
  84 options:
  85
  86   -l ADDRESS    address to listen on (default: $default_listen)
  87   --cert=FILE   default SSL/TLS certificate
  88   --key=FILE    default SSL/TLS certificate
  89   -W WORKERS    number of worker processes to spawn (default: 1)
  90
  91 See public-inbox-daemon(8) and $prog(1) man pages for more.
  92 EOF
  93         my %opt = (
  94                 'l|listen=s' => \@cfg_listen,
  95                 '1|stdout=s' => \$stdout,
  96                 '2|stderr=s' => \$stderr,
  97                 'W|worker-processes=i' => \$worker_processes,
  98                 'P|pid-file=s' => \$pid_file,
  99                 'u|user=s' => \$user,
 100                 'g|group=s' => \$group,
 101                 'D|daemonize' => \$daemonize,
 102                 'cert=s' => \$default_cert,
 103                 'key=s' => \$default_key,
 104                 'help|h' => \(my $show_help),
 105         );
 106         GetOptions(%opt) or die $help;
 107         if ($show_help) { print $help; exit 0 };
 108
 109         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 110                 die "--pid-file cannot end with '.oldbin'\n";
 111         }
 112         @listeners = inherit($listener_names);
 113
 114         # allow socket-activation users to set certs once and not
 115         # have to configure each socket:
 116         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 117
 118         # ignore daemonize when inheriting
 119         $daemonize = undef if scalar @listeners;
 120
 121         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 122
 123         foreach my $l (@cfg_listen) {
 124                 my $orig = $l;
 125                 my $scheme = '';
 126                 if ($l =~ s!\A([^:]+)://!!) {
 127                         $scheme = $1;
 128                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 129                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 130                         $scheme = $s if defined $s;
 131                 }
 132                 if ($l =~ s!/?\?(.+)\z!!) {
 133                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 134                 } elsif (defined($default_cert)) {
 135                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 136                 } elsif ($scheme =~ /\A(?:https|imaps|imaps)\z/) {
 137                         die "$orig specified w/o cert=\n";
 138                 }
 139                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 140
 141                 next if $listener_names->{$l}; # already inherited
 142                 my (%o, $sock_pkg);
 143                 if (index($l, '/') == 0) {
 144                         $sock_pkg = 'IO::Socket::UNIX';
 145                         eval "use $sock_pkg";
 146                         die $@ if $@;
 147                         %o = (Type => SOCK_STREAM, Peer => $l);
 148                         if (-S $l) {
 149                                 my $c = $sock_pkg->new(%o);
 150                                 if (!defined($c) && $!{ECONNREFUSED}) {
 151                                         unlink $l or die
 152 "failed to unlink stale socket=$l: $!\n";
 153                                 } # else: let the bind fail
 154                         }
 155                         $o{Local} = delete $o{Peer};
 156                 } else {
 157                         # both work for IPv4, too
 158                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 159                                 $sock_pkg = $_;
 160                                 eval "use $sock_pkg";
 161                                 $@ or last;
 162                         }
 163                         die $@ if $@;
 164                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 165                 }
 166                 $o{Listen} = 1024;
 167                 my $prev = umask 0000;
 168                 my $s = eval { $sock_pkg->new(%o) };
 169                 warn "error binding $l: $! ($@)\n" unless $s;
 170                 umask $prev;
 171                 if ($s) {
 172                         $listener_names->{sockname($s)} = $s;
 173                         $s->blocking(0);
 174                         push @listeners, $s;
 175                 }
 176         }
 177
 178         # cert/key options in @cfg_listen takes precedence when inheriting,
 179         # but map well-known inherited ports if --listen isn't specified
 180         # at all
 181         for my $sockname (@inherited_names) {
 182                 $sockname =~ /:([0-9]+)\z/ or next;
 183                 if (my $scheme = $KNOWN_TLS{$1}) {
 184                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 185                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 186                         next if $tls_opt{"$scheme://$sockname"};
 187                         $tls_opt{''} ||= accept_tls_opt('');
 188                 }
 189         }
 190
 191         die "No listeners bound\n" unless @listeners;
 192 }
 193
 194 sub check_absolute ($$) {
 195         my ($var, $val) = @_;
 196         if (defined $val && index($val, '/') != 0) {
 197                 die
 198 "--$var must be an absolute path when using --daemonize: $val\n";
 199         }
 200 }
 201
 202 sub daemonize () {
 203         if ($daemonize) {
 204                 foreach my $i (0..$#ARGV) {
 205                         my $arg = $ARGV[$i];
 206                         next unless -e $arg;
 207                         $ARGV[$i] = abs_path($arg);
 208                 }
 209                 check_absolute('stdout', $stdout);
 210                 check_absolute('stderr', $stderr);
 211                 check_absolute('pid-file', $pid_file);
 212
 213                 chdir '/' or die "chdir failed: $!";
 214         }
 215
 216         return unless (defined $pid_file || defined $group || defined $user
 217                         || $daemonize);
 218
 219         eval { require Net::Server::Daemonize };
 220         if ($@) {
 221                 die
 222 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 223         }
 224
 225         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 226         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 227         if (defined $group) {
 228                 $gid = Net::Server::Daemonize::get_gid($group);
 229                 $gid = (split /\s+/, $gid)[0];
 230         } elsif (defined $uid) {
 231                 $gid = (getpwuid($uid))[3];
 232         }
 233
 234         # We change users in the worker to ensure upgradability,
 235         # The upgrade will create the ".oldbin" pid file in the
 236         # same directory as the given pid file.
 237         $uid and $set_user = sub {
 238                 $set_user = undef;
 239                 Net::Server::Daemonize::set_user($uid, $gid);
 240         };
 241
 242         if ($daemonize) {
 243                 my $pid = fork;
 244                 die "could not fork: $!\n" unless defined $pid;
 245                 exit if $pid;
 246
 247                 open(STDIN, '+<', '/dev/null') or
 248                                         die "redirect stdin failed: $!\n";
 249                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 250                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 251                 POSIX::setsid();
 252                 $pid = fork;
 253                 die "could not fork: $!\n" unless defined $pid;
 254                 exit if $pid;
 255         }
 256         return unless defined $pid_file;
 257
 258         write_pid($pid_file);
 259         # for ->DESTROY:
 260         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 261 }
 262
 263 sub worker_quit { # $_[0] = signal name or number (unused)
 264         # killing again terminates immediately:
 265         exit unless @listeners;
 266
 267         $_->close foreach @listeners; # call PublicInbox::DS::close
 268         @listeners = ();
 269         my $proc_name;
 270         my $warn = 0;
 271         # drop idle connections and try to quit gracefully
 272         PublicInbox::DS->SetPostLoopCallback(sub {
 273                 my ($dmap, undef) = @_;
 274                 my $n = 0;
 275                 my $now = now();
 276
 277                 foreach my $s (values %$dmap) {
 278                         $s->can('busy') or next;
 279                         if ($s->busy($now)) {
 280                                 ++$n;
 281                         } else {
 282                                 # close as much as possible, early as possible
 283                                 $s->close;
 284                         }
 285                 }
 286                 if ($n) {
 287                         if (($warn + 5) < now()) {
 288                                 warn "$$ quitting, $n client(s) left\n";
 289                                 $warn = now();
 290                         }
 291                         unless (defined $proc_name) {
 292                                 $proc_name = (split(/\s+/, $0))[0];
 293                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 294                         }
 295                         $0 = "$proc_name quitting, $n client(s) left";
 296                 }
 297                 $n; # true: loop continues, false: loop breaks
 298         });
 299 }
 300
 301 sub reopen_logs {
 302         if ($stdout) {
 303                 open STDOUT, '>>', $stdout or
 304                         warn "failed to redirect stdout to $stdout: $!\n";
 305                 STDOUT->autoflush(1);
 306                 do_chown($stdout);
 307         }
 308         if ($stderr) {
 309                 open STDERR, '>>', $stderr or
 310                         warn "failed to redirect stderr to $stderr: $!\n";
 311                 STDERR->autoflush(1);
 312                 do_chown($stderr);
 313         }
 314 }
 315
 316 sub sockname ($) {
 317         my ($s) = @_;
 318         my $addr = getsockname($s) or return;
 319         my ($host, $port) = host_with_port($addr);
 320         if ($port == 0 && $host eq '127.0.0.1') {
 321                 my ($path) = Socket::sockaddr_un($addr);
 322                 return $path;
 323         }
 324         "$host:$port";
 325 }
 326
 327 sub unpack_ipv6 ($) {
 328         my ($addr) = @_;
 329         my ($port, $host);
 330
 331         # Socket.pm in Perl 5.14+ supports IPv6:
 332         eval {
 333                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 334                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 335         };
 336
 337         if ($@) {
 338                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 339                 # Socket6, so it may be installed on our system, already
 340                 # (otherwise die here):
 341                 require Socket6;
 342
 343                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 344                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 345         }
 346         ($host, $port);
 347 }
 348
 349 sub host_with_port ($) {
 350         my ($addr) = @_;
 351         my ($port, $host);
 352
 353         # this eval will die on Unix sockets:
 354         eval {
 355                 if (length($addr) >= 28) {
 356                         ($host, $port) = unpack_ipv6($addr);
 357                         $host = "[$host]";
 358                 } else {
 359                         ($port, $host) = Socket::sockaddr_in($addr);
 360                         $host = Socket::inet_ntoa($host);
 361                 }
 362         };
 363         $@ ? ('127.0.0.1', 0) : ($host, $port);
 364 }
 365
 366 sub inherit ($) {
 367         my ($listener_names) = @_;
 368         return () if ($ENV{LISTEN_PID} || 0) != $$;
 369         my $fds = $ENV{LISTEN_FDS} or return ();
 370         my $end = $fds + 2; # LISTEN_FDS_START - 1
 371         my @rv = ();
 372         foreach my $fd (3..$end) {
 373                 my $s = IO::Handle->new_from_fd($fd, 'r');
 374                 if (my $k = sockname($s)) {
 375                         if ($s->blocking) {
 376                                 $s->blocking(0);
 377                                 warn <<"";
 378 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 379 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 380 processes when multiple service instances start.
 381
 382                         }
 383                         $listener_names->{$k} = $s;
 384                         push @rv, $s;
 385                 } else {
 386                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 387                 }
 388         }
 389         @rv
 390 }
 391
 392 sub upgrade { # $_[0] = signal name or number (unused)
 393         if ($reexec_pid) {
 394                 warn "upgrade in-progress: $reexec_pid\n";
 395                 return;
 396         }
 397         if (defined $pid_file) {
 398                 if ($pid_file =~ /\.oldbin\z/) {
 399                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 400                         return;
 401                 }
 402                 unlink_pid_file_safe_ish($$, $pid_file);
 403                 $pid_file .= '.oldbin';
 404                 write_pid($pid_file);
 405         }
 406         my $pid = fork;
 407         unless (defined $pid) {
 408                 warn "fork failed: $!\n";
 409                 return;
 410         }
 411         if ($pid == 0) {
 412                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 413                 $ENV{LISTEN_FDS} = scalar @listeners;
 414                 $ENV{LISTEN_PID} = $$;
 415                 foreach my $s (@listeners) {
 416                         # @listeners are globs with workers, PI::L w/o workers
 417                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 418
 419                         my $fl = fcntl($s, F_GETFD, 0);
 420                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 421                 }
 422                 exec @CMD;
 423                 die "Failed to exec: $!\n";
 424         }
 425         $reexec_pid = $pid;
 426 }
 427
 428 sub kill_workers ($) {
 429         my ($s) = @_;
 430
 431         while (my ($pid, $id) = each %pids) {
 432                 kill $s, $pid;
 433         }
 434 }
 435
 436 sub upgrade_aborted ($) {
 437         my ($p) = @_;
 438         warn "reexec PID($p) died with: $?\n";
 439         $reexec_pid = undef;
 440         return unless $pid_file;
 441
 442         my $file = $pid_file;
 443         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 444         unlink_pid_file_safe_ish($$, $pid_file);
 445         $pid_file = $file;
 446         eval { write_pid($pid_file) };
 447         warn $@, "\n" if $@;
 448 }
 449
 450 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 451         while (1) {
 452                 my $p = waitpid(-1, WNOHANG) or return;
 453                 if (defined $reexec_pid && $p == $reexec_pid) {
 454                         upgrade_aborted($p);
 455                 } elsif (defined(my $id = delete $pids{$p})) {
 456                         warn "worker[$id] PID($p) died with: $?\n";
 457                 } elsif ($p > 0) {
 458                         warn "unknown PID($p) reaped: $?\n";
 459                 } else {
 460                         return;
 461                 }
 462         }
 463 }
 464
 465 sub unlink_pid_file_safe_ish ($$) {
 466         my ($unlink_pid, $file) = @_;
 467         return unless defined $unlink_pid && $unlink_pid == $$;
 468
 469         open my $fh, '<', $file or return;
 470         local $/ = "\n";
 471         defined(my $read_pid = <$fh>) or return;
 472         chomp $read_pid;
 473         if ($read_pid == $unlink_pid) {
 474                 Net::Server::Daemonize::unlink_pid_file($file);
 475         }
 476 }
 477
 478 sub master_quit ($) {
 479         exit unless @listeners;
 480         @listeners = ();
 481         kill_workers($_[0]);
 482 }
 483
 484 sub master_loop {
 485         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 486         my $set_workers = $worker_processes;
 487         reopen_logs();
 488         my $ignore_winch;
 489         my $sig = {
 490                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 491                 USR2 => \&upgrade,
 492                 QUIT => \&master_quit,
 493                 INT => \&master_quit,
 494                 TERM => \&master_quit,
 495                 WINCH => sub {
 496                         return if $ignore_winch || !@listeners;
 497                         if (-t STDIN || -t STDOUT || -t STDERR) {
 498                                 $ignore_winch = 1;
 499                                 warn <<EOF;
 500 ignoring SIGWINCH since we are not daemonized
 501 EOF
 502                         } else {
 503                                 $worker_processes = 0;
 504                         }
 505                 },
 506                 HUP => sub {
 507                         return unless @listeners;
 508                         $worker_processes = $set_workers;
 509                         kill_workers($_[0]);
 510                 },
 511                 TTIN => sub {
 512                         return unless @listeners;
 513                         if ($set_workers > $worker_processes) {
 514                                 ++$worker_processes;
 515                         } else {
 516                                 $worker_processes = ++$set_workers;
 517                         }
 518                 },
 519                 TTOU => sub {
 520                         $worker_processes = --$set_workers if $set_workers > 0;
 521                 },
 522                 CHLD => \&reap_children,
 523         };
 524         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 525         local %SIG = (%SIG, %$sig) if !$sigfd;
 526         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 527         while (1) { # main loop
 528                 my $n = scalar keys %pids;
 529                 unless (@listeners) {
 530                         exit if $n == 0;
 531                         $set_workers = $worker_processes = $n = 0;
 532                 }
 533
 534                 if ($n > $worker_processes) {
 535                         while (my ($k, $v) = each %pids) {
 536                                 kill('TERM', $k) if $v >= $worker_processes;
 537                         }
 538                         $n = $worker_processes;
 539                 }
 540                 my $want = $worker_processes - 1;
 541                 if ($n <= $want) {
 542                         PublicInbox::Sigfd::block_signals() if !$sigfd;
 543                         for my $i ($n..$want) {
 544                                 my $pid = fork;
 545                                 if (!defined $pid) {
 546                                         warn "failed to fork worker[$i]: $!\n";
 547                                 } elsif ($pid == 0) {
 548                                         $set_user->() if $set_user;
 549                                         return $p0; # run normal work code
 550                                 } else {
 551                                         warn "PID=$pid is worker[$i]\n";
 552                                         $pids{$pid} = $i;
 553                                 }
 554                         }
 555                         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 556                 }
 557
 558                 if ($sigfd) { # Linux and IO::KQueue users:
 559                         $sigfd->wait_once;
 560                 } else { # wake up every second
 561                         sleep(1);
 562                 }
 563         }
 564         exit # never gets here, just for documentation
 565 }
 566
 567 sub tls_start_cb ($$) {
 568         my ($opt, $orig_post_accept) = @_;
 569         sub {
 570                 my ($io, $addr, $srv) = @_;
 571                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 572                 $orig_post_accept->($ssl, $addr, $srv);
 573         }
 574 }
 575
 576 sub defer_accept ($$) {
 577         my ($s, $af_name) = @_;
 578         return unless defined $af_name;
 579         if ($^O eq 'linux') {
 580                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 581                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 582                 return unless defined $x; # may be Unix socket
 583                 my $sec = unpack('i', $x);
 584                 return if $sec > 0; # systemd users may set a higher value
 585                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 586         } elsif ($^O eq 'freebsd') {
 587                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 588                 return if defined $x; # don't change if set
 589                 my $accf_arg = pack('a16a240', $af_name, '');
 590                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 591         }
 592 }
 593
 594 sub daemon_loop ($$$$) {
 595         my ($refresh, $post_accept, $tlsd, $af_default) = @_;
 596         my %post_accept;
 597         while (my ($k, $v) = each %tls_opt) {
 598                 if ($k =~ s!\A(?:https|imaps|nntps)://!!) {
 599                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 600                 } elsif ($tlsd) { # STARTTLS, $k eq '' is OK
 601                         $tlsd->{accept_tls} = $v;
 602                 }
 603         }
 604         my $sig = {
 605                 HUP => $refresh,
 606                 INT => \&worker_quit,
 607                 QUIT => \&worker_quit,
 608                 TERM => \&worker_quit,
 609                 TTIN => 'IGNORE',
 610                 TTOU => 'IGNORE',
 611                 USR1 => \&reopen_logs,
 612                 USR2 => 'IGNORE',
 613                 WINCH => 'IGNORE',
 614                 CHLD => \&PublicInbox::DS::enqueue_reap,
 615         };
 616         if ($worker_processes > 0) {
 617                 $refresh->(); # preload by default
 618                 my $fh = master_loop(); # returns if in child process
 619                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 620         } else {
 621                 reopen_logs();
 622                 $set_user->() if $set_user;
 623                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 624                 $refresh->();
 625         }
 626         $uid = $gid = undef;
 627         reopen_logs();
 628         @listeners = map {;
 629                 my $tls_cb = $post_accept{sockname($_)};
 630
 631                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 632                 # IMAP, NNTP and POP3 are server-first
 633                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 634
 635                 # this calls epoll_create:
 636                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 637         } @listeners;
 638         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 639         local %SIG = (%SIG, %$sig) if !$sigfd;
 640         if (!$sigfd) {
 641                 # wake up every second to accept signals if we don't
 642                 # have signalfd or IO::KQueue:
 643                 PublicInbox::Sigfd::sig_setmask($oldset);
 644                 PublicInbox::DS->SetLoopTimeout(1000);
 645         }
 646         PublicInbox::DS->EventLoop;
 647 }
 648
 649 sub run ($$$;$) {
 650         my ($default, $refresh, $post_accept, $tlsd) = @_;
 651         local $SIG{PIPE} = 'IGNORE';
 652         daemon_prepare($default);
 653         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 654         my $for_destroy = daemonize();
 655         daemon_loop($refresh, $post_accept, $tlsd, $af_default);
 656         PublicInbox::DS->Reset;
 657         # ->DESTROY runs when $for_destroy goes out-of-scope
 658 }
 659
 660 sub do_chown ($) {
 661         my ($path) = @_;
 662         if (defined $uid and !chown($uid, $gid, $path)) {
 663                 warn "could not chown $path: $!\n";
 664         }
 665 }
 666
 667 sub write_pid ($) {
 668         my ($path) = @_;
 669         Net::Server::Daemonize::create_pid_file($path);
 670         do_chown($path);
 671 }
 672
 673 sub DESTROY {
 674         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 675 }
 676
 677 1;