lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 use Cwd qw/abs_path/;
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 require PublicInbox::EvCleanup;
  19 require PublicInbox::Listener;
  20 require PublicInbox::ParentPipe;
  21 my @CMD;
  22 my ($set_user, $oldset, $newset);
  23 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  24 my $worker_processes = 1;
  25 my @listeners;
  26 my %pids;
  27 my %listener_names; # sockname => IO::Handle
  28 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  29 my $reexec_pid;
  30 my $cleanup;
  31 my ($uid, $gid);
  32 my ($default_cert, $default_key);
  33 END { $cleanup->() if $cleanup };
  34 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps' );
  35 my %KNOWN_STARTTLS = ( 119 => 'nntp' );
  36
  37 sub accept_tls_opt ($) {
  38         my ($opt_str) = @_;
  39         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  40         require PublicInbox::TLS;
  41         my $o = {};
  42         # allow ',' as delimiter since '&' is shell-unfriendly
  43         foreach (split(/[,&]/, $opt_str)) {
  44                 my ($k, $v) = split(/=/, $_, 2);
  45                 push @{$o->{$k} ||= []}, $v;
  46         }
  47
  48         # key may be a part of cert.  At least
  49         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  50         $o->{cert} //= [ $default_cert ];
  51         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  52         my %ctx_opt = (SSL_server => 1);
  53         # parse out hostname:/path/to/ mappings:
  54         foreach my $k (qw(cert key)) {
  55                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  56                 foreach my $path (@{$o->{$k}}) {
  57                         my $host = '';
  58                         $path =~ s/\A([^:]+):// and $host = $1;
  59                         $x->{$host} = $path;
  60                 }
  61         }
  62         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  63                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  64
  65         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  66         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  67         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  68         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  69         if ($mode && $ctx->{context}) {
  70                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  71                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  72         }
  73
  74         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  75 }
  76
  77 sub daemon_prepare ($) {
  78         my ($default_listen) = @_;
  79         $oldset = POSIX::SigSet->new();
  80         $newset = POSIX::SigSet->new();
  81         $newset->fillset or die "fillset: $!";
  82         sigprocmask(SIG_SETMASK, $newset, $oldset) or die "sigprocmask: $!";
  83         @CMD = ($0, @ARGV);
  84         my %opts = (
  85                 'l|listen=s' => \@cfg_listen,
  86                 '1|stdout=s' => \$stdout,
  87                 '2|stderr=s' => \$stderr,
  88                 'W|worker-processes=i' => \$worker_processes,
  89                 'P|pid-file=s' => \$pid_file,
  90                 'u|user=s' => \$user,
  91                 'g|group=s' => \$group,
  92                 'D|daemonize' => \$daemonize,
  93                 'cert=s' => \$default_cert,
  94                 'key=s' => \$default_key,
  95         );
  96         GetOptions(%opts) or die "bad command-line args\n";
  97
  98         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  99                 die "--pid-file cannot end with '.oldbin'\n";
 100         }
 101         @listeners = inherit();
 102
 103         # allow socket-activation users to set certs once and not
 104         # have to configure each socket:
 105         my @inherited_names = keys(%listener_names) if defined($default_cert);
 106
 107         # ignore daemonize when inheriting
 108         $daemonize = undef if scalar @listeners;
 109
 110         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 111
 112         foreach my $l (@cfg_listen) {
 113                 my $orig = $l;
 114                 my $scheme = '';
 115                 if ($l =~ s!\A([^:]+)://!!) {
 116                         $scheme = $1;
 117                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 118                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 119                         $scheme = $s if defined $s;
 120                 }
 121                 if ($l =~ s!/?\?(.+)\z!!) {
 122                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 123                 } elsif (defined($default_cert)) {
 124                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 125                 } elsif ($scheme =~ /\A(?:nntps|https)\z/) {
 126                         die "$orig specified w/o cert=\n";
 127                 }
 128                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 129
 130                 next if $listener_names{$l}; # already inherited
 131                 my (%o, $sock_pkg);
 132                 if (index($l, '/') == 0) {
 133                         $sock_pkg = 'IO::Socket::UNIX';
 134                         eval "use $sock_pkg";
 135                         die $@ if $@;
 136                         %o = (Type => SOCK_STREAM, Peer => $l);
 137                         if (-S $l) {
 138                                 my $c = $sock_pkg->new(%o);
 139                                 if (!defined($c) && $!{ECONNREFUSED}) {
 140                                         unlink $l or die
 141 "failed to unlink stale socket=$l: $!\n";
 142                                 } # else: let the bind fail
 143                         }
 144                         $o{Local} = delete $o{Peer};
 145                 } else {
 146                         # both work for IPv4, too
 147                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 148                                 $sock_pkg = $_;
 149                                 eval "use $sock_pkg";
 150                                 $@ or last;
 151                         }
 152                         die $@ if $@;
 153                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 154                 }
 155                 $o{Listen} = 1024;
 156                 my $prev = umask 0000;
 157                 my $s = eval { $sock_pkg->new(%o) };
 158                 warn "error binding $l: $! ($@)\n" unless $s;
 159                 umask $prev;
 160                 if ($s) {
 161                         $listener_names{sockname($s)} = $s;
 162                         $s->blocking(0);
 163                         push @listeners, $s;
 164                 }
 165         }
 166
 167         # cert/key options in @cfg_listen takes precedence when inheriting,
 168         # but map well-known inherited ports if --listen isn't specified
 169         # at all
 170         for my $sockname (@inherited_names) {
 171                 $sockname =~ /:([0-9]+)\z/ or next;
 172                 if (my $scheme = $KNOWN_TLS{$1}) {
 173                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 174                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 175                         next if $tls_opt{"$scheme://$sockname"};
 176                         $tls_opt{''} ||= accept_tls_opt('');
 177                 }
 178         }
 179
 180         die "No listeners bound\n" unless @listeners;
 181 }
 182
 183 sub check_absolute ($$) {
 184         my ($var, $val) = @_;
 185         if (defined $val && index($val, '/') != 0) {
 186                 die
 187 "--$var must be an absolute path when using --daemonize: $val\n";
 188         }
 189 }
 190
 191 sub daemonize () {
 192         if ($daemonize) {
 193                 foreach my $i (0..$#ARGV) {
 194                         my $arg = $ARGV[$i];
 195                         next unless -e $arg;
 196                         $ARGV[$i] = abs_path($arg);
 197                 }
 198                 check_absolute('stdout', $stdout);
 199                 check_absolute('stderr', $stderr);
 200                 check_absolute('pid-file', $pid_file);
 201
 202                 chdir '/' or die "chdir failed: $!";
 203         }
 204
 205         return unless (defined $pid_file || defined $group || defined $user
 206                         || $daemonize);
 207
 208         eval { require Net::Server::Daemonize };
 209         if ($@) {
 210                 die
 211 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 212         }
 213
 214         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 215         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 216         if (defined $group) {
 217                 $gid = Net::Server::Daemonize::get_gid($group);
 218                 $gid = (split /\s+/, $gid)[0];
 219         } elsif (defined $uid) {
 220                 $gid = (getpwuid($uid))[3];
 221         }
 222
 223         # We change users in the worker to ensure upgradability,
 224         # The upgrade will create the ".oldbin" pid file in the
 225         # same directory as the given pid file.
 226         $uid and $set_user = sub {
 227                 $set_user = undef;
 228                 Net::Server::Daemonize::set_user($uid, $gid);
 229         };
 230
 231         if ($daemonize) {
 232                 my $pid = fork;
 233                 die "could not fork: $!\n" unless defined $pid;
 234                 exit if $pid;
 235
 236                 open(STDIN, '+<', '/dev/null') or
 237                                         die "redirect stdin failed: $!\n";
 238                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 239                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 240                 POSIX::setsid();
 241                 $pid = fork;
 242                 die "could not fork: $!\n" unless defined $pid;
 243                 exit if $pid;
 244         }
 245         if (defined $pid_file) {
 246                 write_pid($pid_file);
 247                 my $unlink_pid = $$;
 248                 $cleanup = sub {
 249                         $cleanup = undef; # avoid cyclic reference
 250                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 251                 };
 252         }
 253 }
 254
 255 sub shrink_pipes {
 256         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ, 4096: page size
 257                 fcntl($_, 1031, 4096) for @_;
 258         }
 259 }
 260
 261 sub worker_quit {
 262         # killing again terminates immediately:
 263         exit unless @listeners;
 264
 265         $_->close foreach @listeners; # call PublicInbox::DS::close
 266         @listeners = ();
 267
 268         # create a lazy self-pipe which kicks us out of the EventLoop
 269         # so DS::PostEventLoop can fire
 270         if (pipe(my ($r, $w))) {
 271                 shrink_pipes($w);
 272
 273                 # shrink_pipes == noop
 274                 PublicInbox::ParentPipe->new($r, *shrink_pipes);
 275                 close $w; # wake up from the event loop
 276         } else {
 277                 warn "E: pipe failed ($!), quit unreliable\n";
 278         }
 279         my $proc_name;
 280         my $warn = 0;
 281         # drop idle connections and try to quit gracefully
 282         PublicInbox::DS->SetPostLoopCallback(sub {
 283                 my ($dmap, undef) = @_;
 284                 my $n = 0;
 285                 my $now = now();
 286
 287                 foreach my $s (values %$dmap) {
 288                         $s->can('busy') or next;
 289                         if ($s->busy($now)) {
 290                                 ++$n;
 291                         } else {
 292                                 # close as much as possible, early as possible
 293                                 $s->close;
 294                         }
 295                 }
 296                 if ($n) {
 297                         if (($warn + 5) < now()) {
 298                                 warn "$$ quitting, $n client(s) left\n";
 299                                 $warn = now();
 300                         }
 301                         unless (defined $proc_name) {
 302                                 $proc_name = (split(/\s+/, $0))[0];
 303                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 304                         }
 305                         $0 = "$proc_name quitting, $n client(s) left";
 306                 }
 307                 $n; # true: loop continues, false: loop breaks
 308         });
 309 }
 310
 311 sub reopen_logs {
 312         if ($stdout) {
 313                 open STDOUT, '>>', $stdout or
 314                         warn "failed to redirect stdout to $stdout: $!\n";
 315                 STDOUT->autoflush(1);
 316                 do_chown($stdout);
 317         }
 318         if ($stderr) {
 319                 open STDERR, '>>', $stderr or
 320                         warn "failed to redirect stderr to $stderr: $!\n";
 321                 STDERR->autoflush(1);
 322                 do_chown($stderr);
 323         }
 324 }
 325
 326 sub sockname ($) {
 327         my ($s) = @_;
 328         my $addr = getsockname($s) or return;
 329         my ($host, $port) = host_with_port($addr);
 330         if ($port == 0 && $host eq '127.0.0.1') {
 331                 my ($path) = Socket::sockaddr_un($addr);
 332                 return $path;
 333         }
 334         "$host:$port";
 335 }
 336
 337 sub unpack_ipv6 ($) {
 338         my ($addr) = @_;
 339         my ($port, $host);
 340
 341         # Socket.pm in Perl 5.14+ supports IPv6:
 342         eval {
 343                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 344                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 345         };
 346
 347         if ($@) {
 348                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 349                 # Socket6, so it may be installed on our system, already
 350                 # (otherwise die here):
 351                 require Socket6;
 352
 353                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 354                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 355         }
 356         ($host, $port);
 357 }
 358
 359 sub host_with_port ($) {
 360         my ($addr) = @_;
 361         my ($port, $host);
 362
 363         # this eval will die on Unix sockets:
 364         eval {
 365                 if (length($addr) >= 28) {
 366                         ($host, $port) = unpack_ipv6($addr);
 367                         $host = "[$host]";
 368                 } else {
 369                         ($port, $host) = Socket::sockaddr_in($addr);
 370                         $host = Socket::inet_ntoa($host);
 371                 }
 372         };
 373         $@ ? ('127.0.0.1', 0) : ($host, $port);
 374 }
 375
 376 sub inherit () {
 377         return () if ($ENV{LISTEN_PID} || 0) != $$;
 378         my $fds = $ENV{LISTEN_FDS} or return ();
 379         my $end = $fds + 2; # LISTEN_FDS_START - 1
 380         my @rv = ();
 381         foreach my $fd (3..$end) {
 382                 my $s = IO::Handle->new_from_fd($fd, 'r');
 383                 if (my $k = sockname($s)) {
 384                         if ($s->blocking) {
 385                                 $s->blocking(0);
 386                                 warn <<"";
 387 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 388 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 389 processes when multiple service instances start.
 390
 391                         }
 392                         $listener_names{$k} = $s;
 393                         push @rv, $s;
 394                 } else {
 395                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 396                 }
 397         }
 398         @rv
 399 }
 400
 401 sub upgrade () {
 402         if ($reexec_pid) {
 403                 warn "upgrade in-progress: $reexec_pid\n";
 404                 return;
 405         }
 406         if (defined $pid_file) {
 407                 if ($pid_file =~ /\.oldbin\z/) {
 408                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 409                         return;
 410                 }
 411                 unlink_pid_file_safe_ish($$, $pid_file);
 412                 $pid_file .= '.oldbin';
 413                 write_pid($pid_file);
 414         }
 415         my $pid = fork;
 416         unless (defined $pid) {
 417                 warn "fork failed: $!\n";
 418                 return;
 419         }
 420         if ($pid == 0) {
 421                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 422                 $ENV{LISTEN_FDS} = scalar @listeners;
 423                 $ENV{LISTEN_PID} = $$;
 424                 foreach my $s (@listeners) {
 425                         my $fl = fcntl($s, F_GETFD, 0);
 426                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 427                 }
 428                 exec @CMD;
 429                 die "Failed to exec: $!\n";
 430         }
 431         $reexec_pid = $pid;
 432 }
 433
 434 sub kill_workers ($) {
 435         my ($s) = @_;
 436
 437         while (my ($pid, $id) = each %pids) {
 438                 kill $s, $pid;
 439         }
 440 }
 441
 442 sub upgrade_aborted ($) {
 443         my ($p) = @_;
 444         warn "reexec PID($p) died with: $?\n";
 445         $reexec_pid = undef;
 446         return unless $pid_file;
 447
 448         my $file = $pid_file;
 449         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 450         unlink_pid_file_safe_ish($$, $pid_file);
 451         $pid_file = $file;
 452         eval { write_pid($pid_file) };
 453         warn $@, "\n" if $@;
 454 }
 455
 456 sub reap_children () {
 457         while (1) {
 458                 my $p = waitpid(-1, WNOHANG) or return;
 459                 if (defined $reexec_pid && $p == $reexec_pid) {
 460                         upgrade_aborted($p);
 461                 } elsif (defined(my $id = delete $pids{$p})) {
 462                         warn "worker[$id] PID($p) died with: $?\n";
 463                 } elsif ($p > 0) {
 464                         warn "unknown PID($p) reaped: $?\n";
 465                 } else {
 466                         return;
 467                 }
 468         }
 469 }
 470
 471 sub unlink_pid_file_safe_ish ($$) {
 472         my ($unlink_pid, $file) = @_;
 473         return unless defined $unlink_pid && $unlink_pid == $$;
 474
 475         open my $fh, '<', $file or return;
 476         local $/ = "\n";
 477         defined(my $read_pid = <$fh>) or return;
 478         chomp $read_pid;
 479         if ($read_pid == $unlink_pid) {
 480                 Net::Server::Daemonize::unlink_pid_file($file);
 481         }
 482 }
 483
 484 sub master_loop {
 485         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 486         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 487         shrink_pipes($w, $p1);
 488
 489         IO::Handle::blocking($w, 0);
 490         my $set_workers = $worker_processes;
 491         my @caught;
 492         my $master_pid = $$;
 493         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 494                 $SIG{$s} = sub {
 495                         return if $$ != $master_pid;
 496                         push @caught, $s;
 497                         syswrite($w, '.');
 498                 };
 499         }
 500         sigprocmask(SIG_SETMASK, $oldset) or die "sigprocmask: $!";
 501         reopen_logs();
 502         # main loop
 503         my $quit = 0;
 504         while (1) {
 505                 while (my $s = shift @caught) {
 506                         if ($s eq 'USR1') {
 507                                 reopen_logs();
 508                                 kill_workers($s);
 509                         } elsif ($s eq 'USR2') {
 510                                 upgrade();
 511                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 512                                 exit if $quit++;
 513                                 kill_workers($s);
 514                         } elsif ($s eq 'WINCH') {
 515                                 if (-t STDIN || -t STDOUT || -t STDERR) {
 516                                         warn
 517 "ignoring SIGWINCH since we are not daemonized\n";
 518                                         $SIG{WINCH} = 'IGNORE';
 519                                 } else {
 520                                         $worker_processes = 0;
 521                                 }
 522                         } elsif ($s eq 'HUP') {
 523                                 $worker_processes = $set_workers;
 524                                 kill_workers($s);
 525                         } elsif ($s eq 'TTIN') {
 526                                 if ($set_workers > $worker_processes) {
 527                                         ++$worker_processes;
 528                                 } else {
 529                                         $worker_processes = ++$set_workers;
 530                                 }
 531                         } elsif ($s eq 'TTOU') {
 532                                 if ($set_workers > 0) {
 533                                         $worker_processes = --$set_workers;
 534                                 }
 535                         } elsif ($s eq 'CHLD') {
 536                                 reap_children();
 537                         }
 538                 }
 539
 540                 my $n = scalar keys %pids;
 541                 if ($quit) {
 542                         exit if $n == 0;
 543                         $set_workers = $worker_processes = $n = 0;
 544                 }
 545
 546                 if ($n > $worker_processes) {
 547                         while (my ($k, $v) = each %pids) {
 548                                 kill('TERM', $k) if $v >= $worker_processes;
 549                         }
 550                         $n = $worker_processes;
 551                 }
 552                 sigprocmask(SIG_SETMASK, $newset) or die "sigprocmask: $!";
 553                 foreach my $i ($n..($worker_processes - 1)) {
 554                         my $pid = fork;
 555                         if (!defined $pid) {
 556                                 warn "failed to fork worker[$i]: $!\n";
 557                         } elsif ($pid == 0) {
 558                                 $set_user->() if $set_user;
 559                                 return $p0; # run normal work code
 560                         } else {
 561                                 warn "PID=$pid is worker[$i]\n";
 562                                 $pids{$pid} = $i;
 563                         }
 564                 }
 565                 sigprocmask(SIG_SETMASK, $oldset) or die "sigprocmask: $!";
 566                 # just wait on signal events here:
 567                 sysread($r, my $buf, 8);
 568         }
 569         exit # never gets here, just for documentation
 570 }
 571
 572 sub tls_start_cb ($$) {
 573         my ($opt, $orig_post_accept) = @_;
 574         sub {
 575                 my ($io, $addr, $srv) = @_;
 576                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 577                 $orig_post_accept->($ssl, $addr, $srv);
 578         }
 579 }
 580
 581 sub defer_accept ($$) {
 582         my ($s, $af_name) = @_;
 583         return unless defined $af_name;
 584         if ($^O eq 'linux') {
 585                 my $x = getsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT());
 586                 return unless defined $x; # may be Unix socket
 587                 my $sec = unpack('i', $x);
 588                 return if $sec > 0; # systemd users may set a higher value
 589                 setsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT(), 1);
 590         } elsif ($^O eq 'freebsd') {
 591                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 592                 return if defined $x; # don't change if set
 593                 my $accf_arg = pack('a16a240', $af_name, '');
 594                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 595         }
 596 }
 597
 598 sub daemon_loop ($$$$) {
 599         my ($refresh, $post_accept, $nntpd, $af_default) = @_;
 600         PublicInbox::EvCleanup::enable(); # early for $refresh
 601         my %post_accept;
 602         while (my ($k, $v) = each %tls_opt) {
 603                 if ($k =~ s!\A(?:nntps|https)://!!) {
 604                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 605                 } elsif ($nntpd) { # STARTTLS, $k eq '' is OK
 606                         $nntpd->{accept_tls} = $v;
 607                 }
 608         }
 609         my $parent_pipe;
 610         if ($worker_processes > 0) {
 611                 $refresh->(); # preload by default
 612                 my $fh = master_loop(); # returns if in child process
 613                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 614         } else {
 615                 reopen_logs();
 616                 $set_user->() if $set_user;
 617                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 618                 $refresh->();
 619         }
 620         $uid = $gid = undef;
 621         reopen_logs();
 622         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 623         $SIG{USR1} = *reopen_logs;
 624         $SIG{HUP} = $refresh;
 625         $SIG{CHLD} = 'DEFAULT';
 626         $SIG{$_} = 'IGNORE' for qw(USR2 TTIN TTOU WINCH);
 627         @listeners = map {;
 628                 my $tls_cb = $post_accept{sockname($_)};
 629
 630                 # NNTPS, HTTPS, HTTP, and POP3S are client-first traffic
 631                 # NNTP and POP3 are server-first
 632                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 633
 634                 # this calls epoll_create:
 635                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 636         } @listeners;
 637         sigprocmask(SIG_SETMASK, $oldset) or die "sigprocmask: $!";
 638         PublicInbox::DS->EventLoop;
 639         $parent_pipe = undef;
 640 }
 641
 642
 643 sub run ($$$;$) {
 644         my ($default, $refresh, $post_accept, $nntpd) = @_;
 645         daemon_prepare($default);
 646         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 647         daemonize();
 648         daemon_loop($refresh, $post_accept, $nntpd, $af_default);
 649 }
 650
 651 sub do_chown ($) {
 652         my ($path) = @_;
 653         if (defined $uid and !chown($uid, $gid, $path)) {
 654                 warn "could not chown $path: $!\n";
 655         }
 656 }
 657
 658 sub write_pid ($) {
 659         my ($path) = @_;
 660         Net::Server::Daemonize::create_pid_file($path);
 661         do_chown($path);
 662 }
 663
 664 1;