lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use File::Spec;
  14 use POSIX qw(WNOHANG :signal_h);
  15 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::Git;
  23 use PublicInbox::GitAsyncCat;
  24 use PublicInbox::Eml;
  25 use PublicInbox::Config;
  26 our $SO_ACCEPTFILTER = 0x1000;
  27 my @CMD;
  28 my ($set_user, $oldset);
  29 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  30 my $worker_processes = 1;
  31 my @listeners;
  32 my (%pids, %logs);
  33 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL::SSL_Context->new
  34 my $reexec_pid;
  35 my ($uid, $gid);
  36 my ($default_cert, $default_key);
  37 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  38 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  39 my %SCHEME2PORT = map { $KNOWN_TLS{$_} => $_ + 0 } keys %KNOWN_TLS;
  40 for (keys %KNOWN_STARTTLS) { $SCHEME2PORT{$KNOWN_STARTTLS{$_}} = $_ + 0 }
  41 $SCHEME2PORT{http} = 80;
  42
  43 sub listener_opt ($) {
  44         my ($str) = @_; # opt1=val1,opt2=val2 (opt may repeat for multi-value)
  45         my $o = {};
  46         # allow ',' as delimiter since '&' is shell-unfriendly
  47         for (split(/[,&]/, $str)) {
  48                 my ($k, $v) = split(/=/, $_, 2);
  49                 push @{$o->{$k}}, $v;
  50         }
  51
  52         # key may be a part of cert.  At least
  53         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  54         $o->{cert} //= [ $default_cert ] if defined($default_cert);
  55         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  56         $o;
  57 }
  58
  59 sub check_absolute ($$) {
  60         my ($var, $val) = @_;
  61         die <<EOM if index($val // '/', '/') != 0;
  62 $var must be an absolute path when using --daemonize: $val
  63 EOM
  64 }
  65
  66 sub accept_tls_opt ($) {
  67         my ($opt) = @_;
  68         my $o = ref($opt) eq 'HASH' ? $opt : listener_opt($opt);
  69         return if !defined($o->{cert});
  70         require PublicInbox::TLS;
  71         my @ctx_opt;
  72         # parse out hostname:/path/to/ mappings:
  73         for my $k (qw(cert key)) {
  74                 $o->{$k} // next;
  75                 push(@ctx_opt, "SSL_${k}_file", {});
  76                 foreach my $path (@{$o->{$k}}) {
  77                         my $host = '';
  78                         $path =~ s/\A([^:]+):// and $host = $1;
  79                         $ctx_opt[-1]->{$host} = $path;
  80                         check_absolute($k, $path) if $daemonize;
  81                 }
  82         }
  83         \@ctx_opt;
  84 }
  85
  86 sub do_chown ($) {
  87         $uid // return;
  88         my ($path) = @_;
  89         chown($uid, $gid, $path) or warn "chown $path: $!\n";
  90 }
  91
  92 sub open_log_path ($$) { # my ($fh, $path) = @_; # $_[0] is modified
  93         open $_[0], '>>', $_[1] or die "open(>> $_[1]): $!";
  94         $_[0]->autoflush(1);
  95         do_chown($_[1]);
  96         $_[0];
  97 }
  98
  99 sub load_mod ($;$$) {
 100         my ($scheme, $opt, $addr) = @_;
 101         my $modc = "PublicInbox::\U$scheme";
 102         $modc =~ s/S\z//;
 103         my $mod = $modc.'D';
 104         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
 105         die $@ if $@;
 106         my %xn;
 107         my $tlsd = $xn{tlsd} = $mod->new;
 108         my %env = map {
 109                 substr($_, length('env.')) => $opt->{$_}->[-1];
 110         } grep(/\Aenv\./, keys %$opt);
 111         $xn{refresh} = sub {
 112                 my ($sig) = @_;
 113                 local @ENV{keys %env} = values %env;
 114                 $tlsd->refresh_groups($sig);
 115         };
 116         $xn{post_accept} = $tlsd->can('post_accept_cb') ?
 117                         $tlsd->post_accept_cb : sub { $modc->new($_[0], $tlsd) };
 118         my @paths = qw(out err);
 119         if ($modc eq 'PublicInbox::HTTP') {
 120                 @paths = qw(err);
 121                 $xn{af_default} = 'httpready';
 122                 if (my $p = $opt->{psgi}) {
 123                         die "multiple psgi= options specified\n" if @$p > 1;
 124                         check_absolute('psgi=', $p->[0]) if $daemonize;
 125                         $tlsd->{psgi} = $p->[0];
 126                         warn "# $scheme://$addr psgi=$p->[0]\n";
 127                 }
 128         }
 129         for my $f (@paths) {
 130                 my $p = $opt->{$f} or next;
 131                 die "multiple $f= options specified\n" if @$p > 1;
 132                 check_absolute("$f=", $p->[0]) if $daemonize;
 133                 $p = File::Spec->canonpath($p->[0]);
 134                 $tlsd->{$f} = $logs{$p} //= open_log_path(my $fh, $p);
 135                 warn "# $scheme://$addr $f=$p\n";
 136         }
 137         \%xn;
 138 }
 139
 140 sub daemon_prepare ($$) {
 141         my ($default_listen, $xnetd) = @_;
 142         my $listener_names = {}; # sockname => IO::Handle
 143         $oldset = PublicInbox::DS::block_signals();
 144         @CMD = ($0, @ARGV);
 145         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
 146         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 147         my $help = <<EOF;
 148 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 149
 150 options:
 151
 152   -l ADDRESS    address to listen on$dh
 153   --cert=FILE   default SSL/TLS certificate
 154   --key=FILE    default SSL/TLS certificate
 155   -W WORKERS    number of worker processes to spawn (default: 1)
 156
 157 See public-inbox-daemon(8) and $prog(1) man pages for more.
 158 EOF
 159         my %opt = (
 160                 'l|listen=s' => \@cfg_listen,
 161                 '1|stdout=s' => \$stdout,
 162                 '2|stderr=s' => \$stderr,
 163                 'W|worker-processes=i' => \$worker_processes,
 164                 'P|pid-file=s' => \$pid_file,
 165                 'u|user=s' => \$user,
 166                 'g|group=s' => \$group,
 167                 'D|daemonize' => \$daemonize,
 168                 'cert=s' => \$default_cert,
 169                 'key=s' => \$default_key,
 170                 'help|h' => \(my $show_help),
 171         );
 172         GetOptions(%opt) or die $help;
 173         if ($show_help) { print $help; exit 0 };
 174
 175         $_ = File::Spec->canonpath($_ // next) for ($stdout, $stderr);
 176         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 177                 die "--pid-file cannot end with '.oldbin'\n";
 178         }
 179         @listeners = inherit($listener_names);
 180
 181         # allow socket-activation users to set certs once and not
 182         # have to configure each socket:
 183         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 184
 185         # ignore daemonize when inheriting
 186         $daemonize = undef if scalar @listeners;
 187
 188         unless (@listeners || @cfg_listen) {
 189                 $default_listen // die "no listeners specified\n";
 190                 push @cfg_listen, $default_listen
 191         }
 192
 193         foreach my $l (@cfg_listen) {
 194                 my $orig = $l;
 195                 my ($scheme, $port, $opt);
 196
 197                 $l =~ s!\A([a-z0-9]+)://!! and $scheme = $1;
 198                 (!$scheme && ($default_listen // '') =~ m!\A([^:]+)://!) and
 199                         $scheme = $1;
 200                 if ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9]+)/) {
 201                         $port = $1 + 0;
 202                         $scheme //= $KNOWN_TLS{$port} // $KNOWN_STARTTLS{$port};
 203                 }
 204                 $scheme or die "unable to determine URL scheme of $orig\n";
 205                 if (!defined($port) && index($l, '/') != 0) { # unix socket
 206                         $port = $SCHEME2PORT{$scheme} //
 207                                 die "no port in listen=$orig\n";
 208                         $l =~ s!\A([^/]+)!$1:$port! or
 209                                 die "unable to add port=$port to $l\n";
 210                 }
 211                 $l =~ s!/\z!!; # chop one trailing slash
 212                 if ($l =~ s!/?\?(.+)\z!!) {
 213                         $opt = listener_opt($1);
 214                         $tls_opt{"$scheme://$l"} = accept_tls_opt($opt);
 215                 } elsif (defined($default_cert)) {
 216                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 217                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 218                         die "$orig specified w/o cert=\n";
 219                 }
 220                 if ($listener_names->{$l}) { # already inherited
 221                         $xnetd->{$l} = load_mod($scheme, $opt, $l);
 222                         next;
 223                 }
 224                 my (%o, $sock_pkg);
 225                 if (index($l, '/') == 0) {
 226                         $sock_pkg = 'IO::Socket::UNIX';
 227                         eval "use $sock_pkg";
 228                         die $@ if $@;
 229                         %o = (Type => SOCK_STREAM, Peer => $l);
 230                         if (-S $l) {
 231                                 my $c = $sock_pkg->new(%o);
 232                                 if (!defined($c) && $!{ECONNREFUSED}) {
 233                                         unlink $l or die
 234 "failed to unlink stale socket=$l: $!\n";
 235                                 } # else: let the bind fail
 236                         }
 237                         $o{Local} = delete $o{Peer};
 238                 } else {
 239                         # both work for IPv4, too
 240                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 241                                 $sock_pkg = $_;
 242                                 eval "use $sock_pkg";
 243                                 $@ or last;
 244                         }
 245                         die $@ if $@;
 246                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 247                 }
 248                 $o{Listen} = 1024;
 249                 my $prev = umask 0000;
 250                 my $s = eval { $sock_pkg->new(%o) } or
 251                         warn "error binding $l: $! ($@)\n";
 252                 umask $prev;
 253                 $s // next;
 254                 $s->blocking(0);
 255                 my $sockname = sockname($s);
 256                 warn "# bound $scheme://$sockname\n";
 257                 $xnetd->{$sockname} //= load_mod($scheme);
 258                 $listener_names->{$sockname} = $s;
 259                 push @listeners, $s;
 260         }
 261
 262         # cert/key options in @cfg_listen takes precedence when inheriting,
 263         # but map well-known inherited ports if --listen isn't specified
 264         # at all
 265         for my $sockname (@inherited_names) {
 266                 $sockname =~ /:([0-9]+)\z/ or next;
 267                 if (my $scheme = $KNOWN_TLS{$1}) {
 268                         $xnetd->{$sockname} //= load_mod($scheme);
 269                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 270                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 271                         $xnetd->{$sockname} //= load_mod($scheme);
 272                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 273                         $tls_opt{''} ||= accept_tls_opt('');
 274                 }
 275         }
 276         my @d;
 277         while (my ($k, $v) = each %tls_opt) { push(@d, $k) if !defined($v) }
 278         delete @tls_opt{@d};
 279         die "No listeners bound\n" unless @listeners;
 280 }
 281
 282 sub daemonize () {
 283         if ($daemonize) {
 284                 require Cwd;
 285                 foreach my $i (0..$#ARGV) {
 286                         my $arg = $ARGV[$i];
 287                         next unless -e $arg;
 288                         $ARGV[$i] = Cwd::abs_path($arg);
 289                 }
 290                 check_absolute('--stdout', $stdout);
 291                 check_absolute('--stderr', $stderr);
 292                 check_absolute('--pid-file', $pid_file);
 293                 check_absolute('--cert', $default_cert);
 294                 check_absolute('--key', $default_key);
 295
 296                 chdir '/' or die "chdir failed: $!";
 297         }
 298         if (defined($pid_file) || defined($group) || defined($user)) {
 299                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 300 Net::Server required for --pid-file, --group, --user
 301 $@
 302 EOF
 303         }
 304         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 305         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 306         if (defined $group) {
 307                 $gid = Net::Server::Daemonize::get_gid($group);
 308                 $gid = (split /\s+/, $gid)[0];
 309         } elsif (defined $uid) {
 310                 $gid = (getpwuid($uid))[3];
 311         }
 312
 313         # We change users in the worker to ensure upgradability,
 314         # The upgrade will create the ".oldbin" pid file in the
 315         # same directory as the given pid file.
 316         $uid and $set_user = sub {
 317                 $set_user = undef;
 318                 Net::Server::Daemonize::set_user($uid, $gid);
 319         };
 320
 321         if ($daemonize) {
 322                 my $pid = fork // die "fork: $!";
 323                 exit if $pid;
 324
 325                 open(STDIN, '+<', '/dev/null') or
 326                                         die "redirect stdin failed: $!\n";
 327                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 328                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 329                 POSIX::setsid();
 330                 $pid = fork // die "fork: $!";
 331                 exit if $pid;
 332         }
 333         return unless defined $pid_file;
 334
 335         write_pid($pid_file);
 336         # for ->DESTROY:
 337         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 338 }
 339
 340 sub worker_quit { # $_[0] = signal name or number (unused)
 341         # killing again terminates immediately:
 342         exit unless @listeners;
 343
 344         $_->close foreach @listeners; # call PublicInbox::DS::close
 345         @listeners = ();
 346         my $proc_name;
 347         my $warn = 0;
 348         # drop idle connections and try to quit gracefully
 349         PublicInbox::DS->SetPostLoopCallback(sub {
 350                 my ($dmap, undef) = @_;
 351                 my $n = 0;
 352                 my $now = now();
 353                 for my $s (values %$dmap) {
 354                         $s->can('busy') or next;
 355                         if ($s->busy) {
 356                                 ++$n;
 357                         } else { # close as much as possible, early as possible
 358                                 $s->close;
 359                         }
 360                 }
 361                 if ($n) {
 362                         if (($warn + 5) < now()) {
 363                                 warn "$$ quitting, $n client(s) left\n";
 364                                 $warn = now();
 365                         }
 366                         unless (defined $proc_name) {
 367                                 $proc_name = (split(/\s+/, $0))[0];
 368                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 369                         }
 370                         $0 = "$proc_name quitting, $n client(s) left";
 371                 }
 372                 $n; # true: loop continues, false: loop breaks
 373         });
 374 }
 375
 376 sub reopen_logs {
 377         $logs{$stdout} //= \*STDOUT if defined $stdout;
 378         $logs{$stderr} //= \*STDERR if defined $stderr;
 379         while (my ($p, $fh) = each %logs) { open_log_path($fh, $p) }
 380 }
 381
 382 sub sockname ($) {
 383         my ($s) = @_;
 384         my $addr = getsockname($s) or return;
 385         my ($host, $port) = host_with_port($addr);
 386         if ($port == 0 && $host eq '127.0.0.1') {
 387                 my ($path) = Socket::sockaddr_un($addr);
 388                 return $path;
 389         }
 390         "$host:$port";
 391 }
 392
 393 sub unpack_ipv6 ($) {
 394         my ($addr) = @_;
 395         my ($port, $host);
 396
 397         # Socket.pm in Perl 5.14+ supports IPv6:
 398         eval {
 399                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 400                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 401         };
 402
 403         if ($@) {
 404                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 405                 # Socket6, so it may be installed on our system, already
 406                 # (otherwise die here):
 407                 require Socket6;
 408
 409                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 410                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 411         }
 412         ($host, $port);
 413 }
 414
 415 sub host_with_port ($) {
 416         my ($addr) = @_;
 417         my ($port, $host);
 418
 419         # this eval will die on Unix sockets:
 420         eval {
 421                 if (length($addr) >= 28) {
 422                         ($host, $port) = unpack_ipv6($addr);
 423                         $host = "[$host]";
 424                 } else {
 425                         ($port, $host) = Socket::sockaddr_in($addr);
 426                         $host = Socket::inet_ntoa($host);
 427                 }
 428         };
 429         $@ ? ('127.0.0.1', 0) : ($host, $port);
 430 }
 431
 432 sub inherit ($) {
 433         my ($listener_names) = @_;
 434         return () if ($ENV{LISTEN_PID} || 0) != $$;
 435         my $fds = $ENV{LISTEN_FDS} or return ();
 436         my $end = $fds + 2; # LISTEN_FDS_START - 1
 437         my @rv = ();
 438         foreach my $fd (3..$end) {
 439                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 440                 if (my $k = sockname($s)) {
 441                         my $prev_was_blocking = $s->blocking(0);
 442                         warn <<"" if $prev_was_blocking;
 443 Inherited socket ($k fd=$fd) is blocking, making it non-blocking.
 444 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 445 processes when multiple service instances start.
 446
 447                         $listener_names->{$k} = $s;
 448                         warn "# inherited $k fd=$fd\n";
 449                         push @rv, $s;
 450                 } else {
 451                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 452                 }
 453         }
 454         @rv
 455 }
 456
 457 sub upgrade { # $_[0] = signal name or number (unused)
 458         if ($reexec_pid) {
 459                 warn "upgrade in-progress: $reexec_pid\n";
 460                 return;
 461         }
 462         if (defined $pid_file) {
 463                 if ($pid_file =~ /\.oldbin\z/) {
 464                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 465                         return;
 466                 }
 467                 unlink_pid_file_safe_ish($$, $pid_file);
 468                 $pid_file .= '.oldbin';
 469                 write_pid($pid_file);
 470         }
 471         my $pid = fork;
 472         unless (defined $pid) {
 473                 warn "fork failed: $!\n";
 474                 return;
 475         }
 476         if ($pid == 0) {
 477                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 478                 $ENV{LISTEN_FDS} = scalar @listeners;
 479                 $ENV{LISTEN_PID} = $$;
 480                 foreach my $s (@listeners) {
 481                         # @listeners are globs with workers, PI::L w/o workers
 482                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 483
 484                         my $fl = fcntl($s, F_GETFD, 0);
 485                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 486                 }
 487                 exec @CMD;
 488                 die "Failed to exec: $!\n";
 489         }
 490         $reexec_pid = $pid;
 491 }
 492
 493 sub kill_workers ($) {
 494         my ($sig) = @_;
 495         kill $sig, keys(%pids);
 496 }
 497
 498 sub upgrade_aborted ($) {
 499         my ($p) = @_;
 500         warn "reexec PID($p) died with: $?\n";
 501         $reexec_pid = undef;
 502         return unless $pid_file;
 503
 504         my $file = $pid_file;
 505         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 506         unlink_pid_file_safe_ish($$, $pid_file);
 507         $pid_file = $file;
 508         eval { write_pid($pid_file) };
 509         warn $@, "\n" if $@;
 510 }
 511
 512 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 513         while (1) {
 514                 my $p = waitpid(-1, WNOHANG) or return;
 515                 if (defined $reexec_pid && $p == $reexec_pid) {
 516                         upgrade_aborted($p);
 517                 } elsif (defined(my $id = delete $pids{$p})) {
 518                         warn "worker[$id] PID($p) died with: $?\n";
 519                 } elsif ($p > 0) {
 520                         warn "unknown PID($p) reaped: $?\n";
 521                 } else {
 522                         return;
 523                 }
 524         }
 525 }
 526
 527 sub unlink_pid_file_safe_ish ($$) {
 528         my ($unlink_pid, $file) = @_;
 529         return unless defined $unlink_pid && $unlink_pid == $$;
 530
 531         open my $fh, '<', $file or return;
 532         local $/ = "\n";
 533         defined(my $read_pid = <$fh>) or return;
 534         chomp $read_pid;
 535         if ($read_pid == $unlink_pid) {
 536                 Net::Server::Daemonize::unlink_pid_file($file);
 537         }
 538 }
 539
 540 sub master_quit ($) {
 541         exit unless @listeners;
 542         @listeners = ();
 543         kill_workers($_[0]);
 544 }
 545
 546 sub master_loop {
 547         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 548         my $set_workers = $worker_processes;
 549         reopen_logs();
 550         my $ignore_winch;
 551         my $sig = {
 552                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 553                 USR2 => \&upgrade,
 554                 QUIT => \&master_quit,
 555                 INT => \&master_quit,
 556                 TERM => \&master_quit,
 557                 WINCH => sub {
 558                         return if $ignore_winch || !@listeners;
 559                         if (-t STDIN || -t STDOUT || -t STDERR) {
 560                                 $ignore_winch = 1;
 561                                 warn <<EOF;
 562 ignoring SIGWINCH since we are not daemonized
 563 EOF
 564                         } else {
 565                                 $worker_processes = 0;
 566                         }
 567                 },
 568                 HUP => sub {
 569                         return unless @listeners;
 570                         $worker_processes = $set_workers;
 571                         kill_workers($_[0]);
 572                 },
 573                 TTIN => sub {
 574                         return unless @listeners;
 575                         if ($set_workers > $worker_processes) {
 576                                 ++$worker_processes;
 577                         } else {
 578                                 $worker_processes = ++$set_workers;
 579                         }
 580                 },
 581                 TTOU => sub {
 582                         $worker_processes = --$set_workers if $set_workers > 0;
 583                 },
 584                 CHLD => \&reap_children,
 585         };
 586         my $sigfd = PublicInbox::Sigfd->new($sig);
 587         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 588         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 589         while (1) { # main loop
 590                 my $n = scalar keys %pids;
 591                 unless (@listeners) {
 592                         exit if $n == 0;
 593                         $set_workers = $worker_processes = $n = 0;
 594                 }
 595
 596                 if ($n > $worker_processes) {
 597                         while (my ($k, $v) = each %pids) {
 598                                 kill('TERM', $k) if $v >= $worker_processes;
 599                         }
 600                         $n = $worker_processes;
 601                 }
 602                 my $want = $worker_processes - 1;
 603                 if ($n <= $want) {
 604                         PublicInbox::DS::block_signals() if !$sigfd;
 605                         for my $i ($n..$want) {
 606                                 my $seed = rand(0xffffffff);
 607                                 my $pid = fork;
 608                                 if (!defined $pid) {
 609                                         warn "failed to fork worker[$i]: $!\n";
 610                                 } elsif ($pid == 0) {
 611                                         srand($seed);
 612                                         eval { Net::SSLeay::randomize() };
 613                                         $set_user->() if $set_user;
 614                                         return $p0; # run normal work code
 615                                 } else {
 616                                         warn "PID=$pid is worker[$i]\n";
 617                                         $pids{$pid} = $i;
 618                                 }
 619                         }
 620                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 621                 }
 622
 623                 if ($sigfd) { # Linux and IO::KQueue users:
 624                         $sigfd->wait_once;
 625                 } else { # wake up every second
 626                         sleep(1);
 627                 }
 628         }
 629         exit # never gets here, just for documentation
 630 }
 631
 632 sub tls_cb {
 633         my ($post_accept, $tlsd) = @_;
 634         sub {
 635                 my ($io, $addr, $srv) = @_;
 636                 $post_accept->(PublicInbox::TLS::start($io, $tlsd), $addr, $srv)
 637         }
 638 }
 639
 640 sub defer_accept ($$) {
 641         my ($s, $af_name) = @_;
 642         return unless defined $af_name;
 643         if ($^O eq 'linux') {
 644                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 645                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 646                 return unless defined $x; # may be Unix socket
 647                 my $sec = unpack('i', $x);
 648                 return if $sec > 0; # systemd users may set a higher value
 649                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 650         } elsif ($^O eq 'freebsd') {
 651                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 652                 return if defined $x; # don't change if set
 653                 my $accf_arg = pack('a16a240', $af_name, '');
 654                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 655         }
 656 }
 657
 658 sub daemon_loop ($) {
 659         my ($xnetd) = @_;
 660         local $PublicInbox::Config::DEDUPE = {}; # enable dedupe cache
 661         my $refresh = sub {
 662                 my ($sig) = @_;
 663                 %$PublicInbox::Config::DEDUPE = (); # clear cache
 664                 for my $xn (values %$xnetd) {
 665                         delete $xn->{tlsd}->{ssl_ctx}; # PublicInbox::TLS::start
 666                         eval { $xn->{refresh}->($sig) };
 667                         warn "refresh $@\n" if $@;
 668                 }
 669         };
 670         my %post_accept;
 671         while (my ($k, $ctx_opt) = each %tls_opt) {
 672                 my $l = $k;
 673                 $l =~ s!\A([^:]+)://!!;
 674                 my $scheme = $1 // '';
 675                 my $xn = $xnetd->{$l} // $xnetd->{''};
 676                 $xn->{tlsd}->{ssl_ctx_opt} //= $ctx_opt;
 677                 $scheme =~ m!\A(?:https|imaps|nntps|pop3s)! and
 678                         $post_accept{$l} = tls_cb(@$xn{qw(post_accept tlsd)});
 679         }
 680         my $sig = {
 681                 HUP => $refresh,
 682                 INT => \&worker_quit,
 683                 QUIT => \&worker_quit,
 684                 TERM => \&worker_quit,
 685                 TTIN => 'IGNORE',
 686                 TTOU => 'IGNORE',
 687                 USR1 => \&reopen_logs,
 688                 USR2 => 'IGNORE',
 689                 WINCH => 'IGNORE',
 690                 CHLD => \&PublicInbox::DS::enqueue_reap,
 691         };
 692         if ($worker_processes > 0) {
 693                 $refresh->(); # preload by default
 694                 my $fh = master_loop(); # returns if in child process
 695                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 696         } else {
 697                 reopen_logs();
 698                 $set_user->() if $set_user;
 699                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 700                 $refresh->();
 701         }
 702         $uid = $gid = undef;
 703         reopen_logs();
 704         @listeners = map {;
 705                 my $l = sockname($_);
 706                 my $tls_cb = $post_accept{$l};
 707                 my $xn = $xnetd->{$l} // $xnetd->{''};
 708
 709                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 710                 # IMAP, NNTP and POP3 are server-first
 711                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 712
 713                 # this calls epoll_create:
 714                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 715         } @listeners;
 716         PublicInbox::DS::event_loop($sig, $oldset);
 717 }
 718
 719 sub run {
 720         my ($default_listen) = @_;
 721         my $xnetd = {};
 722         if ($default_listen) {
 723                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 724                         die "BUG: $default_listen";
 725                 $xnetd->{''} = load_mod($1);
 726         }
 727         daemon_prepare($default_listen, $xnetd);
 728         my $for_destroy = daemonize();
 729
 730         # localize GCF2C for tests:
 731         local $PublicInbox::GitAsyncCat::GCF2C;
 732         local $PublicInbox::Git::async_warn = 1;
 733         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 734
 735         daemon_loop($xnetd);
 736         PublicInbox::DS->Reset;
 737         # ->DESTROY runs when $for_destroy goes out-of-scope
 738 }
 739
 740 sub write_pid ($) {
 741         my ($path) = @_;
 742         Net::Server::Daemonize::create_pid_file($path);
 743         do_chown($path);
 744 }
 745
 746 sub DESTROY {
 747         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 748 }
 749
 750 1;