lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use File::Spec;
  14 use POSIX qw(WNOHANG :signal_h F_SETFD);
  15 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::Git;
  23 use PublicInbox::GitAsyncCat;
  24 use PublicInbox::Eml;
  25 use PublicInbox::Config;
  26 our $SO_ACCEPTFILTER = 0x1000;
  27 my @CMD;
  28 my ($set_user, $oldset);
  29 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  30 my $worker_processes = 1;
  31 my @listeners;
  32 my (%pids, %logs);
  33 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL::SSL_Context->new
  34 my $reexec_pid;
  35 my ($uid, $gid);
  36 my ($default_cert, $default_key);
  37 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  38 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  39 my %SCHEME2PORT = map { $KNOWN_TLS{$_} => $_ + 0 } keys %KNOWN_TLS;
  40 for (keys %KNOWN_STARTTLS) { $SCHEME2PORT{$KNOWN_STARTTLS{$_}} = $_ + 0 }
  41 $SCHEME2PORT{http} = 80;
  42
  43 sub listener_opt ($) {
  44         my ($str) = @_; # opt1=val1,opt2=val2 (opt may repeat for multi-value)
  45         my $o = {};
  46         # allow ',' as delimiter since '&' is shell-unfriendly
  47         for (split(/[,&]/, $str)) {
  48                 my ($k, $v) = split(/=/, $_, 2);
  49                 push @{$o->{$k}}, $v;
  50         }
  51
  52         # key may be a part of cert.  At least
  53         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  54         $o->{cert} //= [ $default_cert ] if defined($default_cert);
  55         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  56         $o;
  57 }
  58
  59 sub check_absolute ($$) {
  60         my ($var, $val) = @_;
  61         die <<EOM if index($val // '/', '/') != 0;
  62 $var must be an absolute path when using --daemonize: $val
  63 EOM
  64 }
  65
  66 sub accept_tls_opt ($) {
  67         my ($opt) = @_;
  68         my $o = ref($opt) eq 'HASH' ? $opt : listener_opt($opt);
  69         return if !defined($o->{cert});
  70         require PublicInbox::TLS;
  71         my @ctx_opt;
  72         # parse out hostname:/path/to/ mappings:
  73         for my $k (qw(cert key)) {
  74                 $o->{$k} // next;
  75                 push(@ctx_opt, "SSL_${k}_file", {});
  76                 foreach my $path (@{$o->{$k}}) {
  77                         my $host = '';
  78                         $path =~ s/\A([^:]+):// and $host = $1;
  79                         $ctx_opt[-1]->{$host} = $path;
  80                         check_absolute($k, $path) if $daemonize;
  81                 }
  82         }
  83         \@ctx_opt;
  84 }
  85
  86 sub do_chown ($) {
  87         $uid // return;
  88         my ($path) = @_;
  89         chown($uid, $gid, $path) or warn "chown $path: $!\n";
  90 }
  91
  92 sub open_log_path ($$) { # my ($fh, $path) = @_; # $_[0] is modified
  93         open $_[0], '>>', $_[1] or die "open(>> $_[1]): $!";
  94         $_[0]->autoflush(1);
  95         do_chown($_[1]);
  96         $_[0];
  97 }
  98
  99 sub load_mod ($;$$) {
 100         my ($scheme, $opt, $addr) = @_;
 101         my $modc = "PublicInbox::\U$scheme";
 102         $modc =~ s/S\z//;
 103         my $mod = $modc.'D';
 104         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
 105         die $@ if $@;
 106         my %xn;
 107         my $tlsd = $xn{tlsd} = $mod->new;
 108         my %env = map {
 109                 substr($_, length('env.')) => $opt->{$_}->[-1];
 110         } grep(/\Aenv\./, keys %$opt);
 111         $xn{refresh} = sub {
 112                 my ($sig) = @_;
 113                 local @ENV{keys %env} = values %env;
 114                 $tlsd->refresh_groups($sig);
 115         };
 116         $xn{post_accept} = $tlsd->can('post_accept_cb') ?
 117                         $tlsd->post_accept_cb : sub { $modc->new($_[0], $tlsd) };
 118         my @paths = qw(out err);
 119         if ($modc eq 'PublicInbox::HTTP') {
 120                 @paths = qw(err);
 121                 $xn{af_default} = 'httpready';
 122                 if (my $p = $opt->{psgi}) {
 123                         die "multiple psgi= options specified\n" if @$p > 1;
 124                         check_absolute('psgi=', $p->[0]) if $daemonize;
 125                         $tlsd->{psgi} = $p->[0];
 126                         warn "# $scheme://$addr psgi=$p->[0]\n";
 127                 }
 128         }
 129         for my $f (@paths) {
 130                 my $p = $opt->{$f} or next;
 131                 die "multiple $f= options specified\n" if @$p > 1;
 132                 check_absolute("$f=", $p->[0]) if $daemonize;
 133                 $p = File::Spec->canonpath($p->[0]);
 134                 $tlsd->{$f} = $logs{$p} //= open_log_path(my $fh, $p);
 135                 warn "# $scheme://$addr $f=$p\n";
 136         }
 137         my $err = $tlsd->{err};
 138         $tlsd->{warn_cb} = sub { print $err @_ }; # for local $SIG{__WARN__}
 139         \%xn;
 140 }
 141
 142 sub daemon_prepare ($$) {
 143         my ($default_listen, $xnetd) = @_;
 144         my $listener_names = {}; # sockname => IO::Handle
 145         $oldset = PublicInbox::DS::block_signals();
 146         @CMD = ($0, @ARGV);
 147         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
 148         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 149         my $help = <<EOF;
 150 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 151
 152 options:
 153
 154   -l ADDRESS    address to listen on$dh
 155   --cert=FILE   default SSL/TLS certificate
 156   --key=FILE    default SSL/TLS certificate
 157   -W WORKERS    number of worker processes to spawn (default: 1)
 158
 159 See public-inbox-daemon(8) and $prog(1) man pages for more.
 160 EOF
 161         my %opt = (
 162                 'l|listen=s' => \@cfg_listen,
 163                 '1|stdout=s' => \$stdout,
 164                 '2|stderr=s' => \$stderr,
 165                 'W|worker-processes=i' => \$worker_processes,
 166                 'P|pid-file=s' => \$pid_file,
 167                 'u|user=s' => \$user,
 168                 'g|group=s' => \$group,
 169                 'D|daemonize' => \$daemonize,
 170                 'cert=s' => \$default_cert,
 171                 'key=s' => \$default_key,
 172                 'help|h' => \(my $show_help),
 173         );
 174         GetOptions(%opt) or die $help;
 175         if ($show_help) { print $help; exit 0 };
 176
 177         $_ = File::Spec->canonpath($_ // next) for ($stdout, $stderr);
 178         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 179                 die "--pid-file cannot end with '.oldbin'\n";
 180         }
 181         @listeners = inherit($listener_names);
 182         my @inherited_names = keys(%$listener_names);
 183
 184         # ignore daemonize when inheriting
 185         $daemonize = undef if scalar @listeners;
 186
 187         unless (@listeners || @cfg_listen) {
 188                 $default_listen // die "no listeners specified\n";
 189                 push @cfg_listen, $default_listen
 190         }
 191         my ($default_scheme) = (($default_listen // '') =~ m!\A([^:]+)://!);
 192         foreach my $l (@cfg_listen) {
 193                 my $orig = $l;
 194                 my ($scheme, $port, $opt);
 195                 $l =~ s!\A([a-z0-9]+)://!! and $scheme = $1;
 196                 $scheme //= $default_scheme;
 197                 if ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9]+)/) {
 198                         $port = $1 + 0;
 199                         $scheme //= $KNOWN_TLS{$port} // $KNOWN_STARTTLS{$port};
 200                 }
 201                 $scheme // die "unable to determine URL scheme of $orig\n";
 202                 if (!defined($port) && index($l, '/') != 0) { # AF_UNIX socket
 203                         $port = $SCHEME2PORT{$scheme} //
 204                                 die "no port in listen=$orig\n";
 205                         $l =~ s!\A([^/]+)!$1:$port! or
 206                                 die "unable to add port=$port to $l\n";
 207                 }
 208                 $l =~ s!/\z!!; # chop one trailing slash
 209                 if ($l =~ s!/?\?(.+)\z!!) {
 210                         $opt = listener_opt($1);
 211                         $tls_opt{"$scheme://$l"} = accept_tls_opt($opt);
 212                 } elsif (defined($default_cert)) {
 213                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 214                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 215                         die "$orig specified w/o cert=\n";
 216                 }
 217                 if ($listener_names->{$l}) { # already inherited
 218                         $xnetd->{$l} = load_mod($scheme, $opt, $l);
 219                         next;
 220                 }
 221                 my (%o, $sock_pkg);
 222                 if (index($l, '/') == 0) {
 223                         $sock_pkg = 'IO::Socket::UNIX';
 224                         eval "use $sock_pkg";
 225                         die $@ if $@;
 226                         %o = (Type => SOCK_STREAM, Peer => $l);
 227                         if (-S $l) {
 228                                 my $c = $sock_pkg->new(%o);
 229                                 if (!defined($c) && $!{ECONNREFUSED}) {
 230                                         unlink $l or die
 231 "failed to unlink stale socket=$l: $!\n";
 232                                 } # else: let the bind fail
 233                         }
 234                         $o{Local} = delete $o{Peer};
 235                 } else {
 236                         # both work for IPv4, too
 237                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 238                                 $sock_pkg = $_;
 239                                 eval "use $sock_pkg";
 240                                 $@ or last;
 241                         }
 242                         die $@ if $@;
 243                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 244                 }
 245                 $o{Listen} = 1024;
 246                 my $prev = umask 0000;
 247                 my $s = eval { $sock_pkg->new(%o) } or
 248                         warn "error binding $l: $! ($@)\n";
 249                 umask $prev;
 250                 $s // next;
 251                 $s->blocking(0);
 252                 my $sockname = sockname($s);
 253                 warn "# bound $scheme://$sockname\n";
 254                 $xnetd->{$sockname} //= load_mod($scheme);
 255                 $listener_names->{$sockname} = $s;
 256                 push @listeners, $s;
 257         }
 258
 259         # cert/key options in @cfg_listen takes precedence when inheriting,
 260         # but map well-known inherited ports if --listen isn't specified
 261         # at all.  This allows socket-activation users to set certs once
 262         # and not have to configure each socket:
 263         if (defined $default_cert) {
 264                 my ($stls) = (($default_scheme // '') =~ /\A(pop3|nntp|imap)/);
 265                 for my $x (@inherited_names) {
 266                         $x =~ /:([0-9]+)\z/ or next; # no TLS for AF_UNIX
 267                         if (my $scheme = $KNOWN_TLS{$1}) {
 268                                 $xnetd->{$x} //= load_mod($scheme);
 269                                 $tls_opt{"$scheme://$x"} ||= accept_tls_opt('');
 270                         } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 271                                 $xnetd->{$x} //= load_mod($scheme);
 272                                 $tls_opt{"$scheme://$x"} ||= accept_tls_opt('');
 273                         } elsif (defined $stls) {
 274                                 $tls_opt{"$stls://$x"} ||= accept_tls_opt('');
 275                         }
 276                 }
 277         }
 278         if (defined $default_scheme) {
 279                 for my $x (@inherited_names) {
 280                         $xnetd->{$x} //= load_mod($default_scheme);
 281                 }
 282         }
 283         die "No listeners bound\n" unless @listeners;
 284 }
 285
 286 sub daemonize () {
 287         if ($daemonize) {
 288                 require Cwd;
 289                 foreach my $i (0..$#ARGV) {
 290                         my $arg = $ARGV[$i];
 291                         next unless -e $arg;
 292                         $ARGV[$i] = Cwd::abs_path($arg);
 293                 }
 294                 check_absolute('--stdout', $stdout);
 295                 check_absolute('--stderr', $stderr);
 296                 check_absolute('--pid-file', $pid_file);
 297                 check_absolute('--cert', $default_cert);
 298                 check_absolute('--key', $default_key);
 299
 300                 chdir '/' or die "chdir failed: $!";
 301         }
 302         if (defined($pid_file) || defined($group) || defined($user)) {
 303                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 304 Net::Server required for --pid-file, --group, --user
 305 $@
 306 EOF
 307         }
 308         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 309         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 310         if (defined $group) {
 311                 $gid = Net::Server::Daemonize::get_gid($group);
 312                 $gid = (split /\s+/, $gid)[0];
 313         } elsif (defined $uid) {
 314                 $gid = (getpwuid($uid))[3];
 315         }
 316
 317         # We change users in the worker to ensure upgradability,
 318         # The upgrade will create the ".oldbin" pid file in the
 319         # same directory as the given pid file.
 320         $uid and $set_user = sub {
 321                 $set_user = undef;
 322                 Net::Server::Daemonize::set_user($uid, $gid);
 323         };
 324
 325         if ($daemonize) {
 326                 my $pid = fork // die "fork: $!";
 327                 exit if $pid;
 328
 329                 open(STDIN, '+<', '/dev/null') or
 330                                         die "redirect stdin failed: $!\n";
 331                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 332                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 333                 POSIX::setsid();
 334                 $pid = fork // die "fork: $!";
 335                 exit if $pid;
 336         }
 337         return unless defined $pid_file;
 338
 339         write_pid($pid_file);
 340         # for ->DESTROY:
 341         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 342 }
 343
 344 sub worker_quit { # $_[0] = signal name or number (unused)
 345         # killing again terminates immediately:
 346         exit unless @listeners;
 347
 348         $_->close foreach @listeners; # call PublicInbox::DS::close
 349         @listeners = ();
 350         my $proc_name;
 351         my $warn = 0;
 352         # drop idle connections and try to quit gracefully
 353         PublicInbox::DS->SetPostLoopCallback(sub {
 354                 my ($dmap, undef) = @_;
 355                 my $n = 0;
 356                 my $now = now();
 357                 for my $s (values %$dmap) {
 358                         $s->can('busy') or next;
 359                         if ($s->busy) {
 360                                 ++$n;
 361                         } else { # close as much as possible, early as possible
 362                                 $s->close;
 363                         }
 364                 }
 365                 if ($n) {
 366                         if (($warn + 5) < now()) {
 367                                 warn "$$ quitting, $n client(s) left\n";
 368                                 $warn = now();
 369                         }
 370                         unless (defined $proc_name) {
 371                                 $proc_name = (split(/\s+/, $0))[0];
 372                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 373                         }
 374                         $0 = "$proc_name quitting, $n client(s) left";
 375                 }
 376                 $n; # true: loop continues, false: loop breaks
 377         });
 378 }
 379
 380 sub reopen_logs {
 381         $logs{$stdout} //= \*STDOUT if defined $stdout;
 382         $logs{$stderr} //= \*STDERR if defined $stderr;
 383         while (my ($p, $fh) = each %logs) { open_log_path($fh, $p) }
 384 }
 385
 386 sub sockname ($) {
 387         my ($s) = @_;
 388         my $addr = getsockname($s) or return;
 389         my ($host, $port) = host_with_port($addr);
 390         if ($port == 0 && $host eq '127.0.0.1') {
 391                 my ($path) = Socket::sockaddr_un($addr);
 392                 return $path;
 393         }
 394         "$host:$port";
 395 }
 396
 397 sub unpack_ipv6 ($) {
 398         my ($addr) = @_;
 399         my ($port, $host);
 400
 401         # Socket.pm in Perl 5.14+ supports IPv6:
 402         eval {
 403                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 404                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 405         };
 406
 407         if ($@) {
 408                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 409                 # Socket6, so it may be installed on our system, already
 410                 # (otherwise die here):
 411                 require Socket6;
 412
 413                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 414                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 415         }
 416         ($host, $port);
 417 }
 418
 419 sub host_with_port ($) {
 420         my ($addr) = @_;
 421         my ($port, $host);
 422
 423         # this eval will die on Unix sockets:
 424         eval {
 425                 if (length($addr) >= 28) {
 426                         ($host, $port) = unpack_ipv6($addr);
 427                         $host = "[$host]";
 428                 } else {
 429                         ($port, $host) = Socket::sockaddr_in($addr);
 430                         $host = Socket::inet_ntoa($host);
 431                 }
 432         };
 433         $@ ? ('127.0.0.1', 0) : ($host, $port);
 434 }
 435
 436 sub inherit ($) {
 437         my ($listener_names) = @_;
 438         return () if ($ENV{LISTEN_PID} || 0) != $$;
 439         my $fds = $ENV{LISTEN_FDS} or return ();
 440         my $end = $fds + 2; # LISTEN_FDS_START - 1
 441         my @rv = ();
 442         foreach my $fd (3..$end) {
 443                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 444                 if (my $k = sockname($s)) {
 445                         my $prev_was_blocking = $s->blocking(0);
 446                         warn <<"" if $prev_was_blocking;
 447 Inherited socket ($k fd=$fd) is blocking, making it non-blocking.
 448 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 449 processes when multiple service instances start.
 450
 451                         $listener_names->{$k} = $s;
 452                         warn "# inherited $k fd=$fd\n";
 453                         push @rv, $s;
 454                 } else {
 455                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 456                 }
 457         }
 458         @rv
 459 }
 460
 461 sub upgrade { # $_[0] = signal name or number (unused)
 462         if ($reexec_pid) {
 463                 warn "upgrade in-progress: $reexec_pid\n";
 464                 return;
 465         }
 466         if (defined $pid_file) {
 467                 if ($pid_file =~ /\.oldbin\z/) {
 468                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 469                         return;
 470                 }
 471                 unlink_pid_file_safe_ish($$, $pid_file);
 472                 $pid_file .= '.oldbin';
 473                 write_pid($pid_file);
 474         }
 475         my $pid = fork;
 476         unless (defined $pid) {
 477                 warn "fork failed: $!\n";
 478                 return;
 479         }
 480         if ($pid == 0) {
 481                 $ENV{LISTEN_FDS} = scalar @listeners;
 482                 $ENV{LISTEN_PID} = $$;
 483                 foreach my $s (@listeners) {
 484                         # @listeners are globs with workers, PI::L w/o workers
 485                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 486                         fcntl($s, F_SETFD, 0) // die "F_SETFD: $!";
 487                 }
 488                 exec @CMD;
 489                 die "Failed to exec: $!\n";
 490         }
 491         $reexec_pid = $pid;
 492 }
 493
 494 sub kill_workers ($) {
 495         my ($sig) = @_;
 496         kill $sig, keys(%pids);
 497 }
 498
 499 sub upgrade_aborted ($) {
 500         my ($p) = @_;
 501         warn "reexec PID($p) died with: $?\n";
 502         $reexec_pid = undef;
 503         return unless $pid_file;
 504
 505         my $file = $pid_file;
 506         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 507         unlink_pid_file_safe_ish($$, $pid_file);
 508         $pid_file = $file;
 509         eval { write_pid($pid_file) };
 510         warn $@, "\n" if $@;
 511 }
 512
 513 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 514         while (1) {
 515                 my $p = waitpid(-1, WNOHANG) or return;
 516                 if (defined $reexec_pid && $p == $reexec_pid) {
 517                         upgrade_aborted($p);
 518                 } elsif (defined(my $id = delete $pids{$p})) {
 519                         warn "worker[$id] PID($p) died with: $?\n";
 520                 } elsif ($p > 0) {
 521                         warn "unknown PID($p) reaped: $?\n";
 522                 } else {
 523                         return;
 524                 }
 525         }
 526 }
 527
 528 sub unlink_pid_file_safe_ish ($$) {
 529         my ($unlink_pid, $file) = @_;
 530         return unless defined $unlink_pid && $unlink_pid == $$;
 531
 532         open my $fh, '<', $file or return;
 533         local $/ = "\n";
 534         defined(my $read_pid = <$fh>) or return;
 535         chomp $read_pid;
 536         if ($read_pid == $unlink_pid) {
 537                 Net::Server::Daemonize::unlink_pid_file($file);
 538         }
 539 }
 540
 541 sub master_quit ($) {
 542         exit unless @listeners;
 543         @listeners = ();
 544         kill_workers($_[0]);
 545 }
 546
 547 sub master_loop {
 548         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 549         my $set_workers = $worker_processes;
 550         reopen_logs();
 551         my $ignore_winch;
 552         my $sig = {
 553                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 554                 USR2 => \&upgrade,
 555                 QUIT => \&master_quit,
 556                 INT => \&master_quit,
 557                 TERM => \&master_quit,
 558                 WINCH => sub {
 559                         return if $ignore_winch || !@listeners;
 560                         if (-t STDIN || -t STDOUT || -t STDERR) {
 561                                 $ignore_winch = 1;
 562                                 warn <<EOF;
 563 ignoring SIGWINCH since we are not daemonized
 564 EOF
 565                         } else {
 566                                 $worker_processes = 0;
 567                         }
 568                 },
 569                 HUP => sub {
 570                         return unless @listeners;
 571                         $worker_processes = $set_workers;
 572                         kill_workers($_[0]);
 573                 },
 574                 TTIN => sub {
 575                         return unless @listeners;
 576                         if ($set_workers > $worker_processes) {
 577                                 ++$worker_processes;
 578                         } else {
 579                                 $worker_processes = ++$set_workers;
 580                         }
 581                 },
 582                 TTOU => sub {
 583                         $worker_processes = --$set_workers if $set_workers > 0;
 584                 },
 585                 CHLD => \&reap_children,
 586         };
 587         my $sigfd = PublicInbox::Sigfd->new($sig);
 588         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 589         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 590         while (1) { # main loop
 591                 my $n = scalar keys %pids;
 592                 unless (@listeners) {
 593                         exit if $n == 0;
 594                         $set_workers = $worker_processes = $n = 0;
 595                 }
 596
 597                 if ($n > $worker_processes) {
 598                         while (my ($k, $v) = each %pids) {
 599                                 kill('TERM', $k) if $v >= $worker_processes;
 600                         }
 601                         $n = $worker_processes;
 602                 }
 603                 my $want = $worker_processes - 1;
 604                 if ($n <= $want) {
 605                         PublicInbox::DS::block_signals() if !$sigfd;
 606                         for my $i ($n..$want) {
 607                                 my $seed = rand(0xffffffff);
 608                                 my $pid = fork;
 609                                 if (!defined $pid) {
 610                                         warn "failed to fork worker[$i]: $!\n";
 611                                 } elsif ($pid == 0) {
 612                                         srand($seed);
 613                                         eval { Net::SSLeay::randomize() };
 614                                         $set_user->() if $set_user;
 615                                         return $p0; # run normal work code
 616                                 } else {
 617                                         warn "PID=$pid is worker[$i]\n";
 618                                         $pids{$pid} = $i;
 619                                 }
 620                         }
 621                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 622                 }
 623
 624                 if ($sigfd) { # Linux and IO::KQueue users:
 625                         $sigfd->wait_once;
 626                 } else { # wake up every second
 627                         sleep(1);
 628                 }
 629         }
 630         exit # never gets here, just for documentation
 631 }
 632
 633 sub tls_cb {
 634         my ($post_accept, $tlsd) = @_;
 635         sub {
 636                 my ($io, $addr, $srv) = @_;
 637                 $post_accept->(PublicInbox::TLS::start($io, $tlsd), $addr, $srv)
 638         }
 639 }
 640
 641 sub defer_accept ($$) {
 642         my ($s, $af_name) = @_;
 643         return unless defined $af_name;
 644         if ($^O eq 'linux') {
 645                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 646                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 647                 return unless defined $x; # may be Unix socket
 648                 my $sec = unpack('i', $x);
 649                 return if $sec > 0; # systemd users may set a higher value
 650                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 651         } elsif ($^O eq 'freebsd') {
 652                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 653                 return if defined $x; # don't change if set
 654                 my $accf_arg = pack('a16a240', $af_name, '');
 655                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 656         }
 657 }
 658
 659 sub daemon_loop ($) {
 660         my ($xnetd) = @_;
 661         local $PublicInbox::Config::DEDUPE = {}; # enable dedupe cache
 662         my $refresh = sub {
 663                 my ($sig) = @_;
 664                 %$PublicInbox::Config::DEDUPE = (); # clear cache
 665                 for my $xn (values %$xnetd) {
 666                         delete $xn->{tlsd}->{ssl_ctx}; # PublicInbox::TLS::start
 667                         eval { $xn->{refresh}->($sig) };
 668                         warn "refresh $@\n" if $@;
 669                 }
 670         };
 671         my %post_accept;
 672         while (my ($k, $ctx_opt) = each %tls_opt) {
 673                 $ctx_opt // next;
 674                 my ($scheme, $l) = split(m!://!, $k, 2);
 675                 my $xn = $xnetd->{$l} // die "BUG: no xnetd for $k";
 676                 $xn->{tlsd}->{ssl_ctx_opt} //= $ctx_opt;
 677                 $scheme =~ m!\A(?:https|imaps|nntps|pop3s)! and
 678                         $post_accept{$l} = tls_cb(@$xn{qw(post_accept tlsd)});
 679         }
 680         undef %tls_opt;
 681         my $sig = {
 682                 HUP => $refresh,
 683                 INT => \&worker_quit,
 684                 QUIT => \&worker_quit,
 685                 TERM => \&worker_quit,
 686                 TTIN => 'IGNORE',
 687                 TTOU => 'IGNORE',
 688                 USR1 => \&reopen_logs,
 689                 USR2 => 'IGNORE',
 690                 WINCH => 'IGNORE',
 691                 CHLD => \&PublicInbox::DS::enqueue_reap,
 692         };
 693         if ($worker_processes > 0) {
 694                 $refresh->(); # preload by default
 695                 my $fh = master_loop(); # returns if in child process
 696                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 697         } else {
 698                 reopen_logs();
 699                 $set_user->() if $set_user;
 700                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 701                 $refresh->();
 702         }
 703         $uid = $gid = undef;
 704         reopen_logs();
 705         @listeners = map {;
 706                 my $l = sockname($_);
 707                 my $tls_cb = $post_accept{$l};
 708                 my $xn = $xnetd->{$l} // die "BUG: no xnetd for $l";
 709
 710                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 711                 # IMAP, NNTP and POP3 are server-first
 712                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 713
 714                 # this calls epoll_create:
 715                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 716         } @listeners;
 717         PublicInbox::DS::event_loop($sig, $oldset);
 718 }
 719
 720 sub run {
 721         my ($default_listen) = @_;
 722         daemon_prepare($default_listen, my $xnetd = {});
 723         my $for_destroy = daemonize();
 724
 725         # localize GCF2C for tests:
 726         local $PublicInbox::GitAsyncCat::GCF2C;
 727         local $PublicInbox::Git::async_warn = 1;
 728         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 729
 730         daemon_loop($xnetd);
 731         PublicInbox::DS->Reset;
 732         # ->DESTROY runs when $for_destroy goes out-of-scope
 733 }
 734
 735 sub write_pid ($) {
 736         my ($path) = @_;
 737         Net::Server::Daemonize::create_pid_file($path);
 738         do_chown($path);
 739 }
 740
 741 sub DESTROY {
 742         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 743 }
 744
 745 1;