lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use warnings;
  10 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use POSIX qw(WNOHANG :signal_h);
  14 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  15 sub SO_ACCEPTFILTER () { 0x1000 }
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Syscall qw(SFD_NONBLOCK);
  20 require PublicInbox::Listener;
  21 use PublicInbox::EOFpipe;
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::GitAsyncCat;
  24 my @CMD;
  25 my ($set_user, $oldset);
  26 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  27 my $worker_processes = 1;
  28 my @listeners;
  29 my %pids;
  30 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  31 my $reexec_pid;
  32 my ($uid, $gid);
  33 my ($default_cert, $default_key);
  34 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps', 993 => 'imaps' );
  35 my %KNOWN_STARTTLS = ( 119 => 'nntp', 143 => 'imap' );
  36
  37 sub accept_tls_opt ($) {
  38         my ($opt_str) = @_;
  39         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  40         require PublicInbox::TLS;
  41         my $o = {};
  42         # allow ',' as delimiter since '&' is shell-unfriendly
  43         foreach (split(/[,&]/, $opt_str)) {
  44                 my ($k, $v) = split(/=/, $_, 2);
  45                 push @{$o->{$k} ||= []}, $v;
  46         }
  47
  48         # key may be a part of cert.  At least
  49         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  50         $o->{cert} //= [ $default_cert ];
  51         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  52         my %ctx_opt = (SSL_server => 1);
  53         # parse out hostname:/path/to/ mappings:
  54         foreach my $k (qw(cert key)) {
  55                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  56                 foreach my $path (@{$o->{$k}}) {
  57                         my $host = '';
  58                         $path =~ s/\A([^:]+):// and $host = $1;
  59                         $x->{$host} = $path;
  60                 }
  61         }
  62         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  63                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  64
  65         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  66         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  67         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  68         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  69         if ($mode && $ctx->{context}) {
  70                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  71                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  72         }
  73
  74         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  75 }
  76
  77 sub daemon_prepare ($) {
  78         my ($default_listen) = @_;
  79         my $listener_names = {}; # sockname => IO::Handle
  80         $oldset = PublicInbox::Sigfd::block_signals();
  81         @CMD = ($0, @ARGV);
  82         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  83         my $help = <<EOF;
  84 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
  85
  86 options:
  87
  88   -l ADDRESS    address to listen on (default: $default_listen)
  89   --cert=FILE   default SSL/TLS certificate
  90   --key=FILE    default SSL/TLS certificate
  91   -W WORKERS    number of worker processes to spawn (default: 1)
  92
  93 See public-inbox-daemon(8) and $prog(1) man pages for more.
  94 EOF
  95         my %opt = (
  96                 'l|listen=s' => \@cfg_listen,
  97                 '1|stdout=s' => \$stdout,
  98                 '2|stderr=s' => \$stderr,
  99                 'W|worker-processes=i' => \$worker_processes,
 100                 'P|pid-file=s' => \$pid_file,
 101                 'u|user=s' => \$user,
 102                 'g|group=s' => \$group,
 103                 'D|daemonize' => \$daemonize,
 104                 'cert=s' => \$default_cert,
 105                 'key=s' => \$default_key,
 106                 'help|h' => \(my $show_help),
 107         );
 108         GetOptions(%opt) or die $help;
 109         if ($show_help) { print $help; exit 0 };
 110
 111         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 112                 die "--pid-file cannot end with '.oldbin'\n";
 113         }
 114         @listeners = inherit($listener_names);
 115
 116         # allow socket-activation users to set certs once and not
 117         # have to configure each socket:
 118         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 119
 120         # ignore daemonize when inheriting
 121         $daemonize = undef if scalar @listeners;
 122
 123         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 124
 125         foreach my $l (@cfg_listen) {
 126                 my $orig = $l;
 127                 my $scheme = '';
 128                 if ($l =~ s!\A([^:]+)://!!) {
 129                         $scheme = $1;
 130                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 131                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 132                         $scheme = $s if defined $s;
 133                 }
 134                 if ($l =~ s!/?\?(.+)\z!!) {
 135                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 136                 } elsif (defined($default_cert)) {
 137                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 138                 } elsif ($scheme =~ /\A(?:https|imaps|imaps)\z/) {
 139                         die "$orig specified w/o cert=\n";
 140                 }
 141                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 142
 143                 next if $listener_names->{$l}; # already inherited
 144                 my (%o, $sock_pkg);
 145                 if (index($l, '/') == 0) {
 146                         $sock_pkg = 'IO::Socket::UNIX';
 147                         eval "use $sock_pkg";
 148                         die $@ if $@;
 149                         %o = (Type => SOCK_STREAM, Peer => $l);
 150                         if (-S $l) {
 151                                 my $c = $sock_pkg->new(%o);
 152                                 if (!defined($c) && $!{ECONNREFUSED}) {
 153                                         unlink $l or die
 154 "failed to unlink stale socket=$l: $!\n";
 155                                 } # else: let the bind fail
 156                         }
 157                         $o{Local} = delete $o{Peer};
 158                 } else {
 159                         # both work for IPv4, too
 160                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 161                                 $sock_pkg = $_;
 162                                 eval "use $sock_pkg";
 163                                 $@ or last;
 164                         }
 165                         die $@ if $@;
 166                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 167                 }
 168                 $o{Listen} = 1024;
 169                 my $prev = umask 0000;
 170                 my $s = eval { $sock_pkg->new(%o) };
 171                 warn "error binding $l: $! ($@)\n" unless $s;
 172                 umask $prev;
 173                 if ($s) {
 174                         $listener_names->{sockname($s)} = $s;
 175                         $s->blocking(0);
 176                         push @listeners, $s;
 177                 }
 178         }
 179
 180         # cert/key options in @cfg_listen takes precedence when inheriting,
 181         # but map well-known inherited ports if --listen isn't specified
 182         # at all
 183         for my $sockname (@inherited_names) {
 184                 $sockname =~ /:([0-9]+)\z/ or next;
 185                 if (my $scheme = $KNOWN_TLS{$1}) {
 186                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 187                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 188                         next if $tls_opt{"$scheme://$sockname"};
 189                         $tls_opt{''} ||= accept_tls_opt('');
 190                 }
 191         }
 192
 193         die "No listeners bound\n" unless @listeners;
 194 }
 195
 196 sub check_absolute ($$) {
 197         my ($var, $val) = @_;
 198         if (defined $val && index($val, '/') != 0) {
 199                 die
 200 "--$var must be an absolute path when using --daemonize: $val\n";
 201         }
 202 }
 203
 204 sub daemonize () {
 205         if ($daemonize) {
 206                 require Cwd;
 207                 foreach my $i (0..$#ARGV) {
 208                         my $arg = $ARGV[$i];
 209                         next unless -e $arg;
 210                         $ARGV[$i] = Cwd::abs_path($arg);
 211                 }
 212                 check_absolute('stdout', $stdout);
 213                 check_absolute('stderr', $stderr);
 214                 check_absolute('pid-file', $pid_file);
 215
 216                 chdir '/' or die "chdir failed: $!";
 217         }
 218         if (defined($pid_file) || defined($group) || defined($user)) {
 219                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 220 Net::Server required for --pid-file, --group, --user
 221 $@
 222 EOF
 223         }
 224         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 225         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 226         if (defined $group) {
 227                 $gid = Net::Server::Daemonize::get_gid($group);
 228                 $gid = (split /\s+/, $gid)[0];
 229         } elsif (defined $uid) {
 230                 $gid = (getpwuid($uid))[3];
 231         }
 232
 233         # We change users in the worker to ensure upgradability,
 234         # The upgrade will create the ".oldbin" pid file in the
 235         # same directory as the given pid file.
 236         $uid and $set_user = sub {
 237                 $set_user = undef;
 238                 Net::Server::Daemonize::set_user($uid, $gid);
 239         };
 240
 241         if ($daemonize) {
 242                 my $pid = fork // die "fork: $!";
 243                 exit if $pid;
 244
 245                 open(STDIN, '+<', '/dev/null') or
 246                                         die "redirect stdin failed: $!\n";
 247                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 248                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 249                 POSIX::setsid();
 250                 $pid = fork // die "fork: $!";
 251                 exit if $pid;
 252         }
 253         return unless defined $pid_file;
 254
 255         write_pid($pid_file);
 256         # for ->DESTROY:
 257         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 258 }
 259
 260 sub worker_quit { # $_[0] = signal name or number (unused)
 261         # killing again terminates immediately:
 262         exit unless @listeners;
 263
 264         $_->close foreach @listeners; # call PublicInbox::DS::close
 265         @listeners = ();
 266         my $proc_name;
 267         my $warn = 0;
 268         # drop idle connections and try to quit gracefully
 269         PublicInbox::DS->SetPostLoopCallback(sub {
 270                 my ($dmap, undef) = @_;
 271                 my $n = 0;
 272                 my $now = now();
 273
 274                 foreach my $s (values %$dmap) {
 275                         $s->can('busy') or next;
 276                         if ($s->busy($now)) {
 277                                 ++$n;
 278                         } else {
 279                                 # close as much as possible, early as possible
 280                                 $s->close;
 281                         }
 282                 }
 283                 if ($n) {
 284                         if (($warn + 5) < now()) {
 285                                 warn "$$ quitting, $n client(s) left\n";
 286                                 $warn = now();
 287                         }
 288                         unless (defined $proc_name) {
 289                                 $proc_name = (split(/\s+/, $0))[0];
 290                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 291                         }
 292                         $0 = "$proc_name quitting, $n client(s) left";
 293                 }
 294                 $n; # true: loop continues, false: loop breaks
 295         });
 296 }
 297
 298 sub reopen_logs {
 299         if ($stdout) {
 300                 open STDOUT, '>>', $stdout or
 301                         warn "failed to redirect stdout to $stdout: $!\n";
 302                 STDOUT->autoflush(1);
 303                 do_chown($stdout);
 304         }
 305         if ($stderr) {
 306                 open STDERR, '>>', $stderr or
 307                         warn "failed to redirect stderr to $stderr: $!\n";
 308                 STDERR->autoflush(1);
 309                 do_chown($stderr);
 310         }
 311 }
 312
 313 sub sockname ($) {
 314         my ($s) = @_;
 315         my $addr = getsockname($s) or return;
 316         my ($host, $port) = host_with_port($addr);
 317         if ($port == 0 && $host eq '127.0.0.1') {
 318                 my ($path) = Socket::sockaddr_un($addr);
 319                 return $path;
 320         }
 321         "$host:$port";
 322 }
 323
 324 sub unpack_ipv6 ($) {
 325         my ($addr) = @_;
 326         my ($port, $host);
 327
 328         # Socket.pm in Perl 5.14+ supports IPv6:
 329         eval {
 330                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 331                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 332         };
 333
 334         if ($@) {
 335                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 336                 # Socket6, so it may be installed on our system, already
 337                 # (otherwise die here):
 338                 require Socket6;
 339
 340                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 341                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 342         }
 343         ($host, $port);
 344 }
 345
 346 sub host_with_port ($) {
 347         my ($addr) = @_;
 348         my ($port, $host);
 349
 350         # this eval will die on Unix sockets:
 351         eval {
 352                 if (length($addr) >= 28) {
 353                         ($host, $port) = unpack_ipv6($addr);
 354                         $host = "[$host]";
 355                 } else {
 356                         ($port, $host) = Socket::sockaddr_in($addr);
 357                         $host = Socket::inet_ntoa($host);
 358                 }
 359         };
 360         $@ ? ('127.0.0.1', 0) : ($host, $port);
 361 }
 362
 363 sub inherit ($) {
 364         my ($listener_names) = @_;
 365         return () if ($ENV{LISTEN_PID} || 0) != $$;
 366         my $fds = $ENV{LISTEN_FDS} or return ();
 367         my $end = $fds + 2; # LISTEN_FDS_START - 1
 368         my @rv = ();
 369         foreach my $fd (3..$end) {
 370                 my $s = IO::Handle->new_from_fd($fd, 'r');
 371                 if (my $k = sockname($s)) {
 372                         my $prev_was_blocking = $s->blocking(0);
 373                         warn <<"" if $prev_was_blocking;
 374 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 375 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 376 processes when multiple service instances start.
 377
 378                         $listener_names->{$k} = $s;
 379                         push @rv, $s;
 380                 } else {
 381                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 382                 }
 383         }
 384         @rv
 385 }
 386
 387 sub upgrade { # $_[0] = signal name or number (unused)
 388         if ($reexec_pid) {
 389                 warn "upgrade in-progress: $reexec_pid\n";
 390                 return;
 391         }
 392         if (defined $pid_file) {
 393                 if ($pid_file =~ /\.oldbin\z/) {
 394                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 395                         return;
 396                 }
 397                 unlink_pid_file_safe_ish($$, $pid_file);
 398                 $pid_file .= '.oldbin';
 399                 write_pid($pid_file);
 400         }
 401         my $pid = fork;
 402         unless (defined $pid) {
 403                 warn "fork failed: $!\n";
 404                 return;
 405         }
 406         if ($pid == 0) {
 407                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 408                 $ENV{LISTEN_FDS} = scalar @listeners;
 409                 $ENV{LISTEN_PID} = $$;
 410                 foreach my $s (@listeners) {
 411                         # @listeners are globs with workers, PI::L w/o workers
 412                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 413
 414                         my $fl = fcntl($s, F_GETFD, 0);
 415                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 416                 }
 417                 exec @CMD;
 418                 die "Failed to exec: $!\n";
 419         }
 420         $reexec_pid = $pid;
 421 }
 422
 423 sub kill_workers ($) {
 424         my ($sig) = @_;
 425         kill $sig, keys(%pids);
 426 }
 427
 428 sub upgrade_aborted ($) {
 429         my ($p) = @_;
 430         warn "reexec PID($p) died with: $?\n";
 431         $reexec_pid = undef;
 432         return unless $pid_file;
 433
 434         my $file = $pid_file;
 435         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 436         unlink_pid_file_safe_ish($$, $pid_file);
 437         $pid_file = $file;
 438         eval { write_pid($pid_file) };
 439         warn $@, "\n" if $@;
 440 }
 441
 442 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 443         while (1) {
 444                 my $p = waitpid(-1, WNOHANG) or return;
 445                 if (defined $reexec_pid && $p == $reexec_pid) {
 446                         upgrade_aborted($p);
 447                 } elsif (defined(my $id = delete $pids{$p})) {
 448                         warn "worker[$id] PID($p) died with: $?\n";
 449                 } elsif ($p > 0) {
 450                         warn "unknown PID($p) reaped: $?\n";
 451                 } else {
 452                         return;
 453                 }
 454         }
 455 }
 456
 457 sub unlink_pid_file_safe_ish ($$) {
 458         my ($unlink_pid, $file) = @_;
 459         return unless defined $unlink_pid && $unlink_pid == $$;
 460
 461         open my $fh, '<', $file or return;
 462         local $/ = "\n";
 463         defined(my $read_pid = <$fh>) or return;
 464         chomp $read_pid;
 465         if ($read_pid == $unlink_pid) {
 466                 Net::Server::Daemonize::unlink_pid_file($file);
 467         }
 468 }
 469
 470 sub master_quit ($) {
 471         exit unless @listeners;
 472         @listeners = ();
 473         kill_workers($_[0]);
 474 }
 475
 476 sub master_loop {
 477         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 478         my $set_workers = $worker_processes;
 479         reopen_logs();
 480         my $ignore_winch;
 481         my $sig = {
 482                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 483                 USR2 => \&upgrade,
 484                 QUIT => \&master_quit,
 485                 INT => \&master_quit,
 486                 TERM => \&master_quit,
 487                 WINCH => sub {
 488                         return if $ignore_winch || !@listeners;
 489                         if (-t STDIN || -t STDOUT || -t STDERR) {
 490                                 $ignore_winch = 1;
 491                                 warn <<EOF;
 492 ignoring SIGWINCH since we are not daemonized
 493 EOF
 494                         } else {
 495                                 $worker_processes = 0;
 496                         }
 497                 },
 498                 HUP => sub {
 499                         return unless @listeners;
 500                         $worker_processes = $set_workers;
 501                         kill_workers($_[0]);
 502                 },
 503                 TTIN => sub {
 504                         return unless @listeners;
 505                         if ($set_workers > $worker_processes) {
 506                                 ++$worker_processes;
 507                         } else {
 508                                 $worker_processes = ++$set_workers;
 509                         }
 510                 },
 511                 TTOU => sub {
 512                         $worker_processes = --$set_workers if $set_workers > 0;
 513                 },
 514                 CHLD => \&reap_children,
 515         };
 516         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 517         local %SIG = (%SIG, %$sig) if !$sigfd;
 518         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 519         while (1) { # main loop
 520                 my $n = scalar keys %pids;
 521                 unless (@listeners) {
 522                         exit if $n == 0;
 523                         $set_workers = $worker_processes = $n = 0;
 524                 }
 525
 526                 if ($n > $worker_processes) {
 527                         while (my ($k, $v) = each %pids) {
 528                                 kill('TERM', $k) if $v >= $worker_processes;
 529                         }
 530                         $n = $worker_processes;
 531                 }
 532                 my $want = $worker_processes - 1;
 533                 if ($n <= $want) {
 534                         PublicInbox::Sigfd::block_signals() if !$sigfd;
 535                         for my $i ($n..$want) {
 536                                 my $pid = fork;
 537                                 if (!defined $pid) {
 538                                         warn "failed to fork worker[$i]: $!\n";
 539                                 } elsif ($pid == 0) {
 540                                         $set_user->() if $set_user;
 541                                         return $p0; # run normal work code
 542                                 } else {
 543                                         warn "PID=$pid is worker[$i]\n";
 544                                         $pids{$pid} = $i;
 545                                 }
 546                         }
 547                         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 548                 }
 549
 550                 if ($sigfd) { # Linux and IO::KQueue users:
 551                         $sigfd->wait_once;
 552                 } else { # wake up every second
 553                         sleep(1);
 554                 }
 555         }
 556         exit # never gets here, just for documentation
 557 }
 558
 559 sub tls_start_cb ($$) {
 560         my ($opt, $orig_post_accept) = @_;
 561         sub {
 562                 my ($io, $addr, $srv) = @_;
 563                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 564                 $orig_post_accept->($ssl, $addr, $srv);
 565         }
 566 }
 567
 568 sub defer_accept ($$) {
 569         my ($s, $af_name) = @_;
 570         return unless defined $af_name;
 571         if ($^O eq 'linux') {
 572                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 573                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 574                 return unless defined $x; # may be Unix socket
 575                 my $sec = unpack('i', $x);
 576                 return if $sec > 0; # systemd users may set a higher value
 577                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 578         } elsif ($^O eq 'freebsd') {
 579                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 580                 return if defined $x; # don't change if set
 581                 my $accf_arg = pack('a16a240', $af_name, '');
 582                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 583         }
 584 }
 585
 586 sub daemon_loop ($$$$) {
 587         my ($refresh, $post_accept, $tlsd, $af_default) = @_;
 588         my %post_accept;
 589         while (my ($k, $v) = each %tls_opt) {
 590                 if ($k =~ s!\A(?:https|imaps|nntps)://!!) {
 591                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 592                 } elsif ($tlsd) { # STARTTLS, $k eq '' is OK
 593                         $tlsd->{accept_tls} = $v;
 594                 }
 595         }
 596         my $sig = {
 597                 HUP => $refresh,
 598                 INT => \&worker_quit,
 599                 QUIT => \&worker_quit,
 600                 TERM => \&worker_quit,
 601                 TTIN => 'IGNORE',
 602                 TTOU => 'IGNORE',
 603                 USR1 => \&reopen_logs,
 604                 USR2 => 'IGNORE',
 605                 WINCH => 'IGNORE',
 606                 CHLD => \&PublicInbox::DS::enqueue_reap,
 607         };
 608         if ($worker_processes > 0) {
 609                 $refresh->(); # preload by default
 610                 my $fh = master_loop(); # returns if in child process
 611                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 612         } else {
 613                 reopen_logs();
 614                 $set_user->() if $set_user;
 615                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 616                 $refresh->();
 617         }
 618         $uid = $gid = undef;
 619         reopen_logs();
 620         @listeners = map {;
 621                 my $tls_cb = $post_accept{sockname($_)};
 622
 623                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 624                 # IMAP, NNTP and POP3 are server-first
 625                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 626
 627                 # this calls epoll_create:
 628                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 629         } @listeners;
 630         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 631         local %SIG = (%SIG, %$sig) if !$sigfd;
 632         if (!$sigfd) {
 633                 # wake up every second to accept signals if we don't
 634                 # have signalfd or IO::KQueue:
 635                 PublicInbox::Sigfd::sig_setmask($oldset);
 636                 PublicInbox::DS->SetLoopTimeout(1000);
 637         }
 638         PublicInbox::DS->EventLoop;
 639 }
 640
 641 sub run ($$$;$) {
 642         my ($default, $refresh, $post_accept, $tlsd) = @_;
 643         local $SIG{PIPE} = 'IGNORE';
 644         daemon_prepare($default);
 645         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 646         my $for_destroy = daemonize();
 647
 648         # localize GCF2C for tests:
 649         local $PublicInbox::GitAsyncCat::GCF2C;
 650
 651         daemon_loop($refresh, $post_accept, $tlsd, $af_default);
 652         PublicInbox::DS->Reset;
 653         # ->DESTROY runs when $for_destroy goes out-of-scope
 654 }
 655
 656 sub do_chown ($) {
 657         my ($path) = @_;
 658         if (defined $uid and !chown($uid, $gid, $path)) {
 659                 warn "could not chown $path: $!\n";
 660         }
 661 }
 662
 663 sub write_pid ($) {
 664         my ($path) = @_;
 665         Net::Server::Daemonize::create_pid_file($path);
 666         do_chown($path);
 667 }
 668
 669 sub DESTROY {
 670         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 671 }
 672
 673 1;