lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 use Cwd qw/abs_path/;
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Syscall qw(SFD_NONBLOCK);
  19 require PublicInbox::Listener;
  20 require PublicInbox::ParentPipe;
  21 require PublicInbox::Sigfd;
  22 my @CMD;
  23 my ($set_user, $oldset, $newset);
  24 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  25 my $worker_processes = 1;
  26 my @listeners;
  27 my %pids;
  28 my %listener_names; # sockname => IO::Handle
  29 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  30 my $reexec_pid;
  31 my $cleanup;
  32 my ($uid, $gid);
  33 my ($default_cert, $default_key);
  34 END { $cleanup->() if $cleanup };
  35 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps' );
  36 my %KNOWN_STARTTLS = ( 119 => 'nntp' );
  37
  38 sub accept_tls_opt ($) {
  39         my ($opt_str) = @_;
  40         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  41         require PublicInbox::TLS;
  42         my $o = {};
  43         # allow ',' as delimiter since '&' is shell-unfriendly
  44         foreach (split(/[,&]/, $opt_str)) {
  45                 my ($k, $v) = split(/=/, $_, 2);
  46                 push @{$o->{$k} ||= []}, $v;
  47         }
  48
  49         # key may be a part of cert.  At least
  50         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  51         $o->{cert} //= [ $default_cert ];
  52         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  53         my %ctx_opt = (SSL_server => 1);
  54         # parse out hostname:/path/to/ mappings:
  55         foreach my $k (qw(cert key)) {
  56                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  57                 foreach my $path (@{$o->{$k}}) {
  58                         my $host = '';
  59                         $path =~ s/\A([^:]+):// and $host = $1;
  60                         $x->{$host} = $path;
  61                 }
  62         }
  63         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  64                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  65
  66         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  67         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  68         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  69         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  70         if ($mode && $ctx->{context}) {
  71                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  72                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  73         }
  74
  75         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  76 }
  77
  78 sub sig_setmask { sigprocmask(SIG_SETMASK, @_) or die "sigprocmask: $!" }
  79
  80 sub daemon_prepare ($) {
  81         my ($default_listen) = @_;
  82         $oldset = POSIX::SigSet->new();
  83         $newset = POSIX::SigSet->new();
  84         $newset->fillset or die "fillset: $!";
  85         sig_setmask($newset, $oldset);
  86         @CMD = ($0, @ARGV);
  87         my %opts = (
  88                 'l|listen=s' => \@cfg_listen,
  89                 '1|stdout=s' => \$stdout,
  90                 '2|stderr=s' => \$stderr,
  91                 'W|worker-processes=i' => \$worker_processes,
  92                 'P|pid-file=s' => \$pid_file,
  93                 'u|user=s' => \$user,
  94                 'g|group=s' => \$group,
  95                 'D|daemonize' => \$daemonize,
  96                 'cert=s' => \$default_cert,
  97                 'key=s' => \$default_key,
  98         );
  99         GetOptions(%opts) or die "bad command-line args\n";
 100
 101         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 102                 die "--pid-file cannot end with '.oldbin'\n";
 103         }
 104         @listeners = inherit();
 105
 106         # allow socket-activation users to set certs once and not
 107         # have to configure each socket:
 108         my @inherited_names = keys(%listener_names) if defined($default_cert);
 109
 110         # ignore daemonize when inheriting
 111         $daemonize = undef if scalar @listeners;
 112
 113         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 114
 115         foreach my $l (@cfg_listen) {
 116                 my $orig = $l;
 117                 my $scheme = '';
 118                 if ($l =~ s!\A([^:]+)://!!) {
 119                         $scheme = $1;
 120                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 121                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 122                         $scheme = $s if defined $s;
 123                 }
 124                 if ($l =~ s!/?\?(.+)\z!!) {
 125                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 126                 } elsif (defined($default_cert)) {
 127                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 128                 } elsif ($scheme =~ /\A(?:nntps|https)\z/) {
 129                         die "$orig specified w/o cert=\n";
 130                 }
 131                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 132
 133                 next if $listener_names{$l}; # already inherited
 134                 my (%o, $sock_pkg);
 135                 if (index($l, '/') == 0) {
 136                         $sock_pkg = 'IO::Socket::UNIX';
 137                         eval "use $sock_pkg";
 138                         die $@ if $@;
 139                         %o = (Type => SOCK_STREAM, Peer => $l);
 140                         if (-S $l) {
 141                                 my $c = $sock_pkg->new(%o);
 142                                 if (!defined($c) && $!{ECONNREFUSED}) {
 143                                         unlink $l or die
 144 "failed to unlink stale socket=$l: $!\n";
 145                                 } # else: let the bind fail
 146                         }
 147                         $o{Local} = delete $o{Peer};
 148                 } else {
 149                         # both work for IPv4, too
 150                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 151                                 $sock_pkg = $_;
 152                                 eval "use $sock_pkg";
 153                                 $@ or last;
 154                         }
 155                         die $@ if $@;
 156                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 157                 }
 158                 $o{Listen} = 1024;
 159                 my $prev = umask 0000;
 160                 my $s = eval { $sock_pkg->new(%o) };
 161                 warn "error binding $l: $! ($@)\n" unless $s;
 162                 umask $prev;
 163                 if ($s) {
 164                         $listener_names{sockname($s)} = $s;
 165                         $s->blocking(0);
 166                         push @listeners, $s;
 167                 }
 168         }
 169
 170         # cert/key options in @cfg_listen takes precedence when inheriting,
 171         # but map well-known inherited ports if --listen isn't specified
 172         # at all
 173         for my $sockname (@inherited_names) {
 174                 $sockname =~ /:([0-9]+)\z/ or next;
 175                 if (my $scheme = $KNOWN_TLS{$1}) {
 176                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 177                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 178                         next if $tls_opt{"$scheme://$sockname"};
 179                         $tls_opt{''} ||= accept_tls_opt('');
 180                 }
 181         }
 182
 183         die "No listeners bound\n" unless @listeners;
 184 }
 185
 186 sub check_absolute ($$) {
 187         my ($var, $val) = @_;
 188         if (defined $val && index($val, '/') != 0) {
 189                 die
 190 "--$var must be an absolute path when using --daemonize: $val\n";
 191         }
 192 }
 193
 194 sub daemonize () {
 195         if ($daemonize) {
 196                 foreach my $i (0..$#ARGV) {
 197                         my $arg = $ARGV[$i];
 198                         next unless -e $arg;
 199                         $ARGV[$i] = abs_path($arg);
 200                 }
 201                 check_absolute('stdout', $stdout);
 202                 check_absolute('stderr', $stderr);
 203                 check_absolute('pid-file', $pid_file);
 204
 205                 chdir '/' or die "chdir failed: $!";
 206         }
 207
 208         return unless (defined $pid_file || defined $group || defined $user
 209                         || $daemonize);
 210
 211         eval { require Net::Server::Daemonize };
 212         if ($@) {
 213                 die
 214 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 215         }
 216
 217         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 218         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 219         if (defined $group) {
 220                 $gid = Net::Server::Daemonize::get_gid($group);
 221                 $gid = (split /\s+/, $gid)[0];
 222         } elsif (defined $uid) {
 223                 $gid = (getpwuid($uid))[3];
 224         }
 225
 226         # We change users in the worker to ensure upgradability,
 227         # The upgrade will create the ".oldbin" pid file in the
 228         # same directory as the given pid file.
 229         $uid and $set_user = sub {
 230                 $set_user = undef;
 231                 Net::Server::Daemonize::set_user($uid, $gid);
 232         };
 233
 234         if ($daemonize) {
 235                 my $pid = fork;
 236                 die "could not fork: $!\n" unless defined $pid;
 237                 exit if $pid;
 238
 239                 open(STDIN, '+<', '/dev/null') or
 240                                         die "redirect stdin failed: $!\n";
 241                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 242                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 243                 POSIX::setsid();
 244                 $pid = fork;
 245                 die "could not fork: $!\n" unless defined $pid;
 246                 exit if $pid;
 247         }
 248         if (defined $pid_file) {
 249                 write_pid($pid_file);
 250                 my $unlink_pid = $$;
 251                 $cleanup = sub {
 252                         $cleanup = undef; # avoid cyclic reference
 253                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 254                 };
 255         }
 256 }
 257
 258 sub worker_quit { # $_[0] = signal name or number (unused)
 259         # killing again terminates immediately:
 260         exit unless @listeners;
 261
 262         $_->close foreach @listeners; # call PublicInbox::DS::close
 263         @listeners = ();
 264         my $proc_name;
 265         my $warn = 0;
 266         # drop idle connections and try to quit gracefully
 267         PublicInbox::DS->SetPostLoopCallback(sub {
 268                 my ($dmap, undef) = @_;
 269                 my $n = 0;
 270                 my $now = now();
 271
 272                 foreach my $s (values %$dmap) {
 273                         $s->can('busy') or next;
 274                         if ($s->busy($now)) {
 275                                 ++$n;
 276                         } else {
 277                                 # close as much as possible, early as possible
 278                                 $s->close;
 279                         }
 280                 }
 281                 if ($n) {
 282                         if (($warn + 5) < now()) {
 283                                 warn "$$ quitting, $n client(s) left\n";
 284                                 $warn = now();
 285                         }
 286                         unless (defined $proc_name) {
 287                                 $proc_name = (split(/\s+/, $0))[0];
 288                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 289                         }
 290                         $0 = "$proc_name quitting, $n client(s) left";
 291                 }
 292                 $n; # true: loop continues, false: loop breaks
 293         });
 294 }
 295
 296 sub reopen_logs {
 297         if ($stdout) {
 298                 open STDOUT, '>>', $stdout or
 299                         warn "failed to redirect stdout to $stdout: $!\n";
 300                 STDOUT->autoflush(1);
 301                 do_chown($stdout);
 302         }
 303         if ($stderr) {
 304                 open STDERR, '>>', $stderr or
 305                         warn "failed to redirect stderr to $stderr: $!\n";
 306                 STDERR->autoflush(1);
 307                 do_chown($stderr);
 308         }
 309 }
 310
 311 sub sockname ($) {
 312         my ($s) = @_;
 313         my $addr = getsockname($s) or return;
 314         my ($host, $port) = host_with_port($addr);
 315         if ($port == 0 && $host eq '127.0.0.1') {
 316                 my ($path) = Socket::sockaddr_un($addr);
 317                 return $path;
 318         }
 319         "$host:$port";
 320 }
 321
 322 sub unpack_ipv6 ($) {
 323         my ($addr) = @_;
 324         my ($port, $host);
 325
 326         # Socket.pm in Perl 5.14+ supports IPv6:
 327         eval {
 328                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 329                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 330         };
 331
 332         if ($@) {
 333                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 334                 # Socket6, so it may be installed on our system, already
 335                 # (otherwise die here):
 336                 require Socket6;
 337
 338                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 339                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 340         }
 341         ($host, $port);
 342 }
 343
 344 sub host_with_port ($) {
 345         my ($addr) = @_;
 346         my ($port, $host);
 347
 348         # this eval will die on Unix sockets:
 349         eval {
 350                 if (length($addr) >= 28) {
 351                         ($host, $port) = unpack_ipv6($addr);
 352                         $host = "[$host]";
 353                 } else {
 354                         ($port, $host) = Socket::sockaddr_in($addr);
 355                         $host = Socket::inet_ntoa($host);
 356                 }
 357         };
 358         $@ ? ('127.0.0.1', 0) : ($host, $port);
 359 }
 360
 361 sub inherit () {
 362         return () if ($ENV{LISTEN_PID} || 0) != $$;
 363         my $fds = $ENV{LISTEN_FDS} or return ();
 364         my $end = $fds + 2; # LISTEN_FDS_START - 1
 365         my @rv = ();
 366         foreach my $fd (3..$end) {
 367                 my $s = IO::Handle->new_from_fd($fd, 'r');
 368                 if (my $k = sockname($s)) {
 369                         if ($s->blocking) {
 370                                 $s->blocking(0);
 371                                 warn <<"";
 372 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 373 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 374 processes when multiple service instances start.
 375
 376                         }
 377                         $listener_names{$k} = $s;
 378                         push @rv, $s;
 379                 } else {
 380                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 381                 }
 382         }
 383         @rv
 384 }
 385
 386 sub upgrade { # $_[0] = signal name or number (unused)
 387         if ($reexec_pid) {
 388                 warn "upgrade in-progress: $reexec_pid\n";
 389                 return;
 390         }
 391         if (defined $pid_file) {
 392                 if ($pid_file =~ /\.oldbin\z/) {
 393                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 394                         return;
 395                 }
 396                 unlink_pid_file_safe_ish($$, $pid_file);
 397                 $pid_file .= '.oldbin';
 398                 write_pid($pid_file);
 399         }
 400         my $pid = fork;
 401         unless (defined $pid) {
 402                 warn "fork failed: $!\n";
 403                 return;
 404         }
 405         if ($pid == 0) {
 406                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 407                 $ENV{LISTEN_FDS} = scalar @listeners;
 408                 $ENV{LISTEN_PID} = $$;
 409                 foreach my $s (@listeners) {
 410                         my $fl = fcntl($s, F_GETFD, 0);
 411                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 412                 }
 413                 exec @CMD;
 414                 die "Failed to exec: $!\n";
 415         }
 416         $reexec_pid = $pid;
 417 }
 418
 419 sub kill_workers ($) {
 420         my ($s) = @_;
 421
 422         while (my ($pid, $id) = each %pids) {
 423                 kill $s, $pid;
 424         }
 425 }
 426
 427 sub upgrade_aborted ($) {
 428         my ($p) = @_;
 429         warn "reexec PID($p) died with: $?\n";
 430         $reexec_pid = undef;
 431         return unless $pid_file;
 432
 433         my $file = $pid_file;
 434         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 435         unlink_pid_file_safe_ish($$, $pid_file);
 436         $pid_file = $file;
 437         eval { write_pid($pid_file) };
 438         warn $@, "\n" if $@;
 439 }
 440
 441 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 442         while (1) {
 443                 my $p = waitpid(-1, WNOHANG) or return;
 444                 if (defined $reexec_pid && $p == $reexec_pid) {
 445                         upgrade_aborted($p);
 446                 } elsif (defined(my $id = delete $pids{$p})) {
 447                         warn "worker[$id] PID($p) died with: $?\n";
 448                 } elsif ($p > 0) {
 449                         warn "unknown PID($p) reaped: $?\n";
 450                 } else {
 451                         return;
 452                 }
 453         }
 454 }
 455
 456 sub unlink_pid_file_safe_ish ($$) {
 457         my ($unlink_pid, $file) = @_;
 458         return unless defined $unlink_pid && $unlink_pid == $$;
 459
 460         open my $fh, '<', $file or return;
 461         local $/ = "\n";
 462         defined(my $read_pid = <$fh>) or return;
 463         chomp $read_pid;
 464         if ($read_pid == $unlink_pid) {
 465                 Net::Server::Daemonize::unlink_pid_file($file);
 466         }
 467 }
 468
 469 sub master_loop {
 470         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 471         # 1031: F_SETPIPE_SZ, 4096: page size
 472         fcntl($p1, 1031, 4096) if $^O eq 'linux';
 473         my $set_workers = $worker_processes;
 474         reopen_logs();
 475         my $quit = 0;
 476         my $ignore_winch;
 477         my $quit_cb = sub { exit if $quit++; kill_workers($_[0]) };
 478         my $sig = {
 479                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 480                 USR2 => \&upgrade,
 481                 QUIT => $quit_cb,
 482                 INT => $quit_cb,
 483                 TERM => $quit_cb,
 484                 WINCH => sub {
 485                         return if $ignore_winch;
 486                         if (-t STDIN || -t STDOUT || -t STDERR) {
 487                                 $ignore_winch = 1;
 488                                 warn <<EOF;
 489 ignoring SIGWINCH since we are not daemonized
 490 EOF
 491                         } else {
 492                                 $worker_processes = 0;
 493                         }
 494                 },
 495                 HUP => sub {
 496                         $worker_processes = $set_workers;
 497                         kill_workers($_[0]);
 498                 },
 499                 TTIN => sub {
 500                         if ($set_workers > $worker_processes) {
 501                                 ++$worker_processes;
 502                         } else {
 503                                 $worker_processes = ++$set_workers;
 504                         }
 505                 },
 506                 TTOU => sub {
 507                         $worker_processes = --$set_workers if $set_workers > 0;
 508                 },
 509                 CHLD => \&reap_children,
 510         };
 511         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 512         local %SIG = (%SIG, %$sig) if !$sigfd;
 513         sig_setmask($oldset) if !$sigfd;
 514         while (1) { # main loop
 515                 my $n = scalar keys %pids;
 516                 if ($quit) {
 517                         exit if $n == 0;
 518                         $set_workers = $worker_processes = $n = 0;
 519                 }
 520
 521                 if ($n > $worker_processes) {
 522                         while (my ($k, $v) = each %pids) {
 523                                 kill('TERM', $k) if $v >= $worker_processes;
 524                         }
 525                         $n = $worker_processes;
 526                 }
 527                 my $want = $worker_processes - 1;
 528                 if ($n <= $want) {
 529                         sig_setmask($newset) if !$sigfd;
 530                         for my $i ($n..$want) {
 531                                 my $pid = fork;
 532                                 if (!defined $pid) {
 533                                         warn "failed to fork worker[$i]: $!\n";
 534                                 } elsif ($pid == 0) {
 535                                         $set_user->() if $set_user;
 536                                         return $p0; # run normal work code
 537                                 } else {
 538                                         warn "PID=$pid is worker[$i]\n";
 539                                         $pids{$pid} = $i;
 540                                 }
 541                         }
 542                         sig_setmask($oldset) if !$sigfd;
 543                 }
 544
 545                 if ($sigfd) { # Linux and IO::KQueue users:
 546                         $sigfd->wait_once;
 547                 } else { # wake up every second
 548                         sleep(1);
 549                 }
 550         }
 551         exit # never gets here, just for documentation
 552 }
 553
 554 sub tls_start_cb ($$) {
 555         my ($opt, $orig_post_accept) = @_;
 556         sub {
 557                 my ($io, $addr, $srv) = @_;
 558                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 559                 $orig_post_accept->($ssl, $addr, $srv);
 560         }
 561 }
 562
 563 sub defer_accept ($$) {
 564         my ($s, $af_name) = @_;
 565         return unless defined $af_name;
 566         if ($^O eq 'linux') {
 567                 my $x = getsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT());
 568                 return unless defined $x; # may be Unix socket
 569                 my $sec = unpack('i', $x);
 570                 return if $sec > 0; # systemd users may set a higher value
 571                 setsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT(), 1);
 572         } elsif ($^O eq 'freebsd') {
 573                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 574                 return if defined $x; # don't change if set
 575                 my $accf_arg = pack('a16a240', $af_name, '');
 576                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 577         }
 578 }
 579
 580 sub daemon_loop ($$$$) {
 581         my ($refresh, $post_accept, $nntpd, $af_default) = @_;
 582         my %post_accept;
 583         while (my ($k, $v) = each %tls_opt) {
 584                 if ($k =~ s!\A(?:nntps|https)://!!) {
 585                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 586                 } elsif ($nntpd) { # STARTTLS, $k eq '' is OK
 587                         $nntpd->{accept_tls} = $v;
 588                 }
 589         }
 590         my $sig = {
 591                 HUP => $refresh,
 592                 INT => \&worker_quit,
 593                 QUIT => \&worker_quit,
 594                 TERM => \&worker_quit,
 595                 TTIN => 'IGNORE',
 596                 TTOU => 'IGNORE',
 597                 USR1 => \&reopen_logs,
 598                 USR2 => 'IGNORE',
 599                 WINCH => 'IGNORE',
 600                 CHLD => \&PublicInbox::DS::enqueue_reap,
 601         };
 602         my $parent_pipe;
 603         if ($worker_processes > 0) {
 604                 $refresh->(); # preload by default
 605                 my $fh = master_loop(); # returns if in child process
 606                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 607         } else {
 608                 reopen_logs();
 609                 $set_user->() if $set_user;
 610                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 611                 $refresh->();
 612         }
 613         $uid = $gid = undef;
 614         reopen_logs();
 615         @listeners = map {;
 616                 my $tls_cb = $post_accept{sockname($_)};
 617
 618                 # NNTPS, HTTPS, HTTP, and POP3S are client-first traffic
 619                 # NNTP and POP3 are server-first
 620                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 621
 622                 # this calls epoll_create:
 623                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 624         } @listeners;
 625         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 626         local %SIG = (%SIG, %$sig) if !$sigfd;
 627         if (!$sigfd) {
 628                 # wake up every second to accept signals if we don't
 629                 # have signalfd or IO::KQueue:
 630                 sig_setmask($oldset);
 631                 PublicInbox::DS->SetLoopTimeout(1000);
 632         }
 633         PublicInbox::DS->EventLoop;
 634         $parent_pipe = undef;
 635 }
 636
 637
 638 sub run ($$$;$) {
 639         my ($default, $refresh, $post_accept, $nntpd) = @_;
 640         daemon_prepare($default);
 641         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 642         daemonize();
 643         daemon_loop($refresh, $post_accept, $nntpd, $af_default);
 644 }
 645
 646 sub do_chown ($) {
 647         my ($path) = @_;
 648         if (defined $uid and !chown($uid, $gid, $path)) {
 649                 warn "could not chown $path: $!\n";
 650         }
 651 }
 652
 653 sub write_pid ($) {
 654         my ($path) = @_;
 655         Net::Server::Daemonize::create_pid_file($path);
 656         do_chown($path);
 657 }
 658
 659 1;