lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 use Cwd qw/abs_path/;
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Syscall qw(SFD_NONBLOCK);
  19 require PublicInbox::EvCleanup;
  20 require PublicInbox::Listener;
  21 require PublicInbox::ParentPipe;
  22 require PublicInbox::Sigfd;
  23 my @CMD;
  24 my ($set_user, $oldset, $newset);
  25 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  26 my $worker_processes = 1;
  27 my @listeners;
  28 my %pids;
  29 my %listener_names; # sockname => IO::Handle
  30 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  31 my $reexec_pid;
  32 my $cleanup;
  33 my ($uid, $gid);
  34 my ($default_cert, $default_key);
  35 END { $cleanup->() if $cleanup };
  36 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps' );
  37 my %KNOWN_STARTTLS = ( 119 => 'nntp' );
  38
  39 sub accept_tls_opt ($) {
  40         my ($opt_str) = @_;
  41         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  42         require PublicInbox::TLS;
  43         my $o = {};
  44         # allow ',' as delimiter since '&' is shell-unfriendly
  45         foreach (split(/[,&]/, $opt_str)) {
  46                 my ($k, $v) = split(/=/, $_, 2);
  47                 push @{$o->{$k} ||= []}, $v;
  48         }
  49
  50         # key may be a part of cert.  At least
  51         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  52         $o->{cert} //= [ $default_cert ];
  53         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  54         my %ctx_opt = (SSL_server => 1);
  55         # parse out hostname:/path/to/ mappings:
  56         foreach my $k (qw(cert key)) {
  57                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  58                 foreach my $path (@{$o->{$k}}) {
  59                         my $host = '';
  60                         $path =~ s/\A([^:]+):// and $host = $1;
  61                         $x->{$host} = $path;
  62                 }
  63         }
  64         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  65                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  66
  67         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  68         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  69         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  70         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  71         if ($mode && $ctx->{context}) {
  72                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  73                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  74         }
  75
  76         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  77 }
  78
  79 sub sig_setmask { sigprocmask(SIG_SETMASK, @_) or die "sigprocmask: $!" }
  80
  81 sub daemon_prepare ($) {
  82         my ($default_listen) = @_;
  83         $oldset = POSIX::SigSet->new();
  84         $newset = POSIX::SigSet->new();
  85         $newset->fillset or die "fillset: $!";
  86         sig_setmask($newset, $oldset);
  87         @CMD = ($0, @ARGV);
  88         my %opts = (
  89                 'l|listen=s' => \@cfg_listen,
  90                 '1|stdout=s' => \$stdout,
  91                 '2|stderr=s' => \$stderr,
  92                 'W|worker-processes=i' => \$worker_processes,
  93                 'P|pid-file=s' => \$pid_file,
  94                 'u|user=s' => \$user,
  95                 'g|group=s' => \$group,
  96                 'D|daemonize' => \$daemonize,
  97                 'cert=s' => \$default_cert,
  98                 'key=s' => \$default_key,
  99         );
 100         GetOptions(%opts) or die "bad command-line args\n";
 101
 102         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 103                 die "--pid-file cannot end with '.oldbin'\n";
 104         }
 105         @listeners = inherit();
 106
 107         # allow socket-activation users to set certs once and not
 108         # have to configure each socket:
 109         my @inherited_names = keys(%listener_names) if defined($default_cert);
 110
 111         # ignore daemonize when inheriting
 112         $daemonize = undef if scalar @listeners;
 113
 114         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 115
 116         foreach my $l (@cfg_listen) {
 117                 my $orig = $l;
 118                 my $scheme = '';
 119                 if ($l =~ s!\A([^:]+)://!!) {
 120                         $scheme = $1;
 121                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 122                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 123                         $scheme = $s if defined $s;
 124                 }
 125                 if ($l =~ s!/?\?(.+)\z!!) {
 126                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 127                 } elsif (defined($default_cert)) {
 128                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 129                 } elsif ($scheme =~ /\A(?:nntps|https)\z/) {
 130                         die "$orig specified w/o cert=\n";
 131                 }
 132                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 133
 134                 next if $listener_names{$l}; # already inherited
 135                 my (%o, $sock_pkg);
 136                 if (index($l, '/') == 0) {
 137                         $sock_pkg = 'IO::Socket::UNIX';
 138                         eval "use $sock_pkg";
 139                         die $@ if $@;
 140                         %o = (Type => SOCK_STREAM, Peer => $l);
 141                         if (-S $l) {
 142                                 my $c = $sock_pkg->new(%o);
 143                                 if (!defined($c) && $!{ECONNREFUSED}) {
 144                                         unlink $l or die
 145 "failed to unlink stale socket=$l: $!\n";
 146                                 } # else: let the bind fail
 147                         }
 148                         $o{Local} = delete $o{Peer};
 149                 } else {
 150                         # both work for IPv4, too
 151                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 152                                 $sock_pkg = $_;
 153                                 eval "use $sock_pkg";
 154                                 $@ or last;
 155                         }
 156                         die $@ if $@;
 157                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 158                 }
 159                 $o{Listen} = 1024;
 160                 my $prev = umask 0000;
 161                 my $s = eval { $sock_pkg->new(%o) };
 162                 warn "error binding $l: $! ($@)\n" unless $s;
 163                 umask $prev;
 164                 if ($s) {
 165                         $listener_names{sockname($s)} = $s;
 166                         $s->blocking(0);
 167                         push @listeners, $s;
 168                 }
 169         }
 170
 171         # cert/key options in @cfg_listen takes precedence when inheriting,
 172         # but map well-known inherited ports if --listen isn't specified
 173         # at all
 174         for my $sockname (@inherited_names) {
 175                 $sockname =~ /:([0-9]+)\z/ or next;
 176                 if (my $scheme = $KNOWN_TLS{$1}) {
 177                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 178                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 179                         next if $tls_opt{"$scheme://$sockname"};
 180                         $tls_opt{''} ||= accept_tls_opt('');
 181                 }
 182         }
 183
 184         die "No listeners bound\n" unless @listeners;
 185 }
 186
 187 sub check_absolute ($$) {
 188         my ($var, $val) = @_;
 189         if (defined $val && index($val, '/') != 0) {
 190                 die
 191 "--$var must be an absolute path when using --daemonize: $val\n";
 192         }
 193 }
 194
 195 sub daemonize () {
 196         if ($daemonize) {
 197                 foreach my $i (0..$#ARGV) {
 198                         my $arg = $ARGV[$i];
 199                         next unless -e $arg;
 200                         $ARGV[$i] = abs_path($arg);
 201                 }
 202                 check_absolute('stdout', $stdout);
 203                 check_absolute('stderr', $stderr);
 204                 check_absolute('pid-file', $pid_file);
 205
 206                 chdir '/' or die "chdir failed: $!";
 207         }
 208
 209         return unless (defined $pid_file || defined $group || defined $user
 210                         || $daemonize);
 211
 212         eval { require Net::Server::Daemonize };
 213         if ($@) {
 214                 die
 215 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 216         }
 217
 218         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 219         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 220         if (defined $group) {
 221                 $gid = Net::Server::Daemonize::get_gid($group);
 222                 $gid = (split /\s+/, $gid)[0];
 223         } elsif (defined $uid) {
 224                 $gid = (getpwuid($uid))[3];
 225         }
 226
 227         # We change users in the worker to ensure upgradability,
 228         # The upgrade will create the ".oldbin" pid file in the
 229         # same directory as the given pid file.
 230         $uid and $set_user = sub {
 231                 $set_user = undef;
 232                 Net::Server::Daemonize::set_user($uid, $gid);
 233         };
 234
 235         if ($daemonize) {
 236                 my $pid = fork;
 237                 die "could not fork: $!\n" unless defined $pid;
 238                 exit if $pid;
 239
 240                 open(STDIN, '+<', '/dev/null') or
 241                                         die "redirect stdin failed: $!\n";
 242                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 243                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 244                 POSIX::setsid();
 245                 $pid = fork;
 246                 die "could not fork: $!\n" unless defined $pid;
 247                 exit if $pid;
 248         }
 249         if (defined $pid_file) {
 250                 write_pid($pid_file);
 251                 my $unlink_pid = $$;
 252                 $cleanup = sub {
 253                         $cleanup = undef; # avoid cyclic reference
 254                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 255                 };
 256         }
 257 }
 258
 259 sub worker_quit { # $_[0] = signal name or number (unused)
 260         # killing again terminates immediately:
 261         exit unless @listeners;
 262
 263         $_->close foreach @listeners; # call PublicInbox::DS::close
 264         @listeners = ();
 265         my $proc_name;
 266         my $warn = 0;
 267         # drop idle connections and try to quit gracefully
 268         PublicInbox::DS->SetPostLoopCallback(sub {
 269                 my ($dmap, undef) = @_;
 270                 my $n = 0;
 271                 my $now = now();
 272
 273                 foreach my $s (values %$dmap) {
 274                         $s->can('busy') or next;
 275                         if ($s->busy($now)) {
 276                                 ++$n;
 277                         } else {
 278                                 # close as much as possible, early as possible
 279                                 $s->close;
 280                         }
 281                 }
 282                 if ($n) {
 283                         if (($warn + 5) < now()) {
 284                                 warn "$$ quitting, $n client(s) left\n";
 285                                 $warn = now();
 286                         }
 287                         unless (defined $proc_name) {
 288                                 $proc_name = (split(/\s+/, $0))[0];
 289                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 290                         }
 291                         $0 = "$proc_name quitting, $n client(s) left";
 292                 }
 293                 $n; # true: loop continues, false: loop breaks
 294         });
 295 }
 296
 297 sub reopen_logs {
 298         if ($stdout) {
 299                 open STDOUT, '>>', $stdout or
 300                         warn "failed to redirect stdout to $stdout: $!\n";
 301                 STDOUT->autoflush(1);
 302                 do_chown($stdout);
 303         }
 304         if ($stderr) {
 305                 open STDERR, '>>', $stderr or
 306                         warn "failed to redirect stderr to $stderr: $!\n";
 307                 STDERR->autoflush(1);
 308                 do_chown($stderr);
 309         }
 310 }
 311
 312 sub sockname ($) {
 313         my ($s) = @_;
 314         my $addr = getsockname($s) or return;
 315         my ($host, $port) = host_with_port($addr);
 316         if ($port == 0 && $host eq '127.0.0.1') {
 317                 my ($path) = Socket::sockaddr_un($addr);
 318                 return $path;
 319         }
 320         "$host:$port";
 321 }
 322
 323 sub unpack_ipv6 ($) {
 324         my ($addr) = @_;
 325         my ($port, $host);
 326
 327         # Socket.pm in Perl 5.14+ supports IPv6:
 328         eval {
 329                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 330                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 331         };
 332
 333         if ($@) {
 334                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 335                 # Socket6, so it may be installed on our system, already
 336                 # (otherwise die here):
 337                 require Socket6;
 338
 339                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 340                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 341         }
 342         ($host, $port);
 343 }
 344
 345 sub host_with_port ($) {
 346         my ($addr) = @_;
 347         my ($port, $host);
 348
 349         # this eval will die on Unix sockets:
 350         eval {
 351                 if (length($addr) >= 28) {
 352                         ($host, $port) = unpack_ipv6($addr);
 353                         $host = "[$host]";
 354                 } else {
 355                         ($port, $host) = Socket::sockaddr_in($addr);
 356                         $host = Socket::inet_ntoa($host);
 357                 }
 358         };
 359         $@ ? ('127.0.0.1', 0) : ($host, $port);
 360 }
 361
 362 sub inherit () {
 363         return () if ($ENV{LISTEN_PID} || 0) != $$;
 364         my $fds = $ENV{LISTEN_FDS} or return ();
 365         my $end = $fds + 2; # LISTEN_FDS_START - 1
 366         my @rv = ();
 367         foreach my $fd (3..$end) {
 368                 my $s = IO::Handle->new_from_fd($fd, 'r');
 369                 if (my $k = sockname($s)) {
 370                         if ($s->blocking) {
 371                                 $s->blocking(0);
 372                                 warn <<"";
 373 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 374 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 375 processes when multiple service instances start.
 376
 377                         }
 378                         $listener_names{$k} = $s;
 379                         push @rv, $s;
 380                 } else {
 381                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 382                 }
 383         }
 384         @rv
 385 }
 386
 387 sub upgrade { # $_[0] = signal name or number (unused)
 388         if ($reexec_pid) {
 389                 warn "upgrade in-progress: $reexec_pid\n";
 390                 return;
 391         }
 392         if (defined $pid_file) {
 393                 if ($pid_file =~ /\.oldbin\z/) {
 394                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 395                         return;
 396                 }
 397                 unlink_pid_file_safe_ish($$, $pid_file);
 398                 $pid_file .= '.oldbin';
 399                 write_pid($pid_file);
 400         }
 401         my $pid = fork;
 402         unless (defined $pid) {
 403                 warn "fork failed: $!\n";
 404                 return;
 405         }
 406         if ($pid == 0) {
 407                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 408                 $ENV{LISTEN_FDS} = scalar @listeners;
 409                 $ENV{LISTEN_PID} = $$;
 410                 foreach my $s (@listeners) {
 411                         my $fl = fcntl($s, F_GETFD, 0);
 412                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 413                 }
 414                 exec @CMD;
 415                 die "Failed to exec: $!\n";
 416         }
 417         $reexec_pid = $pid;
 418 }
 419
 420 sub kill_workers ($) {
 421         my ($s) = @_;
 422
 423         while (my ($pid, $id) = each %pids) {
 424                 kill $s, $pid;
 425         }
 426 }
 427
 428 sub upgrade_aborted ($) {
 429         my ($p) = @_;
 430         warn "reexec PID($p) died with: $?\n";
 431         $reexec_pid = undef;
 432         return unless $pid_file;
 433
 434         my $file = $pid_file;
 435         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 436         unlink_pid_file_safe_ish($$, $pid_file);
 437         $pid_file = $file;
 438         eval { write_pid($pid_file) };
 439         warn $@, "\n" if $@;
 440 }
 441
 442 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 443         while (1) {
 444                 my $p = waitpid(-1, WNOHANG) or return;
 445                 if (defined $reexec_pid && $p == $reexec_pid) {
 446                         upgrade_aborted($p);
 447                 } elsif (defined(my $id = delete $pids{$p})) {
 448                         warn "worker[$id] PID($p) died with: $?\n";
 449                 } elsif ($p > 0) {
 450                         warn "unknown PID($p) reaped: $?\n";
 451                 } else {
 452                         return;
 453                 }
 454         }
 455 }
 456
 457 sub unlink_pid_file_safe_ish ($$) {
 458         my ($unlink_pid, $file) = @_;
 459         return unless defined $unlink_pid && $unlink_pid == $$;
 460
 461         open my $fh, '<', $file or return;
 462         local $/ = "\n";
 463         defined(my $read_pid = <$fh>) or return;
 464         chomp $read_pid;
 465         if ($read_pid == $unlink_pid) {
 466                 Net::Server::Daemonize::unlink_pid_file($file);
 467         }
 468 }
 469
 470 sub master_loop {
 471         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 472         # 1031: F_SETPIPE_SZ, 4096: page size
 473         fcntl($p1, 1031, 4096) if $^O eq 'linux';
 474         my $set_workers = $worker_processes;
 475         reopen_logs();
 476         my $quit = 0;
 477         my $ignore_winch;
 478         my $quit_cb = sub { exit if $quit++; kill_workers($_[0]) };
 479         my $sig = {
 480                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 481                 USR2 => \&upgrade,
 482                 QUIT => $quit_cb,
 483                 INT => $quit_cb,
 484                 TERM => $quit_cb,
 485                 WINCH => sub {
 486                         return if $ignore_winch;
 487                         if (-t STDIN || -t STDOUT || -t STDERR) {
 488                                 $ignore_winch = 1;
 489                                 warn <<EOF;
 490 ignoring SIGWINCH since we are not daemonized
 491 EOF
 492                         } else {
 493                                 $worker_processes = 0;
 494                         }
 495                 },
 496                 HUP => sub {
 497                         $worker_processes = $set_workers;
 498                         kill_workers($_[0]);
 499                 },
 500                 TTIN => sub {
 501                         if ($set_workers > $worker_processes) {
 502                                 ++$worker_processes;
 503                         } else {
 504                                 $worker_processes = ++$set_workers;
 505                         }
 506                 },
 507                 TTOU => sub {
 508                         $worker_processes = --$set_workers if $set_workers > 0;
 509                 },
 510                 CHLD => \&reap_children,
 511         };
 512         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 513         local %SIG = (%SIG, %$sig) if !$sigfd;
 514         sig_setmask($oldset) if !$sigfd;
 515         while (1) { # main loop
 516                 my $n = scalar keys %pids;
 517                 if ($quit) {
 518                         exit if $n == 0;
 519                         $set_workers = $worker_processes = $n = 0;
 520                 }
 521
 522                 if ($n > $worker_processes) {
 523                         while (my ($k, $v) = each %pids) {
 524                                 kill('TERM', $k) if $v >= $worker_processes;
 525                         }
 526                         $n = $worker_processes;
 527                 }
 528                 my $want = $worker_processes - 1;
 529                 if ($n <= $want) {
 530                         sig_setmask($newset) if !$sigfd;
 531                         for my $i ($n..$want) {
 532                                 my $pid = fork;
 533                                 if (!defined $pid) {
 534                                         warn "failed to fork worker[$i]: $!\n";
 535                                 } elsif ($pid == 0) {
 536                                         $set_user->() if $set_user;
 537                                         return $p0; # run normal work code
 538                                 } else {
 539                                         warn "PID=$pid is worker[$i]\n";
 540                                         $pids{$pid} = $i;
 541                                 }
 542                         }
 543                         sig_setmask($oldset) if !$sigfd;
 544                 }
 545
 546                 if ($sigfd) { # Linux and IO::KQueue users:
 547                         $sigfd->wait_once;
 548                 } else { # wake up every second
 549                         sleep(1);
 550                 }
 551         }
 552         exit # never gets here, just for documentation
 553 }
 554
 555 sub tls_start_cb ($$) {
 556         my ($opt, $orig_post_accept) = @_;
 557         sub {
 558                 my ($io, $addr, $srv) = @_;
 559                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 560                 $orig_post_accept->($ssl, $addr, $srv);
 561         }
 562 }
 563
 564 sub defer_accept ($$) {
 565         my ($s, $af_name) = @_;
 566         return unless defined $af_name;
 567         if ($^O eq 'linux') {
 568                 my $x = getsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT());
 569                 return unless defined $x; # may be Unix socket
 570                 my $sec = unpack('i', $x);
 571                 return if $sec > 0; # systemd users may set a higher value
 572                 setsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT(), 1);
 573         } elsif ($^O eq 'freebsd') {
 574                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 575                 return if defined $x; # don't change if set
 576                 my $accf_arg = pack('a16a240', $af_name, '');
 577                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 578         }
 579 }
 580
 581 sub daemon_loop ($$$$) {
 582         my ($refresh, $post_accept, $nntpd, $af_default) = @_;
 583         PublicInbox::EvCleanup::enable(); # early for $refresh
 584         my %post_accept;
 585         while (my ($k, $v) = each %tls_opt) {
 586                 if ($k =~ s!\A(?:nntps|https)://!!) {
 587                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 588                 } elsif ($nntpd) { # STARTTLS, $k eq '' is OK
 589                         $nntpd->{accept_tls} = $v;
 590                 }
 591         }
 592         my $sig = {
 593                 HUP => $refresh,
 594                 INT => \&worker_quit,
 595                 QUIT => \&worker_quit,
 596                 TERM => \&worker_quit,
 597                 TTIN => 'IGNORE',
 598                 TTOU => 'IGNORE',
 599                 USR1 => \&reopen_logs,
 600                 USR2 => 'IGNORE',
 601                 WINCH => 'IGNORE',
 602                 CHLD => \&PublicInbox::DS::enqueue_reap,
 603         };
 604         my $parent_pipe;
 605         if ($worker_processes > 0) {
 606                 $refresh->(); # preload by default
 607                 my $fh = master_loop(); # returns if in child process
 608                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 609         } else {
 610                 reopen_logs();
 611                 $set_user->() if $set_user;
 612                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 613                 $refresh->();
 614         }
 615         $uid = $gid = undef;
 616         reopen_logs();
 617         @listeners = map {;
 618                 my $tls_cb = $post_accept{sockname($_)};
 619
 620                 # NNTPS, HTTPS, HTTP, and POP3S are client-first traffic
 621                 # NNTP and POP3 are server-first
 622                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 623
 624                 # this calls epoll_create:
 625                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 626         } @listeners;
 627         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 628         local %SIG = (%SIG, %$sig) if !$sigfd;
 629         if (!$sigfd) {
 630                 # wake up every second to accept signals if we don't
 631                 # have signalfd or IO::KQueue:
 632                 sig_setmask($oldset);
 633                 PublicInbox::DS->SetLoopTimeout(1000);
 634         }
 635         PublicInbox::DS->EventLoop;
 636         $parent_pipe = undef;
 637 }
 638
 639
 640 sub run ($$$;$) {
 641         my ($default, $refresh, $post_accept, $nntpd) = @_;
 642         daemon_prepare($default);
 643         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 644         daemonize();
 645         daemon_loop($refresh, $post_accept, $nntpd, $af_default);
 646 }
 647
 648 sub do_chown ($) {
 649         my ($path) = @_;
 650         if (defined $uid and !chown($uid, $gid, $path)) {
 651                 warn "could not chown $path: $!\n";
 652         }
 653 }
 654
 655 sub write_pid ($) {
 656         my ($path) = @_;
 657         Net::Server::Daemonize::create_pid_file($path);
 658         do_chown($path);
 659 }
 660
 661 1;