lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 STDOUT->autoflush(1);
  11 STDERR->autoflush(1);
  12 require Danga::Socket;
  13 require POSIX;
  14 require PublicInbox::Listener;
  15 my @CMD;
  16 my $set_user;
  17 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  18 my $worker_processes = 1;
  19 my @listeners;
  20 my %pids;
  21 my %listener_names;
  22 my $reexec_pid;
  23 my $cleanup;
  24 my ($uid, $gid);
  25 END { $cleanup->() if $cleanup };
  26
  27 sub daemon_prepare ($) {
  28         my ($default_listen) = @_;
  29         @CMD = ($0, @ARGV);
  30         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  31                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  32         my %opts = (
  33                 'l|listen=s' => \@cfg_listen,
  34                 '1|stdout=s' => \$stdout,
  35                 '2|stderr=s' => \$stderr,
  36                 'W|worker-processes=i' => \$worker_processes,
  37                 'P|pid-file=s' => \$pid_file,
  38                 'u|user=s' => \$user,
  39                 'g|group=s' => \$group,
  40                 'D|daemonize' => \$daemonize,
  41         );
  42         GetOptions(%opts) or die "bad command-line args\n";
  43
  44         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  45                 die "--pid-file cannot end with '.oldbin'\n";
  46         }
  47         @listeners = inherit();
  48         # ignore daemonize when inheriting
  49         $daemonize = undef if scalar @listeners;
  50
  51         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  52
  53         foreach my $l (@cfg_listen) {
  54                 next if $listener_names{$l}; # already inherited
  55                 require IO::Socket::INET6; # works for IPv4, too
  56                 my %o = (
  57                         LocalAddr => $l,
  58                         ReuseAddr => 1,
  59                         Proto => 'tcp',
  60                 );
  61                 if (my $s = IO::Socket::INET6->new(%o)) {
  62                         $listener_names{sockname($s)} = $s;
  63                         push @listeners, $s;
  64                 } else {
  65                         warn "error binding $l: $!\n";
  66                 }
  67         }
  68         die "No listeners bound\n" unless @listeners;
  69 }
  70
  71 sub daemonize () {
  72         chdir '/' or die "chdir failed: $!";
  73         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
  74
  75         return unless (defined $pid_file || defined $group || defined $user
  76                         || $daemonize);
  77
  78         require Net::Server::Daemonize;
  79
  80         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
  81         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
  82         if (defined $group) {
  83                 $gid = Net::Server::Daemonize::get_gid($group);
  84                 $gid = (split /\s+/, $gid)[0];
  85         } elsif (defined $uid) {
  86                 $gid = (getpwuid($uid))[3];
  87         }
  88
  89         # We change users in the worker to ensure upgradability,
  90         # The upgrade will create the ".oldbin" pid file in the
  91         # same directory as the given pid file.
  92         $uid and $set_user = sub {
  93                 Net::Server::Daemonize::set_user($uid, $gid);
  94         };
  95
  96         if ($daemonize) {
  97                 my ($pid, $err) = do_fork();
  98                 die "could not fork: $err\n" unless defined $pid;
  99                 exit if $pid;
 100
 101                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 102                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 103                 POSIX::setsid();
 104                 ($pid, $err) = do_fork();
 105                 die "could not fork: $err\n" unless defined $pid;
 106                 exit if $pid;
 107         }
 108         if (defined $pid_file) {
 109                 write_pid($pid_file);
 110                 my $unlink_pid = $$;
 111                 $cleanup = sub {
 112                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 113                 };
 114         }
 115 }
 116
 117 sub worker_quit () {
 118         # killing again terminates immediately:
 119         exit unless @listeners;
 120
 121         @listeners = ();
 122
 123         # give slow clients 30s to finish reading/writing whatever
 124         Danga::Socket->AddTimer(30, sub { exit });
 125
 126         # drop idle connections and try to quit gracefully
 127         Danga::Socket->SetPostLoopCallback(sub {
 128                 my ($dmap, undef) = @_;
 129                 my $n = 0;
 130
 131                 foreach my $s (values %$dmap) {
 132                         if ($s->can('busy') && $s->busy) {
 133                                 $n = 1;
 134                         } else {
 135                                 # close as much as possible, early as possible
 136                                 $s->close;
 137                         }
 138                 }
 139                 $n; # true: loop continues, false: loop breaks
 140         });
 141 }
 142
 143 sub reopen_logs {
 144         if ($stdout) {
 145                 open STDOUT, '>>', $stdout or
 146                         warn "failed to redirect stdout to $stdout: $!\n";
 147                 STDOUT->autoflush(1);
 148                 do_chown($stdout);
 149         }
 150         if ($stderr) {
 151                 open STDERR, '>>', $stderr or
 152                         warn "failed to redirect stderr to $stderr: $!\n";
 153                 STDERR->autoflush(1);
 154                 do_chown($stderr);
 155         }
 156 }
 157
 158 sub sockname ($) {
 159         my ($s) = @_;
 160         my $addr = getsockname($s) or return;
 161         my ($host, $port) = host_with_port($addr);
 162         "$host:$port";
 163 }
 164
 165 sub host_with_port ($) {
 166         my ($addr) = @_;
 167         my ($port, $host);
 168         if (length($addr) >= 28) {
 169                 require Socket6;
 170                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 171                 $host = '['.Socket6::inet_ntop(Socket6::AF_INET6(), $host).']';
 172         } else {
 173                 ($port, $host) = Socket::sockaddr_in($addr);
 174                 $host = Socket::inet_ntoa($host);
 175         }
 176         ($host, $port);
 177 }
 178
 179 sub inherit () {
 180         return () if ($ENV{LISTEN_PID} || 0) != $$;
 181         my $fds = $ENV{LISTEN_FDS} or return ();
 182         my $end = $fds + 2; # LISTEN_FDS_START - 1
 183         my @rv = ();
 184         foreach my $fd (3..$end) {
 185                 my $s = IO::Handle->new;
 186                 $s->fdopen($fd, 'r');
 187                 if (my $k = sockname($s)) {
 188                         $listener_names{$k} = $s;
 189                         push @rv, $s;
 190                 } else {
 191                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 192                 }
 193         }
 194         @rv
 195 }
 196
 197 sub upgrade () {
 198         if ($reexec_pid) {
 199                 warn "upgrade in-progress: $reexec_pid\n";
 200                 return;
 201         }
 202         if (defined $pid_file) {
 203                 if ($pid_file =~ /\.oldbin\z/) {
 204                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 205                         return;
 206                 }
 207                 unlink_pid_file_safe_ish($$, $pid_file);
 208                 $pid_file .= '.oldbin';
 209                 write_pid($pid_file);
 210         }
 211         my ($pid, $err) = do_fork();
 212         unless (defined $pid) {
 213                 warn "fork failed: $err\n";
 214                 return;
 215         }
 216         if ($pid == 0) {
 217                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 218                 $ENV{LISTEN_FDS} = scalar @listeners;
 219                 $ENV{LISTEN_PID} = $$;
 220                 foreach my $s (@listeners) {
 221                         my $fl = fcntl($s, F_GETFD, 0);
 222                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 223                 }
 224                 exec @CMD;
 225                 die "Failed to exec: $!\n";
 226         }
 227         $reexec_pid = $pid;
 228 }
 229
 230 sub kill_workers ($) {
 231         my ($s) = @_;
 232
 233         while (my ($pid, $id) = each %pids) {
 234                 kill $s, $pid;
 235         }
 236 }
 237
 238 sub do_fork () {
 239         my $new = POSIX::SigSet->new;
 240         $new->fillset;
 241         my $old = POSIX::SigSet->new;
 242         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 243         my $pid = fork;
 244         my $err = $!;
 245         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 246         ($pid, $err);
 247 }
 248
 249 sub upgrade_aborted ($) {
 250         my ($p) = @_;
 251         warn "reexec PID($p) died with: $?\n";
 252         $reexec_pid = undef;
 253         return unless $pid_file;
 254
 255         my $file = $pid_file;
 256         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 257         unlink_pid_file_safe_ish($$, $pid_file);
 258         $pid_file = $file;
 259         eval { write_pid($pid_file) };
 260         warn $@, "\n" if $@;
 261 }
 262
 263 sub reap_children () {
 264         while (1) {
 265                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 266                 if (defined $reexec_pid && $p == $reexec_pid) {
 267                         upgrade_aborted($p);
 268                 } elsif (defined(my $id = delete $pids{$p})) {
 269                         warn "worker[$id] PID($p) died with: $?\n";
 270                 } elsif ($p > 0) {
 271                         warn "unknown PID($p) reaped: $?\n";
 272                 } else {
 273                         return;
 274                 }
 275         }
 276 }
 277
 278 sub unlink_pid_file_safe_ish ($$) {
 279         my ($unlink_pid, $file) = @_;
 280         return unless defined $unlink_pid && $unlink_pid == $$;
 281
 282         open my $fh, '<', $file or return;
 283         defined(my $read_pid = <$fh>) or return;
 284         chomp $read_pid;
 285         if ($read_pid == $unlink_pid) {
 286                 Net::Server::Daemonize::unlink_pid_file($file);
 287         }
 288 }
 289
 290 sub master_loop {
 291         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 292         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 293         IO::Handle::blocking($w, 0);
 294         my $set_workers = $worker_processes;
 295         my @caught;
 296         my $master_pid = $$;
 297         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 298                 $SIG{$s} = sub {
 299                         return if $$ != $master_pid;
 300                         push @caught, $s;
 301                         syswrite($w, '.');
 302                 };
 303         }
 304         reopen_logs();
 305         # main loop
 306         while (1) {
 307                 while (my $s = shift @caught) {
 308                         if ($s eq 'USR1') {
 309                                 reopen_logs();
 310                                 kill_workers($s);
 311                         } elsif ($s eq 'USR2') {
 312                                 upgrade();
 313                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 314                                 # drops pipes and causes children to die
 315                                 exit
 316                         } elsif ($s eq 'WINCH') {
 317                                 $worker_processes = 0;
 318                         } elsif ($s eq 'HUP') {
 319                                 $worker_processes = $set_workers;
 320                                 kill_workers($s);
 321                         } elsif ($s eq 'TTIN') {
 322                                 if ($set_workers > $worker_processes) {
 323                                         ++$worker_processes;
 324                                 } else {
 325                                         $worker_processes = ++$set_workers;
 326                                 }
 327                         } elsif ($s eq 'TTOU') {
 328                                 if ($set_workers > 0) {
 329                                         $worker_processes = --$set_workers;
 330                                 }
 331                         } elsif ($s eq 'CHLD') {
 332                                 reap_children();
 333                         }
 334                 }
 335
 336                 my $n = scalar keys %pids;
 337                 if ($n > $worker_processes) {
 338                         while (my ($k, $v) = each %pids) {
 339                                 kill('TERM', $k) if $v >= $worker_processes;
 340                         }
 341                         $n = $worker_processes;
 342                 }
 343                 foreach my $i ($n..($worker_processes - 1)) {
 344                         my ($pid, $err) = do_fork();
 345                         if (!defined $pid) {
 346                                 warn "failed to fork worker[$i]: $err\n";
 347                         } elsif ($pid == 0) {
 348                                 $set_user->() if $set_user;
 349                                 return $p0; # run normal work code
 350                         } else {
 351                                 warn "PID=$pid is worker[$i]\n";
 352                                 $pids{$pid} = $i;
 353                         }
 354                 }
 355                 # just wait on signal events here:
 356                 sysread($r, my $buf, 8);
 357         }
 358         exit # never gets here, just for documentation
 359 }
 360
 361 sub daemon_loop ($$) {
 362         my ($refresh, $post_accept) = @_;
 363         my $parent_pipe;
 364         if ($worker_processes > 0) {
 365                 $refresh->(); # preload by default
 366                 $parent_pipe = master_loop(); # returns if in child process
 367                 my $fd = fileno($parent_pipe);
 368                 Danga::Socket->AddOtherFds($fd => sub { kill('TERM', $$) } );
 369         } else {
 370                 reopen_logs();
 371                 $set_user->() if $set_user;
 372                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 373                 $refresh->();
 374         }
 375         $uid = $gid = undef;
 376         reopen_logs();
 377         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 378         $SIG{USR1} = *reopen_logs;
 379         $SIG{HUP} = $refresh;
 380         # this calls epoll_create:
 381         PublicInbox::Listener->new($_, $post_accept) for @listeners;
 382         Danga::Socket->EventLoop;
 383         $parent_pipe = undef;
 384 }
 385
 386
 387 sub run ($$$) {
 388         my ($default, $refresh, $post_accept) = @_;
 389         daemon_prepare($default);
 390         daemonize();
 391         daemon_loop($refresh, $post_accept);
 392 }
 393
 394 sub do_chown ($) {
 395         my ($path) = @_;
 396         if (defined $uid and !chown($uid, $gid, $path)) {
 397                 warn "could not chown $path: $!\n";
 398         }
 399 }
 400
 401 sub write_pid ($) {
 402         my ($path) = @_;
 403         Net::Server::Daemonize::create_pid_file($path);
 404         do_chown($path);
 405 }
 406
 407 1;