lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Daemon; # empty class :p
   4
   5 # contains common daemon code for the nntpd and httpd servers.
   6 # This may be used for read-only IMAP server if we decide to implement it.
   7 package main;
   8 use strict;
   9 use warnings;
  10 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  11 use IO::Handle;
  12 STDOUT->autoflush(1);
  13 STDERR->autoflush(1);
  14 require Danga::Socket;
  15 require POSIX;
  16 require PublicInbox::Listener;
  17 my @CMD;
  18 my $set_user;
  19 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  20 my $worker_processes = 1;
  21 my @listeners;
  22 my %pids;
  23 my %listener_names;
  24 my $reexec_pid;
  25 my $cleanup;
  26 my ($uid, $gid);
  27 END { $cleanup->() if $cleanup };
  28
  29 sub daemon_prepare ($) {
  30         my ($default_listen) = @_;
  31         @CMD = ($0, @ARGV);
  32         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  33                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  34         my %opts = (
  35                 'l|listen=s' => \@cfg_listen,
  36                 '1|stdout=s' => \$stdout,
  37                 '2|stderr=s' => \$stderr,
  38                 'W|worker-processes=i' => \$worker_processes,
  39                 'P|pid-file=s' => \$pid_file,
  40                 'u|user=s' => \$user,
  41                 'g|group=s' => \$group,
  42                 'D|daemonize' => \$daemonize,
  43         );
  44         GetOptions(%opts) or die "bad command-line args\n";
  45
  46         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  47                 die "--pid-file cannot end with '.oldbin'\n";
  48         }
  49         @listeners = inherit();
  50         # ignore daemonize when inheriting
  51         $daemonize = undef if scalar @listeners;
  52
  53         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  54
  55         foreach my $l (@cfg_listen) {
  56                 next if $listener_names{$l}; # already inherited
  57                 require IO::Socket::INET6; # works for IPv4, too
  58                 my %o = (
  59                         LocalAddr => $l,
  60                         ReuseAddr => 1,
  61                         Proto => 'tcp',
  62                 );
  63                 if (my $s = IO::Socket::INET6->new(%o)) {
  64                         $listener_names{sockname($s)} = $s;
  65                         push @listeners, $s;
  66                 } else {
  67                         warn "error binding $l: $!\n";
  68                 }
  69         }
  70         die "No listeners bound\n" unless @listeners;
  71 }
  72
  73 sub daemonize () {
  74         chdir '/' or die "chdir failed: $!";
  75         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
  76
  77         return unless (defined $pid_file || defined $group || defined $user
  78                         || $daemonize);
  79
  80         require Net::Server::Daemonize;
  81
  82         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
  83         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
  84         if (defined $group) {
  85                 $gid = Net::Server::Daemonize::get_gid($group);
  86                 $gid = (split /\s+/, $gid)[0];
  87         } elsif (defined $uid) {
  88                 $gid = (getpwuid($uid))[3];
  89         }
  90
  91         # We change users in the worker to ensure upgradability,
  92         # The upgrade will create the ".oldbin" pid file in the
  93         # same directory as the given pid file.
  94         $uid and $set_user = sub {
  95                 Net::Server::Daemonize::set_user($uid, $gid);
  96         };
  97
  98         if ($daemonize) {
  99                 my ($pid, $err) = do_fork();
 100                 die "could not fork: $err\n" unless defined $pid;
 101                 exit if $pid;
 102
 103                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 104                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 105                 POSIX::setsid();
 106                 ($pid, $err) = do_fork();
 107                 die "could not fork: $err\n" unless defined $pid;
 108                 exit if $pid;
 109         }
 110         if (defined $pid_file) {
 111                 write_pid($pid_file);
 112                 my $unlink_pid = $$;
 113                 $cleanup = sub {
 114                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 115                 };
 116         }
 117 }
 118
 119 sub worker_quit () {
 120         # killing again terminates immediately:
 121         exit unless @listeners;
 122
 123         @listeners = ();
 124
 125         # give slow clients 30s to finish reading/writing whatever
 126         Danga::Socket->AddTimer(30, sub { exit });
 127
 128         # drop idle connections and try to quit gracefully
 129         Danga::Socket->SetPostLoopCallback(sub {
 130                 my ($dmap, undef) = @_;
 131                 my $n = 0;
 132
 133                 foreach my $s (values %$dmap) {
 134                         if ($s->can('busy') && $s->busy) {
 135                                 $n = 1;
 136                         } else {
 137                                 # close as much as possible, early as possible
 138                                 $s->close;
 139                         }
 140                 }
 141                 $n; # true: loop continues, false: loop breaks
 142         });
 143 }
 144
 145 sub reopen_logs {
 146         if ($stdout) {
 147                 open STDOUT, '>>', $stdout or
 148                         warn "failed to redirect stdout to $stdout: $!\n";
 149                 STDOUT->autoflush(1);
 150                 do_chown($stdout);
 151         }
 152         if ($stderr) {
 153                 open STDERR, '>>', $stderr or
 154                         warn "failed to redirect stderr to $stderr: $!\n";
 155                 STDERR->autoflush(1);
 156                 do_chown($stderr);
 157         }
 158 }
 159
 160 sub sockname ($) {
 161         my ($s) = @_;
 162         my $n = getsockname($s) or return;
 163         my ($port, $addr);
 164         if (length($n) >= 28) {
 165                 require Socket6;
 166                 ($port, $addr) = Socket6::unpack_sockaddr_in6($n);
 167         } else {
 168                 ($port, $addr) = Socket::sockaddr_in($n);
 169         }
 170         if (length($addr) == 4) {
 171                 $n = Socket::inet_ntoa($addr)
 172         } else {
 173                 $n = '['.Socket6::inet_ntop(Socket6::AF_INET6(), $addr).']';
 174         }
 175         $n .= ":$port";
 176 }
 177
 178 sub inherit () {
 179         return () if ($ENV{LISTEN_PID} || 0) != $$;
 180         my $fds = $ENV{LISTEN_FDS} or return ();
 181         my $end = $fds + 2; # LISTEN_FDS_START - 1
 182         my @rv = ();
 183         foreach my $fd (3..$end) {
 184                 my $s = IO::Handle->new;
 185                 $s->fdopen($fd, 'r');
 186                 if (my $k = sockname($s)) {
 187                         $listener_names{$k} = $s;
 188                         push @rv, $s;
 189                 } else {
 190                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 191                 }
 192         }
 193         @rv
 194 }
 195
 196 sub upgrade () {
 197         if ($reexec_pid) {
 198                 warn "upgrade in-progress: $reexec_pid\n";
 199                 return;
 200         }
 201         if (defined $pid_file) {
 202                 if ($pid_file =~ /\.oldbin\z/) {
 203                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 204                         return;
 205                 }
 206                 unlink_pid_file_safe_ish($$, $pid_file);
 207                 $pid_file .= '.oldbin';
 208                 write_pid($pid_file);
 209         }
 210         my ($pid, $err) = do_fork();
 211         unless (defined $pid) {
 212                 warn "fork failed: $err\n";
 213                 return;
 214         }
 215         if ($pid == 0) {
 216                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 217                 $ENV{LISTEN_FDS} = scalar @listeners;
 218                 $ENV{LISTEN_PID} = $$;
 219                 foreach my $s (@listeners) {
 220                         my $fl = fcntl($s, F_GETFD, 0);
 221                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 222                 }
 223                 exec @CMD;
 224                 die "Failed to exec: $!\n";
 225         }
 226         $reexec_pid = $pid;
 227 }
 228
 229 sub kill_workers ($) {
 230         my ($s) = @_;
 231
 232         while (my ($pid, $id) = each %pids) {
 233                 kill $s, $pid;
 234         }
 235 }
 236
 237 sub do_fork () {
 238         my $new = POSIX::SigSet->new;
 239         $new->fillset;
 240         my $old = POSIX::SigSet->new;
 241         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 242         my $pid = fork;
 243         my $err = $!;
 244         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 245         ($pid, $err);
 246 }
 247
 248 sub upgrade_aborted ($) {
 249         my ($p) = @_;
 250         warn "reexec PID($p) died with: $?\n";
 251         $reexec_pid = undef;
 252         return unless $pid_file;
 253
 254         my $file = $pid_file;
 255         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 256         unlink_pid_file_safe_ish($$, $pid_file);
 257         $pid_file = $file;
 258         eval { write_pid($pid_file) };
 259         warn $@, "\n" if $@;
 260 }
 261
 262 sub reap_children () {
 263         while (1) {
 264                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 265                 if (defined $reexec_pid && $p == $reexec_pid) {
 266                         upgrade_aborted($p);
 267                 } elsif (defined(my $id = delete $pids{$p})) {
 268                         warn "worker[$id] PID($p) died with: $?\n";
 269                 } elsif ($p > 0) {
 270                         warn "unknown PID($p) reaped: $?\n";
 271                 } else {
 272                         return;
 273                 }
 274         }
 275 }
 276
 277 sub unlink_pid_file_safe_ish ($$) {
 278         my ($unlink_pid, $file) = @_;
 279         return unless defined $unlink_pid && $unlink_pid == $$;
 280
 281         open my $fh, '<', $file or return;
 282         defined(my $read_pid = <$fh>) or return;
 283         chomp $read_pid;
 284         if ($read_pid == $unlink_pid) {
 285                 Net::Server::Daemonize::unlink_pid_file($file);
 286         }
 287 }
 288
 289 sub master_loop {
 290         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 291         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 292         IO::Handle::blocking($w, 0);
 293         my $set_workers = $worker_processes;
 294         my @caught;
 295         my $master_pid = $$;
 296         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 297                 $SIG{$s} = sub {
 298                         return if $$ != $master_pid;
 299                         push @caught, $s;
 300                         syswrite($w, '.');
 301                 };
 302         }
 303         reopen_logs();
 304         # main loop
 305         while (1) {
 306                 while (my $s = shift @caught) {
 307                         if ($s eq 'USR1') {
 308                                 reopen_logs();
 309                                 kill_workers($s);
 310                         } elsif ($s eq 'USR2') {
 311                                 upgrade();
 312                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 313                                 # drops pipes and causes children to die
 314                                 exit
 315                         } elsif ($s eq 'WINCH') {
 316                                 $worker_processes = 0;
 317                         } elsif ($s eq 'HUP') {
 318                                 $worker_processes = $set_workers;
 319                                 kill_workers($s);
 320                         } elsif ($s eq 'TTIN') {
 321                                 if ($set_workers > $worker_processes) {
 322                                         ++$worker_processes;
 323                                 } else {
 324                                         $worker_processes = ++$set_workers;
 325                                 }
 326                         } elsif ($s eq 'TTOU') {
 327                                 if ($set_workers > 0) {
 328                                         $worker_processes = --$set_workers;
 329                                 }
 330                         } elsif ($s eq 'CHLD') {
 331                                 reap_children();
 332                         }
 333                 }
 334
 335                 my $n = scalar keys %pids;
 336                 if ($n > $worker_processes) {
 337                         while (my ($k, $v) = each %pids) {
 338                                 kill('TERM', $k) if $v >= $worker_processes;
 339                         }
 340                         $n = $worker_processes;
 341                 }
 342                 foreach my $i ($n..($worker_processes - 1)) {
 343                         my ($pid, $err) = do_fork();
 344                         if (!defined $pid) {
 345                                 warn "failed to fork worker[$i]: $err\n";
 346                         } elsif ($pid == 0) {
 347                                 $set_user->() if $set_user;
 348                                 return $p0; # run normal work code
 349                         } else {
 350                                 warn "PID=$pid is worker[$i]\n";
 351                                 $pids{$pid} = $i;
 352                         }
 353                 }
 354                 # just wait on signal events here:
 355                 sysread($r, my $buf, 8);
 356         }
 357         exit # never gets here, just for documentation
 358 }
 359
 360 sub daemon_loop ($$) {
 361         my ($refresh, $post_accept) = @_;
 362         my $parent_pipe;
 363         if ($worker_processes > 0) {
 364                 $refresh->(); # preload by default
 365                 $parent_pipe = master_loop(); # returns if in child process
 366                 my $fd = fileno($parent_pipe);
 367                 Danga::Socket->AddOtherFds($fd => sub { kill('TERM', $$) } );
 368         } else {
 369                 reopen_logs();
 370                 $set_user->() if $set_user;
 371                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 372                 $refresh->();
 373         }
 374         $uid = $gid = undef;
 375         reopen_logs();
 376         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 377         $SIG{USR1} = *reopen_logs;
 378         $SIG{HUP} = $refresh;
 379         # this calls epoll_create:
 380         PublicInbox::Listener->new($_, $post_accept) for @listeners;
 381         Danga::Socket->EventLoop;
 382         $parent_pipe = undef;
 383 }
 384
 385
 386 sub daemon_run ($$$) {
 387         my ($default, $refresh, $post_accept) = @_;
 388         daemon_prepare($default);
 389         daemonize();
 390         daemon_loop($refresh, $post_accept);
 391 }
 392
 393 sub do_chown ($) {
 394         my ($path) = @_;
 395         if (defined $uid and !chown($uid, $gid, $path)) {
 396                 warn "could not chown $path: $!\n";
 397         }
 398 }
 399
 400 sub write_pid ($) {
 401         my ($path) = @_;
 402         Net::Server::Daemonize::create_pid_file($path);
 403         do_chown($path);
 404 }
 405
 406 1;