lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 STDOUT->autoflush(1);
  12 STDERR->autoflush(1);
  13 require Danga::Socket;
  14 require POSIX;
  15 require PublicInbox::Listener;
  16 my @CMD;
  17 my $set_user;
  18 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  19 my $worker_processes = 1;
  20 my @listeners;
  21 my %pids;
  22 my %listener_names;
  23 my $reexec_pid;
  24 my $cleanup;
  25 my ($uid, $gid);
  26 END { $cleanup->() if $cleanup };
  27
  28 sub daemon_prepare ($) {
  29         my ($default_listen) = @_;
  30         @CMD = ($0, @ARGV);
  31         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  32                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  33         my %opts = (
  34                 'l|listen=s' => \@cfg_listen,
  35                 '1|stdout=s' => \$stdout,
  36                 '2|stderr=s' => \$stderr,
  37                 'W|worker-processes=i' => \$worker_processes,
  38                 'P|pid-file=s' => \$pid_file,
  39                 'u|user=s' => \$user,
  40                 'g|group=s' => \$group,
  41                 'D|daemonize' => \$daemonize,
  42         );
  43         GetOptions(%opts) or die "bad command-line args\n";
  44
  45         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  46                 die "--pid-file cannot end with '.oldbin'\n";
  47         }
  48         @listeners = inherit();
  49         # ignore daemonize when inheriting
  50         $daemonize = undef if scalar @listeners;
  51
  52         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  53
  54         foreach my $l (@cfg_listen) {
  55                 next if $listener_names{$l}; # already inherited
  56                 my (%o, $sock_pkg);
  57                 if (index($l, '/') == 0) {
  58                         $sock_pkg = 'IO::Socket::UNIX';
  59                         eval "use $sock_pkg";
  60                         die $@ if $@;
  61                         %o = (Type => SOCK_STREAM, Peer => $l);
  62                         if (-S $l) {
  63                                 my $c = $sock_pkg->new(%o);
  64                                 if (!defined($c) && $!{ECONNREFUSED}) {
  65                                         unlink $l or die
  66 "failed to unlink stale socket=$l: $!\n";
  67                                 } # else: let the bind fail
  68                         }
  69                         $o{Local} = delete $o{Peer};
  70                 } else {
  71                         $sock_pkg = 'IO::Socket::INET6'; # works for IPv4, too
  72                         eval "use $sock_pkg";
  73                         die $@ if $@;
  74                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
  75                 }
  76                 $o{Listen} = 1024;
  77                 my $prev = umask 0000;
  78                 my $s = eval { $sock_pkg->new(%o) };
  79                 warn "error binding $l: $!\n" unless $s;
  80                 umask $prev;
  81
  82                 if ($s) {
  83                         $listener_names{sockname($s)} = $s;
  84                         push @listeners, $s;
  85                 }
  86         }
  87         die "No listeners bound\n" unless @listeners;
  88 }
  89
  90 sub daemonize () {
  91         chdir '/' or die "chdir failed: $!";
  92         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
  93
  94         return unless (defined $pid_file || defined $group || defined $user
  95                         || $daemonize);
  96
  97         eval { require Net::Server::Daemonize };
  98         if ($@) {
  99                 die
 100 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 101         }
 102
 103         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 104         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 105         if (defined $group) {
 106                 $gid = Net::Server::Daemonize::get_gid($group);
 107                 $gid = (split /\s+/, $gid)[0];
 108         } elsif (defined $uid) {
 109                 $gid = (getpwuid($uid))[3];
 110         }
 111
 112         # We change users in the worker to ensure upgradability,
 113         # The upgrade will create the ".oldbin" pid file in the
 114         # same directory as the given pid file.
 115         $uid and $set_user = sub {
 116                 $set_user = undef;
 117                 Net::Server::Daemonize::set_user($uid, $gid);
 118         };
 119
 120         if ($daemonize) {
 121                 my ($pid, $err) = do_fork();
 122                 die "could not fork: $err\n" unless defined $pid;
 123                 exit if $pid;
 124
 125                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 126                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 127                 POSIX::setsid();
 128                 ($pid, $err) = do_fork();
 129                 die "could not fork: $err\n" unless defined $pid;
 130                 exit if $pid;
 131         }
 132         if (defined $pid_file) {
 133                 write_pid($pid_file);
 134                 my $unlink_pid = $$;
 135                 $cleanup = sub {
 136                         $cleanup = undef; # avoid cyclic reference
 137                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 138                 };
 139         }
 140 }
 141
 142 sub worker_quit () {
 143         # killing again terminates immediately:
 144         exit unless @listeners;
 145
 146         $_->close foreach @listeners; # call Danga::Socket::close
 147         @listeners = ();
 148
 149         # give slow clients 30s to finish reading/writing whatever
 150         Danga::Socket->AddTimer(30, sub { exit });
 151
 152         # drop idle connections and try to quit gracefully
 153         Danga::Socket->SetPostLoopCallback(sub {
 154                 my ($dmap, undef) = @_;
 155                 my $n = 0;
 156
 157                 foreach my $s (values %$dmap) {
 158                         if ($s->can('busy') && $s->busy) {
 159                                 $n = 1;
 160                         } else {
 161                                 # close as much as possible, early as possible
 162                                 $s->close;
 163                         }
 164                 }
 165                 $n; # true: loop continues, false: loop breaks
 166         });
 167 }
 168
 169 sub reopen_logs {
 170         if ($stdout) {
 171                 open STDOUT, '>>', $stdout or
 172                         warn "failed to redirect stdout to $stdout: $!\n";
 173                 STDOUT->autoflush(1);
 174                 do_chown($stdout);
 175         }
 176         if ($stderr) {
 177                 open STDERR, '>>', $stderr or
 178                         warn "failed to redirect stderr to $stderr: $!\n";
 179                 STDERR->autoflush(1);
 180                 do_chown($stderr);
 181         }
 182 }
 183
 184 sub sockname ($) {
 185         my ($s) = @_;
 186         my $addr = getsockname($s) or return;
 187         my ($host, $port) = host_with_port($addr);
 188         if ($port == 0 && $host eq '127.0.0.1') {
 189                 my ($path) = Socket::sockaddr_un($addr);
 190                 return $path;
 191         }
 192         "$host:$port";
 193 }
 194
 195 sub host_with_port ($) {
 196         my ($addr) = @_;
 197         my ($port, $host);
 198
 199         # this eval will die on Unix sockets:
 200         eval {
 201                 if (length($addr) >= 28) {
 202                         require Socket6;
 203                         ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 204                         $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 205                         $host = "[$host]";
 206                 } else {
 207                         ($port, $host) = Socket::sockaddr_in($addr);
 208                         $host = Socket::inet_ntoa($host);
 209                 }
 210         };
 211         $@ ? ('127.0.0.1', 0) : ($host, $port);
 212 }
 213
 214 sub inherit () {
 215         return () if ($ENV{LISTEN_PID} || 0) != $$;
 216         my $fds = $ENV{LISTEN_FDS} or return ();
 217         my $end = $fds + 2; # LISTEN_FDS_START - 1
 218         my @rv = ();
 219         foreach my $fd (3..$end) {
 220                 my $s = IO::Handle->new_from_fd($fd, 'r');
 221                 if (my $k = sockname($s)) {
 222                         $listener_names{$k} = $s;
 223                         push @rv, $s;
 224                 } else {
 225                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 226                 }
 227         }
 228         @rv
 229 }
 230
 231 sub upgrade () {
 232         if ($reexec_pid) {
 233                 warn "upgrade in-progress: $reexec_pid\n";
 234                 return;
 235         }
 236         if (defined $pid_file) {
 237                 if ($pid_file =~ /\.oldbin\z/) {
 238                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 239                         return;
 240                 }
 241                 unlink_pid_file_safe_ish($$, $pid_file);
 242                 $pid_file .= '.oldbin';
 243                 write_pid($pid_file);
 244         }
 245         my ($pid, $err) = do_fork();
 246         unless (defined $pid) {
 247                 warn "fork failed: $err\n";
 248                 return;
 249         }
 250         if ($pid == 0) {
 251                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 252                 $ENV{LISTEN_FDS} = scalar @listeners;
 253                 $ENV{LISTEN_PID} = $$;
 254                 foreach my $s (@listeners) {
 255                         my $fl = fcntl($s, F_GETFD, 0);
 256                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 257                 }
 258                 exec @CMD;
 259                 die "Failed to exec: $!\n";
 260         }
 261         $reexec_pid = $pid;
 262 }
 263
 264 sub kill_workers ($) {
 265         my ($s) = @_;
 266
 267         while (my ($pid, $id) = each %pids) {
 268                 kill $s, $pid;
 269         }
 270 }
 271
 272 sub do_fork () {
 273         my $new = POSIX::SigSet->new;
 274         $new->fillset;
 275         my $old = POSIX::SigSet->new;
 276         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 277         my $pid = fork;
 278         my $err = $!;
 279         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 280         ($pid, $err);
 281 }
 282
 283 sub upgrade_aborted ($) {
 284         my ($p) = @_;
 285         warn "reexec PID($p) died with: $?\n";
 286         $reexec_pid = undef;
 287         return unless $pid_file;
 288
 289         my $file = $pid_file;
 290         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 291         unlink_pid_file_safe_ish($$, $pid_file);
 292         $pid_file = $file;
 293         eval { write_pid($pid_file) };
 294         warn $@, "\n" if $@;
 295 }
 296
 297 sub reap_children () {
 298         while (1) {
 299                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 300                 if (defined $reexec_pid && $p == $reexec_pid) {
 301                         upgrade_aborted($p);
 302                 } elsif (defined(my $id = delete $pids{$p})) {
 303                         warn "worker[$id] PID($p) died with: $?\n";
 304                 } elsif ($p > 0) {
 305                         warn "unknown PID($p) reaped: $?\n";
 306                 } else {
 307                         return;
 308                 }
 309         }
 310 }
 311
 312 sub unlink_pid_file_safe_ish ($$) {
 313         my ($unlink_pid, $file) = @_;
 314         return unless defined $unlink_pid && $unlink_pid == $$;
 315
 316         open my $fh, '<', $file or return;
 317         defined(my $read_pid = <$fh>) or return;
 318         chomp $read_pid;
 319         if ($read_pid == $unlink_pid) {
 320                 Net::Server::Daemonize::unlink_pid_file($file);
 321         }
 322 }
 323
 324 sub master_loop {
 325         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 326         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 327         IO::Handle::blocking($w, 0);
 328         my $set_workers = $worker_processes;
 329         my @caught;
 330         my $master_pid = $$;
 331         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 332                 $SIG{$s} = sub {
 333                         return if $$ != $master_pid;
 334                         push @caught, $s;
 335                         syswrite($w, '.');
 336                 };
 337         }
 338         reopen_logs();
 339         # main loop
 340         while (1) {
 341                 while (my $s = shift @caught) {
 342                         if ($s eq 'USR1') {
 343                                 reopen_logs();
 344                                 kill_workers($s);
 345                         } elsif ($s eq 'USR2') {
 346                                 upgrade();
 347                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 348                                 # drops pipes and causes children to die
 349                                 exit
 350                         } elsif ($s eq 'WINCH') {
 351                                 $worker_processes = 0;
 352                         } elsif ($s eq 'HUP') {
 353                                 $worker_processes = $set_workers;
 354                                 kill_workers($s);
 355                         } elsif ($s eq 'TTIN') {
 356                                 if ($set_workers > $worker_processes) {
 357                                         ++$worker_processes;
 358                                 } else {
 359                                         $worker_processes = ++$set_workers;
 360                                 }
 361                         } elsif ($s eq 'TTOU') {
 362                                 if ($set_workers > 0) {
 363                                         $worker_processes = --$set_workers;
 364                                 }
 365                         } elsif ($s eq 'CHLD') {
 366                                 reap_children();
 367                         }
 368                 }
 369
 370                 my $n = scalar keys %pids;
 371                 if ($n > $worker_processes) {
 372                         while (my ($k, $v) = each %pids) {
 373                                 kill('TERM', $k) if $v >= $worker_processes;
 374                         }
 375                         $n = $worker_processes;
 376                 }
 377                 foreach my $i ($n..($worker_processes - 1)) {
 378                         my ($pid, $err) = do_fork();
 379                         if (!defined $pid) {
 380                                 warn "failed to fork worker[$i]: $err\n";
 381                         } elsif ($pid == 0) {
 382                                 $set_user->() if $set_user;
 383                                 return $p0; # run normal work code
 384                         } else {
 385                                 warn "PID=$pid is worker[$i]\n";
 386                                 $pids{$pid} = $i;
 387                         }
 388                 }
 389                 # just wait on signal events here:
 390                 sysread($r, my $buf, 8);
 391         }
 392         exit # never gets here, just for documentation
 393 }
 394
 395 sub daemon_loop ($$) {
 396         my ($refresh, $post_accept) = @_;
 397         my $parent_pipe;
 398         if ($worker_processes > 0) {
 399                 $refresh->(); # preload by default
 400                 $parent_pipe = master_loop(); # returns if in child process
 401                 my $fd = fileno($parent_pipe);
 402                 Danga::Socket->AddOtherFds($fd => *worker_quit);
 403         } else {
 404                 reopen_logs();
 405                 $set_user->() if $set_user;
 406                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 407                 $refresh->();
 408         }
 409         $uid = $gid = undef;
 410         reopen_logs();
 411         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 412         $SIG{USR1} = *reopen_logs;
 413         $SIG{HUP} = $refresh;
 414         # this calls epoll_create:
 415         @listeners = map {
 416                 PublicInbox::Listener->new($_, $post_accept)
 417         } @listeners;
 418         Danga::Socket->EventLoop;
 419         $parent_pipe = undef;
 420 }
 421
 422
 423 sub run ($$$) {
 424         my ($default, $refresh, $post_accept) = @_;
 425         daemon_prepare($default);
 426         daemonize();
 427         daemon_loop($refresh, $post_accept);
 428 }
 429
 430 sub do_chown ($) {
 431         my ($path) = @_;
 432         if (defined $uid and !chown($uid, $gid, $path)) {
 433                 warn "could not chown $path: $!\n";
 434         }
 435 }
 436
 437 sub write_pid ($) {
 438         my ($path) = @_;
 439         Net::Server::Daemonize::create_pid_file($path);
 440         do_chown($path);
 441 }
 442
 443 1;