lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the httpd, imapd, and nntpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle; # ->autoflush
  10 use IO::Socket;
  11 use POSIX qw(WNOHANG :signal_h);
  12 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  13 sub SO_ACCEPTFILTER () { 0x1000 }
  14 use Cwd qw/abs_path/;
  15 STDOUT->autoflush(1);
  16 STDERR->autoflush(1);
  17 use PublicInbox::DS qw(now);
  18 use PublicInbox::Syscall qw($SFD_NONBLOCK);
  19 require PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::GitAsyncCat;
  23 my @CMD;
  24 my ($set_user, $oldset);
  25 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  26 my $worker_processes = 1;
  27 my @listeners;
  28 my %pids;
  29 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  30 my $reexec_pid;
  31 my ($uid, $gid);
  32 my ($default_cert, $default_key);
  33 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps', 993 => 'imaps' );
  34 my %KNOWN_STARTTLS = ( 119 => 'nntp', 143 => 'imap' );
  35
  36 sub accept_tls_opt ($) {
  37         my ($opt_str) = @_;
  38         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  39         require PublicInbox::TLS;
  40         my $o = {};
  41         # allow ',' as delimiter since '&' is shell-unfriendly
  42         foreach (split(/[,&]/, $opt_str)) {
  43                 my ($k, $v) = split(/=/, $_, 2);
  44                 push @{$o->{$k} ||= []}, $v;
  45         }
  46
  47         # key may be a part of cert.  At least
  48         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  49         $o->{cert} //= [ $default_cert ];
  50         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  51         my %ctx_opt = (SSL_server => 1);
  52         # parse out hostname:/path/to/ mappings:
  53         foreach my $k (qw(cert key)) {
  54                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  55                 foreach my $path (@{$o->{$k}}) {
  56                         my $host = '';
  57                         $path =~ s/\A([^:]+):// and $host = $1;
  58                         $x->{$host} = $path;
  59                 }
  60         }
  61         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  62                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  63
  64         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  65         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  66         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  67         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  68         if ($mode && $ctx->{context}) {
  69                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  70                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  71         }
  72
  73         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  74 }
  75
  76 sub daemon_prepare ($) {
  77         my ($default_listen) = @_;
  78         my $listener_names = {}; # sockname => IO::Handle
  79         $oldset = PublicInbox::Sigfd::block_signals();
  80         @CMD = ($0, @ARGV);
  81         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
  82         my $help = <<EOF;
  83 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
  84
  85 options:
  86
  87   -l ADDRESS    address to listen on (default: $default_listen)
  88   --cert=FILE   default SSL/TLS certificate
  89   --key=FILE    default SSL/TLS certificate
  90   -W WORKERS    number of worker processes to spawn (default: 1)
  91
  92 See public-inbox-daemon(8) and $prog(1) man pages for more.
  93 EOF
  94         my %opt = (
  95                 'l|listen=s' => \@cfg_listen,
  96                 '1|stdout=s' => \$stdout,
  97                 '2|stderr=s' => \$stderr,
  98                 'W|worker-processes=i' => \$worker_processes,
  99                 'P|pid-file=s' => \$pid_file,
 100                 'u|user=s' => \$user,
 101                 'g|group=s' => \$group,
 102                 'D|daemonize' => \$daemonize,
 103                 'cert=s' => \$default_cert,
 104                 'key=s' => \$default_key,
 105                 'help|h' => \(my $show_help),
 106         );
 107         GetOptions(%opt) or die $help;
 108         if ($show_help) { print $help; exit 0 };
 109
 110         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 111                 die "--pid-file cannot end with '.oldbin'\n";
 112         }
 113         @listeners = inherit($listener_names);
 114
 115         # allow socket-activation users to set certs once and not
 116         # have to configure each socket:
 117         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 118
 119         # ignore daemonize when inheriting
 120         $daemonize = undef if scalar @listeners;
 121
 122         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 123
 124         foreach my $l (@cfg_listen) {
 125                 my $orig = $l;
 126                 my $scheme = '';
 127                 if ($l =~ s!\A([^:]+)://!!) {
 128                         $scheme = $1;
 129                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 130                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 131                         $scheme = $s if defined $s;
 132                 }
 133                 if ($l =~ s!/?\?(.+)\z!!) {
 134                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 135                 } elsif (defined($default_cert)) {
 136                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 137                 } elsif ($scheme =~ /\A(?:https|imaps|imaps)\z/) {
 138                         die "$orig specified w/o cert=\n";
 139                 }
 140                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 141
 142                 next if $listener_names->{$l}; # already inherited
 143                 my (%o, $sock_pkg);
 144                 if (index($l, '/') == 0) {
 145                         $sock_pkg = 'IO::Socket::UNIX';
 146                         eval "use $sock_pkg";
 147                         die $@ if $@;
 148                         %o = (Type => SOCK_STREAM, Peer => $l);
 149                         if (-S $l) {
 150                                 my $c = $sock_pkg->new(%o);
 151                                 if (!defined($c) && $!{ECONNREFUSED}) {
 152                                         unlink $l or die
 153 "failed to unlink stale socket=$l: $!\n";
 154                                 } # else: let the bind fail
 155                         }
 156                         $o{Local} = delete $o{Peer};
 157                 } else {
 158                         # both work for IPv4, too
 159                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 160                                 $sock_pkg = $_;
 161                                 eval "use $sock_pkg";
 162                                 $@ or last;
 163                         }
 164                         die $@ if $@;
 165                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 166                 }
 167                 $o{Listen} = 1024;
 168                 my $prev = umask 0000;
 169                 my $s = eval { $sock_pkg->new(%o) };
 170                 warn "error binding $l: $! ($@)\n" unless $s;
 171                 umask $prev;
 172                 if ($s) {
 173                         $listener_names->{sockname($s)} = $s;
 174                         $s->blocking(0);
 175                         push @listeners, $s;
 176                 }
 177         }
 178
 179         # cert/key options in @cfg_listen takes precedence when inheriting,
 180         # but map well-known inherited ports if --listen isn't specified
 181         # at all
 182         for my $sockname (@inherited_names) {
 183                 $sockname =~ /:([0-9]+)\z/ or next;
 184                 if (my $scheme = $KNOWN_TLS{$1}) {
 185                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 186                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 187                         next if $tls_opt{"$scheme://$sockname"};
 188                         $tls_opt{''} ||= accept_tls_opt('');
 189                 }
 190         }
 191
 192         die "No listeners bound\n" unless @listeners;
 193 }
 194
 195 sub check_absolute ($$) {
 196         my ($var, $val) = @_;
 197         if (defined $val && index($val, '/') != 0) {
 198                 die
 199 "--$var must be an absolute path when using --daemonize: $val\n";
 200         }
 201 }
 202
 203 sub daemonize () {
 204         if ($daemonize) {
 205                 foreach my $i (0..$#ARGV) {
 206                         my $arg = $ARGV[$i];
 207                         next unless -e $arg;
 208                         $ARGV[$i] = abs_path($arg);
 209                 }
 210                 check_absolute('stdout', $stdout);
 211                 check_absolute('stderr', $stderr);
 212                 check_absolute('pid-file', $pid_file);
 213
 214                 chdir '/' or die "chdir failed: $!";
 215         }
 216         if (defined($pid_file) || defined($group) || defined($user)) {
 217                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 218 Net::Server required for --pid-file, --group, --user
 219 $@
 220 EOF
 221         }
 222         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 223         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 224         if (defined $group) {
 225                 $gid = Net::Server::Daemonize::get_gid($group);
 226                 $gid = (split /\s+/, $gid)[0];
 227         } elsif (defined $uid) {
 228                 $gid = (getpwuid($uid))[3];
 229         }
 230
 231         # We change users in the worker to ensure upgradability,
 232         # The upgrade will create the ".oldbin" pid file in the
 233         # same directory as the given pid file.
 234         $uid and $set_user = sub {
 235                 $set_user = undef;
 236                 Net::Server::Daemonize::set_user($uid, $gid);
 237         };
 238
 239         if ($daemonize) {
 240                 my $pid = fork;
 241                 die "could not fork: $!\n" unless defined $pid;
 242                 exit if $pid;
 243
 244                 open(STDIN, '+<', '/dev/null') or
 245                                         die "redirect stdin failed: $!\n";
 246                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 247                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 248                 POSIX::setsid();
 249                 $pid = fork;
 250                 die "could not fork: $!\n" unless defined $pid;
 251                 exit if $pid;
 252         }
 253         return unless defined $pid_file;
 254
 255         write_pid($pid_file);
 256         # for ->DESTROY:
 257         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 258 }
 259
 260 sub worker_quit { # $_[0] = signal name or number (unused)
 261         # killing again terminates immediately:
 262         exit unless @listeners;
 263
 264         $_->close foreach @listeners; # call PublicInbox::DS::close
 265         @listeners = ();
 266         my $proc_name;
 267         my $warn = 0;
 268         # drop idle connections and try to quit gracefully
 269         PublicInbox::DS->SetPostLoopCallback(sub {
 270                 my ($dmap, undef) = @_;
 271                 my $n = 0;
 272                 my $now = now();
 273
 274                 foreach my $s (values %$dmap) {
 275                         $s->can('busy') or next;
 276                         if ($s->busy($now)) {
 277                                 ++$n;
 278                         } else {
 279                                 # close as much as possible, early as possible
 280                                 $s->close;
 281                         }
 282                 }
 283                 if ($n) {
 284                         if (($warn + 5) < now()) {
 285                                 warn "$$ quitting, $n client(s) left\n";
 286                                 $warn = now();
 287                         }
 288                         unless (defined $proc_name) {
 289                                 $proc_name = (split(/\s+/, $0))[0];
 290                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 291                         }
 292                         $0 = "$proc_name quitting, $n client(s) left";
 293                 }
 294                 $n; # true: loop continues, false: loop breaks
 295         });
 296 }
 297
 298 sub reopen_logs {
 299         if ($stdout) {
 300                 open STDOUT, '>>', $stdout or
 301                         warn "failed to redirect stdout to $stdout: $!\n";
 302                 STDOUT->autoflush(1);
 303                 do_chown($stdout);
 304         }
 305         if ($stderr) {
 306                 open STDERR, '>>', $stderr or
 307                         warn "failed to redirect stderr to $stderr: $!\n";
 308                 STDERR->autoflush(1);
 309                 do_chown($stderr);
 310         }
 311 }
 312
 313 sub sockname ($) {
 314         my ($s) = @_;
 315         my $addr = getsockname($s) or return;
 316         my ($host, $port) = host_with_port($addr);
 317         if ($port == 0 && $host eq '127.0.0.1') {
 318                 my ($path) = Socket::sockaddr_un($addr);
 319                 return $path;
 320         }
 321         "$host:$port";
 322 }
 323
 324 sub unpack_ipv6 ($) {
 325         my ($addr) = @_;
 326         my ($port, $host);
 327
 328         # Socket.pm in Perl 5.14+ supports IPv6:
 329         eval {
 330                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 331                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 332         };
 333
 334         if ($@) {
 335                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 336                 # Socket6, so it may be installed on our system, already
 337                 # (otherwise die here):
 338                 require Socket6;
 339
 340                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 341                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 342         }
 343         ($host, $port);
 344 }
 345
 346 sub host_with_port ($) {
 347         my ($addr) = @_;
 348         my ($port, $host);
 349
 350         # this eval will die on Unix sockets:
 351         eval {
 352                 if (length($addr) >= 28) {
 353                         ($host, $port) = unpack_ipv6($addr);
 354                         $host = "[$host]";
 355                 } else {
 356                         ($port, $host) = Socket::sockaddr_in($addr);
 357                         $host = Socket::inet_ntoa($host);
 358                 }
 359         };
 360         $@ ? ('127.0.0.1', 0) : ($host, $port);
 361 }
 362
 363 sub inherit ($) {
 364         my ($listener_names) = @_;
 365         return () if ($ENV{LISTEN_PID} || 0) != $$;
 366         my $fds = $ENV{LISTEN_FDS} or return ();
 367         my $end = $fds + 2; # LISTEN_FDS_START - 1
 368         my @rv = ();
 369         foreach my $fd (3..$end) {
 370                 my $s = IO::Handle->new_from_fd($fd, 'r');
 371                 if (my $k = sockname($s)) {
 372                         if ($s->blocking) {
 373                                 $s->blocking(0);
 374                                 warn <<"";
 375 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 376 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 377 processes when multiple service instances start.
 378
 379                         }
 380                         $listener_names->{$k} = $s;
 381                         push @rv, $s;
 382                 } else {
 383                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 384                 }
 385         }
 386         @rv
 387 }
 388
 389 sub upgrade { # $_[0] = signal name or number (unused)
 390         if ($reexec_pid) {
 391                 warn "upgrade in-progress: $reexec_pid\n";
 392                 return;
 393         }
 394         if (defined $pid_file) {
 395                 if ($pid_file =~ /\.oldbin\z/) {
 396                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 397                         return;
 398                 }
 399                 unlink_pid_file_safe_ish($$, $pid_file);
 400                 $pid_file .= '.oldbin';
 401                 write_pid($pid_file);
 402         }
 403         my $pid = fork;
 404         unless (defined $pid) {
 405                 warn "fork failed: $!\n";
 406                 return;
 407         }
 408         if ($pid == 0) {
 409                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 410                 $ENV{LISTEN_FDS} = scalar @listeners;
 411                 $ENV{LISTEN_PID} = $$;
 412                 foreach my $s (@listeners) {
 413                         # @listeners are globs with workers, PI::L w/o workers
 414                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 415
 416                         my $fl = fcntl($s, F_GETFD, 0);
 417                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 418                 }
 419                 exec @CMD;
 420                 die "Failed to exec: $!\n";
 421         }
 422         $reexec_pid = $pid;
 423 }
 424
 425 sub kill_workers ($) {
 426         my ($s) = @_;
 427
 428         while (my ($pid, $id) = each %pids) {
 429                 kill $s, $pid;
 430         }
 431 }
 432
 433 sub upgrade_aborted ($) {
 434         my ($p) = @_;
 435         warn "reexec PID($p) died with: $?\n";
 436         $reexec_pid = undef;
 437         return unless $pid_file;
 438
 439         my $file = $pid_file;
 440         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 441         unlink_pid_file_safe_ish($$, $pid_file);
 442         $pid_file = $file;
 443         eval { write_pid($pid_file) };
 444         warn $@, "\n" if $@;
 445 }
 446
 447 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 448         while (1) {
 449                 my $p = waitpid(-1, WNOHANG) or return;
 450                 if (defined $reexec_pid && $p == $reexec_pid) {
 451                         upgrade_aborted($p);
 452                 } elsif (defined(my $id = delete $pids{$p})) {
 453                         warn "worker[$id] PID($p) died with: $?\n";
 454                 } elsif ($p > 0) {
 455                         warn "unknown PID($p) reaped: $?\n";
 456                 } else {
 457                         return;
 458                 }
 459         }
 460 }
 461
 462 sub unlink_pid_file_safe_ish ($$) {
 463         my ($unlink_pid, $file) = @_;
 464         return unless defined $unlink_pid && $unlink_pid == $$;
 465
 466         open my $fh, '<', $file or return;
 467         local $/ = "\n";
 468         defined(my $read_pid = <$fh>) or return;
 469         chomp $read_pid;
 470         if ($read_pid == $unlink_pid) {
 471                 Net::Server::Daemonize::unlink_pid_file($file);
 472         }
 473 }
 474
 475 sub master_quit ($) {
 476         exit unless @listeners;
 477         @listeners = ();
 478         kill_workers($_[0]);
 479 }
 480
 481 sub master_loop {
 482         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 483         my $set_workers = $worker_processes;
 484         reopen_logs();
 485         my $ignore_winch;
 486         my $sig = {
 487                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 488                 USR2 => \&upgrade,
 489                 QUIT => \&master_quit,
 490                 INT => \&master_quit,
 491                 TERM => \&master_quit,
 492                 WINCH => sub {
 493                         return if $ignore_winch || !@listeners;
 494                         if (-t STDIN || -t STDOUT || -t STDERR) {
 495                                 $ignore_winch = 1;
 496                                 warn <<EOF;
 497 ignoring SIGWINCH since we are not daemonized
 498 EOF
 499                         } else {
 500                                 $worker_processes = 0;
 501                         }
 502                 },
 503                 HUP => sub {
 504                         return unless @listeners;
 505                         $worker_processes = $set_workers;
 506                         kill_workers($_[0]);
 507                 },
 508                 TTIN => sub {
 509                         return unless @listeners;
 510                         if ($set_workers > $worker_processes) {
 511                                 ++$worker_processes;
 512                         } else {
 513                                 $worker_processes = ++$set_workers;
 514                         }
 515                 },
 516                 TTOU => sub {
 517                         $worker_processes = --$set_workers if $set_workers > 0;
 518                 },
 519                 CHLD => \&reap_children,
 520         };
 521         my $sigfd = PublicInbox::Sigfd->new($sig, 0);
 522         local %SIG = (%SIG, %$sig) if !$sigfd;
 523         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 524         while (1) { # main loop
 525                 my $n = scalar keys %pids;
 526                 unless (@listeners) {
 527                         exit if $n == 0;
 528                         $set_workers = $worker_processes = $n = 0;
 529                 }
 530
 531                 if ($n > $worker_processes) {
 532                         while (my ($k, $v) = each %pids) {
 533                                 kill('TERM', $k) if $v >= $worker_processes;
 534                         }
 535                         $n = $worker_processes;
 536                 }
 537                 my $want = $worker_processes - 1;
 538                 if ($n <= $want) {
 539                         PublicInbox::Sigfd::block_signals() if !$sigfd;
 540                         for my $i ($n..$want) {
 541                                 my $pid = fork;
 542                                 if (!defined $pid) {
 543                                         warn "failed to fork worker[$i]: $!\n";
 544                                 } elsif ($pid == 0) {
 545                                         $set_user->() if $set_user;
 546                                         return $p0; # run normal work code
 547                                 } else {
 548                                         warn "PID=$pid is worker[$i]\n";
 549                                         $pids{$pid} = $i;
 550                                 }
 551                         }
 552                         PublicInbox::Sigfd::sig_setmask($oldset) if !$sigfd;
 553                 }
 554
 555                 if ($sigfd) { # Linux and IO::KQueue users:
 556                         $sigfd->wait_once;
 557                 } else { # wake up every second
 558                         sleep(1);
 559                 }
 560         }
 561         exit # never gets here, just for documentation
 562 }
 563
 564 sub tls_start_cb ($$) {
 565         my ($opt, $orig_post_accept) = @_;
 566         sub {
 567                 my ($io, $addr, $srv) = @_;
 568                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 569                 $orig_post_accept->($ssl, $addr, $srv);
 570         }
 571 }
 572
 573 sub defer_accept ($$) {
 574         my ($s, $af_name) = @_;
 575         return unless defined $af_name;
 576         if ($^O eq 'linux') {
 577                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 578                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 579                 return unless defined $x; # may be Unix socket
 580                 my $sec = unpack('i', $x);
 581                 return if $sec > 0; # systemd users may set a higher value
 582                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 583         } elsif ($^O eq 'freebsd') {
 584                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 585                 return if defined $x; # don't change if set
 586                 my $accf_arg = pack('a16a240', $af_name, '');
 587                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 588         }
 589 }
 590
 591 sub daemon_loop ($$$$) {
 592         my ($refresh, $post_accept, $tlsd, $af_default) = @_;
 593         my %post_accept;
 594         while (my ($k, $v) = each %tls_opt) {
 595                 if ($k =~ s!\A(?:https|imaps|nntps)://!!) {
 596                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 597                 } elsif ($tlsd) { # STARTTLS, $k eq '' is OK
 598                         $tlsd->{accept_tls} = $v;
 599                 }
 600         }
 601         my $sig = {
 602                 HUP => $refresh,
 603                 INT => \&worker_quit,
 604                 QUIT => \&worker_quit,
 605                 TERM => \&worker_quit,
 606                 TTIN => 'IGNORE',
 607                 TTOU => 'IGNORE',
 608                 USR1 => \&reopen_logs,
 609                 USR2 => 'IGNORE',
 610                 WINCH => 'IGNORE',
 611                 CHLD => \&PublicInbox::DS::enqueue_reap,
 612         };
 613         if ($worker_processes > 0) {
 614                 $refresh->(); # preload by default
 615                 my $fh = master_loop(); # returns if in child process
 616                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 617         } else {
 618                 reopen_logs();
 619                 $set_user->() if $set_user;
 620                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 621                 $refresh->();
 622         }
 623         $uid = $gid = undef;
 624         reopen_logs();
 625         @listeners = map {;
 626                 my $tls_cb = $post_accept{sockname($_)};
 627
 628                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 629                 # IMAP, NNTP and POP3 are server-first
 630                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 631
 632                 # this calls epoll_create:
 633                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 634         } @listeners;
 635         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 636         local %SIG = (%SIG, %$sig) if !$sigfd;
 637         if (!$sigfd) {
 638                 # wake up every second to accept signals if we don't
 639                 # have signalfd or IO::KQueue:
 640                 PublicInbox::Sigfd::sig_setmask($oldset);
 641                 PublicInbox::DS->SetLoopTimeout(1000);
 642         }
 643         PublicInbox::DS->EventLoop;
 644 }
 645
 646 sub run ($$$;$) {
 647         my ($default, $refresh, $post_accept, $tlsd) = @_;
 648         local $SIG{PIPE} = 'IGNORE';
 649         daemon_prepare($default);
 650         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 651         my $for_destroy = daemonize();
 652
 653         # localize GCF2C for tests:
 654         local $PublicInbox::GitAsyncCat::GCF2C;
 655
 656         daemon_loop($refresh, $post_accept, $tlsd, $af_default);
 657         PublicInbox::DS->Reset;
 658         # ->DESTROY runs when $for_destroy goes out-of-scope
 659 }
 660
 661 sub do_chown ($) {
 662         my ($path) = @_;
 663         if (defined $uid and !chown($uid, $gid, $path)) {
 664                 warn "could not chown $path: $!\n";
 665         }
 666 }
 667
 668 sub write_pid ($) {
 669         my ($path) = @_;
 670         Net::Server::Daemonize::create_pid_file($path);
 671         do_chown($path);
 672 }
 673
 674 sub DESTROY {
 675         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 676 }
 677
 678 1;