lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  12 sub SO_ACCEPTFILTER () { 0x1000 }
  13 use Cwd qw/abs_path/;
  14 STDOUT->autoflush(1);
  15 STDERR->autoflush(1);
  16 use PublicInbox::DS qw(now);
  17 require PublicInbox::EvCleanup;
  18 require POSIX;
  19 require PublicInbox::Listener;
  20 require PublicInbox::ParentPipe;
  21 my @CMD;
  22 my $set_user;
  23 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  24 my $worker_processes = 1;
  25 my @listeners;
  26 my %pids;
  27 my %listener_names; # sockname => IO::Handle
  28 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  29 my $reexec_pid;
  30 my $cleanup;
  31 my ($uid, $gid);
  32 my ($default_cert, $default_key);
  33 END { $cleanup->() if $cleanup };
  34 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps' );
  35 my %KNOWN_STARTTLS = ( 119 => 'nntp' );
  36
  37 sub accept_tls_opt ($) {
  38         my ($opt_str) = @_;
  39         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  40         require PublicInbox::TLS;
  41         my $o = {};
  42         # allow ',' as delimiter since '&' is shell-unfriendly
  43         foreach (split(/[,&]/, $opt_str)) {
  44                 my ($k, $v) = split(/=/, $_, 2);
  45                 push @{$o->{$k} ||= []}, $v;
  46         }
  47
  48         # key may be a part of cert.  At least
  49         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  50         $o->{cert} //= [ $default_cert ];
  51         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  52         my %ctx_opt = (SSL_server => 1);
  53         # parse out hostname:/path/to/ mappings:
  54         foreach my $k (qw(cert key)) {
  55                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  56                 foreach my $path (@{$o->{$k}}) {
  57                         my $host = '';
  58                         $path =~ s/\A([^:]+):// and $host = $1;
  59                         $x->{$host} = $path;
  60                 }
  61         }
  62         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  63                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  64
  65         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  66         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  67         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  68         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  69         if ($mode && $ctx->{context}) {
  70                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  71                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  72         }
  73
  74         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  75 }
  76
  77 sub daemon_prepare ($) {
  78         my ($default_listen) = @_;
  79         @CMD = ($0, @ARGV);
  80         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  81                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  82         my %opts = (
  83                 'l|listen=s' => \@cfg_listen,
  84                 '1|stdout=s' => \$stdout,
  85                 '2|stderr=s' => \$stderr,
  86                 'W|worker-processes=i' => \$worker_processes,
  87                 'P|pid-file=s' => \$pid_file,
  88                 'u|user=s' => \$user,
  89                 'g|group=s' => \$group,
  90                 'D|daemonize' => \$daemonize,
  91                 'cert=s' => \$default_cert,
  92                 'key=s' => \$default_key,
  93         );
  94         GetOptions(%opts) or die "bad command-line args\n";
  95
  96         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  97                 die "--pid-file cannot end with '.oldbin'\n";
  98         }
  99         @listeners = inherit();
 100
 101         # allow socket-activation users to set certs once and not
 102         # have to configure each socket:
 103         my @inherited_names = keys(%listener_names) if defined($default_cert);
 104
 105         # ignore daemonize when inheriting
 106         $daemonize = undef if scalar @listeners;
 107
 108         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 109
 110         foreach my $l (@cfg_listen) {
 111                 my $orig = $l;
 112                 my $scheme = '';
 113                 if ($l =~ s!\A([^:]+)://!!) {
 114                         $scheme = $1;
 115                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 116                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 117                         $scheme = $s if defined $s;
 118                 }
 119                 if ($l =~ s!/?\?(.+)\z!!) {
 120                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 121                 } elsif (defined($default_cert)) {
 122                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 123                 } elsif ($scheme =~ /\A(?:nntps|https)\z/) {
 124                         die "$orig specified w/o cert=\n";
 125                 }
 126                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 127
 128                 next if $listener_names{$l}; # already inherited
 129                 my (%o, $sock_pkg);
 130                 if (index($l, '/') == 0) {
 131                         $sock_pkg = 'IO::Socket::UNIX';
 132                         eval "use $sock_pkg";
 133                         die $@ if $@;
 134                         %o = (Type => SOCK_STREAM, Peer => $l);
 135                         if (-S $l) {
 136                                 my $c = $sock_pkg->new(%o);
 137                                 if (!defined($c) && $!{ECONNREFUSED}) {
 138                                         unlink $l or die
 139 "failed to unlink stale socket=$l: $!\n";
 140                                 } # else: let the bind fail
 141                         }
 142                         $o{Local} = delete $o{Peer};
 143                 } else {
 144                         # both work for IPv4, too
 145                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 146                                 $sock_pkg = $_;
 147                                 eval "use $sock_pkg";
 148                                 $@ or last;
 149                         }
 150                         die $@ if $@;
 151                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 152                 }
 153                 $o{Listen} = 1024;
 154                 my $prev = umask 0000;
 155                 my $s = eval { $sock_pkg->new(%o) };
 156                 warn "error binding $l: $! ($@)\n" unless $s;
 157                 umask $prev;
 158
 159                 if ($s) {
 160                         $listener_names{sockname($s)} = $s;
 161                         push @listeners, $s;
 162                 }
 163         }
 164
 165         # cert/key options in @cfg_listen takes precedence when inheriting,
 166         # but map well-known inherited ports if --listen isn't specified
 167         # at all
 168         for my $sockname (@inherited_names) {
 169                 $sockname =~ /:([0-9]+)\z/ or next;
 170                 if (my $scheme = $KNOWN_TLS{$1}) {
 171                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 172                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 173                         next if $tls_opt{"$scheme://$sockname"};
 174                         $tls_opt{''} ||= accept_tls_opt('');
 175                 }
 176         }
 177
 178         die "No listeners bound\n" unless @listeners;
 179 }
 180
 181 sub check_absolute ($$) {
 182         my ($var, $val) = @_;
 183         if (defined $val && index($val, '/') != 0) {
 184                 die
 185 "--$var must be an absolute path when using --daemonize: $val\n";
 186         }
 187 }
 188
 189 sub daemonize () {
 190         if ($daemonize) {
 191                 foreach my $i (0..$#ARGV) {
 192                         my $arg = $ARGV[$i];
 193                         next unless -e $arg;
 194                         $ARGV[$i] = abs_path($arg);
 195                 }
 196                 check_absolute('stdout', $stdout);
 197                 check_absolute('stderr', $stderr);
 198                 check_absolute('pid-file', $pid_file);
 199
 200                 chdir '/' or die "chdir failed: $!";
 201         }
 202
 203         return unless (defined $pid_file || defined $group || defined $user
 204                         || $daemonize);
 205
 206         eval { require Net::Server::Daemonize };
 207         if ($@) {
 208                 die
 209 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 210         }
 211
 212         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 213         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 214         if (defined $group) {
 215                 $gid = Net::Server::Daemonize::get_gid($group);
 216                 $gid = (split /\s+/, $gid)[0];
 217         } elsif (defined $uid) {
 218                 $gid = (getpwuid($uid))[3];
 219         }
 220
 221         # We change users in the worker to ensure upgradability,
 222         # The upgrade will create the ".oldbin" pid file in the
 223         # same directory as the given pid file.
 224         $uid and $set_user = sub {
 225                 $set_user = undef;
 226                 Net::Server::Daemonize::set_user($uid, $gid);
 227         };
 228
 229         if ($daemonize) {
 230                 my $pid = fork;
 231                 die "could not fork: $!\n" unless defined $pid;
 232                 exit if $pid;
 233
 234                 open(STDIN, '+<', '/dev/null') or
 235                                         die "redirect stdin failed: $!\n";
 236                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 237                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 238                 POSIX::setsid();
 239                 $pid = fork;
 240                 die "could not fork: $!\n" unless defined $pid;
 241                 exit if $pid;
 242         }
 243         if (defined $pid_file) {
 244                 write_pid($pid_file);
 245                 my $unlink_pid = $$;
 246                 $cleanup = sub {
 247                         $cleanup = undef; # avoid cyclic reference
 248                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 249                 };
 250         }
 251 }
 252
 253
 254 sub worker_quit {
 255         my ($reason) = @_;
 256         # killing again terminates immediately:
 257         exit unless @listeners;
 258
 259         $_->close foreach @listeners; # call PublicInbox::DS::close
 260         @listeners = ();
 261         $reason->close if ref($reason) eq 'PublicInbox::ParentPipe';
 262
 263         my $proc_name;
 264         my $warn = 0;
 265         # drop idle connections and try to quit gracefully
 266         PublicInbox::DS->SetPostLoopCallback(sub {
 267                 my ($dmap, undef) = @_;
 268                 my $n = 0;
 269                 my $now = now();
 270
 271                 foreach my $s (values %$dmap) {
 272                         $s->can('busy') or next;
 273                         if ($s->busy($now)) {
 274                                 ++$n;
 275                         } else {
 276                                 # close as much as possible, early as possible
 277                                 $s->close;
 278                         }
 279                 }
 280                 if ($n) {
 281                         if (($warn + 5) < now()) {
 282                                 warn "$$ quitting, $n client(s) left\n";
 283                                 $warn = now();
 284                         }
 285                         unless (defined $proc_name) {
 286                                 $proc_name = (split(/\s+/, $0))[0];
 287                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 288                         }
 289                         $0 = "$proc_name quitting, $n client(s) left";
 290                 }
 291                 $n; # true: loop continues, false: loop breaks
 292         });
 293 }
 294
 295 sub reopen_logs {
 296         if ($stdout) {
 297                 open STDOUT, '>>', $stdout or
 298                         warn "failed to redirect stdout to $stdout: $!\n";
 299                 STDOUT->autoflush(1);
 300                 do_chown($stdout);
 301         }
 302         if ($stderr) {
 303                 open STDERR, '>>', $stderr or
 304                         warn "failed to redirect stderr to $stderr: $!\n";
 305                 STDERR->autoflush(1);
 306                 do_chown($stderr);
 307         }
 308 }
 309
 310 sub sockname ($) {
 311         my ($s) = @_;
 312         my $addr = getsockname($s) or return;
 313         my ($host, $port) = host_with_port($addr);
 314         if ($port == 0 && $host eq '127.0.0.1') {
 315                 my ($path) = Socket::sockaddr_un($addr);
 316                 return $path;
 317         }
 318         "$host:$port";
 319 }
 320
 321 sub unpack_ipv6 ($) {
 322         my ($addr) = @_;
 323         my ($port, $host);
 324
 325         # Socket.pm in Perl 5.14+ supports IPv6:
 326         eval {
 327                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 328                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 329         };
 330
 331         if ($@) {
 332                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 333                 # Socket6, so it may be installed on our system, already
 334                 # (otherwise die here):
 335                 require Socket6;
 336
 337                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 338                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 339         }
 340         ($host, $port);
 341 }
 342
 343 sub host_with_port ($) {
 344         my ($addr) = @_;
 345         my ($port, $host);
 346
 347         # this eval will die on Unix sockets:
 348         eval {
 349                 if (length($addr) >= 28) {
 350                         ($host, $port) = unpack_ipv6($addr);
 351                         $host = "[$host]";
 352                 } else {
 353                         ($port, $host) = Socket::sockaddr_in($addr);
 354                         $host = Socket::inet_ntoa($host);
 355                 }
 356         };
 357         $@ ? ('127.0.0.1', 0) : ($host, $port);
 358 }
 359
 360 sub inherit () {
 361         return () if ($ENV{LISTEN_PID} || 0) != $$;
 362         my $fds = $ENV{LISTEN_FDS} or return ();
 363         my $end = $fds + 2; # LISTEN_FDS_START - 1
 364         my @rv = ();
 365         foreach my $fd (3..$end) {
 366                 my $s = IO::Handle->new_from_fd($fd, 'r');
 367                 if (my $k = sockname($s)) {
 368                         $listener_names{$k} = $s;
 369                         push @rv, $s;
 370                 } else {
 371                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 372                 }
 373         }
 374         @rv
 375 }
 376
 377 sub upgrade () {
 378         if ($reexec_pid) {
 379                 warn "upgrade in-progress: $reexec_pid\n";
 380                 return;
 381         }
 382         if (defined $pid_file) {
 383                 if ($pid_file =~ /\.oldbin\z/) {
 384                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 385                         return;
 386                 }
 387                 unlink_pid_file_safe_ish($$, $pid_file);
 388                 $pid_file .= '.oldbin';
 389                 write_pid($pid_file);
 390         }
 391         my $pid = fork;
 392         unless (defined $pid) {
 393                 warn "fork failed: $!\n";
 394                 return;
 395         }
 396         if ($pid == 0) {
 397                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 398                 $ENV{LISTEN_FDS} = scalar @listeners;
 399                 $ENV{LISTEN_PID} = $$;
 400                 foreach my $s (@listeners) {
 401                         my $fl = fcntl($s, F_GETFD, 0);
 402                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 403                 }
 404                 exec @CMD;
 405                 die "Failed to exec: $!\n";
 406         }
 407         $reexec_pid = $pid;
 408 }
 409
 410 sub kill_workers ($) {
 411         my ($s) = @_;
 412
 413         while (my ($pid, $id) = each %pids) {
 414                 kill $s, $pid;
 415         }
 416 }
 417
 418 sub upgrade_aborted ($) {
 419         my ($p) = @_;
 420         warn "reexec PID($p) died with: $?\n";
 421         $reexec_pid = undef;
 422         return unless $pid_file;
 423
 424         my $file = $pid_file;
 425         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 426         unlink_pid_file_safe_ish($$, $pid_file);
 427         $pid_file = $file;
 428         eval { write_pid($pid_file) };
 429         warn $@, "\n" if $@;
 430 }
 431
 432 sub reap_children () {
 433         while (1) {
 434                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 435                 if (defined $reexec_pid && $p == $reexec_pid) {
 436                         upgrade_aborted($p);
 437                 } elsif (defined(my $id = delete $pids{$p})) {
 438                         warn "worker[$id] PID($p) died with: $?\n";
 439                 } elsif ($p > 0) {
 440                         warn "unknown PID($p) reaped: $?\n";
 441                 } else {
 442                         return;
 443                 }
 444         }
 445 }
 446
 447 sub unlink_pid_file_safe_ish ($$) {
 448         my ($unlink_pid, $file) = @_;
 449         return unless defined $unlink_pid && $unlink_pid == $$;
 450
 451         open my $fh, '<', $file or return;
 452         local $/ = "\n";
 453         defined(my $read_pid = <$fh>) or return;
 454         chomp $read_pid;
 455         if ($read_pid == $unlink_pid) {
 456                 Net::Server::Daemonize::unlink_pid_file($file);
 457         }
 458 }
 459
 460 sub master_loop {
 461         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 462         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 463
 464         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ = 1031
 465                 fcntl($_, 1031, 4096) for ($w, $p1);
 466         }
 467
 468         IO::Handle::blocking($w, 0);
 469         my $set_workers = $worker_processes;
 470         my @caught;
 471         my $master_pid = $$;
 472         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 473                 $SIG{$s} = sub {
 474                         return if $$ != $master_pid;
 475                         push @caught, $s;
 476                         syswrite($w, '.');
 477                 };
 478         }
 479         reopen_logs();
 480         # main loop
 481         my $quit = 0;
 482         while (1) {
 483                 while (my $s = shift @caught) {
 484                         if ($s eq 'USR1') {
 485                                 reopen_logs();
 486                                 kill_workers($s);
 487                         } elsif ($s eq 'USR2') {
 488                                 upgrade();
 489                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 490                                 exit if $quit++;
 491                                 kill_workers($s);
 492                         } elsif ($s eq 'WINCH') {
 493                                 if (-t STDIN || -t STDOUT || -t STDERR) {
 494                                         warn
 495 "ignoring SIGWINCH since we are not daemonized\n";
 496                                         $SIG{WINCH} = 'IGNORE';
 497                                 } else {
 498                                         $worker_processes = 0;
 499                                 }
 500                         } elsif ($s eq 'HUP') {
 501                                 $worker_processes = $set_workers;
 502                                 kill_workers($s);
 503                         } elsif ($s eq 'TTIN') {
 504                                 if ($set_workers > $worker_processes) {
 505                                         ++$worker_processes;
 506                                 } else {
 507                                         $worker_processes = ++$set_workers;
 508                                 }
 509                         } elsif ($s eq 'TTOU') {
 510                                 if ($set_workers > 0) {
 511                                         $worker_processes = --$set_workers;
 512                                 }
 513                         } elsif ($s eq 'CHLD') {
 514                                 reap_children();
 515                         }
 516                 }
 517
 518                 my $n = scalar keys %pids;
 519                 if ($quit) {
 520                         exit if $n == 0;
 521                         $set_workers = $worker_processes = $n = 0;
 522                 }
 523
 524                 if ($n > $worker_processes) {
 525                         while (my ($k, $v) = each %pids) {
 526                                 kill('TERM', $k) if $v >= $worker_processes;
 527                         }
 528                         $n = $worker_processes;
 529                 }
 530                 foreach my $i ($n..($worker_processes - 1)) {
 531                         my $pid = fork;
 532                         if (!defined $pid) {
 533                                 warn "failed to fork worker[$i]: $!\n";
 534                         } elsif ($pid == 0) {
 535                                 $set_user->() if $set_user;
 536                                 return $p0; # run normal work code
 537                         } else {
 538                                 warn "PID=$pid is worker[$i]\n";
 539                                 $pids{$pid} = $i;
 540                         }
 541                 }
 542                 # just wait on signal events here:
 543                 sysread($r, my $buf, 8);
 544         }
 545         exit # never gets here, just for documentation
 546 }
 547
 548 sub tls_start_cb ($$) {
 549         my ($opt, $orig_post_accept) = @_;
 550         sub {
 551                 my ($io, $addr, $srv) = @_;
 552                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 553                 $orig_post_accept->($ssl, $addr, $srv);
 554         }
 555 }
 556
 557 sub defer_accept ($$) {
 558         my ($s, $af_name) = @_;
 559         return unless defined $af_name;
 560         if ($^O eq 'linux') {
 561                 my $x = getsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT());
 562                 return unless defined $x; # may be Unix socket
 563                 my $sec = unpack('i', $x);
 564                 return if $sec > 0; # systemd users may set a higher value
 565                 setsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT(), 1);
 566         } elsif ($^O eq 'freebsd') {
 567                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 568                 return if defined $x; # don't change if set
 569                 my $accf_arg = pack('a16a240', $af_name, '');
 570                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 571         }
 572 }
 573
 574 sub daemon_loop ($$$$) {
 575         my ($refresh, $post_accept, $nntpd, $af_default) = @_;
 576         PublicInbox::EvCleanup::enable(); # early for $refresh
 577         my %post_accept;
 578         while (my ($k, $v) = each %tls_opt) {
 579                 if ($k =~ s!\A(?:nntps|https)://!!) {
 580                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 581                 } elsif ($nntpd) { # STARTTLS, $k eq '' is OK
 582                         $nntpd->{accept_tls} = $v;
 583                 }
 584         }
 585         my $parent_pipe;
 586         if ($worker_processes > 0) {
 587                 $refresh->(); # preload by default
 588                 my $fh = master_loop(); # returns if in child process
 589                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 590         } else {
 591                 reopen_logs();
 592                 $set_user->() if $set_user;
 593                 $SIG{USR2} = sub { worker_quit('USR2') if upgrade() };
 594                 $refresh->();
 595         }
 596         $uid = $gid = undef;
 597         reopen_logs();
 598         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 599         $SIG{USR1} = *reopen_logs;
 600         $SIG{HUP} = $refresh;
 601         $SIG{CHLD} = 'DEFAULT';
 602         $SIG{$_} = 'IGNORE' for qw(USR2 TTIN TTOU WINCH);
 603         @listeners = map {;
 604                 my $tls_cb = $post_accept{sockname($_)};
 605
 606                 # NNTPS, HTTPS, HTTP, and POP3S are client-first traffic
 607                 # NNTP and POP3 are server-first
 608                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 609
 610                 # this calls epoll_create:
 611                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 612         } @listeners;
 613         PublicInbox::DS->EventLoop;
 614         $parent_pipe = undef;
 615 }
 616
 617
 618 sub run ($$$;$) {
 619         my ($default, $refresh, $post_accept, $nntpd) = @_;
 620         daemon_prepare($default);
 621         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 622         daemonize();
 623         daemon_loop($refresh, $post_accept, $nntpd, $af_default);
 624 }
 625
 626 sub do_chown ($) {
 627         my ($path) = @_;
 628         if (defined $uid and !chown($uid, $gid, $path)) {
 629                 warn "could not chown $path: $!\n";
 630         }
 631 }
 632
 633 sub write_pid ($) {
 634         my ($path) = @_;
 635         Net::Server::Daemonize::create_pid_file($path);
 636         do_chown($path);
 637 }
 638
 639 1;