lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use POSIX qw(WNOHANG :signal_h);
  14 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Listener;
  19 use PublicInbox::EOFpipe;
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::Git;
  22 use PublicInbox::GitAsyncCat;
  23 use PublicInbox::Eml;
  24 our $SO_ACCEPTFILTER = 0x1000;
  25 my @CMD;
  26 my ($set_user, $oldset);
  27 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  28 my $worker_processes = 1;
  29 my @listeners;
  30 my %pids;
  31 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  32 my $reexec_pid;
  33 my ($uid, $gid);
  34 my ($default_cert, $default_key);
  35 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  36 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  37
  38 sub accept_tls_opt ($) {
  39         my ($opt_str) = @_;
  40         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  41         require PublicInbox::TLS;
  42         my $o = {};
  43         # allow ',' as delimiter since '&' is shell-unfriendly
  44         foreach (split(/[,&]/, $opt_str)) {
  45                 my ($k, $v) = split(/=/, $_, 2);
  46                 push @{$o->{$k} ||= []}, $v;
  47         }
  48
  49         # key may be a part of cert.  At least
  50         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  51         $o->{cert} //= [ $default_cert ];
  52         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  53         my %ctx_opt = (SSL_server => 1);
  54         # parse out hostname:/path/to/ mappings:
  55         foreach my $k (qw(cert key)) {
  56                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  57                 foreach my $path (@{$o->{$k}}) {
  58                         my $host = '';
  59                         $path =~ s/\A([^:]+):// and $host = $1;
  60                         $x->{$host} = $path;
  61                 }
  62         }
  63         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  64                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  65
  66         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  67         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  68         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  69         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  70         if ($mode && $ctx->{context}) {
  71                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  72                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  73         }
  74
  75         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  76 }
  77
  78 sub load_mod ($) {
  79         my ($scheme) = @_;
  80         my $modc = "PublicInbox::\U$scheme";
  81         my $mod = $modc.'D';
  82         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
  83         die $@ if $@;
  84         my %xn = map { $_ => $mod->can($_) } qw(refresh post_accept);
  85         $xn{tlsd} = $mod->new if $mod->can('refresh_groups'); #!HTTPD
  86         my $tlsd = $xn{tlsd};
  87         $xn{refresh} //= sub { $tlsd->refresh_groups(@_) };
  88         $xn{post_accept} //= sub { $modc->new($_[0], $tlsd) };
  89         $xn{af_default} = 'httpready' if $modc eq 'PublicInbox::HTTP';
  90         \%xn;
  91 }
  92
  93 sub daemon_prepare ($$) {
  94         my ($default_listen, $xnetd) = @_;
  95         my $listener_names = {}; # sockname => IO::Handle
  96         $oldset = PublicInbox::DS::block_signals();
  97         @CMD = ($0, @ARGV);
  98         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  99         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 100         my $help = <<EOF;
 101 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 102
 103 options:
 104
 105   -l ADDRESS    address to listen on$dh
 106   --cert=FILE   default SSL/TLS certificate
 107   --key=FILE    default SSL/TLS certificate
 108   -W WORKERS    number of worker processes to spawn (default: 1)
 109
 110 See public-inbox-daemon(8) and $prog(1) man pages for more.
 111 EOF
 112         my %opt = (
 113                 'l|listen=s' => \@cfg_listen,
 114                 '1|stdout=s' => \$stdout,
 115                 '2|stderr=s' => \$stderr,
 116                 'W|worker-processes=i' => \$worker_processes,
 117                 'P|pid-file=s' => \$pid_file,
 118                 'u|user=s' => \$user,
 119                 'g|group=s' => \$group,
 120                 'D|daemonize' => \$daemonize,
 121                 'cert=s' => \$default_cert,
 122                 'key=s' => \$default_key,
 123                 'help|h' => \(my $show_help),
 124         );
 125         GetOptions(%opt) or die $help;
 126         if ($show_help) { print $help; exit 0 };
 127
 128         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 129                 die "--pid-file cannot end with '.oldbin'\n";
 130         }
 131         @listeners = inherit($listener_names);
 132
 133         # allow socket-activation users to set certs once and not
 134         # have to configure each socket:
 135         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 136
 137         # ignore daemonize when inheriting
 138         $daemonize = undef if scalar @listeners;
 139
 140         unless (@listeners || @cfg_listen) {
 141                 $default_listen // die "no listeners specified\n";
 142                 push @cfg_listen, $default_listen
 143         }
 144
 145         foreach my $l (@cfg_listen) {
 146                 my $orig = $l;
 147                 my $scheme = '';
 148                 if ($l =~ s!\A([^:]+)://!!) {
 149                         $scheme = $1;
 150                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 151                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 152                         $scheme = $s if defined $s;
 153                 }
 154                 if ($l =~ s!/?\?(.+)\z!!) {
 155                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 156                 } elsif (defined($default_cert)) {
 157                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 158                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 159                         die "$orig specified w/o cert=\n";
 160                 }
 161                 $scheme =~ /\A(http|imap|nntp|pop3)/ and
 162                         $xnetd->{$l} = load_mod($1);
 163
 164                 next if $listener_names->{$l}; # already inherited
 165                 my (%o, $sock_pkg);
 166                 if (index($l, '/') == 0) {
 167                         $sock_pkg = 'IO::Socket::UNIX';
 168                         eval "use $sock_pkg";
 169                         die $@ if $@;
 170                         %o = (Type => SOCK_STREAM, Peer => $l);
 171                         if (-S $l) {
 172                                 my $c = $sock_pkg->new(%o);
 173                                 if (!defined($c) && $!{ECONNREFUSED}) {
 174                                         unlink $l or die
 175 "failed to unlink stale socket=$l: $!\n";
 176                                 } # else: let the bind fail
 177                         }
 178                         $o{Local} = delete $o{Peer};
 179                 } else {
 180                         # both work for IPv4, too
 181                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 182                                 $sock_pkg = $_;
 183                                 eval "use $sock_pkg";
 184                                 $@ or last;
 185                         }
 186                         die $@ if $@;
 187                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 188                 }
 189                 $o{Listen} = 1024;
 190                 my $prev = umask 0000;
 191                 my $s = eval { $sock_pkg->new(%o) };
 192                 warn "error binding $l: $! ($@)\n" unless $s;
 193                 umask $prev;
 194                 if ($s) {
 195                         $listener_names->{sockname($s)} = $s;
 196                         $s->blocking(0);
 197                         push @listeners, $s;
 198                 }
 199         }
 200
 201         # cert/key options in @cfg_listen takes precedence when inheriting,
 202         # but map well-known inherited ports if --listen isn't specified
 203         # at all
 204         for my $sockname (@inherited_names) {
 205                 $sockname =~ /:([0-9]+)\z/ or next;
 206                 if (my $scheme = $KNOWN_TLS{$1}) {
 207                         $xnetd->{$sockname} = load_mod(substr($scheme, 0, -1));
 208                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 209                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 210                         $xnetd->{$sockname} = load_mod($scheme);
 211                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 212                         $tls_opt{''} ||= accept_tls_opt('');
 213                 }
 214         }
 215
 216         die "No listeners bound\n" unless @listeners;
 217 }
 218
 219 sub check_absolute ($$) {
 220         my ($var, $val) = @_;
 221         if (defined $val && index($val, '/') != 0) {
 222                 die
 223 "--$var must be an absolute path when using --daemonize: $val\n";
 224         }
 225 }
 226
 227 sub daemonize () {
 228         if ($daemonize) {
 229                 require Cwd;
 230                 foreach my $i (0..$#ARGV) {
 231                         my $arg = $ARGV[$i];
 232                         next unless -e $arg;
 233                         $ARGV[$i] = Cwd::abs_path($arg);
 234                 }
 235                 check_absolute('stdout', $stdout);
 236                 check_absolute('stderr', $stderr);
 237                 check_absolute('pid-file', $pid_file);
 238
 239                 chdir '/' or die "chdir failed: $!";
 240         }
 241         if (defined($pid_file) || defined($group) || defined($user)) {
 242                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 243 Net::Server required for --pid-file, --group, --user
 244 $@
 245 EOF
 246         }
 247         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 248         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 249         if (defined $group) {
 250                 $gid = Net::Server::Daemonize::get_gid($group);
 251                 $gid = (split /\s+/, $gid)[0];
 252         } elsif (defined $uid) {
 253                 $gid = (getpwuid($uid))[3];
 254         }
 255
 256         # We change users in the worker to ensure upgradability,
 257         # The upgrade will create the ".oldbin" pid file in the
 258         # same directory as the given pid file.
 259         $uid and $set_user = sub {
 260                 $set_user = undef;
 261                 Net::Server::Daemonize::set_user($uid, $gid);
 262         };
 263
 264         if ($daemonize) {
 265                 my $pid = fork // die "fork: $!";
 266                 exit if $pid;
 267
 268                 open(STDIN, '+<', '/dev/null') or
 269                                         die "redirect stdin failed: $!\n";
 270                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 271                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 272                 POSIX::setsid();
 273                 $pid = fork // die "fork: $!";
 274                 exit if $pid;
 275         }
 276         return unless defined $pid_file;
 277
 278         write_pid($pid_file);
 279         # for ->DESTROY:
 280         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 281 }
 282
 283 sub worker_quit { # $_[0] = signal name or number (unused)
 284         # killing again terminates immediately:
 285         exit unless @listeners;
 286
 287         $_->close foreach @listeners; # call PublicInbox::DS::close
 288         @listeners = ();
 289         my $proc_name;
 290         my $warn = 0;
 291         # drop idle connections and try to quit gracefully
 292         PublicInbox::DS->SetPostLoopCallback(sub {
 293                 my ($dmap, undef) = @_;
 294                 my $n = 0;
 295                 my $now = now();
 296                 for my $s (values %$dmap) {
 297                         $s->can('busy') or next;
 298                         if ($s->busy) {
 299                                 ++$n;
 300                         } else { # close as much as possible, early as possible
 301                                 $s->close;
 302                         }
 303                 }
 304                 if ($n) {
 305                         if (($warn + 5) < now()) {
 306                                 warn "$$ quitting, $n client(s) left\n";
 307                                 $warn = now();
 308                         }
 309                         unless (defined $proc_name) {
 310                                 $proc_name = (split(/\s+/, $0))[0];
 311                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 312                         }
 313                         $0 = "$proc_name quitting, $n client(s) left";
 314                 }
 315                 $n; # true: loop continues, false: loop breaks
 316         });
 317 }
 318
 319 sub reopen_logs {
 320         if ($stdout) {
 321                 open STDOUT, '>>', $stdout or
 322                         warn "failed to redirect stdout to $stdout: $!\n";
 323                 STDOUT->autoflush(1);
 324                 do_chown($stdout);
 325         }
 326         if ($stderr) {
 327                 open STDERR, '>>', $stderr or
 328                         warn "failed to redirect stderr to $stderr: $!\n";
 329                 STDERR->autoflush(1);
 330                 do_chown($stderr);
 331         }
 332 }
 333
 334 sub sockname ($) {
 335         my ($s) = @_;
 336         my $addr = getsockname($s) or return;
 337         my ($host, $port) = host_with_port($addr);
 338         if ($port == 0 && $host eq '127.0.0.1') {
 339                 my ($path) = Socket::sockaddr_un($addr);
 340                 return $path;
 341         }
 342         "$host:$port";
 343 }
 344
 345 sub unpack_ipv6 ($) {
 346         my ($addr) = @_;
 347         my ($port, $host);
 348
 349         # Socket.pm in Perl 5.14+ supports IPv6:
 350         eval {
 351                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 352                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 353         };
 354
 355         if ($@) {
 356                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 357                 # Socket6, so it may be installed on our system, already
 358                 # (otherwise die here):
 359                 require Socket6;
 360
 361                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 362                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 363         }
 364         ($host, $port);
 365 }
 366
 367 sub host_with_port ($) {
 368         my ($addr) = @_;
 369         my ($port, $host);
 370
 371         # this eval will die on Unix sockets:
 372         eval {
 373                 if (length($addr) >= 28) {
 374                         ($host, $port) = unpack_ipv6($addr);
 375                         $host = "[$host]";
 376                 } else {
 377                         ($port, $host) = Socket::sockaddr_in($addr);
 378                         $host = Socket::inet_ntoa($host);
 379                 }
 380         };
 381         $@ ? ('127.0.0.1', 0) : ($host, $port);
 382 }
 383
 384 sub inherit ($) {
 385         my ($listener_names) = @_;
 386         return () if ($ENV{LISTEN_PID} || 0) != $$;
 387         my $fds = $ENV{LISTEN_FDS} or return ();
 388         my $end = $fds + 2; # LISTEN_FDS_START - 1
 389         my @rv = ();
 390         foreach my $fd (3..$end) {
 391                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 392                 if (my $k = sockname($s)) {
 393                         my $prev_was_blocking = $s->blocking(0);
 394                         warn <<"" if $prev_was_blocking;
 395 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 396 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 397 processes when multiple service instances start.
 398
 399                         $listener_names->{$k} = $s;
 400                         push @rv, $s;
 401                 } else {
 402                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 403                 }
 404         }
 405         @rv
 406 }
 407
 408 sub upgrade { # $_[0] = signal name or number (unused)
 409         if ($reexec_pid) {
 410                 warn "upgrade in-progress: $reexec_pid\n";
 411                 return;
 412         }
 413         if (defined $pid_file) {
 414                 if ($pid_file =~ /\.oldbin\z/) {
 415                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 416                         return;
 417                 }
 418                 unlink_pid_file_safe_ish($$, $pid_file);
 419                 $pid_file .= '.oldbin';
 420                 write_pid($pid_file);
 421         }
 422         my $pid = fork;
 423         unless (defined $pid) {
 424                 warn "fork failed: $!\n";
 425                 return;
 426         }
 427         if ($pid == 0) {
 428                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 429                 $ENV{LISTEN_FDS} = scalar @listeners;
 430                 $ENV{LISTEN_PID} = $$;
 431                 foreach my $s (@listeners) {
 432                         # @listeners are globs with workers, PI::L w/o workers
 433                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 434
 435                         my $fl = fcntl($s, F_GETFD, 0);
 436                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 437                 }
 438                 exec @CMD;
 439                 die "Failed to exec: $!\n";
 440         }
 441         $reexec_pid = $pid;
 442 }
 443
 444 sub kill_workers ($) {
 445         my ($sig) = @_;
 446         kill $sig, keys(%pids);
 447 }
 448
 449 sub upgrade_aborted ($) {
 450         my ($p) = @_;
 451         warn "reexec PID($p) died with: $?\n";
 452         $reexec_pid = undef;
 453         return unless $pid_file;
 454
 455         my $file = $pid_file;
 456         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 457         unlink_pid_file_safe_ish($$, $pid_file);
 458         $pid_file = $file;
 459         eval { write_pid($pid_file) };
 460         warn $@, "\n" if $@;
 461 }
 462
 463 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 464         while (1) {
 465                 my $p = waitpid(-1, WNOHANG) or return;
 466                 if (defined $reexec_pid && $p == $reexec_pid) {
 467                         upgrade_aborted($p);
 468                 } elsif (defined(my $id = delete $pids{$p})) {
 469                         warn "worker[$id] PID($p) died with: $?\n";
 470                 } elsif ($p > 0) {
 471                         warn "unknown PID($p) reaped: $?\n";
 472                 } else {
 473                         return;
 474                 }
 475         }
 476 }
 477
 478 sub unlink_pid_file_safe_ish ($$) {
 479         my ($unlink_pid, $file) = @_;
 480         return unless defined $unlink_pid && $unlink_pid == $$;
 481
 482         open my $fh, '<', $file or return;
 483         local $/ = "\n";
 484         defined(my $read_pid = <$fh>) or return;
 485         chomp $read_pid;
 486         if ($read_pid == $unlink_pid) {
 487                 Net::Server::Daemonize::unlink_pid_file($file);
 488         }
 489 }
 490
 491 sub master_quit ($) {
 492         exit unless @listeners;
 493         @listeners = ();
 494         kill_workers($_[0]);
 495 }
 496
 497 sub master_loop {
 498         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 499         my $set_workers = $worker_processes;
 500         reopen_logs();
 501         my $ignore_winch;
 502         my $sig = {
 503                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 504                 USR2 => \&upgrade,
 505                 QUIT => \&master_quit,
 506                 INT => \&master_quit,
 507                 TERM => \&master_quit,
 508                 WINCH => sub {
 509                         return if $ignore_winch || !@listeners;
 510                         if (-t STDIN || -t STDOUT || -t STDERR) {
 511                                 $ignore_winch = 1;
 512                                 warn <<EOF;
 513 ignoring SIGWINCH since we are not daemonized
 514 EOF
 515                         } else {
 516                                 $worker_processes = 0;
 517                         }
 518                 },
 519                 HUP => sub {
 520                         return unless @listeners;
 521                         $worker_processes = $set_workers;
 522                         kill_workers($_[0]);
 523                 },
 524                 TTIN => sub {
 525                         return unless @listeners;
 526                         if ($set_workers > $worker_processes) {
 527                                 ++$worker_processes;
 528                         } else {
 529                                 $worker_processes = ++$set_workers;
 530                         }
 531                 },
 532                 TTOU => sub {
 533                         $worker_processes = --$set_workers if $set_workers > 0;
 534                 },
 535                 CHLD => \&reap_children,
 536         };
 537         my $sigfd = PublicInbox::Sigfd->new($sig);
 538         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 539         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 540         while (1) { # main loop
 541                 my $n = scalar keys %pids;
 542                 unless (@listeners) {
 543                         exit if $n == 0;
 544                         $set_workers = $worker_processes = $n = 0;
 545                 }
 546
 547                 if ($n > $worker_processes) {
 548                         while (my ($k, $v) = each %pids) {
 549                                 kill('TERM', $k) if $v >= $worker_processes;
 550                         }
 551                         $n = $worker_processes;
 552                 }
 553                 my $want = $worker_processes - 1;
 554                 if ($n <= $want) {
 555                         PublicInbox::DS::block_signals() if !$sigfd;
 556                         for my $i ($n..$want) {
 557                                 my $seed = rand(0xffffffff);
 558                                 my $pid = fork;
 559                                 if (!defined $pid) {
 560                                         warn "failed to fork worker[$i]: $!\n";
 561                                 } elsif ($pid == 0) {
 562                                         srand($seed);
 563                                         eval { Net::SSLeay::randomize() };
 564                                         $set_user->() if $set_user;
 565                                         return $p0; # run normal work code
 566                                 } else {
 567                                         warn "PID=$pid is worker[$i]\n";
 568                                         $pids{$pid} = $i;
 569                                 }
 570                         }
 571                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 572                 }
 573
 574                 if ($sigfd) { # Linux and IO::KQueue users:
 575                         $sigfd->wait_once;
 576                 } else { # wake up every second
 577                         sleep(1);
 578                 }
 579         }
 580         exit # never gets here, just for documentation
 581 }
 582
 583 sub tls_start_cb ($$) {
 584         my ($opt, $orig_post_accept) = @_;
 585         sub {
 586                 my ($io, $addr, $srv) = @_;
 587                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 588                 $orig_post_accept->($ssl, $addr, $srv);
 589         }
 590 }
 591
 592 sub defer_accept ($$) {
 593         my ($s, $af_name) = @_;
 594         return unless defined $af_name;
 595         if ($^O eq 'linux') {
 596                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 597                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 598                 return unless defined $x; # may be Unix socket
 599                 my $sec = unpack('i', $x);
 600                 return if $sec > 0; # systemd users may set a higher value
 601                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 602         } elsif ($^O eq 'freebsd') {
 603                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 604                 return if defined $x; # don't change if set
 605                 my $accf_arg = pack('a16a240', $af_name, '');
 606                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 607         }
 608 }
 609
 610 sub daemon_loop ($) {
 611         my ($xnetd) = @_;
 612         my $refresh = sub {
 613                 my ($sig) = @_;
 614                 for my $xn (values %$xnetd) {
 615                         eval { $xn->{refresh}->($sig) };
 616                         warn "refresh $@\n" if $@;
 617                 }
 618         };
 619         my %post_accept;
 620         while (my ($k, $v) = each %tls_opt) {
 621                 my $l = $k;
 622                 $l =~ s!\A([^:]+)://!!;
 623                 my $scheme = $1 // '';
 624                 my $xn = $xnetd->{$l} // $xnetd->{''};
 625                 if ($scheme =~ m!\A(?:https|imaps|nntps|pop3s)!) {
 626                         $post_accept{$l} = tls_start_cb($v, $xn->{post_accept});
 627                 } elsif ($xn->{tlsd}) { # STARTTLS, $k eq '' is OK
 628                         $xn->{tlsd}->{accept_tls} = $v;
 629                 }
 630         }
 631         my $sig = {
 632                 HUP => $refresh,
 633                 INT => \&worker_quit,
 634                 QUIT => \&worker_quit,
 635                 TERM => \&worker_quit,
 636                 TTIN => 'IGNORE',
 637                 TTOU => 'IGNORE',
 638                 USR1 => \&reopen_logs,
 639                 USR2 => 'IGNORE',
 640                 WINCH => 'IGNORE',
 641                 CHLD => \&PublicInbox::DS::enqueue_reap,
 642         };
 643         if ($worker_processes > 0) {
 644                 $refresh->(); # preload by default
 645                 my $fh = master_loop(); # returns if in child process
 646                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 647         } else {
 648                 reopen_logs();
 649                 $set_user->() if $set_user;
 650                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 651                 $refresh->();
 652         }
 653         $uid = $gid = undef;
 654         reopen_logs();
 655         @listeners = map {;
 656                 my $l = sockname($_);
 657                 my $tls_cb = $post_accept{$l};
 658                 my $xn = $xnetd->{$l} // $xnetd->{''};
 659
 660                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 661                 # IMAP, NNTP and POP3 are server-first
 662                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 663
 664                 # this calls epoll_create:
 665                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 666         } @listeners;
 667         PublicInbox::DS::event_loop($sig, $oldset);
 668 }
 669
 670 sub run {
 671         my ($default_listen) = @_;
 672         my $xnetd = {};
 673         if ($default_listen) {
 674                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 675                         die "BUG: $default_listen";
 676                 $xnetd->{''} = load_mod($1);
 677         }
 678         daemon_prepare($default_listen, $xnetd);
 679         my $for_destroy = daemonize();
 680
 681         # localize GCF2C for tests:
 682         local $PublicInbox::GitAsyncCat::GCF2C;
 683         local $PublicInbox::Git::async_warn = 1;
 684         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 685
 686         daemon_loop($xnetd);
 687         PublicInbox::DS->Reset;
 688         # ->DESTROY runs when $for_destroy goes out-of-scope
 689 }
 690
 691 sub do_chown ($) {
 692         my ($path) = @_;
 693         if (defined $uid and !chown($uid, $gid, $path)) {
 694                 warn "could not chown $path: $!\n";
 695         }
 696 }
 697
 698 sub write_pid ($) {
 699         my ($path) = @_;
 700         Net::Server::Daemonize::create_pid_file($path);
 701         do_chown($path);
 702 }
 703
 704 sub DESTROY {
 705         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 706 }
 707
 708 1;